GHC/Base.lhs

   1 \section[GHC.Base]{Module @GHC.Base@}
   2
   3 The overall structure of the GHC Prelude is a bit tricky.
   4
   5   a) We want to avoid "orphan modules", i.e. ones with instance
   6         decls that don't belong either to a tycon or a class
   7         defined in the same module
   8
   9   b) We want to avoid giant modules
  10
  11 So the rough structure is as follows, in (linearised) dependency order
  12
  13
  14 GHC.Prim                Has no implementation.  It defines built-in things, and
  15                 by importing it you bring them into scope.
  16                 The source file is GHC.Prim.hi-boot, which is just
  17                 copied to make GHC.Prim.hi
  18
  19 GHC.Base        Classes: Eq, Ord, Functor, Monad
  20                 Types:   list, (), Int, Bool, Ordering, Char, String
  21
  22 Data.Tuple      Types: tuples, plus instances for GHC.Base classes
  23
  24 GHC.Show        Class: Show, plus instances for GHC.Base/GHC.Tup types
  25
  26 GHC.Enum        Class: Enum,  plus instances for GHC.Base/GHC.Tup types
  27
  28 Data.Maybe      Type: Maybe, plus instances for GHC.Base classes
  29
  30 GHC.List        List functions
  31
  32 GHC.Num         Class: Num, plus instances for Int
  33                 Type:  Integer, plus instances for all classes so far (Eq, Ord, Num, Show)
  34
  35                 Integer is needed here because it is mentioned in the signature
  36                 of 'fromInteger' in class Num
  37
  38 GHC.Real        Classes: Real, Integral, Fractional, RealFrac
  39                          plus instances for Int, Integer
  40                 Types:  Ratio, Rational
  41                         plus intances for classes so far
  42
  43                 Rational is needed here because it is mentioned in the signature
  44                 of 'toRational' in class Real
  45
  46 GHC.ST  The ST monad, instances and a few helper functions
  47
  48 Ix              Classes: Ix, plus instances for Int, Bool, Char, Integer, Ordering, tuples
  49
  50 GHC.Arr         Types: Array, MutableArray, MutableVar
  51
  52                 Arrays are used by a function in GHC.Float
  53
  54 GHC.Float       Classes: Floating, RealFloat
  55                 Types:   Float, Double, plus instances of all classes so far
  56
  57                 This module contains everything to do with floating point.
  58                 It is a big module (900 lines)
  59                 With a bit of luck, many modules can be compiled without ever reading GHC.Float.hi
  60
  61
  62 Other Prelude modules are much easier with fewer complex dependencies.
  63
  64 \begin{code}
  65 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
  66 {-# OPTIONS_HADDOCK hide #-}
  67 -----------------------------------------------------------------------------
  68 -- |
  69 -- Module      :  GHC.Base
  70 -- Copyright   :  (c) The University of Glasgow, 1992-2002
  71 -- License     :  see libraries/base/LICENSE
  72 --
  73 -- Maintainer  :  cvs-ghc@haskell.org
  74 -- Stability   :  internal
  75 -- Portability :  non-portable (GHC extensions)
  76 --
  77 -- Basic data types and classes.
  78 --
  79 -----------------------------------------------------------------------------
  80
  81 #include "MachDeps.h"
  82
  83 -- #hide
  84 module GHC.Base
  85         (
  86         module GHC.Base,
  87         module GHC.Bool,
  88         module GHC.Generics,
  89         module GHC.Ordering,
  90         module GHC.Prim,        -- Re-export GHC.Prim and GHC.Err, to avoid lots
  91         module GHC.Err          -- of people having to import it explicitly
  92   )
  93         where
  94
  95 import GHC.Bool
  96 import GHC.Generics
  97 import GHC.Ordering
  98 import GHC.Prim
  99 import {-# SOURCE #-} GHC.Err
 100
 101 infixr 9  .
 102 infixr 5  ++
 103 infix  4  ==, /=, <, <=, >=, >
 104 infixr 3  &&
 105 infixr 2  ||
 106 infixl 1  >>, >>=
 107 infixr 0  $
 108
 109 default ()              -- Double isn't available yet
 110 \end{code}
 111
 112
 113 %*********************************************************
 114 %*                                                      *
 115 \subsection{DEBUGGING STUFF}
 116 %*  (for use when compiling GHC.Base itself doesn't work)
 117 %*                                                      *
 118 %*********************************************************
 119
 120 \begin{code}
 121 {-
 122 data  Bool  =  False | True
 123 data Ordering = LT | EQ | GT
 124 data Char = C# Char#
 125 type  String = [Char]
 126 data Int = I# Int#
 127 data  ()  =  ()
 128 data [] a = MkNil
 129
 130 not True = False
 131 (&&) True True = True
 132 otherwise = True
 133
 134 build = error "urk"
 135 foldr = error "urk"
 136
 137 unpackCString# :: Addr# -> [Char]
 138 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
 139 unpackAppendCString# :: Addr# -> [Char] -> [Char]
 140 unpackCStringUtf8# :: Addr# -> [Char]
 141 unpackCString# a = error "urk"
 142 unpackFoldrCString# a = error "urk"
 143 unpackAppendCString# a = error "urk"
 144 unpackCStringUtf8# a = error "urk"
 145 -}
 146 \end{code}
 147
 148
 149 %*********************************************************
 150 %*                                                      *
 151 \subsection{Standard classes @Eq@, @Ord@}
 152 %*                                                      *
 153 %*********************************************************
 154
 155 \begin{code}
 156
 157 -- | The 'Eq' class defines equality ('==') and inequality ('/=').
 158 -- All the basic datatypes exported by the "Prelude" are instances of 'Eq',
 159 -- and 'Eq' may be derived for any datatype whose constituents are also
 160 -- instances of 'Eq'.
 161 --
 162 -- Minimal complete definition: either '==' or '/='.
 163 --
 164 class  Eq a  where
 165     (==), (/=)           :: a -> a -> Bool
 166
 167     x /= y               = not (x == y)
 168     x == y               = not (x /= y)
 169
 170 -- | The 'Ord' class is used for totally ordered datatypes.
 171 --
 172 -- Instances of 'Ord' can be derived for any user-defined
 173 -- datatype whose constituent types are in 'Ord'.  The declared order
 174 -- of the constructors in the data declaration determines the ordering
 175 -- in derived 'Ord' instances.  The 'Ordering' datatype allows a single
 176 -- comparison to determine the precise ordering of two objects.
 177 --
 178 -- Minimal complete definition: either 'compare' or '<='.
 179 -- Using 'compare' can be more efficient for complex types.
 180 --
 181 class  (Eq a) => Ord a  where
 182     compare              :: a -> a -> Ordering
 183     (<), (<=), (>), (>=) :: a -> a -> Bool
 184     max, min             :: a -> a -> a
 185
 186     compare x y
 187         | x == y    = EQ
 188         | x <= y    = LT        -- NB: must be '<=' not '<' to validate the
 189                                 -- above claim about the minimal things that
 190                                 -- can be defined for an instance of Ord
 191         | otherwise = GT
 192
 193     x <  y = case compare x y of { LT -> True;  _other -> False }
 194     x <= y = case compare x y of { GT -> False; _other -> True }
 195     x >  y = case compare x y of { GT -> True;  _other -> False }
 196     x >= y = case compare x y of { LT -> False; _other -> True }
 197
 198         -- These two default methods use '<=' rather than 'compare'
 199         -- because the latter is often more expensive
 200     max x y = if x <= y then y else x
 201     min x y = if x <= y then x else y
 202 \end{code}
 203
 204 %*********************************************************
 205 %*                                                      *
 206 \subsection{Monadic classes @Functor@, @Monad@ }
 207 %*                                                      *
 208 %*********************************************************
 209
 210 \begin{code}
 211 {- | The 'Functor' class is used for types that can be mapped over.
 212 Instances of 'Functor' should satisfy the following laws:
 213
 214 > fmap id  ==  id
 215 > fmap (f . g)  ==  fmap f . fmap g
 216
 217 The instances of 'Functor' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 218 defined in the "Prelude" satisfy these laws.
 219 -}
 220
 221 class  Functor f  where
 222     fmap        :: (a -> b) -> f a -> f b
 223
 224 {- | The 'Monad' class defines the basic operations over a /monad/,
 225 a concept from a branch of mathematics known as /category theory/.
 226 From the perspective of a Haskell programmer, however, it is best to
 227 think of a monad as an /abstract datatype/ of actions.
 228 Haskell's @do@ expressions provide a convenient syntax for writing
 229 monadic expressions.
 230
 231 Minimal complete definition: '>>=' and 'return'.
 232
 233 Instances of 'Monad' should satisfy the following laws:
 234
 235 > return a >>= k  ==  k a
 236 > m >>= return  ==  m
 237 > m >>= (\x -> k x >>= h)  ==  (m >>= k) >>= h
 238
 239 Instances of both 'Monad' and 'Functor' should additionally satisfy the law:
 240
 241 > fmap f xs  ==  xs >>= return . f
 242
 243 The instances of 'Monad' for lists, 'Data.Maybe.Maybe' and 'System.IO.IO'
 244 defined in the "Prelude" satisfy these laws.
 245 -}
 246
 247 class  Monad m  where
 248     -- | Sequentially compose two actions, passing any value produced
 249     -- by the first as an argument to the second.
 250     (>>=)       :: forall a b. m a -> (a -> m b) -> m b
 251     -- | Sequentially compose two actions, discarding any value produced
 252     -- by the first, like sequencing operators (such as the semicolon)
 253     -- in imperative languages.
 254     (>>)        :: forall a b. m a -> m b -> m b
 255         -- Explicit for-alls so that we know what order to
 256         -- give type arguments when desugaring
 257
 258     -- | Inject a value into the monadic type.
 259     return      :: a -> m a
 260     -- | Fail with a message.  This operation is not part of the
 261     -- mathematical definition of a monad, but is invoked on pattern-match
 262     -- failure in a @do@ expression.
 263     fail        :: String -> m a
 264
 265     m >> k      = m >>= \_ -> k
 266     fail s      = error s
 267 \end{code}
 268
 269
 270 %*********************************************************
 271 %*                                                      *
 272 \subsection{The list type}
 273 %*                                                      *
 274 %*********************************************************
 275
 276 \begin{code}
 277 -- do explicitly: deriving (Eq, Ord)
 278 -- to avoid weird names like con2tag_[]#
 279
 280 instance (Eq a) => Eq [a] where
 281     {-# SPECIALISE instance Eq [Char] #-}
 282     []     == []     = True
 283     (x:xs) == (y:ys) = x == y && xs == ys
 284     _xs    == _ys    = False
 285
 286 instance (Ord a) => Ord [a] where
 287     {-# SPECIALISE instance Ord [Char] #-}
 288     compare []     []     = EQ
 289     compare []     (_:_)  = LT
 290     compare (_:_)  []     = GT
 291     compare (x:xs) (y:ys) = case compare x y of
 292                                 EQ    -> compare xs ys
 293                                 other -> other
 294
 295 instance Functor [] where
 296     fmap = map
 297
 298 instance  Monad []  where
 299     m >>= k             = foldr ((++) . k) [] m
 300     m >> k              = foldr ((++) . (\ _ -> k)) [] m
 301     return x            = [x]
 302     fail _              = []
 303 \end{code}
 304
 305 A few list functions that appear here because they are used here.
 306 The rest of the prelude list functions are in GHC.List.
 307
 308 ----------------------------------------------
 309 --      foldr/build/augment
 310 ----------------------------------------------
 311
 312 \begin{code}
 313 -- | 'foldr', applied to a binary operator, a starting value (typically
 314 -- the right-identity of the operator), and a list, reduces the list
 315 -- using the binary operator, from right to left:
 316 --
 317 -- > foldr f z [x1, x2, ..., xn] == x1 `f` (x2 `f` ... (xn `f` z)...)
 318
 319 foldr            :: (a -> b -> b) -> b -> [a] -> b
 320 -- foldr _ z []     =  z
 321 -- foldr f z (x:xs) =  f x (foldr f z xs)
 322 {-# INLINE [0] foldr #-}
 323 -- Inline only in the final stage, after the foldr/cons rule has had a chance
 324 foldr k z xs = go xs
 325              where
 326                go []     = z
 327                go (y:ys) = y `k` go ys
 328
 329 -- | A list producer that can be fused with 'foldr'.
 330 -- This function is merely
 331 --
 332 -- >    build g = g (:) []
 333 --
 334 -- but GHC's simplifier will transform an expression of the form
 335 -- @'foldr' k z ('build' g)@, which may arise after inlining, to @g k z@,
 336 -- which avoids producing an intermediate list.
 337
 338 build   :: forall a. (forall b. (a -> b -> b) -> b -> b) -> [a]
 339 {-# INLINE [1] build #-}
 340         -- The INLINE is important, even though build is tiny,
 341         -- because it prevents [] getting inlined in the version that
 342         -- appears in the interface file.  If [] *is* inlined, it
 343         -- won't match with [] appearing in rules in an importing module.
 344         --
 345         -- The "1" says to inline in phase 1
 346
 347 build g = g (:) []
 348
 349 -- | A list producer that can be fused with 'foldr'.
 350 -- This function is merely
 351 --
 352 -- >    augment g xs = g (:) xs
 353 --
 354 -- but GHC's simplifier will transform an expression of the form
 355 -- @'foldr' k z ('augment' g xs)@, which may arise after inlining, to
 356 -- @g k ('foldr' k z xs)@, which avoids producing an intermediate list.
 357
 358 augment :: forall a. (forall b. (a->b->b) -> b -> b) -> [a] -> [a]
 359 {-# INLINE [1] augment #-}
 360 augment g xs = g (:) xs
 361
 362 {-# RULES
 363 "fold/build"    forall k z (g::forall b. (a->b->b) -> b -> b) .
 364                 foldr k z (build g) = g k z
 365
 366 "foldr/augment" forall k z xs (g::forall b. (a->b->b) -> b -> b) .
 367                 foldr k z (augment g xs) = g k (foldr k z xs)
 368
 369 "foldr/id"                        foldr (:) [] = \x  -> x
 370 "foldr/app"     [1] forall ys. foldr (:) ys = \xs -> xs ++ ys
 371         -- Only activate this from phase 1, because that's
 372         -- when we disable the rule that expands (++) into foldr
 373
 374 -- The foldr/cons rule looks nice, but it can give disastrously
 375 -- bloated code when commpiling
 376 --      array (a,b) [(1,2), (2,2), (3,2), ...very long list... ]
 377 -- i.e. when there are very very long literal lists
 378 -- So I've disabled it for now. We could have special cases
 379 -- for short lists, I suppose.
 380 -- "foldr/cons" forall k z x xs. foldr k z (x:xs) = k x (foldr k z xs)
 381
 382 "foldr/single"  forall k z x. foldr k z [x] = k x z
 383 "foldr/nil"     forall k z.   foldr k z []  = z
 384
 385 "augment/build" forall (g::forall b. (a->b->b) -> b -> b)
 386                        (h::forall b. (a->b->b) -> b -> b) .
 387                        augment g (build h) = build (\c n -> g c (h c n))
 388 "augment/nil"   forall (g::forall b. (a->b->b) -> b -> b) .
 389                         augment g [] = build g
 390  #-}
 391
 392 -- This rule is true, but not (I think) useful:
 393 --      augment g (augment h t) = augment (\cn -> g c (h c n)) t
 394 \end{code}
 395
 396
 397 ----------------------------------------------
 398 --              map
 399 ----------------------------------------------
 400
 401 \begin{code}
 402 -- | 'map' @f xs@ is the list obtained by applying @f@ to each element
 403 -- of @xs@, i.e.,
 404 --
 405 -- > map f [x1, x2, ..., xn] == [f x1, f x2, ..., f xn]
 406 -- > map f [x1, x2, ...] == [f x1, f x2, ...]
 407
 408 map :: (a -> b) -> [a] -> [b]
 409 map _ []     = []
 410 map f (x:xs) = f x : map f xs
 411
 412 -- Note eta expanded
 413 mapFB ::  (elt -> lst -> lst) -> (a -> elt) -> a -> lst -> lst
 414 {-# INLINE [0] mapFB #-}
 415 mapFB c f x ys = c (f x) ys
 416
 417 -- The rules for map work like this.
 418 --
 419 -- Up to (but not including) phase 1, we use the "map" rule to
 420 -- rewrite all saturated applications of map with its build/fold
 421 -- form, hoping for fusion to happen.
 422 -- In phase 1 and 0, we switch off that rule, inline build, and
 423 -- switch on the "mapList" rule, which rewrites the foldr/mapFB
 424 -- thing back into plain map.
 425 --
 426 -- It's important that these two rules aren't both active at once
 427 -- (along with build's unfolding) else we'd get an infinite loop
 428 -- in the rules.  Hence the activation control below.
 429 --
 430 -- The "mapFB" rule optimises compositions of map.
 431 --
 432 -- This same pattern is followed by many other functions:
 433 -- e.g. append, filter, iterate, repeat, etc.
 434
 435 {-# RULES
 436 "map"       [~1] forall f xs.   map f xs                = build (\c n -> foldr (mapFB c f) n xs)
 437 "mapList"   [1]  forall f.      foldr (mapFB (:) f) []  = map f
 438 "mapFB"     forall c f g.       mapFB (mapFB c f) g     = mapFB c (f.g)
 439   #-}
 440 \end{code}
 441
 442
 443 ----------------------------------------------
 444 --              append
 445 ----------------------------------------------
 446 \begin{code}
 447 -- | Append two lists, i.e.,
 448 --
 449 -- > [x1, ..., xm] ++ [y1, ..., yn] == [x1, ..., xm, y1, ..., yn]
 450 -- > [x1, ..., xm] ++ [y1, ...] == [x1, ..., xm, y1, ...]
 451 --
 452 -- If the first list is not finite, the result is the first list.
 453
 454 (++) :: [a] -> [a] -> [a]
 455 (++) []     ys = ys
 456 (++) (x:xs) ys = x : xs ++ ys
 457
 458 {-# RULES
 459 "++"    [~1] forall xs ys. xs ++ ys = augment (\c n -> foldr c n xs) ys
 460   #-}
 461
 462 \end{code}
 463
 464
 465 %*********************************************************
 466 %*                                                      *
 467 \subsection{Type @Bool@}
 468 %*                                                      *
 469 %*********************************************************
 470
 471 \begin{code}
 472 -- |The 'Bool' type is an enumeration.  It is defined with 'False'
 473 -- first so that the corresponding 'Prelude.Enum' instance will give
 474 -- 'Prelude.fromEnum' 'False' the value zero, and
 475 -- 'Prelude.fromEnum' 'True' the value 1.
 476 -- The actual definition is in the ghc-prim package.
 477
 478 -- XXX These don't work:
 479 -- deriving instance Eq Bool
 480 -- deriving instance Ord Bool
 481 -- <wired into compiler>:
 482 --     Illegal binding of built-in syntax: con2tag_Bool#
 483
 484 instance Eq Bool where
 485     True  == True  = True
 486     False == False = True
 487     _     == _     = False
 488
 489 instance Ord Bool where
 490     compare False True  = LT
 491     compare True  False = GT
 492     compare _     _     = EQ
 493
 494 -- Read is in GHC.Read, Show in GHC.Show
 495
 496 -- Boolean functions
 497
 498 -- | Boolean \"and\"
 499 (&&)                    :: Bool -> Bool -> Bool
 500 True  && x              =  x
 501 False && _              =  False
 502
 503 -- | Boolean \"or\"
 504 (||)                    :: Bool -> Bool -> Bool
 505 True  || _              =  True
 506 False || x              =  x
 507
 508 -- | Boolean \"not\"
 509 not                     :: Bool -> Bool
 510 not True                =  False
 511 not False               =  True
 512
 513 -- |'otherwise' is defined as the value 'True'.  It helps to make
 514 -- guards more readable.  eg.
 515 --
 516 -- >  f x | x < 0     = ...
 517 -- >      | otherwise = ...
 518 otherwise               :: Bool
 519 otherwise               =  True
 520 \end{code}
 521
 522 %*********************************************************
 523 %*                                                      *
 524 \subsection{Type @Ordering@}
 525 %*                                                      *
 526 %*********************************************************
 527
 528 \begin{code}
 529 -- | Represents an ordering relationship between two values: less
 530 -- than, equal to, or greater than.  An 'Ordering' is returned by
 531 -- 'compare'.
 532 -- XXX These don't work:
 533 -- deriving instance Eq Ordering
 534 -- deriving instance Ord Ordering
 535 -- Illegal binding of built-in syntax: con2tag_Ordering#
 536 instance Eq Ordering where
 537     EQ == EQ = True
 538     LT == LT = True
 539     GT == GT = True
 540     _  == _  = False
 541         -- Read in GHC.Read, Show in GHC.Show
 542
 543 instance Ord Ordering where
 544     LT <= _  = True
 545     _  <= LT = False
 546     EQ <= _  = True
 547     _  <= EQ = False
 548     GT <= GT = True
 549 \end{code}
 550
 551
 552 %*********************************************************
 553 %*                                                      *
 554 \subsection{Type @Char@ and @String@}
 555 %*                                                      *
 556 %*********************************************************
 557
 558 \begin{code}
 559 -- | A 'String' is a list of characters.  String constants in Haskell are values
 560 -- of type 'String'.
 561 --
 562 type String = [Char]
 563
 564 {-| The character type 'Char' is an enumeration whose values represent
 565 Unicode (or equivalently ISO\/IEC 10646) characters
 566 (see <http://www.unicode.org/> for details).
 567 This set extends the ISO 8859-1 (Latin-1) character set
 568 (the first 256 charachers), which is itself an extension of the ASCII
 569 character set (the first 128 characters).
 570 A character literal in Haskell has type 'Char'.
 571
 572 To convert a 'Char' to or from the corresponding 'Int' value defined
 573 by Unicode, use 'Prelude.toEnum' and 'Prelude.fromEnum' from the
 574 'Prelude.Enum' class respectively (or equivalently 'ord' and 'chr').
 575 -}
 576 data Char = C# Char#
 577
 578 -- We don't use deriving for Eq and Ord, because for Ord the derived
 579 -- instance defines only compare, which takes two primops.  Then
 580 -- '>' uses compare, and therefore takes two primops instead of one.
 581
 582 instance Eq Char where
 583     (C# c1) == (C# c2) = c1 `eqChar#` c2
 584     (C# c1) /= (C# c2) = c1 `neChar#` c2
 585
 586 instance Ord Char where
 587     (C# c1) >  (C# c2) = c1 `gtChar#` c2
 588     (C# c1) >= (C# c2) = c1 `geChar#` c2
 589     (C# c1) <= (C# c2) = c1 `leChar#` c2
 590     (C# c1) <  (C# c2) = c1 `ltChar#` c2
 591
 592 {-# RULES
 593 "x# `eqChar#` x#" forall x#. x# `eqChar#` x# = True
 594 "x# `neChar#` x#" forall x#. x# `neChar#` x# = False
 595 "x# `gtChar#` x#" forall x#. x# `gtChar#` x# = False
 596 "x# `geChar#` x#" forall x#. x# `geChar#` x# = True
 597 "x# `leChar#` x#" forall x#. x# `leChar#` x# = True
 598 "x# `ltChar#` x#" forall x#. x# `ltChar#` x# = False
 599   #-}
 600
 601 -- | The 'Prelude.toEnum' method restricted to the type 'Data.Char.Char'.
 602 chr :: Int -> Char
 603 chr (I# i#) | int2Word# i# `leWord#` int2Word# 0x10FFFF# = C# (chr# i#)
 604             | otherwise                                  = error "Prelude.chr: bad argument"
 605
 606 unsafeChr :: Int -> Char
 607 unsafeChr (I# i#) = C# (chr# i#)
 608
 609 -- | The 'Prelude.fromEnum' method restricted to the type 'Data.Char.Char'.
 610 ord :: Char -> Int
 611 ord (C# c#) = I# (ord# c#)
 612 \end{code}
 613
 614 String equality is used when desugaring pattern-matches against strings.
 615
 616 \begin{code}
 617 eqString :: String -> String -> Bool
 618 eqString []       []       = True
 619 eqString (c1:cs1) (c2:cs2) = c1 == c2 && cs1 `eqString` cs2
 620 eqString _        _        = False
 621
 622 {-# RULES "eqString" (==) = eqString #-}
 623 -- eqString also has a BuiltInRule in PrelRules.lhs:
 624 --      eqString (unpackCString# (Lit s1)) (unpackCString# (Lit s2) = s1==s2
 625 \end{code}
 626
 627
 628 %*********************************************************
 629 %*                                                      *
 630 \subsection{Type @Int@}
 631 %*                                                      *
 632 %*********************************************************
 633
 634 \begin{code}
 635 data Int = I# Int#
 636 -- ^A fixed-precision integer type with at least the range @[-2^29 .. 2^29-1]@.
 637 -- The exact range for a given implementation can be determined by using
 638 -- 'Prelude.minBound' and 'Prelude.maxBound' from the 'Prelude.Bounded' class.
 639
 640 zeroInt, oneInt, twoInt, maxInt, minInt :: Int
 641 zeroInt = I# 0#
 642 oneInt  = I# 1#
 643 twoInt  = I# 2#
 644
 645 {- Seems clumsy. Should perhaps put minInt and MaxInt directly into MachDeps.h -}
 646 #if WORD_SIZE_IN_BITS == 31
 647 minInt  = I# (-0x40000000#)
 648 maxInt  = I# 0x3FFFFFFF#
 649 #elif WORD_SIZE_IN_BITS == 32
 650 minInt  = I# (-0x80000000#)
 651 maxInt  = I# 0x7FFFFFFF#
 652 #else
 653 minInt  = I# (-0x8000000000000000#)
 654 maxInt  = I# 0x7FFFFFFFFFFFFFFF#
 655 #endif
 656
 657 instance Eq Int where
 658     (==) = eqInt
 659     (/=) = neInt
 660
 661 instance Ord Int where
 662     compare = compareInt
 663     (<)     = ltInt
 664     (<=)    = leInt
 665     (>=)    = geInt
 666     (>)     = gtInt
 667
 668 compareInt :: Int -> Int -> Ordering
 669 (I# x#) `compareInt` (I# y#) = compareInt# x# y#
 670
 671 compareInt# :: Int# -> Int# -> Ordering
 672 compareInt# x# y#
 673     | x# <#  y# = LT
 674     | x# ==# y# = EQ
 675     | otherwise = GT
 676 \end{code}
 677
 678
 679 %*********************************************************
 680 %*                                                      *
 681 \subsection{The function type}
 682 %*                                                      *
 683 %*********************************************************
 684
 685 \begin{code}
 686 -- | Identity function.
 687 id                      :: a -> a
 688 id x                    =  x
 689
 690 -- | The call '(lazy e)' means the same as 'e', but 'lazy' has a
 691 -- magical strictness property: it is lazy in its first argument,
 692 -- even though its semantics is strict.
 693 lazy :: a -> a
 694 lazy x = x
 695 -- Implementation note: its strictness and unfolding are over-ridden
 696 -- by the definition in MkId.lhs; in both cases to nothing at all.
 697 -- That way, 'lazy' does not get inlined, and the strictness analyser
 698 -- sees it as lazy.  Then the worker/wrapper phase inlines it.
 699 -- Result: happiness
 700
 701
 702 -- | The call '(inline f)' reduces to 'f', but 'inline' has a BuiltInRule
 703 -- that tries to inline 'f' (if it has an unfolding) unconditionally
 704 -- The 'NOINLINE' pragma arranges that inline only gets inlined (and
 705 -- hence eliminated) late in compilation, after the rule has had
 706 -- a god chance to fire.
 707 inline :: a -> a
 708 {-# NOINLINE[0] inline #-}
 709 inline x = x
 710
 711 -- Assertion function.  This simply ignores its boolean argument.
 712 -- The compiler may rewrite it to @('assertError' line)@.
 713
 714 -- | If the first argument evaluates to 'True', then the result is the
 715 -- second argument.  Otherwise an 'AssertionFailed' exception is raised,
 716 -- containing a 'String' with the source file and line number of the
 717 -- call to 'assert'.
 718 --
 719 -- Assertions can normally be turned on or off with a compiler flag
 720 -- (for GHC, assertions are normally on unless optimisation is turned on
 721 -- with @-O@ or the @-fignore-asserts@
 722 -- option is given).  When assertions are turned off, the first
 723 -- argument to 'assert' is ignored, and the second argument is
 724 -- returned as the result.
 725
 726 --      SLPJ: in 5.04 etc 'assert' is in GHC.Prim,
 727 --      but from Template Haskell onwards it's simply
 728 --      defined here in Base.lhs
 729 assert :: Bool -> a -> a
 730 assert _pred r = r
 731
 732 breakpoint :: a -> a
 733 breakpoint r = r
 734
 735 breakpointCond :: Bool -> a -> a
 736 breakpointCond _ r = r
 737
 738 data Opaque = forall a. O a
 739
 740 -- | Constant function.
 741 const                   :: a -> b -> a
 742 const x _               =  x
 743
 744 -- | Function composition.
 745 {-# INLINE (.) #-}
 746 (.)       :: (b -> c) -> (a -> b) -> a -> c
 747 (.) f g x = f (g x)
 748
 749 -- | @'flip' f@ takes its (first) two arguments in the reverse order of @f@.
 750 flip                    :: (a -> b -> c) -> b -> a -> c
 751 flip f x y              =  f y x
 752
 753 -- | Application operator.  This operator is redundant, since ordinary
 754 -- application @(f x)@ means the same as @(f '$' x)@. However, '$' has
 755 -- low, right-associative binding precedence, so it sometimes allows
 756 -- parentheses to be omitted; for example:
 757 --
 758 -- >     f $ g $ h x  =  f (g (h x))
 759 --
 760 -- It is also useful in higher-order situations, such as @'map' ('$' 0) xs@,
 761 -- or @'Data.List.zipWith' ('$') fs xs@.
 762 {-# INLINE ($) #-}
 763 ($)                     :: (a -> b) -> a -> b
 764 f $ x                   =  f x
 765
 766 -- | @'until' p f@ yields the result of applying @f@ until @p@ holds.
 767 until                   :: (a -> Bool) -> (a -> a) -> a -> a
 768 until p f x | p x       =  x
 769             | otherwise =  until p f (f x)
 770
 771 -- | 'asTypeOf' is a type-restricted version of 'const'.  It is usually
 772 -- used as an infix operator, and its typing forces its first argument
 773 -- (which is usually overloaded) to have the same type as the second.
 774 asTypeOf                :: a -> a -> a
 775 asTypeOf                =  const
 776 \end{code}
 777
 778 %*********************************************************
 779 %*                                                      *
 780 \subsection{@getTag@}
 781 %*                                                      *
 782 %*********************************************************
 783
 784 Returns the 'tag' of a constructor application; this function is used
 785 by the deriving code for Eq, Ord and Enum.
 786
 787 The primitive dataToTag# requires an evaluated constructor application
 788 as its argument, so we provide getTag as a wrapper that performs the
 789 evaluation before calling dataToTag#.  We could have dataToTag#
 790 evaluate its argument, but we prefer to do it this way because (a)
 791 dataToTag# can be an inline primop if it doesn't need to do any
 792 evaluation, and (b) we want to expose the evaluation to the
 793 simplifier, because it might be possible to eliminate the evaluation
 794 in the case when the argument is already known to be evaluated.
 795
 796 \begin{code}
 797 {-# INLINE getTag #-}
 798 getTag :: a -> Int#
 799 getTag x = x `seq` dataToTag# x
 800 \end{code}
 801
 802 %*********************************************************
 803 %*                                                      *
 804 \subsection{Numeric primops}
 805 %*                                                      *
 806 %*********************************************************
 807
 808 \begin{code}
 809 divInt# :: Int# -> Int# -> Int#
 810 x# `divInt#` y#
 811         -- Be careful NOT to overflow if we do any additional arithmetic
 812         -- on the arguments...  the following  previous version of this
 813         -- code has problems with overflow:
 814 --    | (x# ># 0#) && (y# <# 0#) = ((x# -# y#) -# 1#) `quotInt#` y#
 815 --    | (x# <# 0#) && (y# ># 0#) = ((x# -# y#) +# 1#) `quotInt#` y#
 816     | (x# ># 0#) && (y# <# 0#) = ((x# -# 1#) `quotInt#` y#) -# 1#
 817     | (x# <# 0#) && (y# ># 0#) = ((x# +# 1#) `quotInt#` y#) -# 1#
 818     | otherwise                = x# `quotInt#` y#
 819
 820 modInt# :: Int# -> Int# -> Int#
 821 x# `modInt#` y#
 822     | (x# ># 0#) && (y# <# 0#) ||
 823       (x# <# 0#) && (y# ># 0#)    = if r# /=# 0# then r# +# y# else 0#
 824     | otherwise                   = r#
 825     where
 826     r# = x# `remInt#` y#
 827 \end{code}
 828
 829 Definitions of the boxed PrimOps; these will be
 830 used in the case of partial applications, etc.
 831
 832 \begin{code}
 833 {-# INLINE eqInt #-}
 834 {-# INLINE neInt #-}
 835 {-# INLINE gtInt #-}
 836 {-# INLINE geInt #-}
 837 {-# INLINE ltInt #-}
 838 {-# INLINE leInt #-}
 839 {-# INLINE plusInt #-}
 840 {-# INLINE minusInt #-}
 841 {-# INLINE timesInt #-}
 842 {-# INLINE quotInt #-}
 843 {-# INLINE remInt #-}
 844 {-# INLINE negateInt #-}
 845
 846 plusInt, minusInt, timesInt, quotInt, remInt, divInt, modInt, gcdInt :: Int -> Int -> Int
 847 (I# x) `plusInt`  (I# y) = I# (x +# y)
 848 (I# x) `minusInt` (I# y) = I# (x -# y)
 849 (I# x) `timesInt` (I# y) = I# (x *# y)
 850 (I# x) `quotInt`  (I# y) = I# (x `quotInt#` y)
 851 (I# x) `remInt`   (I# y) = I# (x `remInt#`  y)
 852 (I# x) `divInt`   (I# y) = I# (x `divInt#`  y)
 853 (I# x) `modInt`   (I# y) = I# (x `modInt#`  y)
 854
 855 {-# RULES
 856 "x# +# 0#" forall x#. x# +# 0# = x#
 857 "0# +# x#" forall x#. 0# +# x# = x#
 858 "x# -# 0#" forall x#. x# -# 0# = x#
 859 "x# -# x#" forall x#. x# -# x# = 0#
 860 "x# *# 0#" forall x#. x# *# 0# = 0#
 861 "0# *# x#" forall x#. 0# *# x# = 0#
 862 "x# *# 1#" forall x#. x# *# 1# = x#
 863 "1# *# x#" forall x#. 1# *# x# = x#
 864   #-}
 865
 866 gcdInt (I# a) (I# b) = g a b
 867    where g 0# 0# = error "GHC.Base.gcdInt: gcd 0 0 is undefined"
 868          g 0# _  = I# absB
 869          g _  0# = I# absA
 870          g _  _  = I# (gcdInt# absA absB)
 871
 872          absInt x = if x <# 0# then negateInt# x else x
 873
 874          absA     = absInt a
 875          absB     = absInt b
 876
 877 negateInt :: Int -> Int
 878 negateInt (I# x) = I# (negateInt# x)
 879
 880 gtInt, geInt, eqInt, neInt, ltInt, leInt :: Int -> Int -> Bool
 881 (I# x) `gtInt` (I# y) = x >#  y
 882 (I# x) `geInt` (I# y) = x >=# y
 883 (I# x) `eqInt` (I# y) = x ==# y
 884 (I# x) `neInt` (I# y) = x /=# y
 885 (I# x) `ltInt` (I# y) = x <#  y
 886 (I# x) `leInt` (I# y) = x <=# y
 887
 888 {-# RULES
 889 "x# ># x#"  forall x#. x# >#  x# = False
 890 "x# >=# x#" forall x#. x# >=# x# = True
 891 "x# ==# x#" forall x#. x# ==# x# = True
 892 "x# /=# x#" forall x#. x# /=# x# = False
 893 "x# <# x#"  forall x#. x# <#  x# = False
 894 "x# <=# x#" forall x#. x# <=# x# = True
 895   #-}
 896
 897 {-# RULES
 898 "plusFloat x 0.0"   forall x#. plusFloat#  x#   0.0# = x#
 899 "plusFloat 0.0 x"   forall x#. plusFloat#  0.0# x#   = x#
 900 "minusFloat x 0.0"  forall x#. minusFloat# x#   0.0# = x#
 901 "minusFloat x x"    forall x#. minusFloat# x#   x#   = 0.0#
 902 "timesFloat x 0.0"  forall x#. timesFloat# x#   0.0# = 0.0#
 903 "timesFloat0.0 x"   forall x#. timesFloat# 0.0# x#   = 0.0#
 904 "timesFloat x 1.0"  forall x#. timesFloat# x#   1.0# = x#
 905 "timesFloat 1.0 x"  forall x#. timesFloat# 1.0# x#   = x#
 906 "divideFloat x 1.0" forall x#. divideFloat# x#  1.0# = x#
 907   #-}
 908
 909 {-# RULES
 910 "plusDouble x 0.0"   forall x#. (+##) x#    0.0## = x#
 911 "plusDouble 0.0 x"   forall x#. (+##) 0.0## x#    = x#
 912 "minusDouble x 0.0"  forall x#. (-##) x#    0.0## = x#
 913 "timesDouble x 1.0"  forall x#. (*##) x#    1.0## = x#
 914 "timesDouble 1.0 x"  forall x#. (*##) 1.0## x#    = x#
 915 "divideDouble x 1.0" forall x#. (/##) x#    1.0## = x#
 916   #-}
 917
 918 {-
 919 We'd like to have more rules, but for example:
 920
 921 This gives wrong answer (0) for NaN - NaN (should be NaN):
 922     "minusDouble x x"    forall x#. (-##) x#    x#    = 0.0##
 923
 924 This gives wrong answer (0) for 0 * NaN (should be NaN):
 925     "timesDouble 0.0 x"  forall x#. (*##) 0.0## x#    = 0.0##
 926
 927 This gives wrong answer (0) for NaN * 0 (should be NaN):
 928     "timesDouble x 0.0"  forall x#. (*##) x#    0.0## = 0.0##
 929
 930 These are tested by num014.
 931 -}
 932
 933 -- Wrappers for the shift operations.  The uncheckedShift# family are
 934 -- undefined when the amount being shifted by is greater than the size
 935 -- in bits of Int#, so these wrappers perform a check and return
 936 -- either zero or -1 appropriately.
 937 --
 938 -- Note that these wrappers still produce undefined results when the
 939 -- second argument (the shift amount) is negative.
 940
 941 -- | Shift the argument left by the specified number of bits
 942 -- (which must be non-negative).
 943 shiftL# :: Word# -> Int# -> Word#
 944 a `shiftL#` b   | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 945                 | otherwise                = a `uncheckedShiftL#` b
 946
 947 -- | Shift the argument right by the specified number of bits
 948 -- (which must be non-negative).
 949 shiftRL# :: Word# -> Int# -> Word#
 950 a `shiftRL#` b  | b >=# WORD_SIZE_IN_BITS# = int2Word# 0#
 951                 | otherwise                = a `uncheckedShiftRL#` b
 952
 953 -- | Shift the argument left by the specified number of bits
 954 -- (which must be non-negative).
 955 iShiftL# :: Int# -> Int# -> Int#
 956 a `iShiftL#` b  | b >=# WORD_SIZE_IN_BITS# = 0#
 957                 | otherwise                = a `uncheckedIShiftL#` b
 958
 959 -- | Shift the argument right (signed) by the specified number of bits
 960 -- (which must be non-negative).
 961 iShiftRA# :: Int# -> Int# -> Int#
 962 a `iShiftRA#` b | b >=# WORD_SIZE_IN_BITS# = if a <# 0# then (-1#) else 0#
 963                 | otherwise                = a `uncheckedIShiftRA#` b
 964
 965 -- | Shift the argument right (unsigned) by the specified number of bits
 966 -- (which must be non-negative).
 967 iShiftRL# :: Int# -> Int# -> Int#
 968 a `iShiftRL#` b | b >=# WORD_SIZE_IN_BITS# = 0#
 969                 | otherwise                = a `uncheckedIShiftRL#` b
 970
 971 #if WORD_SIZE_IN_BITS == 32
 972 {-# RULES
 973 "narrow32Int#"  forall x#. narrow32Int#   x# = x#
 974 "narrow32Word#" forall x#. narrow32Word#   x# = x#
 975    #-}
 976 #endif
 977
 978 {-# RULES
 979 "int2Word2Int"  forall x#. int2Word# (word2Int# x#) = x#
 980 "word2Int2Word" forall x#. word2Int# (int2Word# x#) = x#
 981   #-}
 982 \end{code}
 983
 984
 985 %********************************************************
 986 %*                                                      *
 987 \subsection{Unpacking C strings}
 988 %*                                                      *
 989 %********************************************************
 990
 991 This code is needed for virtually all programs, since it's used for
 992 unpacking the strings of error messages.
 993
 994 \begin{code}
 995 unpackCString# :: Addr# -> [Char]
 996 {-# NOINLINE [1] unpackCString# #-}
 997 unpackCString# addr
 998   = unpack 0#
 999   where
1000     unpack nh
1001       | ch `eqChar#` '\0'# = []
1002       | otherwise          = C# ch : unpack (nh +# 1#)
1003       where
1004         ch = indexCharOffAddr# addr nh
1005
1006 unpackAppendCString# :: Addr# -> [Char] -> [Char]
1007 unpackAppendCString# addr rest
1008   = unpack 0#
1009   where
1010     unpack nh
1011       | ch `eqChar#` '\0'# = rest
1012       | otherwise          = C# ch : unpack (nh +# 1#)
1013       where
1014         ch = indexCharOffAddr# addr nh
1015
1016 unpackFoldrCString# :: Addr# -> (Char  -> a -> a) -> a -> a
1017 {-# NOINLINE [0] unpackFoldrCString# #-}
1018 -- Don't inline till right at the end;
1019 -- usually the unpack-list rule turns it into unpackCStringList
1020 -- It also has a BuiltInRule in PrelRules.lhs:
1021 --      unpackFoldrCString# "foo" c (unpackFoldrCString# "baz" c n)
1022 --        =  unpackFoldrCString# "foobaz" c n
1023 unpackFoldrCString# addr f z
1024   = unpack 0#
1025   where
1026     unpack nh
1027       | ch `eqChar#` '\0'# = z
1028       | otherwise          = C# ch `f` unpack (nh +# 1#)
1029       where
1030         ch = indexCharOffAddr# addr nh
1031
1032 unpackCStringUtf8# :: Addr# -> [Char]
1033 unpackCStringUtf8# addr
1034   = unpack 0#
1035   where
1036     unpack nh
1037       | ch `eqChar#` '\0'#   = []
1038       | ch `leChar#` '\x7F'# = C# ch : unpack (nh +# 1#)
1039       | ch `leChar#` '\xDF'# =
1040           C# (chr# (((ord# ch                                  -# 0xC0#) `uncheckedIShiftL#`  6#) +#
1041                      (ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#))) :
1042           unpack (nh +# 2#)
1043       | ch `leChar#` '\xEF'# =
1044           C# (chr# (((ord# ch                                  -# 0xE0#) `uncheckedIShiftL#` 12#) +#
1045                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1046                      (ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#))) :
1047           unpack (nh +# 3#)
1048       | otherwise            =
1049           C# (chr# (((ord# ch                                  -# 0xF0#) `uncheckedIShiftL#` 18#) +#
1050                     ((ord# (indexCharOffAddr# addr (nh +# 1#)) -# 0x80#) `uncheckedIShiftL#` 12#) +#
1051                     ((ord# (indexCharOffAddr# addr (nh +# 2#)) -# 0x80#) `uncheckedIShiftL#`  6#) +#
1052                      (ord# (indexCharOffAddr# addr (nh +# 3#)) -# 0x80#))) :
1053           unpack (nh +# 4#)
1054       where
1055         ch = indexCharOffAddr# addr nh
1056
1057 unpackNBytes# :: Addr# -> Int# -> [Char]
1058 unpackNBytes# _addr 0#   = []
1059 unpackNBytes#  addr len# = unpack [] (len# -# 1#)
1060     where
1061      unpack acc i#
1062       | i# <# 0#  = acc
1063       | otherwise =
1064          case indexCharOffAddr# addr i# of
1065             ch -> unpack (C# ch : acc) (i# -# 1#)
1066
1067 {-# RULES
1068 "unpack"       [~1] forall a   . unpackCString# a                  = build (unpackFoldrCString# a)
1069 "unpack-list"  [1]  forall a   . unpackFoldrCString# a (:) [] = unpackCString# a
1070 "unpack-append"     forall a n . unpackFoldrCString# a (:) n  = unpackAppendCString# a n
1071
1072 -- There's a built-in rule (in PrelRules.lhs) for
1073 --      unpackFoldr "foo" c (unpackFoldr "baz" c n)  =  unpackFoldr "foobaz" c n
1074
1075   #-}
1076 \end{code}
1077
1078 #ifdef __HADDOCK__
1079 \begin{code}
1080 -- | A special argument for the 'Control.Monad.ST.ST' type constructor,
1081 -- indexing a state embedded in the 'Prelude.IO' monad by
1082 -- 'Control.Monad.ST.stToIO'.
1083 data RealWorld
1084 \end{code}
1085 #endif