Foreign/Marshal/Array.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  Foreign.Marshal.Array
   5 -- Copyright   :  (c) The FFI task force 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  ffi@haskell.org
   9 -- Stability   :  provisional
  10 -- Portability :  portable
  11 --
  12 -- Marshalling support: routines allocating, storing, and retrieving Haskell
  13 -- lists that are represented as arrays in the foreign language
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 module Foreign.Marshal.Array (
  18   -- * Marshalling arrays
  19
  20   -- ** Allocation
  21   --
  22   mallocArray,    -- :: Storable a => Int -> IO (Ptr a)
  23   mallocArray0,   -- :: Storable a => Int -> IO (Ptr a)
  24
  25   allocaArray,    -- :: Storable a => Int -> (Ptr a -> IO b) -> IO b
  26   allocaArray0,   -- :: Storable a => Int -> (Ptr a -> IO b) -> IO b
  27
  28   reallocArray,   -- :: Storable a => Ptr a -> Int -> IO (Ptr a)
  29   reallocArray0,  -- :: Storable a => Ptr a -> Int -> IO (Ptr a)
  30
  31   -- ** Marshalling
  32   --
  33   peekArray,      -- :: Storable a =>         Int -> Ptr a -> IO [a]
  34   peekArray0,     -- :: (Storable a, Eq a) => a   -> Ptr a -> IO [a]
  35
  36   pokeArray,      -- :: Storable a =>      Ptr a -> [a] -> IO ()
  37   pokeArray0,     -- :: Storable a => a -> Ptr a -> [a] -> IO ()
  38
  39   -- ** Combined allocation and marshalling
  40   --
  41   newArray,       -- :: Storable a =>      [a] -> IO (Ptr a)
  42   newArray0,      -- :: Storable a => a -> [a] -> IO (Ptr a)
  43
  44   withArray,      -- :: Storable a =>      [a] -> (Ptr a -> IO b) -> IO b
  45   withArray0,     -- :: Storable a => a -> [a] -> (Ptr a -> IO b) -> IO b
  46
  47   withArrayLen,   -- :: Storable a =>      [a] -> (Int -> Ptr a -> IO b) -> IO b
  48   withArrayLen0,  -- :: Storable a => a -> [a] -> (Int -> Ptr a -> IO b) -> IO b
  49
  50   -- ** Copying
  51
  52   -- | (argument order: destination, source)
  53   copyArray,      -- :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
  54   moveArray,      -- :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
  55
  56   -- ** Finding the length
  57   --
  58   lengthArray0,   -- :: (Storable a, Eq a) => a -> Ptr a -> IO Int
  59
  60   -- ** Indexing
  61   --
  62   advancePtr,     -- :: Storable a => Ptr a -> Int -> Ptr a
  63 ) where
  64
  65 import Foreign.Ptr      (Ptr, plusPtr)
  66 import Foreign.Storable (Storable(sizeOf,peekElemOff,pokeElemOff))
  67 import Foreign.Marshal.Alloc (mallocBytes, allocaBytes, reallocBytes)
  68 import Foreign.Marshal.Utils (copyBytes, moveBytes)
  69
  70 #ifdef __GLASGOW_HASKELL__
  71 import GHC.Num
  72 import GHC.List
  73 import GHC.Err
  74 import GHC.Base
  75 #else
  76 import Control.Monad (zipWithM_)
  77 #endif
  78
  79 -- allocation
  80 -- ----------
  81
  82 -- |Allocate storage for the given number of elements of a storable type
  83 -- (like 'Foreign.Marshal.Alloc.malloc', but for multiple elements).
  84 --
  85 mallocArray :: Storable a => Int -> IO (Ptr a)
  86 mallocArray  = doMalloc undefined
  87   where
  88     doMalloc            :: Storable a' => a' -> Int -> IO (Ptr a')
  89     doMalloc dummy size  = mallocBytes (size * sizeOf dummy)
  90
  91 -- |Like 'mallocArray', but add an extra position to hold a special
  92 -- termination element.
  93 --
  94 mallocArray0      :: Storable a => Int -> IO (Ptr a)
  95 mallocArray0 size  = mallocArray (size + 1)
  96
  97 -- |Temporarily allocate space for the given number of elements
  98 -- (like 'Foreign.Marshal.Alloc.alloca', but for multiple elements).
  99 --
 100 allocaArray :: Storable a => Int -> (Ptr a -> IO b) -> IO b
 101 allocaArray  = doAlloca undefined
 102   where
 103     doAlloca            :: Storable a' => a' -> Int -> (Ptr a' -> IO b') -> IO b'
 104     doAlloca dummy size  = allocaBytes (size * sizeOf dummy)
 105
 106 -- |Like 'allocaArray', but add an extra position to hold a special
 107 -- termination element.
 108 --
 109 allocaArray0      :: Storable a => Int -> (Ptr a -> IO b) -> IO b
 110 allocaArray0 size  = allocaArray (size + 1)
 111 {-# INLINE allocaArray0 #-}
 112   -- needed to get allocaArray to inline into withCString, for unknown
 113   -- reasons --SDM 23/4/2010, see #4004 for benchmark
 114
 115 -- |Adjust the size of an array
 116 --
 117 reallocArray :: Storable a => Ptr a -> Int -> IO (Ptr a)
 118 reallocArray  = doRealloc undefined
 119   where
 120     doRealloc                :: Storable a' => a' -> Ptr a' -> Int -> IO (Ptr a')
 121     doRealloc dummy ptr size  = reallocBytes ptr (size * sizeOf dummy)
 122
 123 -- |Adjust the size of an array including an extra position for the end marker.
 124 --
 125 reallocArray0          :: Storable a => Ptr a -> Int -> IO (Ptr a)
 126 reallocArray0 ptr size  = reallocArray ptr (size + 1)
 127
 128
 129 -- marshalling
 130 -- -----------
 131
 132 -- |Convert an array of given length into a Haskell list.  This version
 133 -- traverses the array backwards using an accumulating parameter,
 134 -- which uses constant stack space.  The previous version using mapM
 135 -- needed linear stack space.
 136 --
 137 peekArray          :: Storable a => Int -> Ptr a -> IO [a]
 138 peekArray size ptr | size <= 0 = return []
 139                  | otherwise = f (size-1) []
 140   where
 141     f 0 acc = do e <- peekElemOff ptr 0; return (e:acc)
 142     f n acc = do e <- peekElemOff ptr n; f (n-1) (e:acc)
 143
 144 -- |Convert an array terminated by the given end marker into a Haskell list
 145 --
 146 peekArray0            :: (Storable a, Eq a) => a -> Ptr a -> IO [a]
 147 peekArray0 marker ptr  = do
 148   size <- lengthArray0 marker ptr
 149   peekArray size ptr
 150
 151 -- |Write the list elements consecutive into memory
 152 --
 153 pokeArray :: Storable a => Ptr a -> [a] -> IO ()
 154 #ifndef __GLASGOW_HASKELL__
 155 pokeArray ptr vals =  zipWithM_ (pokeElemOff ptr) [0..] vals
 156 #else
 157 pokeArray ptr vals0 = go vals0 0#
 158   where go [] _          = return ()
 159         go (val:vals) n# = do pokeElemOff ptr (I# n#) val; go vals (n# +# 1#)
 160 #endif
 161
 162 -- |Write the list elements consecutive into memory and terminate them with the
 163 -- given marker element
 164 --
 165 pokeArray0 :: Storable a => a -> Ptr a -> [a] -> IO ()
 166 #ifndef __GLASGOW_HASKELL__
 167 pokeArray0 marker ptr vals  = do
 168   pokeArray ptr vals
 169   pokeElemOff ptr (length vals) marker
 170 #else
 171 pokeArray0 marker ptr vals0 = go vals0 0#
 172   where go [] n#         = pokeElemOff ptr (I# n#) marker
 173         go (val:vals) n# = do pokeElemOff ptr (I# n#) val; go vals (n# +# 1#)
 174 #endif
 175
 176
 177 -- combined allocation and marshalling
 178 -- -----------------------------------
 179
 180 -- |Write a list of storable elements into a newly allocated, consecutive
 181 -- sequence of storable values
 182 -- (like 'Foreign.Marshal.Utils.new', but for multiple elements).
 183 --
 184 newArray      :: Storable a => [a] -> IO (Ptr a)
 185 newArray vals  = do
 186   ptr <- mallocArray (length vals)
 187   pokeArray ptr vals
 188   return ptr
 189
 190 -- |Write a list of storable elements into a newly allocated, consecutive
 191 -- sequence of storable values, where the end is fixed by the given end marker
 192 --
 193 newArray0             :: Storable a => a -> [a] -> IO (Ptr a)
 194 newArray0 marker vals  = do
 195   ptr <- mallocArray0 (length vals)
 196   pokeArray0 marker ptr vals
 197   return ptr
 198
 199 -- |Temporarily store a list of storable values in memory
 200 -- (like 'Foreign.Marshal.Utils.with', but for multiple elements).
 201 --
 202 withArray :: Storable a => [a] -> (Ptr a -> IO b) -> IO b
 203 withArray vals = withArrayLen vals . const
 204
 205 -- |Like 'withArray', but the action gets the number of values
 206 -- as an additional parameter
 207 --
 208 withArrayLen :: Storable a => [a] -> (Int -> Ptr a -> IO b) -> IO b
 209 withArrayLen vals f  =
 210   allocaArray len $ \ptr -> do
 211       pokeArray ptr vals
 212       res <- f len ptr
 213       return res
 214   where
 215     len = length vals
 216
 217 -- |Like 'withArray', but a terminator indicates where the array ends
 218 --
 219 withArray0 :: Storable a => a -> [a] -> (Ptr a -> IO b) -> IO b
 220 withArray0 marker vals = withArrayLen0 marker vals . const
 221
 222 -- |Like 'withArrayLen', but a terminator indicates where the array ends
 223 --
 224 withArrayLen0 :: Storable a => a -> [a] -> (Int -> Ptr a -> IO b) -> IO b
 225 withArrayLen0 marker vals f  =
 226   allocaArray0 len $ \ptr -> do
 227       pokeArray0 marker ptr vals
 228       res <- f len ptr
 229       return res
 230   where
 231     len = length vals
 232
 233
 234 -- copying (argument order: destination, source)
 235 -- -------
 236
 237 -- |Copy the given number of elements from the second array (source) into the
 238 -- first array (destination); the copied areas may /not/ overlap
 239 --
 240 copyArray :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
 241 copyArray  = doCopy undefined
 242   where
 243     doCopy                     :: Storable a' => a' -> Ptr a' -> Ptr a' -> Int -> IO ()
 244     doCopy dummy dest src size  = copyBytes dest src (size * sizeOf dummy)
 245
 246 -- |Copy the given number of elements from the second array (source) into the
 247 -- first array (destination); the copied areas /may/ overlap
 248 --
 249 moveArray :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
 250 moveArray  = doMove undefined
 251   where
 252     doMove                     :: Storable a' => a' -> Ptr a' -> Ptr a' -> Int -> IO ()
 253     doMove dummy dest src size  = moveBytes dest src (size * sizeOf dummy)
 254
 255
 256 -- finding the length
 257 -- ------------------
 258
 259 -- |Return the number of elements in an array, excluding the terminator
 260 --
 261 lengthArray0            :: (Storable a, Eq a) => a -> Ptr a -> IO Int
 262 lengthArray0 marker ptr  = loop 0
 263   where
 264     loop i = do
 265         val <- peekElemOff ptr i
 266         if val == marker then return i else loop (i+1)
 267
 268
 269 -- indexing
 270 -- --------
 271
 272 -- |Advance a pointer into an array by the given number of elements
 273 --
 274 advancePtr :: Storable a => Ptr a -> Int -> Ptr a
 275 advancePtr  = doAdvance undefined
 276   where
 277     doAdvance             :: Storable a' => a' -> Ptr a' -> Int -> Ptr a'
 278     doAdvance dummy ptr i  = ptr `plusPtr` (i * sizeOf dummy)