GHC/Enum.lhs

   1 % -----------------------------------------------------------------------------
   2 % $Id: Enum.lhs,v 1.7 2002/02/05 17:32:26 simonmar Exp $
   3 %
   4 % (c) The University of Glasgow, 1992-2000
   5 %
   6
   7 \section[GHC.Bounded]{Module @GHC.Bounded@}
   8
   9 Instances of Bounded for various datatypes.
  10
  11 \begin{code}
  12 {-# OPTIONS -fno-implicit-prelude #-}
  13
  14 module GHC.Enum(
  15         Bounded(..), Enum(..),
  16         boundedEnumFrom, boundedEnumFromThen,
  17
  18         -- Instances for Bounded and Eum: (), Char, Int
  19
  20    ) where
  21
  22 import {-# SOURCE #-} GHC.Err ( error )
  23 import GHC.Base
  24 import Data.Tuple       ()              -- for dependencies
  25 default ()              -- Double isn't available yet
  26 \end{code}
  27
  28
  29 %*********************************************************
  30 %*                                                      *
  31 \subsection{Class declarations}
  32 %*                                                      *
  33 %*********************************************************
  34
  35 \begin{code}
  36 class  Bounded a  where
  37     minBound, maxBound :: a
  38
  39 class  Enum a   where
  40     succ, pred          :: a -> a
  41     toEnum              :: Int -> a
  42     fromEnum            :: a -> Int
  43     enumFrom            :: a -> [a]             -- [n..]
  44     enumFromThen        :: a -> a -> [a]        -- [n,n'..]
  45     enumFromTo          :: a -> a -> [a]        -- [n..m]
  46     enumFromThenTo      :: a -> a -> a -> [a]   -- [n,n'..m]
  47
  48     succ                   = toEnum . (`plusInt` oneInt)  . fromEnum
  49     pred                   = toEnum . (`minusInt` oneInt) . fromEnum
  50     enumFrom x             = map toEnum [fromEnum x ..]
  51     enumFromThen x y       = map toEnum [fromEnum x, fromEnum y ..]
  52     enumFromTo x y         = map toEnum [fromEnum x .. fromEnum y]
  53     enumFromThenTo x1 x2 y = map toEnum [fromEnum x1, fromEnum x2 .. fromEnum y]
  54
  55 -- Default methods for bounded enumerations
  56 boundedEnumFrom :: (Enum a, Bounded a) => a -> [a]
  57 boundedEnumFrom n = map toEnum [fromEnum n .. fromEnum (maxBound `asTypeOf` n)]
  58
  59 boundedEnumFromThen :: (Enum a, Bounded a) => a -> a -> [a]
  60 boundedEnumFromThen n1 n2
  61   | i_n2 >= i_n1  = map toEnum [i_n1, i_n2 .. fromEnum (maxBound `asTypeOf` n1)]
  62   | otherwise     = map toEnum [i_n1, i_n2 .. fromEnum (minBound `asTypeOf` n1)]
  63   where
  64     i_n1 = fromEnum n1
  65     i_n2 = fromEnum n2
  66 \end{code}
  67
  68
  69 %*********************************************************
  70 %*                                                      *
  71 \subsection{Tuples}
  72 %*                                                      *
  73 %*********************************************************
  74
  75 \begin{code}
  76 instance Bounded () where
  77     minBound = ()
  78     maxBound = ()
  79
  80 instance Enum () where
  81     succ _      = error "Prelude.Enum.().succ: bad argment"
  82     pred _      = error "Prelude.Enum.().pred: bad argument"
  83
  84     toEnum x | x == zeroInt = ()
  85              | otherwise    = error "Prelude.Enum.().toEnum: bad argument"
  86
  87     fromEnum () = zeroInt
  88     enumFrom ()         = [()]
  89     enumFromThen () ()  = [()]
  90     enumFromTo () ()    = [()]
  91     enumFromThenTo () () () = [()]
  92 \end{code}
  93
  94 \begin{code}
  95 instance (Bounded a, Bounded b) => Bounded (a,b) where
  96    minBound = (minBound, minBound)
  97    maxBound = (maxBound, maxBound)
  98
  99 instance (Bounded a, Bounded b, Bounded c) => Bounded (a,b,c) where
 100    minBound = (minBound, minBound, minBound)
 101    maxBound = (maxBound, maxBound, maxBound)
 102
 103 instance (Bounded a, Bounded b, Bounded c, Bounded d) => Bounded (a,b,c,d) where
 104    minBound = (minBound, minBound, minBound, minBound)
 105    maxBound = (maxBound, maxBound, maxBound, maxBound)
 106 \end{code}
 107
 108
 109 %*********************************************************
 110 %*                                                      *
 111 \subsection{Type @Bool@}
 112 %*                                                      *
 113 %*********************************************************
 114
 115 \begin{code}
 116 instance Bounded Bool where
 117   minBound = False
 118   maxBound = True
 119
 120 instance Enum Bool where
 121   succ False = True
 122   succ True  = error "Prelude.Enum.Bool.succ: bad argment"
 123
 124   pred True  = False
 125   pred False  = error "Prelude.Enum.Bool.pred: bad argment"
 126
 127   toEnum n | n == zeroInt = False
 128            | n == oneInt  = True
 129            | otherwise    = error "Prelude.Enum.Bool.toEnum: bad argment"
 130
 131   fromEnum False = zeroInt
 132   fromEnum True  = oneInt
 133
 134   -- Use defaults for the rest
 135   enumFrom     = boundedEnumFrom
 136   enumFromThen = boundedEnumFromThen
 137 \end{code}
 138
 139 %*********************************************************
 140 %*                                                      *
 141 \subsection{Type @Ordering@}
 142 %*                                                      *
 143 %*********************************************************
 144
 145 \begin{code}
 146 instance Bounded Ordering where
 147   minBound = LT
 148   maxBound = GT
 149
 150 instance Enum Ordering where
 151   succ LT = EQ
 152   succ EQ = GT
 153   succ GT = error "Prelude.Enum.Ordering.succ: bad argment"
 154
 155   pred GT = EQ
 156   pred EQ = LT
 157   pred LT = error "Prelude.Enum.Ordering.pred: bad argment"
 158
 159   toEnum n | n == zeroInt = LT
 160            | n == oneInt  = EQ
 161            | n == twoInt  = GT
 162   toEnum _ = error "Prelude.Enum.Ordering.toEnum: bad argment"
 163
 164   fromEnum LT = zeroInt
 165   fromEnum EQ = oneInt
 166   fromEnum GT = twoInt
 167
 168   -- Use defaults for the rest
 169   enumFrom     = boundedEnumFrom
 170   enumFromThen = boundedEnumFromThen
 171 \end{code}
 172
 173 %*********************************************************
 174 %*                                                      *
 175 \subsection{Type @Char@}
 176 %*                                                      *
 177 %*********************************************************
 178
 179 \begin{code}
 180 instance  Bounded Char  where
 181     minBound =  '\0'
 182     maxBound =  '\x10FFFF'
 183
 184 instance  Enum Char  where
 185     succ (C# c#)
 186        | not (ord# c# ==# 0x10FFFF#) = C# (chr# (ord# c# +# 1#))
 187        | otherwise              = error ("Prelude.Enum.Char.succ: bad argument")
 188     pred (C# c#)
 189        | not (ord# c# ==# 0#)   = C# (chr# (ord# c# -# 1#))
 190        | otherwise              = error ("Prelude.Enum.Char.pred: bad argument")
 191
 192     toEnum   = chr
 193     fromEnum = ord
 194
 195     {-# INLINE enumFrom #-}
 196     enumFrom (C# x) = eftChar (ord# x) 0x10FFFF#
 197         -- Blarg: technically I guess enumFrom isn't strict!
 198
 199     {-# INLINE enumFromTo #-}
 200     enumFromTo (C# x) (C# y) = eftChar (ord# x) (ord# y)
 201
 202     {-# INLINE enumFromThen #-}
 203     enumFromThen (C# x1) (C# x2) = efdChar (ord# x1) (ord# x2)
 204
 205     {-# INLINE enumFromThenTo #-}
 206     enumFromThenTo (C# x1) (C# x2) (C# y) = efdtChar (ord# x1) (ord# x2) (ord# y)
 207
 208 {-# RULES
 209 "eftChar"       [~1] forall x y.        eftChar x y       = build (\c n -> eftCharFB c n x y)
 210 "efdChar"       [~1] forall x1 x2.      efdChar x1 x2     = build (\ c n -> efdCharFB c n x1 x2)
 211 "efdtChar"      [~1] forall x1 x2 l.    efdtChar x1 x2 l  = build (\ c n -> efdtCharFB c n x1 x2 l)
 212 "eftCharList"   [1]  eftCharFB  (:) [] = eftChar
 213 "efdCharList"   [1]  efdCharFB  (:) [] = efdChar
 214 "efdtCharList"  [1]  efdtCharFB (:) [] = efdtChar
 215  #-}
 216
 217
 218 -- We can do better than for Ints because we don't
 219 -- have hassles about arithmetic overflow at maxBound
 220 {-# INLINE [0] eftCharFB #-}
 221 eftCharFB c n x y = go x
 222                  where
 223                     go x | x ># y    = n
 224                          | otherwise = C# (chr# x) `c` go (x +# 1#)
 225
 226 eftChar x y | x ># y    = []
 227                 | otherwise = C# (chr# x) : eftChar (x +# 1#) y
 228
 229
 230 -- For enumFromThenTo we give up on inlining
 231 {-# NOINLINE [0] efdCharFB #-}
 232 efdCharFB c n x1 x2
 233   | delta >=# 0# = go_up_char_fb c n x1 delta 0x10FFFF#
 234   | otherwise    = go_dn_char_fb c n x1 delta 0#
 235   where
 236     delta = x2 -# x1
 237
 238 efdChar x1 x2
 239   | delta >=# 0# = go_up_char_list x1 delta 0x10FFFF#
 240   | otherwise    = go_dn_char_list x1 delta 0#
 241   where
 242     delta = x2 -# x1
 243
 244 {-# NOINLINE [0] efdtCharFB #-}
 245 efdtCharFB c n x1 x2 lim
 246   | delta >=# 0# = go_up_char_fb c n x1 delta lim
 247   | otherwise    = go_dn_char_fb c n x1 delta lim
 248   where
 249     delta = x2 -# x1
 250
 251 efdtChar x1 x2 lim
 252   | delta >=# 0# = go_up_char_list x1 delta lim
 253   | otherwise    = go_dn_char_list x1 delta lim
 254   where
 255     delta = x2 -# x1
 256
 257 go_up_char_fb c n x delta lim
 258   = go_up x
 259   where
 260     go_up x | x ># lim  = n
 261             | otherwise = C# (chr# x) `c` go_up (x +# delta)
 262
 263 go_dn_char_fb c n x delta lim
 264   = go_dn x
 265   where
 266     go_dn x | x <# lim  = n
 267             | otherwise = C# (chr# x) `c` go_dn (x +# delta)
 268
 269 go_up_char_list x delta lim
 270   = go_up x
 271   where
 272     go_up x | x ># lim  = []
 273             | otherwise = C# (chr# x) : go_up (x +# delta)
 274
 275 go_dn_char_list x delta lim
 276   = go_dn x
 277   where
 278     go_dn x | x <# lim  = []
 279             | otherwise = C# (chr# x) : go_dn (x +# delta)
 280 \end{code}
 281
 282
 283 %*********************************************************
 284 %*                                                      *
 285 \subsection{Type @Int@}
 286 %*                                                      *
 287 %*********************************************************
 288
 289 Be careful about these instances.
 290         (a) remember that you have to count down as well as up e.g. [13,12..0]
 291         (b) be careful of Int overflow
 292         (c) remember that Int is bounded, so [1..] terminates at maxInt
 293
 294 Also NB that the Num class isn't available in this module.
 295
 296 \begin{code}
 297 instance  Bounded Int where
 298     minBound =  minInt
 299     maxBound =  maxInt
 300
 301 instance  Enum Int  where
 302     succ x
 303        | x == maxBound  = error "Prelude.Enum.succ{Int}: tried to take `succ' of maxBound"
 304        | otherwise      = x `plusInt` oneInt
 305     pred x
 306        | x == minBound  = error "Prelude.Enum.pred{Int}: tried to take `pred' of minBound"
 307        | otherwise      = x `minusInt` oneInt
 308
 309     toEnum   x = x
 310     fromEnum x = x
 311
 312     {-# INLINE enumFrom #-}
 313     enumFrom (I# x) = eftInt x maxInt#
 314         where I# maxInt# = maxInt
 315         -- Blarg: technically I guess enumFrom isn't strict!
 316
 317     {-# INLINE enumFromTo #-}
 318     enumFromTo (I# x) (I# y) = eftInt x y
 319
 320     {-# INLINE enumFromThen #-}
 321     enumFromThen (I# x1) (I# x2) = efdInt x1 x2
 322
 323     {-# INLINE enumFromThenTo #-}
 324     enumFromThenTo (I# x1) (I# x2) (I# y) = efdtInt x1 x2 y
 325
 326 {-# RULES
 327 "eftInt"        [~1] forall x y.        eftInt x y       = build (\ c n -> eftIntFB c n x y)
 328 "efdInt"        [~1] forall x1 x2.      efdInt x1 x2     = build (\ c n -> efdIntFB c n x1 x2)
 329 "efdtInt"       [~1] forall x1 x2 l.    efdtInt x1 x2 l  = build (\ c n -> efdtIntFB c n x1 x2 l)
 330
 331 "eftIntList"    [1] eftIntFB  (:) [] = eftInt
 332 "efdIntList"    [1] efdIntFB  (:) [] = efdInt
 333 "efdtIntList"   [1] efdtIntFB (:) [] = efdtInt
 334  #-}
 335
 336
 337 {-# INLINE [0] eftIntFB #-}
 338 eftIntFB c n x y | x ># y    = n
 339                  | otherwise = go x
 340                  where
 341                    go x = I# x `c` if x ==# y then n else go (x +# 1#)
 342                         -- Watch out for y=maxBound; hence ==, not >
 343         -- Be very careful not to have more than one "c"
 344         -- so that when eftInfFB is inlined we can inline
 345         -- whatver is bound to "c"
 346
 347 eftInt x y | x ># y    = []
 348                | otherwise = go x
 349                where
 350                  go x = I# x : if x ==# y then [] else go (x +# 1#)
 351
 352
 353 -- For enumFromThenTo we give up on inlining; so we don't worry
 354 -- about duplicating occurrences of "c"
 355 {-# NOINLINE [0] efdtIntFB #-}
 356 efdtIntFB c n x1 x2 y
 357   | delta >=# 0# = if x1 ># y then n else go_up_int_fb c n x1 delta lim
 358   | otherwise    = if x1 <# y then n else go_dn_int_fb c n x1 delta lim
 359   where
 360     delta = x2 -# x1
 361     lim   = y -# delta
 362
 363 efdtInt x1 x2 y
 364   | delta >=# 0# = if x1 ># y then [] else go_up_int_list x1 delta lim
 365   | otherwise    = if x1 <# y then [] else go_dn_int_list x1 delta lim
 366   where
 367     delta = x2 -# x1
 368     lim   = y -# delta
 369
 370 {-# NOINLINE [0] efdIntFB #-}
 371 efdIntFB c n x1 x2
 372   | delta >=# 0# = case maxInt of I# y -> go_up_int_fb c n x1 delta (y -# delta)
 373   | otherwise    = case minInt of I# y -> go_dn_int_fb c n x1 delta (y -# delta)
 374   where
 375     delta = x2 -# x1
 376
 377 efdInt x1 x2
 378   | delta >=# 0# = case maxInt of I# y -> go_up_int_list x1 delta (y -# delta)
 379   | otherwise    = case minInt of I# y -> go_dn_int_list x1 delta (y -# delta)
 380   where
 381     delta = x2 -# x1
 382
 383 -- In all of these, the (x +# delta) is guaranteed not to overflow
 384
 385 go_up_int_fb c n x delta lim
 386   = go_up x
 387   where
 388     go_up x | x ># lim  = I# x `c` n
 389             | otherwise = I# x `c` go_up (x +# delta)
 390
 391 go_dn_int_fb c n x delta lim
 392   = go_dn x
 393   where
 394     go_dn x | x <# lim  = I# x `c` n
 395             | otherwise = I# x `c` go_dn (x +# delta)
 396
 397 go_up_int_list x delta lim
 398   = go_up x
 399   where
 400     go_up x | x ># lim  = [I# x]
 401             | otherwise = I# x : go_up (x +# delta)
 402
 403 go_dn_int_list x delta lim
 404   = go_dn x
 405   where
 406     go_dn x | x <# lim  = [I# x]
 407             | otherwise = I# x : go_dn (x +# delta)
 408 \end{code}
 409