GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_HADDOCK hide #-}
  67 -----------------------------------------------------------------------------
  68 -- |
  69 -- Module      :  GHC.Base
  70 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  71 -- License     :  see libraries/base/LICENSE
  72 --
  73 -- Maintainer  :  cvs-ghc@haskell.org
  74 -- Stability   :  internal
  75 -- Portability :  non-portable (GHC extensions)
  76 --
  77 -- Basic data types and classes.
  78 --
  79 -----------------------------------------------------------------------------
  80
  81 #include "MachDeps.h"
  82
  83 -- #hide
  84 module GHC.Base
  85         (
  86         module GHC.Base,
  87         module GHC.Bool,
  88         module GHC.Generics,
  89         module GHC.Ordering,
  90         module GHC.Types,
  91         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  92         module GHC.Err          -- of people having to import it explicitly
  93   )
  94         where
  95
  96 import GHC.Types
  97 import GHC.Bool
  98 import GHC.Generics
  99 import GHC.Ordering
 100 import GHC.Prim
 101 import {-# SOURCE #-} GHC.Err
 102
 103 infixr 9  .
 104 infixr 5  ++
 105 infix  4  ==, /=, <, <=, >=, >
 106 infixr 3  &&
 107 infixr 2  ||
 108 infixl 1  >>, >>=
 109 infixr 0  $
 110
 111 default ()              -- Double isn't available yet
 112 \end{code}
 113
 114
 115 %*********************************************************
 116 %*                                                      *
 117 \subsection{DEBUGGING STUFF}
 118 %*  (for use when compiling GHC.Base itself doesn't work)
 119 %*                                                      *
 120 %*********************************************************
 121
 122 \begin{code}
 123 {-
 124 data  Bool  =  False | True
 125 data Ordering = LT | EQ | GT
 126 data Char = C# Char#
 127 type  String = [Char]
 128 data Int = I# Int#
 129 data  ()  =  ()
 130 data [] a = MkNil
 131
 132 not True = False
 133 (&&) True True = True
 134 otherwise = True
 135
 136 build = error "urk"
 137 foldr = error "urk"
 138
 139 unpackCString# :: Addr# -> [Char]
 140 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 141 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 142 unpackCStringUtf8# :: Addr# -> [Char]
 143 unpackCString# a = error "urk"
 144 unpackFoldrCString# a = error "urk"
 145 unpackAppendCString# a = error "urk"
 146 unpackCStringUtf8# a = error "urk"
 147 -}
 148 \end{code}
 149
 150
 151 %*********************************************************
 152 %*                                                      *
 153 \subsection{Standard classes @Eq@, @Ord@}
 154 %*                                                      *
 155 %*********************************************************
 156
 157 \begin{code}
 158
 159 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 160 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 161 -- and 'Eq' may be derived for any datatype whose constituents are also
 162 -- instances of 'Eq'.
 163 --
 164 -- Minimal complete definition: either '==' or '/='.
 165 --
 166 class  Eq a  where
 167     (==), (/=)           :: a -> a -> Bool
 168
 169     x /= y               = not (x == y)
 170     x == y               = not (x /= y)
 171
 172 -- | The 'Ord' class is used for totally ordered datatypes.
 173 --
 174 -- Instances of 'Ord' can be derived for any user-defined
 175 -- datatype whose constituent types are in 'Ord'.  The declared order
 176 -- of the constructors in the data declaration determines the ordering
 177 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 178 -- comparison to determine the precise ordering of two objects.
 179 --
 180 -- Minimal complete definition: either 'compare' or '<='.
 181 -- Using 'compare' can be more efficient for complex types.
 182 --
 183 class  (Eq a) => Ord a  where
 184     compare              :: a -> a -> Ordering
 185     (<), (<=), (>), (>=) :: a -> a -> Bool
 186     max, min             :: a -> a -> a
 187
 188     compare x y
 189         | x == y    = EQ
 190         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 191                                 -- above claim about the minimal things that
 192                                 -- can be defined for an instance of Ord
 193         | otherwise = GT
 194
 195     x <  y = case compare x y of { LT -> True;  _other -> False }
 196     x <= y = case compare x y of { GT -> False; _other -> True }
 197     x >  y = case compare x y of { GT -> True;  _other -> False }
 198     x >= y = case compare x y of { LT -> False; _other -> True }
 199
 200         -- These two default methods use '<=' rather than 'compare'
 201         -- because the latter is often more expensive
 202     max x y = if x <= y then y else x
 203     min x y = if x <= y then x else y
 204 \end{code}
 205
 206 %*********************************************************
 207 %*                                                      *
 208 \subsection{Monadic classes @Functor@, @Monad@ }
 209 %*                                                      *
 210 %*********************************************************
 211
 212 \begin{code}
 213 {- | The 'Functor' class is used for types that can be mapped over.
 214 Instances of 'Functor' should satisfy the following laws:
 215
 216 > fmap id  ==  id
 217 > fmap (f . g)  ==  fmap f . fmap g
 218
 219 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 220 defined in the "Prelude" satisfy these laws.
 221 -}
 222
 223 class  Functor f  where
 224     fmap        :: (a -> b) -> f a -> f b
 225
 226 {- | The 'Monad' class defines the basic operations over a /monad/,
 227 a concept from a branch of mathematics known as /category theory/.
 228 From the perspective of a Haskell programmer, however, it is best to
 229 think of a monad as an /abstract datatype/ of actions.
 230 Haskell's @do@ expressions provide a convenient syntax for writing
 231 monadic expressions.
 232
 233 Minimal complete definition: '>>=' and 'return'.
 234
 235 Instances of 'Monad' should satisfy the following laws:
 236
 237 > return a >>= k  ==  k a
 238 > m >>= return  ==  m
 239 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 240
 241 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 242
 243 > fmap f xs  ==  xs >>= return . f
 244
 245 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 246 defined in the "Prelude" satisfy these laws.
 247 -}
 248
 249 class  Monad m  where
 250     -- | Sequentially compose two actions, passing any value produced
 251     -- by the first as an argument to the second.
 252     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 253     -- | Sequentially compose two actions, discarding any value produced
 254     -- by the first, like sequencing operators (such as the semicolon)
 255     -- in imperative languages.
 256     (>>)        :: forall a b. m a -> m b -> m b
 257         -- Explicit for-alls so that we know what order to
 258         -- give type arguments when desugaring
 259
 260     -- | Inject a value into the monadic type.
 261     return      :: a -> m a
 262     -- | Fail with a message.  This operation is not part of the
 263     -- mathematical definition of a monad, but is invoked on pattern-match
 264     -- failure in a @do@ expression.
 265     fail        :: String -> m a
 266
 267     m >> k      = m >>= \_ -> k
 268     fail s      = error s
 269 \end{code}
 270
 271
 272 %*********************************************************
 273 %*                                                      *
 274 \subsection{The list type}
 275 %*                                                      *
 276 %*********************************************************
 277
 278 \begin{code}
 279 -- do explicitly: deriving (Eq, Ord)
 280 -- to avoid weird names like con2tag_[]#
 281
 282 instance (Eq a) => Eq [a] where
 283     {-# SPECIALISE instance Eq [Char] #-}
 284     []     == []     = True
 285     (x:xs) == (y:ys) = x == y && xs == ys
 286     _xs    == _ys    = False
 287
 288 instance (Ord a) => Ord [a] where
 289     {-# SPECIALISE instance Ord [Char] #-}
 290     compare []     []     = EQ
 291     compare []     (_:_)  = LT
 292     compare (_:_)  []     = GT
 293     compare (x:xs) (y:ys) = case compare x y of
 294                                 EQ    -> compare xs ys
 295                                 other -> other
 296
 297 instance Functor [] where
 298     fmap = map
 299
 300 instance  Monad []  where
 301     m >>= k             = foldr ((++) . k) [] m
 302     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 303     return x            = [x]
 304     fail _              = []
 305 \end{code}
 306
 307 A few list functions that appear here because they are used here.
 308 The rest of the prelude list functions are in GHC.List.
 309
 310 ----------------------------------------------
 311 --      foldr/build/augment
 312 ----------------------------------------------
 313
 314 \begin{code}
 315 -- | 'foldr', applied to a binary operator, a starting value (typically
 316 -- the right-identity of the operator), and a list, reduces the list
 317 -- using the binary operator, from right to left:
 318 --
 319 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 320
 321 foldr            :: (a -> b -> b) -> b -> [a] -> b
 322 -- foldr _ z []     =  z
 323 -- foldr f z (x:xs) =  f x (foldr f z xs)
 324 {-# INLINE [0] foldr #-}
 325 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 326 foldr k z xs = go xs
 327              where
 328                go []     = z
 329                go (y:ys) = y `k` go ys
 330
 331 -- | A list producer that can be fused with 'foldr'.
 332 -- This function is merely
 333 --
 334 -- >    build g = g (:) []
 335 --
 336 -- but GHC's simplifier will transform an expression of the form
 337 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 338 -- which avoids producing an intermediate list.
 339
 340 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 341 {-# INLINE [1] build #-}
 342         -- The INLINE is important, even though build is tiny,
 343         -- because it prevents [] getting inlined in the version that
 344         -- appears in the interface file.  If [] *is* inlined, it
 345         -- won't match with [] appearing in rules in an importing module.
 346         --
 347         -- The "1" says to inline in phase 1
 348
 349 build g = g (:) []
 350
 351 -- | A list producer that can be fused with 'foldr'.
 352 -- This function is merely
 353 --
 354 -- >    augment g xs = g (:) xs
 355 --
 356 -- but GHC's simplifier will transform an expression of the form
 357 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 358 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 359
 360 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 361 {-# INLINE [1] augment #-}
 362 augment g xs = g (:) xs
 363
 364 {-# RULES
 365 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 366                 foldr k z (build g) = g k z
 367
 368 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 369                 foldr k z (augment g xs) = g k (foldr k z xs)
 370
 371 "foldr/id"                        foldr (:) [] = \x  -> x
 372 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 373         -- Only activate this from phase 1, because that's
 374         -- when we disable the rule that expands (++) into foldr
 375
 376 -- The foldr/cons rule looks nice, but it can give disastrously
 377 -- bloated code when commpiling
 378 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 379 -- i.e. when there are very very long literal lists
 380 -- So I've disabled it for now. We could have special cases
 381 -- for short lists, I suppose.
 382 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 383
 384 "foldr/single"  forall k z x. foldr k z [x] = k x z
 385 "foldr/nil"     forall k z.   foldr k z []  = z
 386
 387 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 388                        (h::forall b. (a->b->b) -> b -> b) .
 389                        augment g (build h) = build (\c n -> g c (h c n))
 390 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 391                         augment g [] = build g
 392  #-}
 393
 394 -- This rule is true, but not (I think) useful:
 395 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 396 \end{code}
 397
 398
 399 ----------------------------------------------
 400 --              map
 401 ----------------------------------------------
 402
 403 \begin{code}
 404 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 405 -- of @xs@, i.e.,
 406 --
 407 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 408 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 409
 410 map :: (a -> b) -> [a] -> [b]
 411 map _ []     = []
 412 map f (x:xs) = f x : map f xs
 413
 414 -- Note eta expanded
 415 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 416 {-# INLINE [0] mapFB #-}
 417 mapFB c f x ys = c (f x) ys
 418
 419 -- The rules for map work like this.
 420 --
 421 -- Up to (but not including) phase 1, we use the "map" rule to
 422 -- rewrite all saturated applications of map with its build/fold
 423 -- form, hoping for fusion to happen.
 424 -- In phase 1 and 0, we switch off that rule, inline build, and
 425 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 426 -- thing back into plain map.
 427 --
 428 -- It's important that these two rules aren't both active at once
 429 -- (along with build's unfolding) else we'd get an infinite loop
 430 -- in the rules.  Hence the activation control below.
 431 --
 432 -- The "mapFB" rule optimises compositions of map.
 433 --
 434 -- This same pattern is followed by many other functions:
 435 -- e.g. append, filter, iterate, repeat, etc.
 436
 437 {-# RULES
 438 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 439 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 440 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 441   #-}
 442 \end{code}
 443
 444
 445 ----------------------------------------------
 446 --              append
 447 ----------------------------------------------
 448 \begin{code}
 449 -- | Append two lists, i.e.,
 450 --
 451 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 452 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 453 --
 454 -- If the first list is not finite, the result is the first list.
 455
 456 (++) :: [a] -> [a] -> [a]
 457 (++) []     ys = ys
 458 (++) (x:xs) ys = x : xs ++ ys
 459
 460 {-# RULES
 461 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 462   #-}
 463
 464 \end{code}
 465
 466
 467 %*********************************************************
 468 %*                                                      *
 469 \subsection{Type @Bool@}
 470 %*                                                      *
 471 %*********************************************************
 472
 473 \begin{code}
 474 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 475 -- first so that the corresponding 'Prelude.Enum' instance will give
 476 -- 'Prelude.fromEnum' 'False' the value zero, and
 477 -- 'Prelude.fromEnum' 'True' the value 1.
 478 -- The actual definition is in the ghc-prim package.
 479
 480 -- XXX These don't work:
 481 -- deriving instance Eq Bool
 482 -- deriving instance Ord Bool
 483 -- <wired into compiler>:
 484 --     Illegal binding of built-in syntax: con2tag_Bool#
 485
 486 instance Eq Bool where
 487     True  == True  = True
 488     False == False = True
 489     _     == _     = False
 490
 491 instance Ord Bool where
 492     compare False True  = LT
 493     compare True  False = GT
 494     compare _     _     = EQ
 495
 496 -- Read is in GHC.Read, Show in GHC.Show
 497
 498 -- Boolean functions
 499
 500 -- | Boolean \"and\"
 501 (&&)                    :: Bool -> Bool -> Bool
 502 True  && x              =  x
 503 False && _              =  False
 504
 505 -- | Boolean \"or\"
 506 (||)                    :: Bool -> Bool -> Bool
 507 True  || _              =  True
 508 False || x              =  x
 509
 510 -- | Boolean \"not\"
 511 not                     :: Bool -> Bool
 512 not True                =  False
 513 not False               =  True
 514
 515 -- |'otherwise' is defined as the value 'True'.  It helps to make
 516 -- guards more readable.  eg.
 517 --
 518 -- >  f x | x < 0     = ...
 519 -- >      | otherwise = ...
 520 otherwise               :: Bool
 521 otherwise               =  True
 522 \end{code}
 523
 524 %*********************************************************
 525 %*                                                      *
 526 \subsection{Type @Ordering@}
 527 %*                                                      *
 528 %*********************************************************
 529
 530 \begin{code}
 531 -- | Represents an ordering relationship between two values: less
 532 -- than, equal to, or greater than.  An 'Ordering' is returned by
 533 -- 'compare'.
 534 -- XXX These don't work:
 535 -- deriving instance Eq Ordering
 536 -- deriving instance Ord Ordering
 537 -- Illegal binding of built-in syntax: con2tag_Ordering#
 538 instance Eq Ordering where
 539     EQ == EQ = True
 540     LT == LT = True
 541     GT == GT = True
 542     _  == _  = False
 543         -- Read in GHC.Read, Show in GHC.Show
 544
 545 instance Ord Ordering where
 546     LT <= _  = True
 547     _  <= LT = False
 548     EQ <= _  = True
 549     _  <= EQ = False
 550     GT <= GT = True
 551 \end{code}
 552
 553
 554 %*********************************************************
 555 %*                                                      *
 556 \subsection{Type @Char@ and @String@}
 557 %*                                                      *
 558 %*********************************************************
 559
 560 \begin{code}
 561 -- | A 'String' is a list of characters.  String constants in Haskell are values
 562 -- of type 'String'.
 563 --
 564 type String = [Char]
 565
 566 {-| The character type 'Char' is an enumeration whose values represent
 567 Unicode (or equivalently ISO\/IEC 10646) characters
 568 (see <http://www.unicode.org/> for details).
 569 This set extends the ISO 8859-1 (Latin-1) character set
 570 (the first 256 charachers), which is itself an extension of the ASCII
 571 character set (the first 128 characters).
 572 A character literal in Haskell has type 'Char'.
 573
 574 To convert a 'Char' to or from the corresponding 'Int' value defined
 575 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 576 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 577 -}
 578
 579 -- We don't use deriving for Eq and Ord, because for Ord the derived
 580 -- instance defines only compare, which takes two primops.  Then
 581 -- '>' uses compare, and therefore takes two primops instead of one.
 582
 583 instance Eq Char where
 584     (C# c1) == (C# c2) = c1 `eqChar#` c2
 585     (C# c1) /= (C# c2) = c1 `neChar#` c2
 586
 587 instance Ord Char where
 588     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 589     (C# c1) >= (C# c2) = c1 `geChar#` c2
 590     (C# c1) <= (C# c2) = c1 `leChar#` c2
 591     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 592
 593 {-# RULES
 594 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 595 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 596 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 597 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 598 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 599 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 600   #-}
 601
 602 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 603 chr :: Int -> Char
 604 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 605             | otherwise                                  = error "Prelude.chr: bad argument"
 606
 607 unsafeChr :: Int -> Char
 608 unsafeChr (I# i#) = C# (chr# i#)
 609
 610 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 611 ord :: Char -> Int
 612 ord (C# c#) = I# (ord# c#)
 613 \end{code}
 614
 615 String equality is used when desugaring pattern-matches against strings.
 616
 617 \begin{code}
 618 eqString :: String -> String -> Bool
 619 eqString []       []       = True
 620 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 621 eqString _        _        = False
 622
 623 {-# RULES "eqString" (==) = eqString #-}
 624 -- eqString also has a BuiltInRule in PrelRules.lhs:
 625 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 626 \end{code}
 627
 628
 629 %*********************************************************
 630 %*                                                      *
 631 \subsection{Type @Int@}
 632 %*                                                      *
 633 %*********************************************************
 634
 635 \begin{code}
 636 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 637 zeroInt = I# 0#
 638 oneInt  = I# 1#
 639 twoInt  = I# 2#
 640
 641 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 642 #if WORD_SIZE_IN_BITS == 31
 643 minInt  = I# (-0x40000000#)
 644 maxInt  = I# 0x3FFFFFFF#
 645 #elif WORD_SIZE_IN_BITS == 32
 646 minInt  = I# (-0x80000000#)
 647 maxInt  = I# 0x7FFFFFFF#
 648 #else
 649 minInt  = I# (-0x8000000000000000#)
 650 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 651 #endif
 652
 653 instance Eq Int where
 654     (==) = eqInt
 655     (/=) = neInt
 656
 657 instance Ord Int where
 658     compare = compareInt
 659     (<)     = ltInt
 660     (<=)    = leInt
 661     (>=)    = geInt
 662     (>)     = gtInt
 663
 664 compareInt :: Int -> Int -> Ordering
 665 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 666
 667 compareInt# :: Int# -> Int# -> Ordering
 668 compareInt# x# y#
 669     | x# <#  y# = LT
 670     | x# ==# y# = EQ
 671     | otherwise = GT
 672 \end{code}
 673
 674
 675 %*********************************************************
 676 %*                                                      *
 677 \subsection{The function type}
 678 %*                                                      *
 679 %*********************************************************
 680
 681 \begin{code}
 682 -- | Identity function.
 683 id                      :: a -> a
 684 id x                    =  x
 685
 686 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 687 -- magical strictness property: it is lazy in its first argument,
 688 -- even though its semantics is strict.
 689 lazy :: a -> a
 690 lazy x = x
 691 -- Implementation note: its strictness and unfolding are over-ridden
 692 -- by the definition in MkId.lhs; in both cases to nothing at all.
 693 -- That way, 'lazy' does not get inlined, and the strictness analyser
 694 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 695 -- Result: happiness
 696
 697
 698 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 699 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 700 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 701 -- hence eliminated) late in compilation, after the rule has had
 702 -- a god chance to fire.
 703 inline :: a -> a
 704 {-# NOINLINE[0] inline #-}
 705 inline x = x
 706
 707 -- Assertion function.  This simply ignores its boolean argument.
 708 -- The compiler may rewrite it to @('assertError' line)@.
 709
 710 -- | If the first argument evaluates to 'True', then the result is the
 711 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 712 -- containing a 'String' with the source file and line number of the
 713 -- call to 'assert'.
 714 --
 715 -- Assertions can normally be turned on or off with a compiler flag
 716 -- (for GHC, assertions are normally on unless optimisation is turned on
 717 -- with @-O@ or the @-fignore-asserts@
 718 -- option is given).  When assertions are turned off, the first
 719 -- argument to 'assert' is ignored, and the second argument is
 720 -- returned as the result.
 721
 722 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 723 --      but from Template Haskell onwards it's simply
 724 --      defined here in Base.lhs
 725 assert :: Bool -> a -> a
 726 assert _pred r = r
 727
 728 breakpoint :: a -> a
 729 breakpoint r = r
 730
 731 breakpointCond :: Bool -> a -> a
 732 breakpointCond _ r = r
 733
 734 data Opaque = forall a. O a
 735
 736 -- | Constant function.
 737 const                   :: a -> b -> a
 738 const x _               =  x
 739
 740 -- | Function composition.
 741 {-# INLINE (.) #-}
 742 (.)       :: (b -> c) -> (a -> b) -> a -> c
 743 (.) f g x = f (g x)
 744
 745 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 746 flip                    :: (a -> b -> c) -> b -> a -> c
 747 flip f x y              =  f y x
 748
 749 -- | Application operator.  This operator is redundant, since ordinary
 750 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 751 -- low, right-associative binding precedence, so it sometimes allows
 752 -- parentheses to be omitted; for example:
 753 --
 754 -- >     f $ g $ h x  =  f (g (h x))
 755 --
 756 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 757 -- or @'Data.List.zipWith' ('$') fs xs@.
 758 {-# INLINE ($) #-}
 759 ($)                     :: (a -> b) -> a -> b
 760 f $ x                   =  f x
 761
 762 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 763 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 764 until p f x | p x       =  x
 765             | otherwise =  until p f (f x)
 766
 767 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 768 -- used as an infix operator, and its typing forces its first argument
 769 -- (which is usually overloaded) to have the same type as the second.
 770 asTypeOf                :: a -> a -> a
 771 asTypeOf                =  const
 772 \end{code}
 773
 774 %*********************************************************
 775 %*                                                      *
 776 \subsection{@getTag@}
 777 %*                                                      *
 778 %*********************************************************
 779
 780 Returns the 'tag' of a constructor application; this function is used
 781 by the deriving code for Eq, Ord and Enum.
 782
 783 The primitive dataToTag# requires an evaluated constructor application
 784 as its argument, so we provide getTag as a wrapper that performs the
 785 evaluation before calling dataToTag#.  We could have dataToTag#
 786 evaluate its argument, but we prefer to do it this way because (a)
 787 dataToTag# can be an inline primop if it doesn't need to do any
 788 evaluation, and (b) we want to expose the evaluation to the
 789 simplifier, because it might be possible to eliminate the evaluation
 790 in the case when the argument is already known to be evaluated.
 791
 792 \begin{code}
 793 {-# INLINE getTag #-}
 794 getTag :: a -> Int#
 795 getTag x = x `seq` dataToTag# x
 796 \end{code}
 797
 798 %*********************************************************
 799 %*                                                      *
 800 \subsection{Numeric primops}
 801 %*                                                      *
 802 %*********************************************************
 803
 804 \begin{code}
 805 divInt# :: Int# -> Int# -> Int#
 806 x# `divInt#` y#
 807         -- Be careful NOT to overflow if we do any additional arithmetic
 808         -- on the arguments...  the following  previous version of this
 809         -- code has problems with overflow:
 810 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 811 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 812     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 813     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 814     | otherwise                = x# `quotInt#` y#
 815
 816 modInt# :: Int# -> Int# -> Int#
 817 x# `modInt#` y#
 818     | (x# ># 0#) && (y# <# 0#) ||
 819       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 820     | otherwise                   = r#
 821     where
 822     r# = x# `remInt#` y#
 823 \end{code}
 824
 825 Definitions of the boxed PrimOps; these will be
 826 used in the case of partial applications, etc.
 827
 828 \begin{code}
 829 {-# INLINE eqInt #-}
 830 {-# INLINE neInt #-}
 831 {-# INLINE gtInt #-}
 832 {-# INLINE geInt #-}
 833 {-# INLINE ltInt #-}
 834 {-# INLINE leInt #-}
 835 {-# INLINE plusInt #-}
 836 {-# INLINE minusInt #-}
 837 {-# INLINE timesInt #-}
 838 {-# INLINE quotInt #-}
 839 {-# INLINE remInt #-}
 840 {-# INLINE negateInt #-}
 841
 842 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 843 (I# x) `plusInt`  (I# y) = I# (x +# y)
 844 (I# x) `minusInt` (I# y) = I# (x -# y)
 845 (I# x) `timesInt` (I# y) = I# (x *# y)
 846 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 847 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 848 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 849 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 850
 851 {-# RULES
 852 "x# +# 0#" forall x#. x# +# 0# = x#
 853 "0# +# x#" forall x#. 0# +# x# = x#
 854 "x# -# 0#" forall x#. x# -# 0# = x#
 855 "x# -# x#" forall x#. x# -# x# = 0#
 856 "x# *# 0#" forall x#. x# *# 0# = 0#
 857 "0# *# x#" forall x#. 0# *# x# = 0#
 858 "x# *# 1#" forall x#. x# *# 1# = x#
 859 "1# *# x#" forall x#. 1# *# x# = x#
 860   #-}
 861
 862 gcdInt (I# a) (I# b) = g a b
 863    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 864          g 0# _  = I# absB
 865          g _  0# = I# absA
 866          g _  _  = I# (gcdInt# absA absB)
 867
 868          absInt x = if x <# 0# then negateInt# x else x
 869
 870          absA     = absInt a
 871          absB     = absInt b
 872
 873 negateInt :: Int -> Int
 874 negateInt (I# x) = I# (negateInt# x)
 875
 876 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 877 (I# x) `gtInt` (I# y) = x >#  y
 878 (I# x) `geInt` (I# y) = x >=# y
 879 (I# x) `eqInt` (I# y) = x ==# y
 880 (I# x) `neInt` (I# y) = x /=# y
 881 (I# x) `ltInt` (I# y) = x <#  y
 882 (I# x) `leInt` (I# y) = x <=# y
 883
 884 {-# RULES
 885 "x# ># x#"  forall x#. x# >#  x# = False
 886 "x# >=# x#" forall x#. x# >=# x# = True
 887 "x# ==# x#" forall x#. x# ==# x# = True
 888 "x# /=# x#" forall x#. x# /=# x# = False
 889 "x# <# x#"  forall x#. x# <#  x# = False
 890 "x# <=# x#" forall x#. x# <=# x# = True
 891   #-}
 892
 893 {-# RULES
 894 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 895 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 896 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 897 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 898 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 899 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 900 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 901 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 902 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 903   #-}
 904
 905 {-# RULES
 906 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 907 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 908 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 909 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 910 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 911 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 912   #-}
 913
 914 {-
 915 We'd like to have more rules, but for example:
 916
 917 This gives wrong answer (0) for NaN - NaN (should be NaN):
 918     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 919
 920 This gives wrong answer (0) for 0 * NaN (should be NaN):
 921     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 922
 923 This gives wrong answer (0) for NaN * 0 (should be NaN):
 924     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 925
 926 These are tested by num014.
 927 -}
 928
 929 -- Wrappers for the shift operations.  The uncheckedShift# family are
 930 -- undefined when the amount being shifted by is greater than the size
 931 -- in bits of Int#, so these wrappers perform a check and return
 932 -- either zero or -1 appropriately.
 933 --
 934 -- Note that these wrappers still produce undefined results when the
 935 -- second argument (the shift amount) is negative.
 936
 937 -- | Shift the argument left by the specified number of bits
 938 -- (which must be non-negative).
 939 shiftL# :: Word# -> Int# -> Word#
 940 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 941                 | otherwise                = a `uncheckedShiftL#` b
 942
 943 -- | Shift the argument right by the specified number of bits
 944 -- (which must be non-negative).
 945 shiftRL# :: Word# -> Int# -> Word#
 946 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 947                 | otherwise                = a `uncheckedShiftRL#` b
 948
 949 -- | Shift the argument left by the specified number of bits
 950 -- (which must be non-negative).
 951 iShiftL# :: Int# -> Int# -> Int#
 952 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 953                 | otherwise                = a `uncheckedIShiftL#` b
 954
 955 -- | Shift the argument right (signed) by the specified number of bits
 956 -- (which must be non-negative).
 957 iShiftRA# :: Int# -> Int# -> Int#
 958 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 959                 | otherwise                = a `uncheckedIShiftRA#` b
 960
 961 -- | Shift the argument right (unsigned) by the specified number of bits
 962 -- (which must be non-negative).
 963 iShiftRL# :: Int# -> Int# -> Int#
 964 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 965                 | otherwise                = a `uncheckedIShiftRL#` b
 966
 967 #if WORD_SIZE_IN_BITS == 32
 968 {-# RULES
 969 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 970 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 971    #-}
 972 #endif
 973
 974 {-# RULES
 975 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 976 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 977   #-}
 978 \end{code}
 979
 980
 981 %********************************************************
 982 %*                                                      *
 983 \subsection{Unpacking C strings}
 984 %*                                                      *
 985 %********************************************************
 986
 987 This code is needed for virtually all programs, since it's used for
 988 unpacking the strings of error messages.
 989
 990 \begin{code}
 991 unpackCString# :: Addr# -> [Char]
 992 {-# NOINLINE [1] unpackCString# #-}
 993 unpackCString# addr
 994   = unpack 0#
 995   where
 996     unpack nh
 997       | ch `eqChar#` '\0'# = []
 998       | otherwise          = C# ch : unpack (nh +# 1#)
 999       where
1000         ch = indexCharOffAddr# addr nh
1001
1002 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1003 unpackAppendCString# addr rest
1004   = unpack 0#
1005   where
1006     unpack nh
1007       | ch `eqChar#` '\0'# = rest
1008       | otherwise          = C# ch : unpack (nh +# 1#)
1009       where
1010         ch = indexCharOffAddr# addr nh
1011
1012 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
1013 {-# NOINLINE [0] unpackFoldrCString# #-}
1014 -- Don't inline till right at the end;
1015 -- usually the unpack-list rule turns it into unpackCStringList
1016 -- It also has a BuiltInRule in PrelRules.lhs:
1017 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1018 --        =  unpackFoldrCString# "foobaz" c n
1019 unpackFoldrCString# addr f z
1020   = unpack 0#
1021   where
1022     unpack nh
1023       | ch `eqChar#` '\0'# = z
1024       | otherwise          = C# ch `f` unpack (nh +# 1#)
1025       where
1026         ch = indexCharOffAddr# addr nh
1027
1028 unpackCStringUtf8# :: Addr# -> [Char]
1029 unpackCStringUtf8# addr
1030   = unpack 0#
1031   where
1032     unpack nh
1033       | ch `eqChar#` '\0'#   = []
1034       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1035       | ch `leChar#` '\xDF'# =
1036           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1037                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1038           unpack (nh +# 2#)
1039       | ch `leChar#` '\xEF'# =
1040           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1041                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1042                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1043           unpack (nh +# 3#)
1044       | otherwise            =
1045           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1046                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1047                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1048                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1049           unpack (nh +# 4#)
1050       where
1051         ch = indexCharOffAddr# addr nh
1052
1053 unpackNBytes# :: Addr# -> Int# -> [Char]
1054 unpackNBytes# _addr 0#   = []
1055 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1056     where
1057      unpack acc i#
1058       | i# <# 0#  = acc
1059       | otherwise =
1060          case indexCharOffAddr# addr i# of
1061             ch -> unpack (C# ch : acc) (i# -# 1#)
1062
1063 {-# RULES
1064 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1065 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1066 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1067
1068 -- There's a built-in rule (in PrelRules.lhs) for
1069 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1070
1071   #-}
1072 \end{code}
1073
1074 #ifdef __HADDOCK__
1075 \begin{code}
1076 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1077 -- indexing a state embedded in the 'Prelude.IO' monad by
1078 -- 'Control.Monad.ST.stToIO'.
1079 data RealWorld
1080 \end{code}
1081 #endif