Control/Concurrent.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Control.Concurrent
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable (concurrency)
  10 --
  11 -- A common interface to a collection of useful concurrency
  12 -- abstractions.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module Control.Concurrent (
  17         -- * Concurrent Haskell
  18
  19         -- $conc_intro
  20
  21         -- * Basic concurrency operations
  22
  23         ThreadId,
  24 #ifdef __GLASGOW_HASKELL__
  25         myThreadId,
  26 #endif
  27
  28         forkIO,
  29 #ifdef __GLASGOW_HASKELL__
  30         killThread,
  31         throwTo,
  32 #endif
  33
  34         -- * Scheduling
  35
  36         -- $conc_scheduling
  37         yield,                  -- :: IO ()
  38
  39         -- ** Blocking
  40
  41         -- $blocking
  42
  43 #ifdef __GLASGOW_HASKELL__
  44         -- ** Waiting
  45         threadDelay,            -- :: Int -> IO ()
  46         threadWaitRead,         -- :: Int -> IO ()
  47         threadWaitWrite,        -- :: Int -> IO ()
  48 #endif
  49
  50         -- * Communication abstractions
  51
  52         module Control.Concurrent.MVar,
  53         module Control.Concurrent.Chan,
  54         module Control.Concurrent.QSem,
  55         module Control.Concurrent.QSemN,
  56         module Control.Concurrent.SampleVar,
  57
  58         -- * Merging of streams
  59 #ifndef __HUGS__
  60         mergeIO,                -- :: [a]   -> [a] -> IO [a]
  61         nmergeIO,               -- :: [[a]] -> IO [a]
  62 #endif
  63         -- $merge
  64
  65 #ifdef __GLASGOW_HASKELL__
  66         -- * Bound Threads
  67         -- $boundthreads
  68         rtsSupportsBoundThreads,
  69         forkOS,
  70         isCurrentThreadBound,
  71         runInBoundThread,
  72         runInUnboundThread
  73 #endif
  74
  75         -- * GHC's implementation of concurrency
  76
  77         -- |This section describes features specific to GHC's
  78         -- implementation of Concurrent Haskell.
  79
  80         -- ** Haskell threads and Operating System threads
  81
  82         -- $osthreads
  83
  84         -- ** Terminating the program
  85
  86         -- $termination
  87
  88         -- ** Pre-emption
  89
  90         -- $preemption
  91     ) where
  92
  93 import Prelude
  94
  95 import Control.Exception.Base as Exception
  96
  97 #ifdef __GLASGOW_HASKELL__
  98 import GHC.Exception
  99 import GHC.Conc         ( ThreadId(..), myThreadId, killThread, yield,
 100                           threadDelay, forkIO, childHandler )
 101 import qualified GHC.Conc
 102 import GHC.TopHandler   ( reportStackOverflow, reportError )
 103 import GHC.IOBase       ( IO(..) )
 104 import GHC.IOBase       ( unsafeInterleaveIO )
 105 import GHC.IOBase       ( newIORef, readIORef, writeIORef )
 106 import GHC.Base
 107
 108 import System.Posix.Types ( Fd )
 109 import Foreign.StablePtr
 110 import Foreign.C.Types  ( CInt )
 111 import Control.Monad    ( when )
 112
 113 #ifdef mingw32_HOST_OS
 114 import Foreign.C
 115 import System.IO
 116 import GHC.Handle
 117 #endif
 118 #endif
 119
 120 #ifdef __HUGS__
 121 import Hugs.ConcBase
 122 #endif
 123
 124 import Control.Concurrent.MVar
 125 import Control.Concurrent.Chan
 126 import Control.Concurrent.QSem
 127 import Control.Concurrent.QSemN
 128 import Control.Concurrent.SampleVar
 129
 130 #ifdef __HUGS__
 131 type ThreadId = ()
 132 #endif
 133
 134 {- $conc_intro
 135
 136 The concurrency extension for Haskell is described in the paper
 137 /Concurrent Haskell/
 138 <http://www.haskell.org/ghc/docs/papers/concurrent-haskell.ps.gz>.
 139
 140 Concurrency is \"lightweight\", which means that both thread creation
 141 and context switching overheads are extremely low.  Scheduling of
 142 Haskell threads is done internally in the Haskell runtime system, and
 143 doesn't make use of any operating system-supplied thread packages.
 144
 145 However, if you want to interact with a foreign library that expects your
 146 program to use the operating system-supplied thread package, you can do so
 147 by using 'forkOS' instead of 'forkIO'.
 148
 149 Haskell threads can communicate via 'MVar's, a kind of synchronised
 150 mutable variable (see "Control.Concurrent.MVar").  Several common
 151 concurrency abstractions can be built from 'MVar's, and these are
 152 provided by the "Control.Concurrent" library.
 153 In GHC, threads may also communicate via exceptions.
 154 -}
 155
 156 {- $conc_scheduling
 157
 158     Scheduling may be either pre-emptive or co-operative,
 159     depending on the implementation of Concurrent Haskell (see below
 160     for information related to specific compilers).  In a co-operative
 161     system, context switches only occur when you use one of the
 162     primitives defined in this module.  This means that programs such
 163     as:
 164
 165
 166 >   main = forkIO (write 'a') >> write 'b'
 167 >     where write c = putChar c >> write c
 168
 169     will print either @aaaaaaaaaaaaaa...@ or @bbbbbbbbbbbb...@,
 170     instead of some random interleaving of @a@s and @b@s.  In
 171     practice, cooperative multitasking is sufficient for writing
 172     simple graphical user interfaces.
 173 -}
 174
 175 {- $blocking
 176 Different Haskell implementations have different characteristics with
 177 regard to which operations block /all/ threads.
 178
 179 Using GHC without the @-threaded@ option, all foreign calls will block
 180 all other Haskell threads in the system, although I\/O operations will
 181 not.  With the @-threaded@ option, only foreign calls with the @unsafe@
 182 attribute will block all other threads.
 183
 184 Using Hugs, all I\/O operations and foreign calls will block all other
 185 Haskell threads.
 186 -}
 187
 188 #ifndef __HUGS__
 189 max_buff_size :: Int
 190 max_buff_size = 1
 191
 192 mergeIO :: [a] -> [a] -> IO [a]
 193 nmergeIO :: [[a]] -> IO [a]
 194
 195 -- $merge
 196 -- The 'mergeIO' and 'nmergeIO' functions fork one thread for each
 197 -- input list that concurrently evaluates that list; the results are
 198 -- merged into a single output list.
 199 --
 200 -- Note: Hugs does not provide these functions, since they require
 201 -- preemptive multitasking.
 202
 203 mergeIO ls rs
 204  = newEmptyMVar                >>= \ tail_node ->
 205    newMVar tail_node           >>= \ tail_list ->
 206    newQSem max_buff_size       >>= \ e ->
 207    newMVar 2                   >>= \ branches_running ->
 208    let
 209     buff = (tail_list,e)
 210    in
 211     forkIO (suckIO branches_running buff ls) >>
 212     forkIO (suckIO branches_running buff rs) >>
 213     takeMVar tail_node  >>= \ val ->
 214     signalQSem e        >>
 215     return val
 216
 217 type Buffer a
 218  = (MVar (MVar [a]), QSem)
 219
 220 suckIO :: MVar Int -> Buffer a -> [a] -> IO ()
 221
 222 suckIO branches_running buff@(tail_list,e) vs
 223  = case vs of
 224         [] -> takeMVar branches_running >>= \ val ->
 225               if val == 1 then
 226                  takeMVar tail_list     >>= \ node ->
 227                  putMVar node []        >>
 228                  putMVar tail_list node
 229               else
 230                  putMVar branches_running (val-1)
 231         (x:xs) ->
 232                 waitQSem e                       >>
 233                 takeMVar tail_list               >>= \ node ->
 234                 newEmptyMVar                     >>= \ next_node ->
 235                 unsafeInterleaveIO (
 236                         takeMVar next_node  >>= \ y ->
 237                         signalQSem e        >>
 238                         return y)                >>= \ next_node_val ->
 239                 putMVar node (x:next_node_val)   >>
 240                 putMVar tail_list next_node      >>
 241                 suckIO branches_running buff xs
 242
 243 nmergeIO lss
 244  = let
 245     len = length lss
 246    in
 247     newEmptyMVar          >>= \ tail_node ->
 248     newMVar tail_node     >>= \ tail_list ->
 249     newQSem max_buff_size >>= \ e ->
 250     newMVar len           >>= \ branches_running ->
 251     let
 252      buff = (tail_list,e)
 253     in
 254     mapIO (\ x -> forkIO (suckIO branches_running buff x)) lss >>
 255     takeMVar tail_node  >>= \ val ->
 256     signalQSem e        >>
 257     return val
 258   where
 259     mapIO f xs = sequence (map f xs)
 260 #endif /* __HUGS__ */
 261
 262 #ifdef __GLASGOW_HASKELL__
 263 -- ---------------------------------------------------------------------------
 264 -- Bound Threads
 265
 266 {- $boundthreads
 267    #boundthreads#
 268
 269 Support for multiple operating system threads and bound threads as described
 270 below is currently only available in the GHC runtime system if you use the
 271 /-threaded/ option when linking.
 272
 273 Other Haskell systems do not currently support multiple operating system threads.
 274
 275 A bound thread is a haskell thread that is /bound/ to an operating system
 276 thread. While the bound thread is still scheduled by the Haskell run-time
 277 system, the operating system thread takes care of all the foreign calls made
 278 by the bound thread.
 279
 280 To a foreign library, the bound thread will look exactly like an ordinary
 281 operating system thread created using OS functions like @pthread_create@
 282 or @CreateThread@.
 283
 284 Bound threads can be created using the 'forkOS' function below. All foreign
 285 exported functions are run in a bound thread (bound to the OS thread that
 286 called the function). Also, the @main@ action of every Haskell program is
 287 run in a bound thread.
 288
 289 Why do we need this? Because if a foreign library is called from a thread
 290 created using 'forkIO', it won't have access to any /thread-local state/ -
 291 state variables that have specific values for each OS thread
 292 (see POSIX's @pthread_key_create@ or Win32's @TlsAlloc@). Therefore, some
 293 libraries (OpenGL, for example) will not work from a thread created using
 294 'forkIO'. They work fine in threads created using 'forkOS' or when called
 295 from @main@ or from a @foreign export@.
 296
 297 In terms of performance, 'forkOS' (aka bound) threads are much more
 298 expensive than 'forkIO' (aka unbound) threads, because a 'forkOS'
 299 thread is tied to a particular OS thread, whereas a 'forkIO' thread
 300 can be run by any OS thread.  Context-switching between a 'forkOS'
 301 thread and a 'forkIO' thread is many times more expensive than between
 302 two 'forkIO' threads.
 303
 304 Note in particular that the main program thread (the thread running
 305 @Main.main@) is always a bound thread, so for good concurrency
 306 performance you should ensure that the main thread is not doing
 307 repeated communication with other threads in the system.  Typically
 308 this means forking subthreads to do the work using 'forkIO', and
 309 waiting for the results in the main thread.
 310
 311 -}
 312
 313 -- | 'True' if bound threads are supported.
 314 -- If @rtsSupportsBoundThreads@ is 'False', 'isCurrentThreadBound'
 315 -- will always return 'False' and both 'forkOS' and 'runInBoundThread' will
 316 -- fail.
 317 foreign import ccall rtsSupportsBoundThreads :: Bool
 318
 319
 320 {- |
 321 Like 'forkIO', this sparks off a new thread to run the 'IO'
 322 computation passed as the first argument, and returns the 'ThreadId'
 323 of the newly created thread.
 324
 325 However, 'forkOS' creates a /bound/ thread, which is necessary if you
 326 need to call foreign (non-Haskell) libraries that make use of
 327 thread-local state, such as OpenGL (see "Control.Concurrent#boundthreads").
 328
 329 Using 'forkOS' instead of 'forkIO' makes no difference at all to the
 330 scheduling behaviour of the Haskell runtime system.  It is a common
 331 misconception that you need to use 'forkOS' instead of 'forkIO' to
 332 avoid blocking all the Haskell threads when making a foreign call;
 333 this isn't the case.  To allow foreign calls to be made without
 334 blocking all the Haskell threads (with GHC), it is only necessary to
 335 use the @-threaded@ option when linking your program, and to make sure
 336 the foreign import is not marked @unsafe@.
 337 -}
 338
 339 forkOS :: IO () -> IO ThreadId
 340
 341 foreign export ccall forkOS_entry
 342     :: StablePtr (IO ()) -> IO ()
 343
 344 foreign import ccall "forkOS_entry" forkOS_entry_reimported
 345     :: StablePtr (IO ()) -> IO ()
 346
 347 forkOS_entry stableAction = do
 348         action <- deRefStablePtr stableAction
 349         action
 350
 351 foreign import ccall forkOS_createThread
 352     :: StablePtr (IO ()) -> IO CInt
 353
 354 failNonThreaded = fail $ "RTS doesn't support multiple OS threads "
 355                        ++"(use ghc -threaded when linking)"
 356
 357 forkOS action0
 358     | rtsSupportsBoundThreads = do
 359         mv <- newEmptyMVar
 360         b <- Exception.blocked
 361         let
 362             -- async exceptions are blocked in the child if they are blocked
 363             -- in the parent, as for forkIO (see #1048). forkOS_createThread
 364             -- creates a thread with exceptions blocked by default.
 365             action1 | b = action0
 366                     | otherwise = unblock action0
 367
 368             action_plus = Exception.catch action1 childHandler
 369
 370         entry <- newStablePtr (myThreadId >>= putMVar mv >> action_plus)
 371         err <- forkOS_createThread entry
 372         when (err /= 0) $ fail "Cannot create OS thread."
 373         tid <- takeMVar mv
 374         freeStablePtr entry
 375         return tid
 376     | otherwise = failNonThreaded
 377
 378 -- | Returns 'True' if the calling thread is /bound/, that is, if it is
 379 -- safe to use foreign libraries that rely on thread-local state from the
 380 -- calling thread.
 381 isCurrentThreadBound :: IO Bool
 382 isCurrentThreadBound = IO $ \ s# ->
 383     case isCurrentThreadBound# s# of
 384         (# s2#, flg #) -> (# s2#, not (flg ==# 0#) #)
 385
 386
 387 {- |
 388 Run the 'IO' computation passed as the first argument. If the calling thread
 389 is not /bound/, a bound thread is created temporarily. @runInBoundThread@
 390 doesn't finish until the 'IO' computation finishes.
 391
 392 You can wrap a series of foreign function calls that rely on thread-local state
 393 with @runInBoundThread@ so that you can use them without knowing whether the
 394 current thread is /bound/.
 395 -}
 396 runInBoundThread :: IO a -> IO a
 397
 398 runInBoundThread action
 399     | rtsSupportsBoundThreads = do
 400         bound <- isCurrentThreadBound
 401         if bound
 402             then action
 403             else do
 404                 ref <- newIORef undefined
 405                 let action_plus = Exception.try action >>= writeIORef ref
 406                 resultOrException <-
 407                     bracket (newStablePtr action_plus)
 408                             freeStablePtr
 409                             (\cEntry -> forkOS_entry_reimported cEntry >> readIORef ref)
 410                 case resultOrException of
 411                     Left exception -> Exception.throw (exception :: SomeException)
 412                     Right result -> return result
 413     | otherwise = failNonThreaded
 414
 415 {- |
 416 Run the 'IO' computation passed as the first argument. If the calling thread
 417 is /bound/, an unbound thread is created temporarily using 'forkIO'.
 418 @runInBoundThread@ doesn't finish until the 'IO' computation finishes.
 419
 420 Use this function /only/ in the rare case that you have actually observed a
 421 performance loss due to the use of bound threads. A program that
 422 doesn't need it's main thread to be bound and makes /heavy/ use of concurrency
 423 (e.g. a web server), might want to wrap it's @main@ action in
 424 @runInUnboundThread@.
 425 -}
 426 runInUnboundThread :: IO a -> IO a
 427
 428 runInUnboundThread action = do
 429     bound <- isCurrentThreadBound
 430     if bound
 431         then do
 432             mv <- newEmptyMVar
 433             forkIO (Exception.try action >>= putMVar mv)
 434             takeMVar mv >>= \either -> case either of
 435                 Left exception -> Exception.throw (exception :: SomeException)
 436                 Right result -> return result
 437         else action
 438
 439 #endif /* __GLASGOW_HASKELL__ */
 440
 441 #ifdef __GLASGOW_HASKELL__
 442 -- ---------------------------------------------------------------------------
 443 -- threadWaitRead/threadWaitWrite
 444
 445 -- | Block the current thread until data is available to read on the
 446 -- given file descriptor (GHC only).
 447 threadWaitRead :: Fd -> IO ()
 448 threadWaitRead fd
 449 #ifdef mingw32_HOST_OS
 450   -- we have no IO manager implementing threadWaitRead on Windows.
 451   -- fdReady does the right thing, but we have to call it in a
 452   -- separate thread, otherwise threadWaitRead won't be interruptible,
 453   -- and this only works with -threaded.
 454   | threaded  = withThread (waitFd fd 0)
 455   | otherwise = case fd of
 456                   0 -> do hWaitForInput stdin (-1); return ()
 457                         -- hWaitForInput does work properly, but we can only
 458                         -- do this for stdin since we know its FD.
 459                   _ -> error "threadWaitRead requires -threaded on Windows, or use System.IO.hWaitForInput"
 460 #else
 461   = GHC.Conc.threadWaitRead fd
 462 #endif
 463
 464 -- | Block the current thread until data can be written to the
 465 -- given file descriptor (GHC only).
 466 threadWaitWrite :: Fd -> IO ()
 467 threadWaitWrite fd
 468 #ifdef mingw32_HOST_OS
 469   | threaded  = withThread (waitFd fd 1)
 470   | otherwise = error "threadWaitWrite requires -threaded on Windows"
 471 #else
 472   = GHC.Conc.threadWaitWrite fd
 473 #endif
 474
 475 #ifdef mingw32_HOST_OS
 476 foreign import ccall unsafe "rtsSupportsBoundThreads" threaded :: Bool
 477
 478 withThread :: IO a -> IO a
 479 withThread io = do
 480   m <- newEmptyMVar
 481   forkIO $ try io >>= putMVar m
 482   x <- takeMVar m
 483   case x of
 484     Right a -> return a
 485     Left e  -> throwIO (e :: IOException)
 486
 487 waitFd :: Fd -> CInt -> IO ()
 488 waitFd fd write = do
 489    throwErrnoIfMinus1 "fdReady" $
 490         fdReady (fromIntegral fd) write (fromIntegral iNFINITE) 0
 491    return ()
 492
 493 iNFINITE = 0xFFFFFFFF :: CInt -- urgh
 494
 495 foreign import ccall safe "fdReady"
 496   fdReady :: CInt -> CInt -> CInt -> CInt -> IO CInt
 497 #endif
 498
 499 -- ---------------------------------------------------------------------------
 500 -- More docs
 501
 502 {- $osthreads
 503
 504       #osthreads# In GHC, threads created by 'forkIO' are lightweight threads, and
 505       are managed entirely by the GHC runtime.  Typically Haskell
 506       threads are an order of magnitude or two more efficient (in
 507       terms of both time and space) than operating system threads.
 508
 509       The downside of having lightweight threads is that only one can
 510       run at a time, so if one thread blocks in a foreign call, for
 511       example, the other threads cannot continue.  The GHC runtime
 512       works around this by making use of full OS threads where
 513       necessary.  When the program is built with the @-threaded@
 514       option (to link against the multithreaded version of the
 515       runtime), a thread making a @safe@ foreign call will not block
 516       the other threads in the system; another OS thread will take
 517       over running Haskell threads until the original call returns.
 518       The runtime maintains a pool of these /worker/ threads so that
 519       multiple Haskell threads can be involved in external calls
 520       simultaneously.
 521
 522       The "System.IO" library manages multiplexing in its own way.  On
 523       Windows systems it uses @safe@ foreign calls to ensure that
 524       threads doing I\/O operations don't block the whole runtime,
 525       whereas on Unix systems all the currently blocked I\/O reqwests
 526       are managed by a single thread (the /IO manager thread/) using
 527       @select@.
 528
 529       The runtime will run a Haskell thread using any of the available
 530       worker OS threads.  If you need control over which particular OS
 531       thread is used to run a given Haskell thread, perhaps because
 532       you need to call a foreign library that uses OS-thread-local
 533       state, then you need bound threads (see "Control.Concurrent#boundthreads").
 534
 535       If you don't use the @-threaded@ option, then the runtime does
 536       not make use of multiple OS threads.  Foreign calls will block
 537       all other running Haskell threads until the call returns.  The
 538       "System.IO" library still does multiplexing, so there can be multiple
 539       threads doing I\/O, and this is handled internally by the runtime using
 540       @select@.
 541 -}
 542
 543 {- $termination
 544
 545       In a standalone GHC program, only the main thread is
 546       required to terminate in order for the process to terminate.
 547       Thus all other forked threads will simply terminate at the same
 548       time as the main thread (the terminology for this kind of
 549       behaviour is \"daemonic threads\").
 550
 551       If you want the program to wait for child threads to
 552       finish before exiting, you need to program this yourself.  A
 553       simple mechanism is to have each child thread write to an
 554       'MVar' when it completes, and have the main
 555       thread wait on all the 'MVar's before
 556       exiting:
 557
 558 >   myForkIO :: IO () -> IO (MVar ())
 559 >   myForkIO io = do
 560 >     mvar <- newEmptyMVar
 561 >     forkIO (io `finally` putMVar mvar ())
 562 >     return mvar
 563
 564       Note that we use 'finally' from the
 565       "Control.Exception" module to make sure that the
 566       'MVar' is written to even if the thread dies or
 567       is killed for some reason.
 568
 569       A better method is to keep a global list of all child
 570       threads which we should wait for at the end of the program:
 571
 572 >    children :: MVar [MVar ()]
 573 >    children = unsafePerformIO (newMVar [])
 574 >
 575 >    waitForChildren :: IO ()
 576 >    waitForChildren = do
 577 >      cs <- takeMVar children
 578 >      case cs of
 579 >        []   -> return ()
 580 >        m:ms -> do
 581 >           putMVar children ms
 582 >           takeMVar m
 583 >           waitForChildren
 584 >
 585 >    forkChild :: IO () -> IO ThreadId
 586 >    forkChild io = do
 587 >        mvar <- newEmptyMVar
 588 >        childs <- takeMVar children
 589 >        putMVar children (mvar:childs)
 590 >        forkIO (io `finally` putMVar mvar ())
 591 >
 592 >     main =
 593 >       later waitForChildren $
 594 >       ...
 595
 596       The main thread principle also applies to calls to Haskell from
 597       outside, using @foreign export@.  When the @foreign export@ed
 598       function is invoked, it starts a new main thread, and it returns
 599       when this main thread terminates.  If the call causes new
 600       threads to be forked, they may remain in the system after the
 601       @foreign export@ed function has returned.
 602 -}
 603
 604 {- $preemption
 605
 606       GHC implements pre-emptive multitasking: the execution of
 607       threads are interleaved in a random fashion.  More specifically,
 608       a thread may be pre-empted whenever it allocates some memory,
 609       which unfortunately means that tight loops which do no
 610       allocation tend to lock out other threads (this only seems to
 611       happen with pathological benchmark-style code, however).
 612
 613       The rescheduling timer runs on a 20ms granularity by
 614       default, but this may be altered using the
 615       @-i\<n\>@ RTS option.  After a rescheduling
 616       \"tick\" the running thread is pre-empted as soon as
 617       possible.
 618
 619       One final note: the
 620       @aaaa@ @bbbb@ example may not
 621       work too well on GHC (see Scheduling, above), due
 622       to the locking on a 'System.IO.Handle'.  Only one thread
 623       may hold the lock on a 'System.IO.Handle' at any one
 624       time, so if a reschedule happens while a thread is holding the
 625       lock, the other thread won't be able to run.  The upshot is that
 626       the switch from @aaaa@ to
 627       @bbbbb@ happens infrequently.  It can be
 628       improved by lowering the reschedule tick period.  We also have a
 629       patch that causes a reschedule whenever a thread waiting on a
 630       lock is woken up, but haven't found it to be useful for anything
 631       other than this example :-)
 632 -}
 633 #endif /* __GLASGOW_HASKELL__ */