Control/Exception.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  Control.Exception
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable
  10 --
  11 -- This module provides support for raising and catching both built-in
  12 -- and user-defined exceptions.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module Control.Exception (
  17
  18         -- * The Exception type
  19         Exception(..),          -- instance Eq, Ord, Show, Typeable
  20         IOException,            -- instance Eq, Ord, Show, Typeable
  21         ArithException(..),     -- instance Eq, Ord, Show, Typeable
  22         ArrayException(..),     -- instance Eq, Ord, Show, Typeable
  23         AsyncException(..),     -- instance Eq, Ord, Show, Typeable
  24
  25         -- * Throwing exceptions
  26         throwIO,        -- :: Exception -> IO a
  27         throw,          -- :: Exception -> a
  28         ioError,        -- :: IOError -> IO a
  29 #ifdef __GLASGOW_HASKELL__
  30         throwTo,        -- :: ThreadId -> Exception -> a
  31 #endif
  32
  33         -- * Catching Exceptions
  34
  35         -- |There are several functions for catching and examining
  36         -- exceptions; all of them may only be used from within the
  37         -- 'IO' monad.
  38
  39         -- ** The @catch@ functions
  40         catch,     -- :: IO a -> (Exception -> IO a) -> IO a
  41         catchJust, -- :: (Exception -> Maybe b) -> IO a -> (b -> IO a) -> IO a
  42
  43         -- ** The @handle@ functions
  44         handle,    -- :: (Exception -> IO a) -> IO a -> IO a
  45         handleJust,-- :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
  46
  47         -- ** The @try@ functions
  48         try,       -- :: IO a -> IO (Either Exception a)
  49         tryJust,   -- :: (Exception -> Maybe b) -> a    -> IO (Either b a)
  50
  51         -- ** The @evaluate@ function
  52         evaluate,  -- :: a -> IO a
  53
  54         -- ** The @mapException@ function
  55         mapException,           -- :: (Exception -> Exception) -> a -> a
  56
  57         -- ** Exception predicates
  58
  59         -- $preds
  60
  61         ioErrors,               -- :: Exception -> Maybe IOError
  62         arithExceptions,        -- :: Exception -> Maybe ArithException
  63         errorCalls,             -- :: Exception -> Maybe String
  64         dynExceptions,          -- :: Exception -> Maybe Dynamic
  65         assertions,             -- :: Exception -> Maybe String
  66         asyncExceptions,        -- :: Exception -> Maybe AsyncException
  67         userErrors,             -- :: Exception -> Maybe String
  68
  69         -- * Dynamic exceptions
  70
  71         -- $dynamic
  72         throwDyn,       -- :: Typeable ex => ex -> b
  73 #ifdef __GLASGOW_HASKELL__
  74         throwDynTo,     -- :: Typeable ex => ThreadId -> ex -> b
  75 #endif
  76         catchDyn,       -- :: Typeable ex => IO a -> (ex -> IO a) -> IO a
  77
  78         -- * Asynchronous Exceptions
  79
  80         -- $async
  81
  82         -- ** Asynchronous exception control
  83
  84         -- |The following two functions allow a thread to control delivery of
  85         -- asynchronous exceptions during a critical region.
  86
  87         block,          -- :: IO a -> IO a
  88         unblock,        -- :: IO a -> IO a
  89
  90         -- *** Applying @block@ to an exception handler
  91
  92         -- $block_handler
  93
  94         -- *** Interruptible operations
  95
  96         -- $interruptible
  97
  98         -- * Assertions
  99
 100         assert,         -- :: Bool -> a -> a
 101
 102         -- * Utilities
 103
 104         bracket,        -- :: IO a -> (a -> IO b) -> (a -> IO c) -> IO ()
 105         bracket_,       -- :: IO a -> IO b -> IO c -> IO ()
 106
 107         finally,        -- :: IO a -> IO b -> IO a
 108
 109 #ifdef __GLASGOW_HASKELL__
 110         setUncaughtExceptionHandler,      -- :: (Exception -> IO ()) -> IO ()
 111         getUncaughtExceptionHandler       -- :: IO (Exception -> IO ())
 112 #endif
 113   ) where
 114
 115 #ifdef __GLASGOW_HASKELL__
 116 import GHC.Base         ( assert )
 117 import GHC.Exception    as ExceptionBase hiding (catch)
 118 import GHC.Conc         ( throwTo, ThreadId )
 119 import Data.IORef       ( IORef, newIORef, readIORef, writeIORef )
 120 import Foreign.C.String ( CString, withCStringLen )
 121 import System.IO        ( stdout, hFlush )
 122 #endif
 123
 124 #ifdef __HUGS__
 125 import Hugs.Exception   as ExceptionBase
 126 #endif
 127
 128 import Prelude          hiding ( catch )
 129 import System.IO.Error  hiding ( catch, try )
 130 import System.IO.Unsafe (unsafePerformIO)
 131 import Data.Dynamic
 132
 133 #include "Typeable.h"
 134 INSTANCE_TYPEABLE0(Exception,exceptionTc,"Exception")
 135 INSTANCE_TYPEABLE0(IOException,ioExceptionTc,"IOException")
 136 INSTANCE_TYPEABLE0(ArithException,arithExceptionTc,"ArithException")
 137 INSTANCE_TYPEABLE0(ArrayException,arrayExceptionTc,"ArrayException")
 138 INSTANCE_TYPEABLE0(AsyncException,asyncExceptionTc,"AsyncException")
 139
 140 -----------------------------------------------------------------------------
 141 -- Catching exceptions
 142
 143 -- |This is the simplest of the exception-catching functions.  It
 144 -- takes a single argument, runs it, and if an exception is raised
 145 -- the \"handler\" is executed, with the value of the exception passed as an
 146 -- argument.  Otherwise, the result is returned as normal.  For example:
 147 --
 148 -- >   catch (openFile f ReadMode)
 149 -- >       (\e -> hPutStr stderr (\"Couldn\'t open \"++f++\": \" ++ show e))
 150 --
 151 -- For catching exceptions in pure (non-'IO') expressions, see the
 152 -- function 'evaluate'.
 153 --
 154 -- Note that due to Haskell\'s unspecified evaluation order, an
 155 -- expression may return one of several possible exceptions: consider
 156 -- the expression @error \"urk\" + 1 \`div\` 0@.  Does
 157 -- 'catch' execute the handler passing
 158 -- @ErrorCall \"urk\"@, or @ArithError DivideByZero@?
 159 --
 160 -- The answer is \"either\": 'catch' makes a
 161 -- non-deterministic choice about which exception to catch.  If you
 162 -- call it again, you might get a different exception back.  This is
 163 -- ok, because 'catch' is an 'IO' computation.
 164 --
 165 -- Note that 'catch' catches all types of exceptions, and is generally
 166 -- used for \"cleaning up\" before passing on the exception using
 167 -- 'throwIO'.  It is not good practice to discard the exception and
 168 -- continue, without first checking the type of the exception (it
 169 -- might be a 'ThreadKilled', for example).  In this case it is usually better
 170 -- to use 'catchJust' and select the kinds of exceptions to catch.
 171 --
 172 -- Also note that The "Prelude" also exports a
 173 -- function called 'catch' which has the same type as
 174 -- 'Control.Exception.catch', the difference being that the
 175 -- "Prelude" version only catches the IO and user
 176 -- families of exceptions (as required by Haskell 98).  We recommend
 177 -- either hiding the "Prelude" version of
 178 -- 'catch' when importing
 179 -- "Control.Exception", or importing
 180 -- "Control.Exception" qualified, to avoid name-clashes.
 181
 182 catch   :: IO a                 -- ^ The computation to run
 183         -> (Exception -> IO a)  -- ^ Handler to invoke if an exception is raised
 184         -> IO a
 185 catch =  ExceptionBase.catchException
 186
 187 -- | The function 'catchJust' is like 'catch', but it takes an extra
 188 -- argument which is an /exception predicate/, a function which
 189 -- selects which type of exceptions we\'re interested in.  There are
 190 -- some predefined exception predicates for useful subsets of
 191 -- exceptions: 'ioErrors', 'arithExceptions', and so on.  For example,
 192 -- to catch just calls to the 'error' function, we could use
 193 --
 194 -- >   result <- catchJust errorCalls thing_to_try handler
 195 --
 196 -- Any other exceptions which are not matched by the predicate
 197 -- are re-raised, and may be caught by an enclosing
 198 -- 'catch' or 'catchJust'.
 199 catchJust
 200         :: (Exception -> Maybe b) -- ^ Predicate to select exceptions
 201         -> IO a                   -- ^ Computation to run
 202         -> (b -> IO a)            -- ^ Handler
 203         -> IO a
 204 catchJust p a handler = catch a handler'
 205   where handler' e = case p e of
 206                         Nothing -> throw e
 207                         Just b  -> handler b
 208
 209 -- | A version of 'catch' with the arguments swapped around; useful in
 210 -- situations where the code for the handler is shorter.  For example:
 211 --
 212 -- >   do handle (\e -> exitWith (ExitFailure 1)) $
 213 -- >      ...
 214 handle     :: (Exception -> IO a) -> IO a -> IO a
 215 handle     =  flip catch
 216
 217 -- | A version of 'catchJust' with the arguments swapped around (see
 218 -- 'handle').
 219 handleJust :: (Exception -> Maybe b) -> (b -> IO a) -> IO a -> IO a
 220 handleJust p =  flip (catchJust p)
 221
 222 -----------------------------------------------------------------------------
 223 -- 'mapException'
 224
 225 -- | This function maps one exception into another as proposed in the
 226 -- paper \"A semantics for imprecise exceptions\".
 227
 228 -- Notice that the usage of 'unsafePerformIO' is safe here.
 229
 230 mapException :: (Exception -> Exception) -> a -> a
 231 mapException f v = unsafePerformIO (catch (evaluate v)
 232                                           (\x -> throw (f x)))
 233
 234 -----------------------------------------------------------------------------
 235 -- 'try' and variations.
 236
 237 -- | Similar to 'catch', but returns an 'Either' result which is
 238 -- @(Right a)@ if no exception was raised, or @(Left e)@ if an
 239 -- exception was raised and its value is @e@.
 240 --
 241 -- >  try a = catch (Right \`liftM\` a) (return . Left)
 242 --
 243 -- Note: as with 'catch', it is only polite to use this variant if you intend
 244 -- to re-throw the exception after performing whatever cleanup is needed.
 245 -- Otherwise, 'tryJust' is generally considered to be better.
 246 --
 247 try :: IO a -> IO (Either Exception a)
 248 try a = catch (a >>= \ v -> return (Right v)) (\e -> return (Left e))
 249
 250 -- | A variant of 'try' that takes an exception predicate to select
 251 -- which exceptions are caught (c.f. 'catchJust').  If the exception
 252 -- does not match the predicate, it is re-thrown.
 253 tryJust :: (Exception -> Maybe b) -> IO a -> IO (Either b a)
 254 tryJust p a = do
 255   r <- try a
 256   case r of
 257         Right v -> return (Right v)
 258         Left  e -> case p e of
 259                         Nothing -> throw e
 260                         Just b  -> return (Left b)
 261
 262 -----------------------------------------------------------------------------
 263 -- Dynamic exceptions
 264
 265 -- $dynamic
 266 --  #DynamicExceptions# Because the 'Exception' datatype is not extensible, there is an
 267 -- interface for throwing and catching exceptions of type 'Dynamic'
 268 -- (see "Data.Dynamic") which allows exception values of any type in
 269 -- the 'Typeable' class to be thrown and caught.
 270
 271 -- | Raise any value as an exception, provided it is in the
 272 -- 'Typeable' class.
 273 throwDyn :: Typeable exception => exception -> b
 274 throwDyn exception = throw (DynException (toDyn exception))
 275
 276 #ifdef __GLASGOW_HASKELL__
 277 -- | A variant of 'throwDyn' that throws the dynamic exception to an
 278 -- arbitrary thread (GHC only: c.f. 'throwTo').
 279 throwDynTo :: Typeable exception => ThreadId -> exception -> IO ()
 280 throwDynTo t exception = throwTo t (DynException (toDyn exception))
 281 #endif /* __GLASGOW_HASKELL__ */
 282
 283 -- | Catch dynamic exceptions of the required type.  All other
 284 -- exceptions are re-thrown, including dynamic exceptions of the wrong
 285 -- type.
 286 --
 287 -- When using dynamic exceptions it is advisable to define a new
 288 -- datatype to use for your exception type, to avoid possible clashes
 289 -- with dynamic exceptions used in other libraries.
 290 --
 291 catchDyn :: Typeable exception => IO a -> (exception -> IO a) -> IO a
 292 catchDyn m k = catchException m handle
 293   where handle ex = case ex of
 294                            (DynException dyn) ->
 295                                 case fromDynamic dyn of
 296                                     Just exception  -> k exception
 297                                     Nothing -> throw ex
 298                            _ -> throw ex
 299
 300 -----------------------------------------------------------------------------
 301 -- Exception Predicates
 302
 303 -- $preds
 304 -- These pre-defined predicates may be used as the first argument to
 305 -- 'catchJust', 'tryJust', or 'handleJust' to select certain common
 306 -- classes of exceptions.
 307
 308 ioErrors                :: Exception -> Maybe IOError
 309 arithExceptions         :: Exception -> Maybe ArithException
 310 errorCalls              :: Exception -> Maybe String
 311 assertions              :: Exception -> Maybe String
 312 dynExceptions           :: Exception -> Maybe Dynamic
 313 asyncExceptions         :: Exception -> Maybe AsyncException
 314 userErrors              :: Exception -> Maybe String
 315
 316 ioErrors (IOException e) = Just e
 317 ioErrors _ = Nothing
 318
 319 arithExceptions (ArithException e) = Just e
 320 arithExceptions _ = Nothing
 321
 322 errorCalls (ErrorCall e) = Just e
 323 errorCalls _ = Nothing
 324
 325 assertions (AssertionFailed e) = Just e
 326 assertions _ = Nothing
 327
 328 dynExceptions (DynException e) = Just e
 329 dynExceptions _ = Nothing
 330
 331 asyncExceptions (AsyncException e) = Just e
 332 asyncExceptions _ = Nothing
 333
 334 userErrors (IOException e) | isUserError e = Just (ioeGetErrorString e)
 335 userErrors _ = Nothing
 336
 337 -----------------------------------------------------------------------------
 338 -- Some Useful Functions
 339
 340 -- | When you want to acquire a resource, do some work with it, and
 341 -- then release the resource, it is a good idea to use 'bracket',
 342 -- because 'bracket' will install the necessary exception handler to
 343 -- release the resource in the event that an exception is raised
 344 -- during the computation.  If an exception is raised, then 'bracket' will
 345 -- re-raise the exception (after performing the release).
 346 --
 347 -- A common example is opening a file:
 348 --
 349 -- > bracket
 350 -- >   (openFile "filename" ReadMode)
 351 -- >   (hClose)
 352 -- >   (\handle -> do { ... })
 353 --
 354 -- The arguments to 'bracket' are in this order so that we can partially apply
 355 -- it, e.g.:
 356 --
 357 -- > withFile name = bracket (openFile name) hClose
 358 --
 359 bracket
 360         :: IO a         -- ^ computation to run first (\"acquire resource\")
 361         -> (a -> IO b)  -- ^ computation to run last (\"release resource\")
 362         -> (a -> IO c)  -- ^ computation to run in-between
 363         -> IO c         -- returns the value from the in-between computation
 364 bracket before after thing =
 365   block (do
 366     a <- before
 367     r <- catch
 368            (unblock (thing a))
 369            (\e -> do { after a; throw e })
 370     after a
 371     return r
 372  )
 373
 374
 375 -- | A specialised variant of 'bracket' with just a computation to run
 376 -- afterward.
 377 --
 378 finally :: IO a         -- ^ computation to run first
 379         -> IO b         -- ^ computation to run afterward (even if an exception
 380                         -- was raised)
 381         -> IO a         -- returns the value from the first computation
 382 a `finally` sequel =
 383   block (do
 384     r <- catch
 385              (unblock a)
 386              (\e -> do { sequel; throw e })
 387     sequel
 388     return r
 389   )
 390
 391 -- | A variant of 'bracket' where the return value from the first computation
 392 -- is not required.
 393 bracket_ :: IO a -> IO b -> IO c -> IO c
 394 bracket_ before after thing = bracket before (const after) (const thing)
 395
 396 -- -----------------------------------------------------------------------------
 397 -- Asynchronous exceptions
 398
 399 {- $async
 400
 401  #AsynchronousExceptions# Asynchronous exceptions are so-called because they arise due to
 402 external influences, and can be raised at any point during execution.
 403 'StackOverflow' and 'HeapOverflow' are two examples of
 404 system-generated asynchronous exceptions.
 405
 406 The primary source of asynchronous exceptions, however, is
 407 'throwTo':
 408
 409 >  throwTo :: ThreadId -> Exception -> IO ()
 410
 411 'throwTo' (also 'throwDynTo' and 'Control.Concurrent.killThread') allows one
 412 running thread to raise an arbitrary exception in another thread.  The
 413 exception is therefore asynchronous with respect to the target thread,
 414 which could be doing anything at the time it receives the exception.
 415 Great care should be taken with asynchronous exceptions; it is all too
 416 easy to introduce race conditions by the over zealous use of
 417 'throwTo'.
 418 -}
 419
 420 {- $block_handler
 421 There\'s an implied 'block' around every exception handler in a call
 422 to one of the 'catch' family of functions.  This is because that is
 423 what you want most of the time - it eliminates a common race condition
 424 in starting an exception handler, because there may be no exception
 425 handler on the stack to handle another exception if one arrives
 426 immediately.  If asynchronous exceptions are blocked on entering the
 427 handler, though, we have time to install a new exception handler
 428 before being interrupted.  If this weren\'t the default, one would have
 429 to write something like
 430
 431 >      block (
 432 >           catch (unblock (...))
 433 >                      (\e -> handler)
 434 >      )
 435
 436 If you need to unblock asynchronous exceptions again in the exception
 437 handler, just use 'unblock' as normal.
 438
 439 Note that 'try' and friends /do not/ have a similar default, because
 440 there is no exception handler in this case.  If you want to use 'try'
 441 in an asynchronous-exception-safe way, you will need to use
 442 'block'.
 443 -}
 444
 445 {- $interruptible
 446
 447 Some operations are /interruptible/, which means that they can receive
 448 asynchronous exceptions even in the scope of a 'block'.  Any function
 449 which may itself block is defined as interruptible; this includes
 450 'Control.Concurrent.MVar.takeMVar'
 451 (but not 'Control.Concurrent.MVar.tryTakeMVar'),
 452 and most operations which perform
 453 some I\/O with the outside world.  The reason for having
 454 interruptible operations is so that we can write things like
 455
 456 >      block (
 457 >         a <- takeMVar m
 458 >         catch (unblock (...))
 459 >               (\e -> ...)
 460 >      )
 461
 462 if the 'Control.Concurrent.MVar.takeMVar' was not interruptible,
 463 then this particular
 464 combination could lead to deadlock, because the thread itself would be
 465 blocked in a state where it can\'t receive any asynchronous exceptions.
 466 With 'Control.Concurrent.MVar.takeMVar' interruptible, however, we can be
 467 safe in the knowledge that the thread can receive exceptions right up
 468 until the point when the 'Control.Concurrent.MVar.takeMVar' succeeds.
 469 Similar arguments apply for other interruptible operations like
 470 'System.IO.openFile'.
 471 -}
 472
 473 -- -----------------------------------------------------------------------------
 474 -- Assert
 475
 476 #ifdef __HADDOCK__
 477 -- | If the first argument evaluates to 'True', then the result is the
 478 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 479 -- containing a 'String' with the source file and line number of the
 480 -- call to assert.
 481 --
 482 -- Assertions can normally be turned on or off with a compiler flag
 483 -- (for GHC, assertions are normally on unless the @-fignore-asserts@
 484 -- option is give).  When assertions are turned off, the first
 485 -- argument to 'assert' is ignored, and the second argument is
 486 -- returned as the result.
 487 assert :: Bool -> a -> a
 488 #endif
 489
 490 #ifndef __GLASGOW_HASKELL__
 491 assert :: Bool -> a -> a
 492 assert True x = x
 493 assert False _ = throw (AssertionFailed "")
 494 #endif
 495
 496
 497 #ifdef __GLASGOW_HASKELL__
 498 {-# NOINLINE uncaughtExceptionHandler #-}
 499 uncaughtExceptionHandler :: IORef (Exception -> IO ())
 500 uncaughtExceptionHandler = unsafePerformIO (newIORef defaultHandler)
 501    where
 502       defaultHandler :: Exception -> IO ()
 503       defaultHandler ex = do
 504          (hFlush stdout) `catchException` (\ _ -> return ())
 505          let msg = case ex of
 506                Deadlock    -> "no threads to run:  infinite loop or deadlock?"
 507                ErrorCall s -> s
 508                other       -> showsPrec 0 other "\n"
 509          withCStringLen ("Fail: "++msg) $ \(cstr,len) -> writeErrString cstr len
 510
 511 foreign import ccall unsafe "writeErrString__"
 512         writeErrString :: CString -> Int -> IO ()
 513
 514 setUncaughtExceptionHandler :: (Exception -> IO ()) -> IO ()
 515 setUncaughtExceptionHandler = writeIORef uncaughtExceptionHandler
 516
 517 getUncaughtExceptionHandler :: IO (Exception -> IO ())
 518 getUncaughtExceptionHandler = readIORef uncaughtExceptionHandler
 519 #endif