GHC/Handle.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude -#include "HsBase.h" #-}
   2 {-# OPTIONS_HADDOCK hide #-}
   3
   4 #undef DEBUG_DUMP
   5 #undef DEBUG
   6
   7 -----------------------------------------------------------------------------
   8 -- |
   9 -- Module      :  GHC.Handle
  10 -- Copyright   :  (c) The University of Glasgow, 1994-2001
  11 -- License     :  see libraries/base/LICENSE
  12 --
  13 -- Maintainer  :  libraries@haskell.org
  14 -- Stability   :  internal
  15 -- Portability :  non-portable
  16 --
  17 -- This module defines the basic operations on I\/O \"handles\".
  18 --
  19 -----------------------------------------------------------------------------
  20
  21 -- #hide
  22 module GHC.Handle (
  23   withHandle, withHandle', withHandle_,
  24   wantWritableHandle, wantReadableHandle, wantSeekableHandle,
  25
  26   newEmptyBuffer, allocateBuffer, readCharFromBuffer, writeCharIntoBuffer,
  27   flushWriteBufferOnly, flushWriteBuffer, flushReadBuffer,
  28   fillReadBuffer, fillReadBufferWithoutBlocking,
  29   readRawBuffer, readRawBufferPtr,
  30   readRawBufferNoBlock, readRawBufferPtrNoBlock,
  31   writeRawBuffer, writeRawBufferPtr,
  32
  33 #ifndef mingw32_HOST_OS
  34   unlockFile,
  35 #endif
  36
  37   ioe_closedHandle, ioe_EOF, ioe_notReadable, ioe_notWritable,
  38
  39   stdin, stdout, stderr,
  40   IOMode(..), openFile, openBinaryFile, fdToHandle_stat, fdToHandle, fdToHandle',
  41   hFileSize, hSetFileSize, hIsEOF, isEOF, hLookAhead, hLookAhead', hSetBuffering, hSetBinaryMode,
  42   hFlush, hDuplicate, hDuplicateTo,
  43
  44   hClose, hClose_help,
  45
  46   HandlePosition, HandlePosn(..), hGetPosn, hSetPosn,
  47   SeekMode(..), hSeek, hTell,
  48
  49   hIsOpen, hIsClosed, hIsReadable, hIsWritable, hGetBuffering, hIsSeekable,
  50   hSetEcho, hGetEcho, hIsTerminalDevice,
  51
  52   hShow,
  53
  54 #ifdef DEBUG_DUMP
  55   puts,
  56 #endif
  57
  58  ) where
  59
  60 import Control.Monad
  61 import Data.Maybe
  62 import Foreign
  63 import Foreign.C
  64 import System.IO.Error
  65 import System.Posix.Internals
  66 import System.Posix.Types
  67
  68 import GHC.Real
  69
  70 import GHC.Arr
  71 import GHC.Base
  72 import GHC.Read         ( Read )
  73 import GHC.List
  74 import GHC.IOBase
  75 import GHC.Exception
  76 import GHC.Enum
  77 import GHC.Num          ( Integer, Num(..) )
  78 import GHC.Show
  79 #if defined(DEBUG_DUMP)
  80 import GHC.Pack
  81 #endif
  82
  83 import GHC.Conc
  84
  85 -- -----------------------------------------------------------------------------
  86 -- TODO:
  87
  88 -- hWaitForInput blocks (should use a timeout)
  89
  90 -- unbuffered hGetLine is a bit dodgy
  91
  92 -- hSetBuffering: can't change buffering on a stream,
  93 --      when the read buffer is non-empty? (no way to flush the buffer)
  94
  95 -- ---------------------------------------------------------------------------
  96 -- Are files opened by default in text or binary mode, if the user doesn't
  97 -- specify?
  98
  99 dEFAULT_OPEN_IN_BINARY_MODE :: Bool
 100 dEFAULT_OPEN_IN_BINARY_MODE = False
 101
 102 -- ---------------------------------------------------------------------------
 103 -- Creating a new handle
 104
 105 newFileHandle :: FilePath -> (MVar Handle__ -> IO ()) -> Handle__ -> IO Handle
 106 newFileHandle filepath finalizer hc = do
 107   m <- newMVar hc
 108   addMVarFinalizer m (finalizer m)
 109   return (FileHandle filepath m)
 110
 111 -- ---------------------------------------------------------------------------
 112 -- Working with Handles
 113
 114 {-
 115 In the concurrent world, handles are locked during use.  This is done
 116 by wrapping an MVar around the handle which acts as a mutex over
 117 operations on the handle.
 118
 119 To avoid races, we use the following bracketing operations.  The idea
 120 is to obtain the lock, do some operation and replace the lock again,
 121 whether the operation succeeded or failed.  We also want to handle the
 122 case where the thread receives an exception while processing the IO
 123 operation: in these cases we also want to relinquish the lock.
 124
 125 There are three versions of @withHandle@: corresponding to the three
 126 possible combinations of:
 127
 128         - the operation may side-effect the handle
 129         - the operation may return a result
 130
 131 If the operation generates an error or an exception is raised, the
 132 original handle is always replaced [ this is the case at the moment,
 133 but we might want to revisit this in the future --SDM ].
 134 -}
 135
 136 {-# INLINE withHandle #-}
 137 withHandle :: String -> Handle -> (Handle__ -> IO (Handle__,a)) -> IO a
 138 withHandle fun h@(FileHandle _ m)     act = withHandle' fun h m act
 139 withHandle fun h@(DuplexHandle _ m _) act = withHandle' fun h m act
 140
 141 withHandle' :: String -> Handle -> MVar Handle__
 142    -> (Handle__ -> IO (Handle__,a)) -> IO a
 143 withHandle' fun h m act =
 144    block $ do
 145    h_ <- takeMVar m
 146    checkBufferInvariants h_
 147    (h',v)  <- (act h_ `catchAny` \err -> putMVar m h_ >> throw err)
 148               `catchException` \ex -> ioError (augmentIOError ex fun h)
 149    checkBufferInvariants h'
 150    putMVar m h'
 151    return v
 152
 153 {-# INLINE withHandle_ #-}
 154 withHandle_ :: String -> Handle -> (Handle__ -> IO a) -> IO a
 155 withHandle_ fun h@(FileHandle _ m)     act = withHandle_' fun h m act
 156 withHandle_ fun h@(DuplexHandle _ m _) act = withHandle_' fun h m act
 157
 158 withHandle_' :: String -> Handle -> MVar Handle__ -> (Handle__ -> IO a) -> IO a
 159 withHandle_' fun h m act =
 160    block $ do
 161    h_ <- takeMVar m
 162    checkBufferInvariants h_
 163    v  <- (act h_ `catchAny` \err -> putMVar m h_ >> throw err)
 164          `catchException` \ex -> ioError (augmentIOError ex fun h)
 165    checkBufferInvariants h_
 166    putMVar m h_
 167    return v
 168
 169 withAllHandles__ :: String -> Handle -> (Handle__ -> IO Handle__) -> IO ()
 170 withAllHandles__ fun h@(FileHandle _ m)     act = withHandle__' fun h m act
 171 withAllHandles__ fun h@(DuplexHandle _ r w) act = do
 172   withHandle__' fun h r act
 173   withHandle__' fun h w act
 174
 175 withHandle__' :: String -> Handle -> MVar Handle__ -> (Handle__ -> IO Handle__)
 176               -> IO ()
 177 withHandle__' fun h m act =
 178    block $ do
 179    h_ <- takeMVar m
 180    checkBufferInvariants h_
 181    h'  <- (act h_ `catchAny` \err -> putMVar m h_ >> throw err)
 182           `catchException` \ex -> ioError (augmentIOError ex fun h)
 183    checkBufferInvariants h'
 184    putMVar m h'
 185    return ()
 186
 187 augmentIOError :: IOException -> String -> Handle -> IOException
 188 augmentIOError (IOError _ iot _ str fp) fun h
 189   = IOError (Just h) iot fun str filepath
 190   where filepath
 191           | Just _ <- fp = fp
 192           | otherwise = case h of
 193                           FileHandle path _     -> Just path
 194                           DuplexHandle path _ _ -> Just path
 195
 196 -- ---------------------------------------------------------------------------
 197 -- Wrapper for write operations.
 198
 199 wantWritableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 200 wantWritableHandle fun h@(FileHandle _ m) act
 201   = wantWritableHandle' fun h m act
 202 wantWritableHandle fun h@(DuplexHandle _ _ m) act
 203   = wantWritableHandle' fun h m act
 204   -- ToDo: in the Duplex case, we don't need to checkWritableHandle
 205
 206 wantWritableHandle'
 207         :: String -> Handle -> MVar Handle__
 208         -> (Handle__ -> IO a) -> IO a
 209 wantWritableHandle' fun h m act
 210    = withHandle_' fun h m (checkWritableHandle act)
 211
 212 checkWritableHandle :: (Handle__ -> IO a) -> Handle__ -> IO a
 213 checkWritableHandle act handle_
 214   = case haType handle_ of
 215       ClosedHandle         -> ioe_closedHandle
 216       SemiClosedHandle     -> ioe_closedHandle
 217       ReadHandle           -> ioe_notWritable
 218       ReadWriteHandle      -> do
 219                 let ref = haBuffer handle_
 220                 buf <- readIORef ref
 221                 new_buf <-
 222                   if not (bufferIsWritable buf)
 223                      then do b <- flushReadBuffer (haFD handle_) buf
 224                              return b{ bufState=WriteBuffer }
 225                      else return buf
 226                 writeIORef ref new_buf
 227                 act handle_
 228       _other               -> act handle_
 229
 230 -- ---------------------------------------------------------------------------
 231 -- Wrapper for read operations.
 232
 233 wantReadableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 234 wantReadableHandle fun h@(FileHandle  _ m)   act
 235   = wantReadableHandle' fun h m act
 236 wantReadableHandle fun h@(DuplexHandle _ m _) act
 237   = wantReadableHandle' fun h m act
 238   -- ToDo: in the Duplex case, we don't need to checkReadableHandle
 239
 240 wantReadableHandle'
 241         :: String -> Handle -> MVar Handle__
 242         -> (Handle__ -> IO a) -> IO a
 243 wantReadableHandle' fun h m act
 244   = withHandle_' fun h m (checkReadableHandle act)
 245
 246 checkReadableHandle :: (Handle__ -> IO a) -> Handle__ -> IO a
 247 checkReadableHandle act handle_ =
 248     case haType handle_ of
 249       ClosedHandle         -> ioe_closedHandle
 250       SemiClosedHandle     -> ioe_closedHandle
 251       AppendHandle         -> ioe_notReadable
 252       WriteHandle          -> ioe_notReadable
 253       ReadWriteHandle      -> do
 254         let ref = haBuffer handle_
 255         buf <- readIORef ref
 256         when (bufferIsWritable buf) $ do
 257            new_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
 258            writeIORef ref new_buf{ bufState=ReadBuffer }
 259         act handle_
 260       _other               -> act handle_
 261
 262 -- ---------------------------------------------------------------------------
 263 -- Wrapper for seek operations.
 264
 265 wantSeekableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 266 wantSeekableHandle fun h@(DuplexHandle _ _ _) _act =
 267   ioException (IOError (Just h) IllegalOperation fun
 268                    "handle is not seekable" Nothing)
 269 wantSeekableHandle fun h@(FileHandle _ m) act =
 270   withHandle_' fun h m (checkSeekableHandle act)
 271
 272 checkSeekableHandle :: (Handle__ -> IO a) -> Handle__ -> IO a
 273 checkSeekableHandle act handle_ =
 274     case haType handle_ of
 275       ClosedHandle      -> ioe_closedHandle
 276       SemiClosedHandle  -> ioe_closedHandle
 277       AppendHandle      -> ioe_notSeekable
 278       _  | haIsBin handle_ || tEXT_MODE_SEEK_ALLOWED -> act handle_
 279          | otherwise                                 -> ioe_notSeekable_notBin
 280
 281 -- -----------------------------------------------------------------------------
 282 -- Handy IOErrors
 283
 284 ioe_closedHandle, ioe_EOF,
 285   ioe_notReadable, ioe_notWritable,
 286   ioe_notSeekable, ioe_notSeekable_notBin :: IO a
 287
 288 ioe_closedHandle = ioException
 289    (IOError Nothing IllegalOperation ""
 290         "handle is closed" Nothing)
 291 ioe_EOF = ioException
 292    (IOError Nothing EOF "" "" Nothing)
 293 ioe_notReadable = ioException
 294    (IOError Nothing IllegalOperation ""
 295         "handle is not open for reading" Nothing)
 296 ioe_notWritable = ioException
 297    (IOError Nothing IllegalOperation ""
 298         "handle is not open for writing" Nothing)
 299 ioe_notSeekable = ioException
 300    (IOError Nothing IllegalOperation ""
 301         "handle is not seekable" Nothing)
 302 ioe_notSeekable_notBin = ioException
 303    (IOError Nothing IllegalOperation ""
 304       "seek operations on text-mode handles are not allowed on this platform"
 305         Nothing)
 306
 307 ioe_finalizedHandle :: FilePath -> Handle__
 308 ioe_finalizedHandle fp = throw
 309    (IOError Nothing IllegalOperation ""
 310         "handle is finalized" (Just fp))
 311
 312 ioe_bufsiz :: Int -> IO a
 313 ioe_bufsiz n = ioException
 314    (IOError Nothing InvalidArgument "hSetBuffering"
 315         ("illegal buffer size " ++ showsPrec 9 n []) Nothing)
 316                                 -- 9 => should be parens'ified.
 317
 318 -- -----------------------------------------------------------------------------
 319 -- Handle Finalizers
 320
 321 -- For a duplex handle, we arrange that the read side points to the write side
 322 -- (and hence keeps it alive if the read side is alive).  This is done by
 323 -- having the haOtherSide field of the read side point to the read side.
 324 -- The finalizer is then placed on the write side, and the handle only gets
 325 -- finalized once, when both sides are no longer required.
 326
 327 -- NOTE about finalized handles: It's possible that a handle can be
 328 -- finalized and then we try to use it later, for example if the
 329 -- handle is referenced from another finalizer, or from a thread that
 330 -- has become unreferenced and then resurrected (arguably in the
 331 -- latter case we shouldn't finalize the Handle...).  Anyway,
 332 -- we try to emit a helpful message which is better than nothing.
 333
 334 stdHandleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 335 stdHandleFinalizer fp m = do
 336   h_ <- takeMVar m
 337   flushWriteBufferOnly h_
 338   putMVar m (ioe_finalizedHandle fp)
 339
 340 handleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 341 handleFinalizer fp m = do
 342   handle_ <- takeMVar m
 343   case haType handle_ of
 344       ClosedHandle -> return ()
 345       _ -> do flushWriteBufferOnly handle_ `catchAny` \_ -> return ()
 346                 -- ignore errors and async exceptions, and close the
 347                 -- descriptor anyway...
 348               hClose_handle_ handle_
 349               return ()
 350   putMVar m (ioe_finalizedHandle fp)
 351
 352 -- ---------------------------------------------------------------------------
 353 -- Grimy buffer operations
 354
 355 checkBufferInvariants :: Handle__ -> IO ()
 356 #ifdef DEBUG
 357 checkBufferInvariants h_ = do
 358  let ref = haBuffer h_
 359  Buffer{ bufWPtr=w, bufRPtr=r, bufSize=size, bufState=state } <- readIORef ref
 360  if not (
 361         size > 0
 362         && r <= w
 363         && w <= size
 364         && ( r /= w || (r == 0 && w == 0) )
 365         && ( state /= WriteBuffer || r == 0 )
 366         && ( state /= WriteBuffer || w < size ) -- write buffer is never full
 367      )
 368    then error "buffer invariant violation"
 369    else return ()
 370 #else
 371 checkBufferInvariants _ = return ()
 372 #endif
 373
 374 newEmptyBuffer :: RawBuffer -> BufferState -> Int -> Buffer
 375 newEmptyBuffer b state size
 376   = Buffer{ bufBuf=b, bufRPtr=0, bufWPtr=0, bufSize=size, bufState=state }
 377
 378 allocateBuffer :: Int -> BufferState -> IO Buffer
 379 allocateBuffer sz@(I# size) state = IO $ \s ->
 380    -- We sometimes need to pass the address of this buffer to
 381    -- a "safe" foreign call, hence it must be immovable.
 382   case newPinnedByteArray# size s of { (# s', b #) ->
 383   (# s', newEmptyBuffer b state sz #) }
 384
 385 writeCharIntoBuffer :: RawBuffer -> Int -> Char -> IO Int
 386 writeCharIntoBuffer slab (I# off) (C# c)
 387   = IO $ \s -> case writeCharArray# slab off c s of
 388                s' -> (# s', I# (off +# 1#) #)
 389
 390 readCharFromBuffer :: RawBuffer -> Int -> IO (Char, Int)
 391 readCharFromBuffer slab (I# off)
 392   = IO $ \s -> case readCharArray# slab off s of
 393                  (# s', c #) -> (# s', (C# c, I# (off +# 1#)) #)
 394
 395 getBuffer :: FD -> BufferState -> IO (IORef Buffer, BufferMode)
 396 getBuffer fd state = do
 397   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE state
 398   ioref  <- newIORef buffer
 399   is_tty <- fdIsTTY fd
 400
 401   let buffer_mode
 402          | is_tty    = LineBuffering
 403          | otherwise = BlockBuffering Nothing
 404
 405   return (ioref, buffer_mode)
 406
 407 mkUnBuffer :: IO (IORef Buffer)
 408 mkUnBuffer = do
 409   buffer <- allocateBuffer 1 ReadBuffer
 410   newIORef buffer
 411
 412 -- flushWriteBufferOnly flushes the buffer iff it contains pending write data.
 413 flushWriteBufferOnly :: Handle__ -> IO ()
 414 flushWriteBufferOnly h_ = do
 415   let fd = haFD h_
 416       ref = haBuffer h_
 417   buf <- readIORef ref
 418   new_buf <- if bufferIsWritable buf
 419                 then flushWriteBuffer fd (haIsStream h_) buf
 420                 else return buf
 421   writeIORef ref new_buf
 422
 423 -- flushBuffer syncs the file with the buffer, including moving the
 424 -- file pointer backwards in the case of a read buffer.
 425 flushBuffer :: Handle__ -> IO ()
 426 flushBuffer h_ = do
 427   let ref = haBuffer h_
 428   buf <- readIORef ref
 429
 430   flushed_buf <-
 431     case bufState buf of
 432       ReadBuffer  -> flushReadBuffer  (haFD h_) buf
 433       WriteBuffer -> flushWriteBuffer (haFD h_) (haIsStream h_) buf
 434
 435   writeIORef ref flushed_buf
 436
 437 -- When flushing a read buffer, we seek backwards by the number of
 438 -- characters in the buffer.  The file descriptor must therefore be
 439 -- seekable: attempting to flush the read buffer on an unseekable
 440 -- handle is not allowed.
 441
 442 flushReadBuffer :: FD -> Buffer -> IO Buffer
 443 flushReadBuffer fd buf
 444   | bufferEmpty buf = return buf
 445   | otherwise = do
 446      let off = negate (bufWPtr buf - bufRPtr buf)
 447 #    ifdef DEBUG_DUMP
 448      puts ("flushReadBuffer: new file offset = " ++ show off ++ "\n")
 449 #    endif
 450      throwErrnoIfMinus1Retry "flushReadBuffer"
 451          (c_lseek fd (fromIntegral off) sEEK_CUR)
 452      return buf{ bufWPtr=0, bufRPtr=0 }
 453
 454 flushWriteBuffer :: FD -> Bool -> Buffer -> IO Buffer
 455 flushWriteBuffer fd is_stream buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w }  =
 456   seq fd $ do -- strictness hack
 457   let bytes = w - r
 458 #ifdef DEBUG_DUMP
 459   puts ("flushWriteBuffer, fd=" ++ show fd ++ ", bytes=" ++ show bytes ++ "\n")
 460 #endif
 461   if bytes == 0
 462      then return (buf{ bufRPtr=0, bufWPtr=0 })
 463      else do
 464   res <- writeRawBuffer "flushWriteBuffer" fd is_stream b
 465                         (fromIntegral r) (fromIntegral bytes)
 466   let res' = fromIntegral res
 467   if res' < bytes
 468      then flushWriteBuffer fd is_stream (buf{ bufRPtr = r + res' })
 469      else return buf{ bufRPtr=0, bufWPtr=0 }
 470
 471 fillReadBuffer :: FD -> Bool -> Bool -> Buffer -> IO Buffer
 472 fillReadBuffer fd is_line is_stream
 473       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 474   -- buffer better be empty:
 475   assert (r == 0 && w == 0) $ do
 476   fillReadBufferLoop fd is_line is_stream buf b w size
 477
 478 -- For a line buffer, we just get the first chunk of data to arrive,
 479 -- and don't wait for the whole buffer to be full (but we *do* wait
 480 -- until some data arrives).  This isn't really line buffering, but it
 481 -- appears to be what GHC has done for a long time, and I suspect it
 482 -- is more useful than line buffering in most cases.
 483
 484 fillReadBufferLoop :: FD -> Bool -> Bool -> Buffer -> RawBuffer -> Int -> Int
 485                    -> IO Buffer
 486 fillReadBufferLoop fd is_line is_stream buf b w size = do
 487   let bytes = size - w
 488   if bytes == 0  -- buffer full?
 489      then return buf{ bufRPtr=0, bufWPtr=w }
 490      else do
 491 #ifdef DEBUG_DUMP
 492   puts ("fillReadBufferLoop: bytes = " ++ show bytes ++ "\n")
 493 #endif
 494   res <- readRawBuffer "fillReadBuffer" fd is_stream b
 495                        (fromIntegral w) (fromIntegral bytes)
 496   let res' = fromIntegral res
 497 #ifdef DEBUG_DUMP
 498   puts ("fillReadBufferLoop:  res' = " ++ show res' ++ "\n")
 499 #endif
 500   if res' == 0
 501      then if w == 0
 502              then ioe_EOF
 503              else return buf{ bufRPtr=0, bufWPtr=w }
 504      else if res' < bytes && not is_line
 505              then fillReadBufferLoop fd is_line is_stream buf b (w+res') size
 506              else return buf{ bufRPtr=0, bufWPtr=w+res' }
 507
 508
 509 fillReadBufferWithoutBlocking :: FD -> Bool -> Buffer -> IO Buffer
 510 fillReadBufferWithoutBlocking fd is_stream
 511       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 512   -- buffer better be empty:
 513   assert (r == 0 && w == 0) $ do
 514 #ifdef DEBUG_DUMP
 515   puts ("fillReadBufferLoopNoBlock: bytes = " ++ show size ++ "\n")
 516 #endif
 517   res <- readRawBufferNoBlock "fillReadBuffer" fd is_stream b
 518                        0 (fromIntegral size)
 519   let res' = fromIntegral res
 520 #ifdef DEBUG_DUMP
 521   puts ("fillReadBufferLoopNoBlock:  res' = " ++ show res' ++ "\n")
 522 #endif
 523   return buf{ bufRPtr=0, bufWPtr=res' }
 524
 525 -- Low level routines for reading/writing to (raw)buffers:
 526
 527 #ifndef mingw32_HOST_OS
 528
 529 {-
 530 NOTE [nonblock]:
 531
 532 Unix has broken semantics when it comes to non-blocking I/O: you can
 533 set the O_NONBLOCK flag on an FD, but it applies to the all other FDs
 534 attached to the same underlying file, pipe or TTY; there's no way to
 535 have private non-blocking behaviour for an FD.  See bug #724.
 536
 537 We fix this by only setting O_NONBLOCK on FDs that we create; FDs that
 538 come from external sources or are exposed externally are left in
 539 blocking mode.  This solution has some problems though.  We can't
 540 completely simulate a non-blocking read without O_NONBLOCK: several
 541 cases are wrong here.  The cases that are wrong:
 542
 543   * reading/writing to a blocking FD in non-threaded mode.
 544     In threaded mode, we just make a safe call to read().
 545     In non-threaded mode we call select() before attempting to read,
 546     but that leaves a small race window where the data can be read
 547     from the file descriptor before we issue our blocking read().
 548   * readRawBufferNoBlock for a blocking FD
 549
 550 NOTE [2363]:
 551
 552 In the threaded RTS we could just make safe calls to read()/write()
 553 for file descriptors in blocking mode without worrying about blocking
 554 other threads, but the problem with this is that the thread will be
 555 uninterruptible while it is blocked in the foreign call.  See #2363.
 556 So now we always call fdReady() before reading, and if fdReady
 557 indicates that there's no data, we call threadWaitRead.
 558
 559 -}
 560
 561 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 562 readRawBuffer loc fd is_nonblock buf off len
 563   | is_nonblock  = unsafe_read -- unsafe is ok, it can't block
 564   | otherwise    = do r <- throwErrnoIfMinus1 loc
 565                                 (unsafe_fdReady (fromIntegral fd) 0 0 0)
 566                       if r /= 0
 567                         then read
 568                         else do threadWaitRead (fromIntegral fd); read
 569   where
 570     do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 571                             (threadWaitRead (fromIntegral fd))
 572     read        = if threaded then safe_read else unsafe_read
 573     unsafe_read = do_read (read_rawBuffer fd buf off len)
 574     safe_read   = do_read (safe_read_rawBuffer fd buf off len)
 575
 576 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 577 readRawBufferPtr loc fd is_nonblock buf off len
 578   | is_nonblock  = unsafe_read -- unsafe is ok, it can't block
 579   | otherwise    = do r <- throwErrnoIfMinus1 loc
 580                                 (unsafe_fdReady (fromIntegral fd) 0 0 0)
 581                       if r /= 0
 582                         then read
 583                         else do threadWaitRead (fromIntegral fd); read
 584   where
 585     do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 586                             (threadWaitRead (fromIntegral fd))
 587     read        = if threaded then safe_read else unsafe_read
 588     unsafe_read = do_read (read_off fd buf off len)
 589     safe_read   = do_read (safe_read_off fd buf off len)
 590
 591 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 592 readRawBufferNoBlock loc fd is_nonblock buf off len
 593   | is_nonblock  = unsafe_read -- unsafe is ok, it can't block
 594   | otherwise    = do r <- unsafe_fdReady (fromIntegral fd) 0 0 0
 595                       if r /= 0 then safe_read
 596                                 else return 0
 597        -- XXX see note [nonblock]
 598  where
 599    do_read call = throwErrnoIfMinus1RetryOnBlock loc call (return 0)
 600    unsafe_read  = do_read (read_rawBuffer fd buf off len)
 601    safe_read    = do_read (safe_read_rawBuffer fd buf off len)
 602
 603 readRawBufferPtrNoBlock :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 604 readRawBufferPtrNoBlock loc fd is_nonblock buf off len
 605   | is_nonblock  = unsafe_read -- unsafe is ok, it can't block
 606   | otherwise    = do r <- unsafe_fdReady (fromIntegral fd) 0 0 0
 607                       if r /= 0 then safe_read
 608                                 else return 0
 609        -- XXX see note [nonblock]
 610  where
 611    do_read call = throwErrnoIfMinus1RetryOnBlock loc call (return 0)
 612    unsafe_read  = do_read (read_off fd buf off len)
 613    safe_read    = do_read (safe_read_off fd buf off len)
 614
 615 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 616 writeRawBuffer loc fd is_nonblock buf off len
 617   | is_nonblock = unsafe_write -- unsafe is ok, it can't block
 618   | otherwise   = do r <- unsafe_fdReady (fromIntegral fd) 1 0 0
 619                      if r /= 0
 620                         then write
 621                         else do threadWaitWrite (fromIntegral fd); write
 622   where
 623     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 624                         (threadWaitWrite (fromIntegral fd))
 625     write        = if threaded then safe_write else unsafe_write
 626     unsafe_write = do_write (write_rawBuffer fd buf off len)
 627     safe_write   = do_write (safe_write_rawBuffer (fromIntegral fd) buf off len)
 628
 629 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 630 writeRawBufferPtr loc fd is_nonblock buf off len
 631   | is_nonblock = unsafe_write -- unsafe is ok, it can't block
 632   | otherwise   = do r <- unsafe_fdReady (fromIntegral fd) 1 0 0
 633                      if r /= 0
 634                         then write
 635                         else do threadWaitWrite (fromIntegral fd); write
 636   where
 637     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 638                         (threadWaitWrite (fromIntegral fd))
 639     write         = if threaded then safe_write else unsafe_write
 640     unsafe_write  = do_write (write_off fd buf off len)
 641     safe_write    = do_write (safe_write_off (fromIntegral fd) buf off len)
 642
 643 foreign import ccall unsafe "__hscore_PrelHandle_read"
 644    read_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 645
 646 foreign import ccall unsafe "__hscore_PrelHandle_read"
 647    read_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 648
 649 foreign import ccall unsafe "__hscore_PrelHandle_write"
 650    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 651
 652 foreign import ccall unsafe "__hscore_PrelHandle_write"
 653    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 654
 655 foreign import ccall unsafe "fdReady"
 656   unsafe_fdReady :: CInt -> CInt -> CInt -> CInt -> IO CInt
 657
 658 #else /* mingw32_HOST_OS.... */
 659
 660 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 661 readRawBuffer loc fd is_stream buf off len
 662   | threaded  = blockingReadRawBuffer loc fd is_stream buf off len
 663   | otherwise = asyncReadRawBuffer loc fd is_stream buf off len
 664
 665 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 666 readRawBufferPtr loc fd is_stream buf off len
 667   | threaded  = blockingReadRawBufferPtr loc fd is_stream buf off len
 668   | otherwise = asyncReadRawBufferPtr loc fd is_stream buf off len
 669
 670 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 671 writeRawBuffer loc fd is_stream buf off len
 672   | threaded =  blockingWriteRawBuffer loc fd is_stream buf off len
 673   | otherwise = asyncWriteRawBuffer    loc fd is_stream buf off len
 674
 675 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 676 writeRawBufferPtr loc fd is_stream buf off len
 677   | threaded  = blockingWriteRawBufferPtr loc fd is_stream buf off len
 678   | otherwise = asyncWriteRawBufferPtr    loc fd is_stream buf off len
 679
 680 -- ToDo: we don't have a non-blocking primitve read on Win32
 681 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 682 readRawBufferNoBlock = readRawBuffer
 683
 684 readRawBufferPtrNoBlock :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 685 readRawBufferPtrNoBlock = readRawBufferPtr
 686 -- Async versions of the read/write primitives, for the non-threaded RTS
 687
 688 asyncReadRawBuffer loc fd is_stream buf off len = do
 689     (l, rc) <- asyncReadBA (fromIntegral fd) (if is_stream then 1 else 0)
 690                  (fromIntegral len) off buf
 691     if l == (-1)
 692       then
 693         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 694       else return (fromIntegral l)
 695
 696 asyncReadRawBufferPtr loc fd is_stream buf off len = do
 697     (l, rc) <- asyncRead (fromIntegral fd) (if is_stream then 1 else 0)
 698                         (fromIntegral len) (buf `plusPtr` off)
 699     if l == (-1)
 700       then
 701         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 702       else return (fromIntegral l)
 703
 704 asyncWriteRawBuffer loc fd is_stream buf off len = do
 705     (l, rc) <- asyncWriteBA (fromIntegral fd) (if is_stream then 1 else 0)
 706                         (fromIntegral len) off buf
 707     if l == (-1)
 708       then
 709         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 710       else return (fromIntegral l)
 711
 712 asyncWriteRawBufferPtr loc fd is_stream buf off len = do
 713     (l, rc) <- asyncWrite (fromIntegral fd) (if is_stream then 1 else 0)
 714                   (fromIntegral len) (buf `plusPtr` off)
 715     if l == (-1)
 716       then
 717         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 718       else return (fromIntegral l)
 719
 720 -- Blocking versions of the read/write primitives, for the threaded RTS
 721
 722 blockingReadRawBuffer loc fd True buf off len =
 723   throwErrnoIfMinus1Retry loc $
 724     safe_recv_rawBuffer fd buf off len
 725 blockingReadRawBuffer loc fd False buf off len =
 726   throwErrnoIfMinus1Retry loc $
 727     safe_read_rawBuffer fd buf off len
 728
 729 blockingReadRawBufferPtr loc fd True buf off len =
 730   throwErrnoIfMinus1Retry loc $
 731     safe_recv_off fd buf off len
 732 blockingReadRawBufferPtr loc fd False buf off len =
 733   throwErrnoIfMinus1Retry loc $
 734     safe_read_off fd buf off len
 735
 736 blockingWriteRawBuffer loc fd True buf off len =
 737   throwErrnoIfMinus1Retry loc $
 738     safe_send_rawBuffer fd buf off len
 739 blockingWriteRawBuffer loc fd False buf off len =
 740   throwErrnoIfMinus1Retry loc $
 741     safe_write_rawBuffer fd buf off len
 742
 743 blockingWriteRawBufferPtr loc fd True buf off len =
 744   throwErrnoIfMinus1Retry loc $
 745     safe_send_off fd buf off len
 746 blockingWriteRawBufferPtr loc fd False buf off len =
 747   throwErrnoIfMinus1Retry loc $
 748     safe_write_off fd buf off len
 749
 750 -- NOTE: "safe" versions of the read/write calls for use by the threaded RTS.
 751 -- These calls may block, but that's ok.
 752
 753 foreign import ccall safe "__hscore_PrelHandle_recv"
 754    safe_recv_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 755
 756 foreign import ccall safe "__hscore_PrelHandle_recv"
 757    safe_recv_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 758
 759 foreign import ccall safe "__hscore_PrelHandle_send"
 760    safe_send_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 761
 762 foreign import ccall safe "__hscore_PrelHandle_send"
 763    safe_send_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 764
 765 #endif
 766
 767 foreign import ccall "rtsSupportsBoundThreads" threaded :: Bool
 768
 769 foreign import ccall safe "__hscore_PrelHandle_read"
 770    safe_read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 771
 772 foreign import ccall safe "__hscore_PrelHandle_read"
 773    safe_read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 774
 775 foreign import ccall safe "__hscore_PrelHandle_write"
 776    safe_write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 777
 778 foreign import ccall safe "__hscore_PrelHandle_write"
 779    safe_write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 780
 781 -- ---------------------------------------------------------------------------
 782 -- Standard Handles
 783
 784 -- Three handles are allocated during program initialisation.  The first
 785 -- two manage input or output from the Haskell program's standard input
 786 -- or output channel respectively.  The third manages output to the
 787 -- standard error channel. These handles are initially open.
 788
 789 fd_stdin, fd_stdout, fd_stderr :: FD
 790 fd_stdin  = 0
 791 fd_stdout = 1
 792 fd_stderr = 2
 793
 794 -- | A handle managing input from the Haskell program's standard input channel.
 795 stdin :: Handle
 796 stdin = unsafePerformIO $ do
 797    -- ToDo: acquire lock
 798    -- We don't set non-blocking mode on standard handles, because it may
 799    -- confuse other applications attached to the same TTY/pipe
 800    -- see Note [nonblock]
 801    (buf, bmode) <- getBuffer fd_stdin ReadBuffer
 802    mkStdHandle fd_stdin "<stdin>" ReadHandle buf bmode
 803
 804 -- | A handle managing output to the Haskell program's standard output channel.
 805 stdout :: Handle
 806 stdout = unsafePerformIO $ do
 807    -- ToDo: acquire lock
 808    -- We don't set non-blocking mode on standard handles, because it may
 809    -- confuse other applications attached to the same TTY/pipe
 810    -- see Note [nonblock]
 811    (buf, bmode) <- getBuffer fd_stdout WriteBuffer
 812    mkStdHandle fd_stdout "<stdout>" WriteHandle buf bmode
 813
 814 -- | A handle managing output to the Haskell program's standard error channel.
 815 stderr :: Handle
 816 stderr = unsafePerformIO $ do
 817     -- ToDo: acquire lock
 818    -- We don't set non-blocking mode on standard handles, because it may
 819    -- confuse other applications attached to the same TTY/pipe
 820    -- see Note [nonblock]
 821    buf <- mkUnBuffer
 822    mkStdHandle fd_stderr "<stderr>" WriteHandle buf NoBuffering
 823
 824 -- ---------------------------------------------------------------------------
 825 -- Opening and Closing Files
 826
 827 addFilePathToIOError :: String -> FilePath -> IOException -> IOException
 828 addFilePathToIOError fun fp (IOError h iot _ str _)
 829   = IOError h iot fun str (Just fp)
 830
 831 -- | Computation 'openFile' @file mode@ allocates and returns a new, open
 832 -- handle to manage the file @file@.  It manages input if @mode@
 833 -- is 'ReadMode', output if @mode@ is 'WriteMode' or 'AppendMode',
 834 -- and both input and output if mode is 'ReadWriteMode'.
 835 --
 836 -- If the file does not exist and it is opened for output, it should be
 837 -- created as a new file.  If @mode@ is 'WriteMode' and the file
 838 -- already exists, then it should be truncated to zero length.
 839 -- Some operating systems delete empty files, so there is no guarantee
 840 -- that the file will exist following an 'openFile' with @mode@
 841 -- 'WriteMode' unless it is subsequently written to successfully.
 842 -- The handle is positioned at the end of the file if @mode@ is
 843 -- 'AppendMode', and otherwise at the beginning (in which case its
 844 -- internal position is 0).
 845 -- The initial buffer mode is implementation-dependent.
 846 --
 847 -- This operation may fail with:
 848 --
 849 --  * 'isAlreadyInUseError' if the file is already open and cannot be reopened;
 850 --
 851 --  * 'isDoesNotExistError' if the file does not exist; or
 852 --
 853 --  * 'isPermissionError' if the user does not have permission to open the file.
 854 --
 855 -- Note: if you will be working with files containing binary data, you'll want to
 856 -- be using 'openBinaryFile'.
 857 openFile :: FilePath -> IOMode -> IO Handle
 858 openFile fp im =
 859   catch
 860     (openFile' fp im dEFAULT_OPEN_IN_BINARY_MODE)
 861     (\e -> ioError (addFilePathToIOError "openFile" fp e))
 862
 863 -- | Like 'openFile', but open the file in binary mode.
 864 -- On Windows, reading a file in text mode (which is the default)
 865 -- will translate CRLF to LF, and writing will translate LF to CRLF.
 866 -- This is usually what you want with text files.  With binary files
 867 -- this is undesirable; also, as usual under Microsoft operating systems,
 868 -- text mode treats control-Z as EOF.  Binary mode turns off all special
 869 -- treatment of end-of-line and end-of-file characters.
 870 -- (See also 'hSetBinaryMode'.)
 871
 872 openBinaryFile :: FilePath -> IOMode -> IO Handle
 873 openBinaryFile fp m =
 874   catch
 875     (openFile' fp m True)
 876     (\e -> ioError (addFilePathToIOError "openBinaryFile" fp e))
 877
 878 openFile' :: String -> IOMode -> Bool -> IO Handle
 879 openFile' filepath mode binary =
 880   withCString filepath $ \ f ->
 881
 882     let
 883       oflags1 = case mode of
 884                   ReadMode      -> read_flags
 885 #ifdef mingw32_HOST_OS
 886                   WriteMode     -> write_flags .|. o_TRUNC
 887 #else
 888                   WriteMode     -> write_flags
 889 #endif
 890                   ReadWriteMode -> rw_flags
 891                   AppendMode    -> append_flags
 892
 893       binary_flags
 894           | binary    = o_BINARY
 895           | otherwise = 0
 896
 897       oflags = oflags1 .|. binary_flags
 898     in do
 899
 900     -- the old implementation had a complicated series of three opens,
 901     -- which is perhaps because we have to be careful not to open
 902     -- directories.  However, the man pages I've read say that open()
 903     -- always returns EISDIR if the file is a directory and was opened
 904     -- for writing, so I think we're ok with a single open() here...
 905     fd <- throwErrnoIfMinus1Retry "openFile"
 906                 (c_open f (fromIntegral oflags) 0o666)
 907
 908     stat@(fd_type,_,_) <- fdStat fd
 909
 910     h <- fdToHandle_stat fd (Just stat) False filepath mode binary
 911             `catchAny` \e -> do c_close fd; throw e
 912         -- NB. don't forget to close the FD if fdToHandle' fails, otherwise
 913         -- this FD leaks.
 914         -- ASSERT: if we just created the file, then fdToHandle' won't fail
 915         -- (so we don't need to worry about removing the newly created file
 916         --  in the event of an error).
 917
 918 #ifndef mingw32_HOST_OS
 919         -- we want to truncate() if this is an open in WriteMode, but only
 920         -- if the target is a RegularFile.  ftruncate() fails on special files
 921         -- like /dev/null.
 922     if mode == WriteMode && fd_type == RegularFile
 923       then throwErrnoIf (/=0) "openFile"
 924               (c_ftruncate fd 0)
 925       else return 0
 926 #endif
 927     return h
 928
 929
 930 std_flags, output_flags, read_flags, write_flags, rw_flags,
 931     append_flags :: CInt
 932 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 933 output_flags = std_flags    .|. o_CREAT
 934 read_flags   = std_flags    .|. o_RDONLY
 935 write_flags  = output_flags .|. o_WRONLY
 936 rw_flags     = output_flags .|. o_RDWR
 937 append_flags = write_flags  .|. o_APPEND
 938
 939 -- ---------------------------------------------------------------------------
 940 -- fdToHandle
 941
 942 fdToHandle_stat :: FD
 943             -> Maybe (FDType, CDev, CIno)
 944             -> Bool
 945             -> FilePath
 946             -> IOMode
 947             -> Bool
 948             -> IO Handle
 949
 950 fdToHandle_stat fd mb_stat is_socket filepath mode binary = do
 951
 952 #ifdef mingw32_HOST_OS
 953     -- On Windows, the is_socket flag indicates that the Handle is a socket
 954 #else
 955     -- On Unix, the is_socket flag indicates that the FD can be made non-blocking
 956     let non_blocking = is_socket
 957
 958     when non_blocking $ setNonBlockingFD fd
 959     -- turn on non-blocking mode
 960 #endif
 961
 962     let (ha_type, write) =
 963           case mode of
 964             ReadMode      -> ( ReadHandle,      False )
 965             WriteMode     -> ( WriteHandle,     True )
 966             ReadWriteMode -> ( ReadWriteHandle, True )
 967             AppendMode    -> ( AppendHandle,    True )
 968
 969     -- open() won't tell us if it was a directory if we only opened for
 970     -- reading, so check again.
 971     (fd_type,dev,ino) <-
 972       case mb_stat of
 973         Just x  -> return x
 974         Nothing -> fdStat fd
 975
 976     case fd_type of
 977         Directory ->
 978            ioException (IOError Nothing InappropriateType "openFile"
 979                            "is a directory" Nothing)
 980
 981         -- regular files need to be locked
 982         RegularFile -> do
 983 #ifndef mingw32_HOST_OS
 984            -- On Windows we use explicit exclusion via sopen() to implement
 985            -- this locking (see __hscore_open()); on Unix we have to
 986            -- implment it in the RTS.
 987            r <- lockFile fd dev ino (fromBool write)
 988            when (r == -1)  $
 989                 ioException (IOError Nothing ResourceBusy "openFile"
 990                                    "file is locked" Nothing)
 991 #endif
 992            mkFileHandle fd is_socket filepath ha_type binary
 993
 994         Stream
 995            -- only *Streams* can be DuplexHandles.  Other read/write
 996            -- Handles must share a buffer.
 997            | ReadWriteHandle <- ha_type ->
 998                 mkDuplexHandle fd is_socket filepath binary
 999            | otherwise ->
1000                 mkFileHandle   fd is_socket filepath ha_type binary
1001
1002         RawDevice ->
1003                 mkFileHandle fd is_socket filepath ha_type binary
1004
1005 -- | Old API kept to avoid breaking clients
1006 fdToHandle' :: FD -> Maybe FDType -> Bool -> FilePath  -> IOMode -> Bool
1007             -> IO Handle
1008 fdToHandle' fd mb_type is_socket filepath mode binary
1009  = do
1010        let mb_stat = case mb_type of
1011                         Nothing          -> Nothing
1012                           -- fdToHandle_stat will do the stat:
1013                         Just RegularFile -> Nothing
1014                           -- no stat required for streams etc.:
1015                         Just other       -> Just (other,0,0)
1016        fdToHandle_stat fd mb_stat is_socket filepath mode binary
1017
1018 fdToHandle :: FD -> IO Handle
1019 fdToHandle fd = do
1020    mode <- fdGetMode fd
1021    let fd_str = "<file descriptor: " ++ show fd ++ ">"
1022    fdToHandle_stat fd Nothing False fd_str mode True{-bin mode-}
1023         -- NB. the is_socket flag is False, meaning that:
1024         --  on Unix the file descriptor will *not* be put in non-blocking mode
1025         --  on Windows we're guessing this is not a socket (XXX)
1026
1027 #ifndef mingw32_HOST_OS
1028 foreign import ccall unsafe "lockFile"
1029   lockFile :: CInt -> CDev -> CIno -> CInt -> IO CInt
1030
1031 foreign import ccall unsafe "unlockFile"
1032   unlockFile :: CInt -> IO CInt
1033 #endif
1034
1035 mkStdHandle :: FD -> FilePath -> HandleType -> IORef Buffer -> BufferMode
1036         -> IO Handle
1037 mkStdHandle fd filepath ha_type buf bmode = do
1038    spares <- newIORef BufferListNil
1039    newFileHandle filepath (stdHandleFinalizer filepath)
1040             (Handle__ { haFD = fd,
1041                         haType = ha_type,
1042                         haIsBin = dEFAULT_OPEN_IN_BINARY_MODE,
1043                         haIsStream = False, -- means FD is blocking on Unix
1044                         haBufferMode = bmode,
1045                         haBuffer = buf,
1046                         haBuffers = spares,
1047                         haOtherSide = Nothing
1048                       })
1049
1050 mkFileHandle :: FD -> Bool -> FilePath -> HandleType -> Bool -> IO Handle
1051 mkFileHandle fd is_stream filepath ha_type binary = do
1052   (buf, bmode) <- getBuffer fd (initBufferState ha_type)
1053
1054 #ifdef mingw32_HOST_OS
1055   -- On Windows, if this is a read/write handle and we are in text mode,
1056   -- turn off buffering.  We don't correctly handle the case of switching
1057   -- from read mode to write mode on a buffered text-mode handle, see bug
1058   -- \#679.
1059   bmode <- case ha_type of
1060                 ReadWriteHandle | not binary -> return NoBuffering
1061                 _other                       -> return bmode
1062 #endif
1063
1064   spares <- newIORef BufferListNil
1065   newFileHandle filepath (handleFinalizer filepath)
1066             (Handle__ { haFD = fd,
1067                         haType = ha_type,
1068                         haIsBin = binary,
1069                         haIsStream = is_stream,
1070                         haBufferMode = bmode,
1071                         haBuffer = buf,
1072                         haBuffers = spares,
1073                         haOtherSide = Nothing
1074                       })
1075
1076 mkDuplexHandle :: FD -> Bool -> FilePath -> Bool -> IO Handle
1077 mkDuplexHandle fd is_stream filepath binary = do
1078   (w_buf, w_bmode) <- getBuffer fd WriteBuffer
1079   w_spares <- newIORef BufferListNil
1080   let w_handle_ =
1081              Handle__ { haFD = fd,
1082                         haType = WriteHandle,
1083                         haIsBin = binary,
1084                         haIsStream = is_stream,
1085                         haBufferMode = w_bmode,
1086                         haBuffer = w_buf,
1087                         haBuffers = w_spares,
1088                         haOtherSide = Nothing
1089                       }
1090   write_side <- newMVar w_handle_
1091
1092   (r_buf, r_bmode) <- getBuffer fd ReadBuffer
1093   r_spares <- newIORef BufferListNil
1094   let r_handle_ =
1095              Handle__ { haFD = fd,
1096                         haType = ReadHandle,
1097                         haIsBin = binary,
1098                         haIsStream = is_stream,
1099                         haBufferMode = r_bmode,
1100                         haBuffer = r_buf,
1101                         haBuffers = r_spares,
1102                         haOtherSide = Just write_side
1103                       }
1104   read_side <- newMVar r_handle_
1105
1106   addMVarFinalizer write_side (handleFinalizer filepath write_side)
1107   return (DuplexHandle filepath read_side write_side)
1108
1109 initBufferState :: HandleType -> BufferState
1110 initBufferState ReadHandle = ReadBuffer
1111 initBufferState _          = WriteBuffer
1112
1113 -- ---------------------------------------------------------------------------
1114 -- Closing a handle
1115
1116 -- | Computation 'hClose' @hdl@ makes handle @hdl@ closed.  Before the
1117 -- computation finishes, if @hdl@ is writable its buffer is flushed as
1118 -- for 'hFlush'.
1119 -- Performing 'hClose' on a handle that has already been closed has no effect;
1120 -- doing so is not an error.  All other operations on a closed handle will fail.
1121 -- If 'hClose' fails for any reason, any further operations (apart from
1122 -- 'hClose') on the handle will still fail as if @hdl@ had been successfully
1123 -- closed.
1124
1125 hClose :: Handle -> IO ()
1126 hClose h@(FileHandle _ m)     = do
1127   mb_exc <- hClose' h m
1128   case mb_exc of
1129     Nothing -> return ()
1130     Just e  -> throwIO e
1131 hClose h@(DuplexHandle _ r w) = do
1132   mb_exc1 <- hClose' h w
1133   mb_exc2 <- hClose' h r
1134   case (do mb_exc1; mb_exc2) of
1135      Nothing -> return ()
1136      Just e  -> throwIO e
1137
1138 hClose' :: Handle -> MVar Handle__ -> IO (Maybe SomeException)
1139 hClose' h m = withHandle' "hClose" h m $ hClose_help
1140
1141 -- hClose_help is also called by lazyRead (in PrelIO) when EOF is read
1142 -- or an IO error occurs on a lazy stream.  The semi-closed Handle is
1143 -- then closed immediately.  We have to be careful with DuplexHandles
1144 -- though: we have to leave the closing to the finalizer in that case,
1145 -- because the write side may still be in use.
1146 hClose_help :: Handle__ -> IO (Handle__, Maybe SomeException)
1147 hClose_help handle_ =
1148   case haType handle_ of
1149       ClosedHandle -> return (handle_,Nothing)
1150       _ -> do flushWriteBufferOnly handle_ -- interruptible
1151               hClose_handle_ handle_
1152
1153 hClose_handle_ :: Handle__ -> IO (Handle__, Maybe SomeException)
1154 hClose_handle_ handle_ = do
1155     let fd = haFD handle_
1156
1157     -- close the file descriptor, but not when this is the read
1158     -- side of a duplex handle.
1159     -- If an exception is raised by the close(), we want to continue
1160     -- to close the handle and release the lock if it has one, then
1161     -- we return the exception to the caller of hClose_help which can
1162     -- raise it if necessary.
1163     maybe_exception <-
1164       case haOtherSide handle_ of
1165         Nothing -> (do
1166                       throwErrnoIfMinus1Retry_ "hClose"
1167 #ifdef mingw32_HOST_OS
1168                                 (closeFd (haIsStream handle_) fd)
1169 #else
1170                                 (c_close fd)
1171 #endif
1172                       return Nothing
1173                     )
1174                      `catchException` \e -> return (Just e)
1175
1176         Just _  -> return Nothing
1177
1178     -- free the spare buffers
1179     writeIORef (haBuffers handle_) BufferListNil
1180     writeIORef (haBuffer  handle_) noBuffer
1181
1182 #ifndef mingw32_HOST_OS
1183     -- unlock it
1184     unlockFile fd
1185 #endif
1186
1187     -- we must set the fd to -1, because the finalizer is going
1188     -- to run eventually and try to close/unlock it.
1189     return (handle_{ haFD        = -1,
1190                      haType      = ClosedHandle
1191                    },
1192             maybe_exception)
1193
1194 {-# NOINLINE noBuffer #-}
1195 noBuffer :: Buffer
1196 noBuffer = unsafePerformIO $ allocateBuffer 1 ReadBuffer
1197
1198 -----------------------------------------------------------------------------
1199 -- Detecting and changing the size of a file
1200
1201 -- | For a handle @hdl@ which attached to a physical file,
1202 -- 'hFileSize' @hdl@ returns the size of that file in 8-bit bytes.
1203
1204 hFileSize :: Handle -> IO Integer
1205 hFileSize handle =
1206     withHandle_ "hFileSize" handle $ \ handle_ -> do
1207     case haType handle_ of
1208       ClosedHandle              -> ioe_closedHandle
1209       SemiClosedHandle          -> ioe_closedHandle
1210       _ -> do flushWriteBufferOnly handle_
1211               r <- fdFileSize (haFD handle_)
1212               if r /= -1
1213                  then return r
1214                  else ioException (IOError Nothing InappropriateType "hFileSize"
1215                                    "not a regular file" Nothing)
1216
1217
1218 -- | 'hSetFileSize' @hdl@ @size@ truncates the physical file with handle @hdl@ to @size@ bytes.
1219
1220 hSetFileSize :: Handle -> Integer -> IO ()
1221 hSetFileSize handle size =
1222     withHandle_ "hSetFileSize" handle $ \ handle_ -> do
1223     case haType handle_ of
1224       ClosedHandle              -> ioe_closedHandle
1225       SemiClosedHandle          -> ioe_closedHandle
1226       _ -> do flushWriteBufferOnly handle_
1227               throwErrnoIf (/=0) "hSetFileSize"
1228                  (c_ftruncate (haFD handle_) (fromIntegral size))
1229               return ()
1230
1231 -- ---------------------------------------------------------------------------
1232 -- Detecting the End of Input
1233
1234 -- | For a readable handle @hdl@, 'hIsEOF' @hdl@ returns
1235 -- 'True' if no further input can be taken from @hdl@ or for a
1236 -- physical file, if the current I\/O position is equal to the length of
1237 -- the file.  Otherwise, it returns 'False'.
1238 --
1239 -- NOTE: 'hIsEOF' may block, because it is the same as calling
1240 -- 'hLookAhead' and checking for an EOF exception.
1241
1242 hIsEOF :: Handle -> IO Bool
1243 hIsEOF handle =
1244   catch
1245      (do hLookAhead handle; return False)
1246      (\e -> if isEOFError e then return True else ioError e)
1247
1248 -- | The computation 'isEOF' is identical to 'hIsEOF',
1249 -- except that it works only on 'stdin'.
1250
1251 isEOF :: IO Bool
1252 isEOF = hIsEOF stdin
1253
1254 -- ---------------------------------------------------------------------------
1255 -- Looking ahead
1256
1257 -- | Computation 'hLookAhead' returns the next character from the handle
1258 -- without removing it from the input buffer, blocking until a character
1259 -- is available.
1260 --
1261 -- This operation may fail with:
1262 --
1263 --  * 'isEOFError' if the end of file has been reached.
1264
1265 hLookAhead :: Handle -> IO Char
1266 hLookAhead handle =
1267   wantReadableHandle "hLookAhead"  handle hLookAhead'
1268
1269 hLookAhead' :: Handle__ -> IO Char
1270 hLookAhead' handle_ = do
1271   let ref     = haBuffer handle_
1272       fd      = haFD handle_
1273   buf <- readIORef ref
1274
1275   -- fill up the read buffer if necessary
1276   new_buf <- if bufferEmpty buf
1277                 then fillReadBuffer fd True (haIsStream handle_) buf
1278                 else return buf
1279
1280   writeIORef ref new_buf
1281
1282   (c,_) <- readCharFromBuffer (bufBuf buf) (bufRPtr buf)
1283   return c
1284
1285 -- ---------------------------------------------------------------------------
1286 -- Buffering Operations
1287
1288 -- Three kinds of buffering are supported: line-buffering,
1289 -- block-buffering or no-buffering.  See GHC.IOBase for definition and
1290 -- further explanation of what the type represent.
1291
1292 -- | Computation 'hSetBuffering' @hdl mode@ sets the mode of buffering for
1293 -- handle @hdl@ on subsequent reads and writes.
1294 --
1295 -- If the buffer mode is changed from 'BlockBuffering' or
1296 -- 'LineBuffering' to 'NoBuffering', then
1297 --
1298 --  * if @hdl@ is writable, the buffer is flushed as for 'hFlush';
1299 --
1300 --  * if @hdl@ is not writable, the contents of the buffer is discarded.
1301 --
1302 -- This operation may fail with:
1303 --
1304 --  * 'isPermissionError' if the handle has already been used for reading
1305 --    or writing and the implementation does not allow the buffering mode
1306 --    to be changed.
1307
1308 hSetBuffering :: Handle -> BufferMode -> IO ()
1309 hSetBuffering handle mode =
1310   withAllHandles__ "hSetBuffering" handle $ \ handle_ -> do
1311   case haType handle_ of
1312     ClosedHandle -> ioe_closedHandle
1313     _ -> do
1314          {- Note:
1315             - we flush the old buffer regardless of whether
1316               the new buffer could fit the contents of the old buffer
1317               or not.
1318             - allow a handle's buffering to change even if IO has
1319               occurred (ANSI C spec. does not allow this, nor did
1320               the previous implementation of IO.hSetBuffering).
1321             - a non-standard extension is to allow the buffering
1322               of semi-closed handles to change [sof 6/98]
1323           -}
1324           flushBuffer handle_
1325
1326           let state = initBufferState (haType handle_)
1327           new_buf <-
1328             case mode of
1329                 -- we always have a 1-character read buffer for
1330                 -- unbuffered  handles: it's needed to
1331                 -- support hLookAhead.
1332               NoBuffering            -> allocateBuffer 1 ReadBuffer
1333               LineBuffering          -> allocateBuffer dEFAULT_BUFFER_SIZE state
1334               BlockBuffering Nothing -> allocateBuffer dEFAULT_BUFFER_SIZE state
1335               BlockBuffering (Just n) | n <= 0    -> ioe_bufsiz n
1336                                       | otherwise -> allocateBuffer n state
1337           writeIORef (haBuffer handle_) new_buf
1338
1339           -- for input terminals we need to put the terminal into
1340           -- cooked or raw mode depending on the type of buffering.
1341           is_tty <- fdIsTTY (haFD handle_)
1342           when (is_tty && isReadableHandleType (haType handle_)) $
1343                 case mode of
1344 #ifndef mingw32_HOST_OS
1345         -- 'raw' mode under win32 is a bit too specialised (and troublesome
1346         -- for most common uses), so simply disable its use here.
1347                   NoBuffering -> setCooked (haFD handle_) False
1348 #else
1349                   NoBuffering -> return ()
1350 #endif
1351                   _           -> setCooked (haFD handle_) True
1352
1353           -- throw away spare buffers, they might be the wrong size
1354           writeIORef (haBuffers handle_) BufferListNil
1355
1356           return (handle_{ haBufferMode = mode })
1357
1358 -- -----------------------------------------------------------------------------
1359 -- hFlush
1360
1361 -- | The action 'hFlush' @hdl@ causes any items buffered for output
1362 -- in handle @hdl@ to be sent immediately to the operating system.
1363 --
1364 -- This operation may fail with:
1365 --
1366 --  * 'isFullError' if the device is full;
1367 --
1368 --  * 'isPermissionError' if a system resource limit would be exceeded.
1369 --    It is unspecified whether the characters in the buffer are discarded
1370 --    or retained under these circumstances.
1371
1372 hFlush :: Handle -> IO ()
1373 hFlush handle =
1374    wantWritableHandle "hFlush" handle $ \ handle_ -> do
1375    buf <- readIORef (haBuffer handle_)
1376    if bufferIsWritable buf && not (bufferEmpty buf)
1377         then do flushed_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
1378                 writeIORef (haBuffer handle_) flushed_buf
1379         else return ()
1380
1381
1382 -- -----------------------------------------------------------------------------
1383 -- Repositioning Handles
1384
1385 data HandlePosn = HandlePosn Handle HandlePosition
1386
1387 instance Eq HandlePosn where
1388     (HandlePosn h1 p1) == (HandlePosn h2 p2) = p1==p2 && h1==h2
1389
1390 instance Show HandlePosn where
1391    showsPrec p (HandlePosn h pos) =
1392         showsPrec p h . showString " at position " . shows pos
1393
1394   -- HandlePosition is the Haskell equivalent of POSIX' off_t.
1395   -- We represent it as an Integer on the Haskell side, but
1396   -- cheat slightly in that hGetPosn calls upon a C helper
1397   -- that reports the position back via (merely) an Int.
1398 type HandlePosition = Integer
1399
1400 -- | Computation 'hGetPosn' @hdl@ returns the current I\/O position of
1401 -- @hdl@ as a value of the abstract type 'HandlePosn'.
1402
1403 hGetPosn :: Handle -> IO HandlePosn
1404 hGetPosn handle = do
1405     posn <- hTell handle
1406     return (HandlePosn handle posn)
1407
1408 -- | If a call to 'hGetPosn' @hdl@ returns a position @p@,
1409 -- then computation 'hSetPosn' @p@ sets the position of @hdl@
1410 -- to the position it held at the time of the call to 'hGetPosn'.
1411 --
1412 -- This operation may fail with:
1413 --
1414 --  * 'isPermissionError' if a system resource limit would be exceeded.
1415
1416 hSetPosn :: HandlePosn -> IO ()
1417 hSetPosn (HandlePosn h i) = hSeek h AbsoluteSeek i
1418
1419 -- ---------------------------------------------------------------------------
1420 -- hSeek
1421
1422 -- | A mode that determines the effect of 'hSeek' @hdl mode i@, as follows:
1423 data SeekMode
1424   = AbsoluteSeek        -- ^ the position of @hdl@ is set to @i@.
1425   | RelativeSeek        -- ^ the position of @hdl@ is set to offset @i@
1426                         -- from the current position.
1427   | SeekFromEnd         -- ^ the position of @hdl@ is set to offset @i@
1428                         -- from the end of the file.
1429     deriving (Eq, Ord, Ix, Enum, Read, Show)
1430
1431 {- Note:
1432  - when seeking using `SeekFromEnd', positive offsets (>=0) means
1433    seeking at or past EOF.
1434
1435  - we possibly deviate from the report on the issue of seeking within
1436    the buffer and whether to flush it or not.  The report isn't exactly
1437    clear here.
1438 -}
1439
1440 -- | Computation 'hSeek' @hdl mode i@ sets the position of handle
1441 -- @hdl@ depending on @mode@.
1442 -- The offset @i@ is given in terms of 8-bit bytes.
1443 --
1444 -- If @hdl@ is block- or line-buffered, then seeking to a position which is not
1445 -- in the current buffer will first cause any items in the output buffer to be
1446 -- written to the device, and then cause the input buffer to be discarded.
1447 -- Some handles may not be seekable (see 'hIsSeekable'), or only support a
1448 -- subset of the possible positioning operations (for instance, it may only
1449 -- be possible to seek to the end of a tape, or to a positive offset from
1450 -- the beginning or current position).
1451 -- It is not possible to set a negative I\/O position, or for
1452 -- a physical file, an I\/O position beyond the current end-of-file.
1453 --
1454 -- This operation may fail with:
1455 --
1456 --  * 'isPermissionError' if a system resource limit would be exceeded.
1457
1458 hSeek :: Handle -> SeekMode -> Integer -> IO ()
1459 hSeek handle mode offset =
1460     wantSeekableHandle "hSeek" handle $ \ handle_ -> do
1461 #   ifdef DEBUG_DUMP
1462     puts ("hSeek " ++ show (mode,offset) ++ "\n")
1463 #   endif
1464     let ref = haBuffer handle_
1465     buf <- readIORef ref
1466     let r = bufRPtr buf
1467         w = bufWPtr buf
1468         fd = haFD handle_
1469
1470     let do_seek =
1471           throwErrnoIfMinus1Retry_ "hSeek"
1472             (c_lseek (haFD handle_) (fromIntegral offset) whence)
1473
1474         whence :: CInt
1475         whence = case mode of
1476                    AbsoluteSeek -> sEEK_SET
1477                    RelativeSeek -> sEEK_CUR
1478                    SeekFromEnd  -> sEEK_END
1479
1480     if bufferIsWritable buf
1481         then do new_buf <- flushWriteBuffer fd (haIsStream handle_) buf
1482                 writeIORef ref new_buf
1483                 do_seek
1484         else do
1485
1486     if mode == RelativeSeek && offset >= 0 && offset < fromIntegral (w - r)
1487         then writeIORef ref buf{ bufRPtr = r + fromIntegral offset }
1488         else do
1489
1490     new_buf <- flushReadBuffer (haFD handle_) buf
1491     writeIORef ref new_buf
1492     do_seek
1493
1494
1495 hTell :: Handle -> IO Integer
1496 hTell handle =
1497     wantSeekableHandle "hGetPosn" handle $ \ handle_ -> do
1498
1499 #if defined(mingw32_HOST_OS)
1500         -- urgh, on Windows we have to worry about \n -> \r\n translation,
1501         -- so we can't easily calculate the file position using the
1502         -- current buffer size.  Just flush instead.
1503       flushBuffer handle_
1504 #endif
1505       let fd = haFD handle_
1506       posn <- fromIntegral `liftM`
1507                 throwErrnoIfMinus1Retry "hGetPosn"
1508                    (c_lseek fd 0 sEEK_CUR)
1509
1510       let ref = haBuffer handle_
1511       buf <- readIORef ref
1512
1513       let real_posn
1514            | bufferIsWritable buf = posn + fromIntegral (bufWPtr buf)
1515            | otherwise = posn - fromIntegral (bufWPtr buf - bufRPtr buf)
1516 #     ifdef DEBUG_DUMP
1517       puts ("\nhGetPosn: (fd, posn, real_posn) = " ++ show (fd, posn, real_posn) ++ "\n")
1518       puts ("   (bufWPtr, bufRPtr) = " ++ show (bufWPtr buf, bufRPtr buf) ++ "\n")
1519 #     endif
1520       return real_posn
1521
1522 -- -----------------------------------------------------------------------------
1523 -- Handle Properties
1524
1525 -- A number of operations return information about the properties of a
1526 -- handle.  Each of these operations returns `True' if the handle has
1527 -- the specified property, and `False' otherwise.
1528
1529 hIsOpen :: Handle -> IO Bool
1530 hIsOpen handle =
1531     withHandle_ "hIsOpen" handle $ \ handle_ -> do
1532     case haType handle_ of
1533       ClosedHandle         -> return False
1534       SemiClosedHandle     -> return False
1535       _                    -> return True
1536
1537 hIsClosed :: Handle -> IO Bool
1538 hIsClosed handle =
1539     withHandle_ "hIsClosed" handle $ \ handle_ -> do
1540     case haType handle_ of
1541       ClosedHandle         -> return True
1542       _                    -> return False
1543
1544 {- not defined, nor exported, but mentioned
1545    here for documentation purposes:
1546
1547     hSemiClosed :: Handle -> IO Bool
1548     hSemiClosed h = do
1549        ho <- hIsOpen h
1550        hc <- hIsClosed h
1551        return (not (ho || hc))
1552 -}
1553
1554 hIsReadable :: Handle -> IO Bool
1555 hIsReadable (DuplexHandle _ _ _) = return True
1556 hIsReadable handle =
1557     withHandle_ "hIsReadable" handle $ \ handle_ -> do
1558     case haType handle_ of
1559       ClosedHandle         -> ioe_closedHandle
1560       SemiClosedHandle     -> ioe_closedHandle
1561       htype                -> return (isReadableHandleType htype)
1562
1563 hIsWritable :: Handle -> IO Bool
1564 hIsWritable (DuplexHandle _ _ _) = return True
1565 hIsWritable handle =
1566     withHandle_ "hIsWritable" handle $ \ handle_ -> do
1567     case haType handle_ of
1568       ClosedHandle         -> ioe_closedHandle
1569       SemiClosedHandle     -> ioe_closedHandle
1570       htype                -> return (isWritableHandleType htype)
1571
1572 -- | Computation 'hGetBuffering' @hdl@ returns the current buffering mode
1573 -- for @hdl@.
1574
1575 hGetBuffering :: Handle -> IO BufferMode
1576 hGetBuffering handle =
1577     withHandle_ "hGetBuffering" handle $ \ handle_ -> do
1578     case haType handle_ of
1579       ClosedHandle         -> ioe_closedHandle
1580       _ ->
1581            -- We're being non-standard here, and allow the buffering
1582            -- of a semi-closed handle to be queried.   -- sof 6/98
1583           return (haBufferMode handle_)  -- could be stricter..
1584
1585 hIsSeekable :: Handle -> IO Bool
1586 hIsSeekable handle =
1587     withHandle_ "hIsSeekable" handle $ \ handle_ -> do
1588     case haType handle_ of
1589       ClosedHandle         -> ioe_closedHandle
1590       SemiClosedHandle     -> ioe_closedHandle
1591       AppendHandle         -> return False
1592       _                    -> do t <- fdType (haFD handle_)
1593                                  return ((t == RegularFile    || t == RawDevice)
1594                                          && (haIsBin handle_  || tEXT_MODE_SEEK_ALLOWED))
1595
1596 -- -----------------------------------------------------------------------------
1597 -- Changing echo status (Non-standard GHC extensions)
1598
1599 -- | Set the echoing status of a handle connected to a terminal.
1600
1601 hSetEcho :: Handle -> Bool -> IO ()
1602 hSetEcho handle on = do
1603     isT   <- hIsTerminalDevice handle
1604     if not isT
1605      then return ()
1606      else
1607       withHandle_ "hSetEcho" handle $ \ handle_ -> do
1608       case haType handle_ of
1609          ClosedHandle -> ioe_closedHandle
1610          _            -> setEcho (haFD handle_) on
1611
1612 -- | Get the echoing status of a handle connected to a terminal.
1613
1614 hGetEcho :: Handle -> IO Bool
1615 hGetEcho handle = do
1616     isT   <- hIsTerminalDevice handle
1617     if not isT
1618      then return False
1619      else
1620        withHandle_ "hGetEcho" handle $ \ handle_ -> do
1621        case haType handle_ of
1622          ClosedHandle -> ioe_closedHandle
1623          _            -> getEcho (haFD handle_)
1624
1625 -- | Is the handle connected to a terminal?
1626
1627 hIsTerminalDevice :: Handle -> IO Bool
1628 hIsTerminalDevice handle = do
1629     withHandle_ "hIsTerminalDevice" handle $ \ handle_ -> do
1630      case haType handle_ of
1631        ClosedHandle -> ioe_closedHandle
1632        _            -> fdIsTTY (haFD handle_)
1633
1634 -- -----------------------------------------------------------------------------
1635 -- hSetBinaryMode
1636
1637 -- | Select binary mode ('True') or text mode ('False') on a open handle.
1638 -- (See also 'openBinaryFile'.)
1639
1640 hSetBinaryMode :: Handle -> Bool -> IO ()
1641 hSetBinaryMode handle bin =
1642   withAllHandles__ "hSetBinaryMode" handle $ \ handle_ ->
1643     do throwErrnoIfMinus1_ "hSetBinaryMode"
1644           (setmode (haFD handle_) bin)
1645        return handle_{haIsBin=bin}
1646
1647 foreign import ccall unsafe "__hscore_setmode"
1648   setmode :: CInt -> Bool -> IO CInt
1649
1650 -- -----------------------------------------------------------------------------
1651 -- Duplicating a Handle
1652
1653 -- | Returns a duplicate of the original handle, with its own buffer.
1654 -- The two Handles will share a file pointer, however.  The original
1655 -- handle's buffer is flushed, including discarding any input data,
1656 -- before the handle is duplicated.
1657
1658 hDuplicate :: Handle -> IO Handle
1659 hDuplicate h@(FileHandle path m) = do
1660   new_h_ <- withHandle' "hDuplicate" h m (dupHandle h Nothing)
1661   newFileHandle path (handleFinalizer path) new_h_
1662 hDuplicate h@(DuplexHandle path r w) = do
1663   new_w_ <- withHandle' "hDuplicate" h w (dupHandle h Nothing)
1664   new_w <- newMVar new_w_
1665   new_r_ <- withHandle' "hDuplicate" h r (dupHandle h (Just new_w))
1666   new_r <- newMVar new_r_
1667   addMVarFinalizer new_w (handleFinalizer path new_w)
1668   return (DuplexHandle path new_r new_w)
1669
1670 dupHandle :: Handle -> Maybe (MVar Handle__) -> Handle__
1671           -> IO (Handle__, Handle__)
1672 dupHandle h other_side h_ = do
1673   -- flush the buffer first, so we don't have to copy its contents
1674   flushBuffer h_
1675   new_fd <- case other_side of
1676                 Nothing -> throwErrnoIfMinus1 "dupHandle" $ c_dup (haFD h_)
1677                 Just r -> withHandle_' "dupHandle" h r (return . haFD)
1678   dupHandle_ other_side h_ new_fd
1679
1680 dupHandleTo :: Maybe (MVar Handle__) -> Handle__ -> Handle__
1681             -> IO (Handle__, Handle__)
1682 dupHandleTo other_side hto_ h_ = do
1683   flushBuffer h_
1684   -- Windows' dup2 does not return the new descriptor, unlike Unix
1685   throwErrnoIfMinus1 "dupHandleTo" $
1686         c_dup2 (haFD h_) (haFD hto_)
1687   dupHandle_ other_side h_ (haFD hto_)
1688
1689 dupHandle_ :: Maybe (MVar Handle__) -> Handle__ -> FD
1690            -> IO (Handle__, Handle__)
1691 dupHandle_ other_side h_ new_fd = do
1692   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE (initBufferState (haType h_))
1693   ioref <- newIORef buffer
1694   ioref_buffers <- newIORef BufferListNil
1695
1696   let new_handle_ = h_{ haFD = new_fd,
1697                         haBuffer = ioref,
1698                         haBuffers = ioref_buffers,
1699                         haOtherSide = other_side }
1700   return (h_, new_handle_)
1701
1702 -- -----------------------------------------------------------------------------
1703 -- Replacing a Handle
1704
1705 {- |
1706 Makes the second handle a duplicate of the first handle.  The second
1707 handle will be closed first, if it is not already.
1708
1709 This can be used to retarget the standard Handles, for example:
1710
1711 > do h <- openFile "mystdout" WriteMode
1712 >    hDuplicateTo h stdout
1713 -}
1714
1715 hDuplicateTo :: Handle -> Handle -> IO ()
1716 hDuplicateTo h1@(FileHandle _ m1) h2@(FileHandle _ m2)  = do
1717  withHandle__' "hDuplicateTo" h2 m2 $ \h2_ -> do
1718    _ <- hClose_help h2_
1719    withHandle' "hDuplicateTo" h1 m1 (dupHandleTo Nothing h2_)
1720 hDuplicateTo h1@(DuplexHandle _ r1 w1) h2@(DuplexHandle _ r2 w2)  = do
1721  withHandle__' "hDuplicateTo" h2 w2  $ \w2_ -> do
1722    _ <- hClose_help w2_
1723    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo Nothing w2_)
1724  withHandle__' "hDuplicateTo" h2 r2  $ \r2_ -> do
1725    _ <- hClose_help r2_
1726    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo (Just w1) r2_)
1727 hDuplicateTo h1 _ =
1728    ioException (IOError (Just h1) IllegalOperation "hDuplicateTo"
1729                 "handles are incompatible" Nothing)
1730
1731 -- ---------------------------------------------------------------------------
1732 -- showing Handles.
1733 --
1734 -- | 'hShow' is in the 'IO' monad, and gives more comprehensive output
1735 -- than the (pure) instance of 'Show' for 'Handle'.
1736
1737 hShow :: Handle -> IO String
1738 hShow h@(FileHandle path _) = showHandle' path False h
1739 hShow h@(DuplexHandle path _ _) = showHandle' path True h
1740
1741 showHandle' :: String -> Bool -> Handle -> IO String
1742 showHandle' filepath is_duplex h =
1743   withHandle_ "showHandle" h $ \hdl_ ->
1744     let
1745      showType | is_duplex = showString "duplex (read-write)"
1746               | otherwise = shows (haType hdl_)
1747     in
1748     return
1749       (( showChar '{' .
1750         showHdl (haType hdl_)
1751             (showString "loc=" . showString filepath . showChar ',' .
1752              showString "type=" . showType . showChar ',' .
1753              showString "binary=" . shows (haIsBin hdl_) . showChar ',' .
1754              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
1755       ) "")
1756    where
1757
1758     showHdl :: HandleType -> ShowS -> ShowS
1759     showHdl ht cont =
1760        case ht of
1761         ClosedHandle  -> shows ht . showString "}"
1762         _ -> cont
1763
1764     showBufMode :: Buffer -> BufferMode -> ShowS
1765     showBufMode buf bmo =
1766       case bmo of
1767         NoBuffering   -> showString "none"
1768         LineBuffering -> showString "line"
1769         BlockBuffering (Just n) -> showString "block " . showParen True (shows n)
1770         BlockBuffering Nothing  -> showString "block " . showParen True (shows def)
1771       where
1772        def :: Int
1773        def = bufSize buf
1774
1775 -- ---------------------------------------------------------------------------
1776 -- debugging
1777
1778 #if defined(DEBUG_DUMP)
1779 puts :: String -> IO ()
1780 puts s = do write_rawBuffer 1 (unsafeCoerce# (packCString# s)) 0 (fromIntegral (length s))
1781             return ()
1782 #endif
1783
1784 -- -----------------------------------------------------------------------------
1785 -- utils
1786
1787 throwErrnoIfMinus1RetryOnBlock  :: String -> IO CInt -> IO CInt -> IO CInt
1788 throwErrnoIfMinus1RetryOnBlock loc f on_block  =
1789   do
1790     res <- f
1791     if (res :: CInt) == -1
1792       then do
1793         err <- getErrno
1794         if err == eINTR
1795           then throwErrnoIfMinus1RetryOnBlock loc f on_block
1796           else if err == eWOULDBLOCK || err == eAGAIN
1797                  then do on_block
1798                  else throwErrno loc
1799       else return res
1800
1801 -- -----------------------------------------------------------------------------
1802 -- wrappers to platform-specific constants:
1803
1804 foreign import ccall unsafe "__hscore_supportsTextMode"
1805   tEXT_MODE_SEEK_ALLOWED :: Bool
1806
1807 foreign import ccall unsafe "__hscore_bufsiz"   dEFAULT_BUFFER_SIZE :: Int
1808 foreign import ccall unsafe "__hscore_seek_cur" sEEK_CUR :: CInt
1809 foreign import ccall unsafe "__hscore_seek_set" sEEK_SET :: CInt
1810 foreign import ccall unsafe "__hscore_seek_end" sEEK_END :: CInt