GHC/Enum.lhs

   1 % -----------------------------------------------------------------------------
   2 % $Id: Enum.lhs,v 1.3 2001/07/03 14:13:32 simonmar Exp $
   3 %
   4 % (c) The University of Glasgow, 1992-2000
   5 %
   6
   7 \section[GHC.Bounded]{Module @GHC.Bounded@}
   8
   9 Instances of Bounded for various datatypes.
  10
  11 \begin{code}
  12 {-# OPTIONS -fno-implicit-prelude #-}
  13
  14 module GHC.Enum(
  15         Bounded(..), Enum(..),
  16         boundedEnumFrom, boundedEnumFromThen,
  17
  18         -- Instances for Bounded and Eum: (), Char, Int
  19
  20    ) where
  21
  22 import {-# SOURCE #-} GHC.Err ( error )
  23 import GHC.Base
  24 default ()              -- Double isn't available yet
  25 \end{code}
  26
  27
  28 %*********************************************************
  29 %*                                                      *
  30 \subsection{Class declarations}
  31 %*                                                      *
  32 %*********************************************************
  33
  34 \begin{code}
  35 class  Bounded a  where
  36     minBound, maxBound :: a
  37
  38 class  Enum a   where
  39     succ, pred          :: a -> a
  40     toEnum              :: Int -> a
  41     fromEnum            :: a -> Int
  42     enumFrom            :: a -> [a]             -- [n..]
  43     enumFromThen        :: a -> a -> [a]        -- [n,n'..]
  44     enumFromTo          :: a -> a -> [a]        -- [n..m]
  45     enumFromThenTo      :: a -> a -> a -> [a]   -- [n,n'..m]
  46
  47     succ                   = toEnum . (`plusInt` oneInt)  . fromEnum
  48     pred                   = toEnum . (`minusInt` oneInt) . fromEnum
  49     enumFrom x             = map toEnum [fromEnum x ..]
  50     enumFromThen x y       = map toEnum [fromEnum x, fromEnum y ..]
  51     enumFromTo x y         = map toEnum [fromEnum x .. fromEnum y]
  52     enumFromThenTo x1 x2 y = map toEnum [fromEnum x1, fromEnum x2 .. fromEnum y]
  53
  54 -- Default methods for bounded enumerations
  55 boundedEnumFrom :: (Enum a, Bounded a) => a -> [a]
  56 boundedEnumFrom n = map toEnum [fromEnum n .. fromEnum (maxBound `asTypeOf` n)]
  57
  58 boundedEnumFromThen :: (Enum a, Bounded a) => a -> a -> [a]
  59 boundedEnumFromThen n1 n2
  60   | i_n2 >= i_n1  = map toEnum [i_n1, i_n2 .. fromEnum (maxBound `asTypeOf` n1)]
  61   | otherwise     = map toEnum [i_n1, i_n2 .. fromEnum (minBound `asTypeOf` n1)]
  62   where
  63     i_n1 = fromEnum n1
  64     i_n2 = fromEnum n2
  65 \end{code}
  66
  67
  68 %*********************************************************
  69 %*                                                      *
  70 \subsection{Tuples}
  71 %*                                                      *
  72 %*********************************************************
  73
  74 \begin{code}
  75 instance Bounded () where
  76     minBound = ()
  77     maxBound = ()
  78
  79 instance Enum () where
  80     succ _      = error "Prelude.Enum.().succ: bad argment"
  81     pred _      = error "Prelude.Enum.().pred: bad argument"
  82
  83     toEnum x | x == zeroInt = ()
  84              | otherwise    = error "Prelude.Enum.().toEnum: bad argument"
  85
  86     fromEnum () = zeroInt
  87     enumFrom ()         = [()]
  88     enumFromThen () ()  = [()]
  89     enumFromTo () ()    = [()]
  90     enumFromThenTo () () () = [()]
  91 \end{code}
  92
  93 \begin{code}
  94 instance (Bounded a, Bounded b) => Bounded (a,b) where
  95    minBound = (minBound, minBound)
  96    maxBound = (maxBound, maxBound)
  97
  98 instance (Bounded a, Bounded b, Bounded c) => Bounded (a,b,c) where
  99    minBound = (minBound, minBound, minBound)
 100    maxBound = (maxBound, maxBound, maxBound)
 101
 102 instance (Bounded a, Bounded b, Bounded c, Bounded d) => Bounded (a,b,c,d) where
 103    minBound = (minBound, minBound, minBound, minBound)
 104    maxBound = (maxBound, maxBound, maxBound, maxBound)
 105 \end{code}
 106
 107
 108 %*********************************************************
 109 %*                                                      *
 110 \subsection{Type @Bool@}
 111 %*                                                      *
 112 %*********************************************************
 113
 114 \begin{code}
 115 instance Bounded Bool where
 116   minBound = False
 117   maxBound = True
 118
 119 instance Enum Bool where
 120   succ False = True
 121   succ True  = error "Prelude.Enum.Bool.succ: bad argment"
 122
 123   pred True  = False
 124   pred False  = error "Prelude.Enum.Bool.pred: bad argment"
 125
 126   toEnum n | n == zeroInt = False
 127            | n == oneInt  = True
 128            | otherwise    = error "Prelude.Enum.Bool.toEnum: bad argment"
 129
 130   fromEnum False = zeroInt
 131   fromEnum True  = oneInt
 132
 133   -- Use defaults for the rest
 134   enumFrom     = boundedEnumFrom
 135   enumFromThen = boundedEnumFromThen
 136 \end{code}
 137
 138 %*********************************************************
 139 %*                                                      *
 140 \subsection{Type @Ordering@}
 141 %*                                                      *
 142 %*********************************************************
 143
 144 \begin{code}
 145 instance Bounded Ordering where
 146   minBound = LT
 147   maxBound = GT
 148
 149 instance Enum Ordering where
 150   succ LT = EQ
 151   succ EQ = GT
 152   succ GT = error "Prelude.Enum.Ordering.succ: bad argment"
 153
 154   pred GT = EQ
 155   pred EQ = LT
 156   pred LT = error "Prelude.Enum.Ordering.pred: bad argment"
 157
 158   toEnum n | n == zeroInt = LT
 159            | n == oneInt  = EQ
 160            | n == twoInt  = GT
 161   toEnum _ = error "Prelude.Enum.Ordering.toEnum: bad argment"
 162
 163   fromEnum LT = zeroInt
 164   fromEnum EQ = oneInt
 165   fromEnum GT = twoInt
 166
 167   -- Use defaults for the rest
 168   enumFrom     = boundedEnumFrom
 169   enumFromThen = boundedEnumFromThen
 170 \end{code}
 171
 172 %*********************************************************
 173 %*                                                      *
 174 \subsection{Type @Char@}
 175 %*                                                      *
 176 %*********************************************************
 177
 178 \begin{code}
 179 instance  Bounded Char  where
 180     minBound =  '\0'
 181     maxBound =  '\x10FFFF'
 182
 183 instance  Enum Char  where
 184     succ (C# c#)
 185        | not (ord# c# ==# 0x10FFFF#) = C# (chr# (ord# c# +# 1#))
 186        | otherwise              = error ("Prelude.Enum.Char.succ: bad argument")
 187     pred (C# c#)
 188        | not (ord# c# ==# 0#)   = C# (chr# (ord# c# -# 1#))
 189        | otherwise              = error ("Prelude.Enum.Char.pred: bad argument")
 190
 191     toEnum   = chr
 192     fromEnum = ord
 193
 194     {-# INLINE enumFrom #-}
 195     enumFrom (C# x) = eftChar (ord# x) 0x10FFFF#
 196         -- Blarg: technically I guess enumFrom isn't strict!
 197
 198     {-# INLINE enumFromTo #-}
 199     enumFromTo (C# x) (C# y) = eftChar (ord# x) (ord# y)
 200
 201     {-# INLINE enumFromThen #-}
 202     enumFromThen (C# x1) (C# x2) = efdChar (ord# x1) (ord# x2)
 203
 204     {-# INLINE enumFromThenTo #-}
 205     enumFromThenTo (C# x1) (C# x2) (C# y) = efdtChar (ord# x1) (ord# x2) (ord# y)
 206
 207 eftChar  = eftCharList
 208 efdChar  = efdCharList
 209 efdtChar = efdtCharList
 210
 211
 212 {-# RULES
 213 "eftChar"       forall x y.     eftChar x y       = build (\c n -> eftCharFB c n x y)
 214 "efdChar"       forall x1 x2.   efdChar x1 x2     = build (\ c n -> efdCharFB c n x1 x2)
 215 "efdtChar"      forall x1 x2 l. efdtChar x1 x2 l  = build (\ c n -> efdtCharFB c n x1 x2 l)
 216 "eftCharList"   eftCharFB  (:) [] = eftCharList
 217 "efdCharList"   efdCharFB  (:) [] = efdCharList
 218 "efdtCharList"  efdtCharFB (:) [] = efdtCharList
 219  #-}
 220
 221
 222 -- We can do better than for Ints because we don't
 223 -- have hassles about arithmetic overflow at maxBound
 224 {-# INLINE eftCharFB #-}
 225 eftCharFB c n x y = go x
 226                  where
 227                     go x | x ># y    = n
 228                          | otherwise = C# (chr# x) `c` go (x +# 1#)
 229
 230 eftCharList x y | x ># y    = []
 231                 | otherwise = C# (chr# x) : eftCharList (x +# 1#) y
 232
 233
 234 -- For enumFromThenTo we give up on inlining
 235 efdCharFB c n x1 x2
 236   | delta >=# 0# = go_up_char_fb c n x1 delta 0x10FFFF#
 237   | otherwise    = go_dn_char_fb c n x1 delta 0#
 238   where
 239     delta = x2 -# x1
 240
 241 efdCharList x1 x2
 242   | delta >=# 0# = go_up_char_list x1 delta 0x10FFFF#
 243   | otherwise    = go_dn_char_list x1 delta 0#
 244   where
 245     delta = x2 -# x1
 246
 247 efdtCharFB c n x1 x2 lim
 248   | delta >=# 0# = go_up_char_fb c n x1 delta lim
 249   | otherwise    = go_dn_char_fb c n x1 delta lim
 250   where
 251     delta = x2 -# x1
 252
 253 efdtCharList x1 x2 lim
 254   | delta >=# 0# = go_up_char_list x1 delta lim
 255   | otherwise    = go_dn_char_list x1 delta lim
 256   where
 257     delta = x2 -# x1
 258
 259 go_up_char_fb c n x delta lim
 260   = go_up x
 261   where
 262     go_up x | x ># lim  = n
 263             | otherwise = C# (chr# x) `c` go_up (x +# delta)
 264
 265 go_dn_char_fb c n x delta lim
 266   = go_dn x
 267   where
 268     go_dn x | x <# lim  = n
 269             | otherwise = C# (chr# x) `c` go_dn (x +# delta)
 270
 271 go_up_char_list x delta lim
 272   = go_up x
 273   where
 274     go_up x | x ># lim  = []
 275             | otherwise = C# (chr# x) : go_up (x +# delta)
 276
 277 go_dn_char_list x delta lim
 278   = go_dn x
 279   where
 280     go_dn x | x <# lim  = []
 281             | otherwise = C# (chr# x) : go_dn (x +# delta)
 282 \end{code}
 283
 284
 285 %*********************************************************
 286 %*                                                      *
 287 \subsection{Type @Int@}
 288 %*                                                      *
 289 %*********************************************************
 290
 291 Be careful about these instances.
 292         (a) remember that you have to count down as well as up e.g. [13,12..0]
 293         (b) be careful of Int overflow
 294         (c) remember that Int is bounded, so [1..] terminates at maxInt
 295
 296 Also NB that the Num class isn't available in this module.
 297
 298 \begin{code}
 299 instance  Bounded Int where
 300     minBound =  minInt
 301     maxBound =  maxInt
 302
 303 instance  Enum Int  where
 304     succ x
 305        | x == maxBound  = error "Prelude.Enum.succ{Int}: tried to take `succ' of maxBound"
 306        | otherwise      = x `plusInt` oneInt
 307     pred x
 308        | x == minBound  = error "Prelude.Enum.pred{Int}: tried to take `pred' of minBound"
 309        | otherwise      = x `minusInt` oneInt
 310
 311     toEnum   x = x
 312     fromEnum x = x
 313
 314     {-# INLINE enumFrom #-}
 315     enumFrom (I# x) = eftInt x 2147483647#
 316         -- Blarg: technically I guess enumFrom isn't strict!
 317
 318     {-# INLINE enumFromTo #-}
 319     enumFromTo (I# x) (I# y) = eftInt x y
 320
 321     {-# INLINE enumFromThen #-}
 322     enumFromThen (I# x1) (I# x2) = efdInt x1 x2
 323
 324     {-# INLINE enumFromThenTo #-}
 325     enumFromThenTo (I# x1) (I# x2) (I# y) = efdtInt x1 x2 y
 326
 327 eftInt  = eftIntList
 328 efdInt  = efdIntList
 329 efdtInt = efdtIntList
 330
 331 {-# RULES
 332 "eftInt"        forall x y.     eftInt x y       = build (\ c n -> eftIntFB c n x y)
 333 "efdInt"        forall x1 x2.   efdInt x1 x2     = build (\ c n -> efdIntFB c n x1 x2)
 334 "efdtInt"       forall x1 x2 l. efdtInt x1 x2 l  = build (\ c n -> efdtIntFB c n x1 x2 l)
 335
 336 "eftIntList"    eftIntFB  (:) [] = eftIntList
 337 "efdIntList"    efdIntFB  (:) [] = efdIntList
 338 "efdtIntList"   efdtIntFB (:) [] = efdtIntList
 339  #-}
 340
 341
 342 {-# INLINE eftIntFB #-}
 343 eftIntFB c n x y | x ># y    = n
 344                  | otherwise = go x
 345                  where
 346                    go x = I# x `c` if x ==# y then n else go (x +# 1#)
 347                         -- Watch out for y=maxBound; hence ==, not >
 348         -- Be very careful not to have more than one "c"
 349         -- so that when eftInfFB is inlined we can inline
 350         -- whatver is bound to "c"
 351
 352 eftIntList x y | x ># y    = []
 353                | otherwise = go x
 354                where
 355                  go x = I# x : if x ==# y then [] else go (x +# 1#)
 356
 357
 358 -- For enumFromThenTo we give up on inlining; so we don't worry
 359 -- about duplicating occurrences of "c"
 360 efdtIntFB c n x1 x2 y
 361   | delta >=# 0# = if x1 ># y then n else go_up_int_fb c n x1 delta lim
 362   | otherwise    = if x1 <# y then n else go_dn_int_fb c n x1 delta lim
 363   where
 364     delta = x2 -# x1
 365     lim   = y -# delta
 366
 367 efdtIntList x1 x2 y
 368   | delta >=# 0# = if x1 ># y then [] else go_up_int_list x1 delta lim
 369   | otherwise    = if x1 <# y then [] else go_dn_int_list x1 delta lim
 370   where
 371     delta = x2 -# x1
 372     lim   = y -# delta
 373
 374 efdIntFB c n x1 x2
 375   | delta >=# 0# = go_up_int_fb c n x1 delta (  2147483647#  -# delta)
 376   | otherwise    = go_dn_int_fb c n x1 delta ((-2147483648#) -# delta)
 377   where
 378     delta = x2 -# x1
 379
 380 efdIntList x1 x2
 381   | delta >=# 0# = go_up_int_list x1 delta (  2147483647#  -# delta)
 382   | otherwise    = go_dn_int_list x1 delta ((-2147483648#) -# delta)
 383   where
 384     delta = x2 -# x1
 385
 386 -- In all of these, the (x +# delta) is guaranteed not to overflow
 387
 388 go_up_int_fb c n x delta lim
 389   = go_up x
 390   where
 391     go_up x | x ># lim  = I# x `c` n
 392             | otherwise = I# x `c` go_up (x +# delta)
 393
 394 go_dn_int_fb c n x delta lim
 395   = go_dn x
 396   where
 397     go_dn x | x <# lim  = I# x `c` n
 398             | otherwise = I# x `c` go_dn (x +# delta)
 399
 400 go_up_int_list x delta lim
 401   = go_up x
 402   where
 403     go_up x | x ># lim  = [I# x]
 404             | otherwise = I# x : go_up (x +# delta)
 405
 406 go_dn_int_list x delta lim
 407   = go_dn x
 408   where
 409     go_dn x | x <# lim  = [I# x]
 410             | otherwise = I# x : go_dn (x +# delta)
 411 \end{code}
 412