GHC/Handle.hs

   1 {-# OPTIONS_GHC -fno-implicit-prelude -#include "HsBase.h" #-}
   2
   3 #undef DEBUG_DUMP
   4 #undef DEBUG
   5
   6 -----------------------------------------------------------------------------
   7 -- |
   8 -- Module      :  GHC.Handle
   9 -- Copyright   :  (c) The University of Glasgow, 1994-2001
  10 -- License     :  see libraries/base/LICENSE
  11 --
  12 -- Maintainer  :  libraries@haskell.org
  13 -- Stability   :  internal
  14 -- Portability :  non-portable
  15 --
  16 -- This module defines the basic operations on I\/O \"handles\".
  17 --
  18 -----------------------------------------------------------------------------
  19
  20 -- #hide
  21 module GHC.Handle (
  22   withHandle, withHandle', withHandle_,
  23   wantWritableHandle, wantReadableHandle, wantSeekableHandle,
  24
  25   newEmptyBuffer, allocateBuffer, readCharFromBuffer, writeCharIntoBuffer,
  26   flushWriteBufferOnly, flushWriteBuffer, flushReadBuffer,
  27   fillReadBuffer, fillReadBufferWithoutBlocking,
  28   readRawBuffer, readRawBufferPtr,
  29   writeRawBuffer, writeRawBufferPtr,
  30
  31 #ifndef mingw32_HOST_OS
  32   unlockFile,
  33 #endif
  34
  35   ioe_closedHandle, ioe_EOF, ioe_notReadable, ioe_notWritable,
  36
  37   stdin, stdout, stderr,
  38   IOMode(..), openFile, openBinaryFile, openTempFile, openBinaryTempFile, openFd, fdToHandle,
  39   hFileSize, hSetFileSize, hIsEOF, isEOF, hLookAhead, hSetBuffering, hSetBinaryMode,
  40   hFlush, hDuplicate, hDuplicateTo,
  41
  42   hClose, hClose_help,
  43
  44   HandlePosition, HandlePosn(..), hGetPosn, hSetPosn,
  45   SeekMode(..), hSeek, hTell,
  46
  47   hIsOpen, hIsClosed, hIsReadable, hIsWritable, hGetBuffering, hIsSeekable,
  48   hSetEcho, hGetEcho, hIsTerminalDevice,
  49
  50   hShow,
  51
  52 #ifdef DEBUG_DUMP
  53   puts,
  54 #endif
  55
  56  ) where
  57
  58 import System.Directory.Internals
  59 import Control.Monad
  60 import Data.Bits
  61 import Data.Maybe
  62 import Foreign
  63 import Foreign.C
  64 import System.IO.Error
  65 import System.Posix.Internals
  66
  67 import GHC.Real
  68
  69 import GHC.Arr
  70 import GHC.Base
  71 import GHC.Read         ( Read )
  72 import GHC.List
  73 import GHC.IOBase
  74 import GHC.Exception
  75 import GHC.Enum
  76 import GHC.Num          ( Integer(..), Num(..) )
  77 import GHC.Show
  78 import GHC.Real         ( toInteger )
  79 #if defined(DEBUG_DUMP)
  80 import GHC.Pack
  81 #endif
  82
  83 import GHC.Conc
  84
  85 -- -----------------------------------------------------------------------------
  86 -- TODO:
  87
  88 -- hWaitForInput blocks (should use a timeout)
  89
  90 -- unbuffered hGetLine is a bit dodgy
  91
  92 -- hSetBuffering: can't change buffering on a stream,
  93 --      when the read buffer is non-empty? (no way to flush the buffer)
  94
  95 -- ---------------------------------------------------------------------------
  96 -- Are files opened by default in text or binary mode, if the user doesn't
  97 -- specify?
  98
  99 dEFAULT_OPEN_IN_BINARY_MODE = False :: Bool
 100
 101 -- ---------------------------------------------------------------------------
 102 -- Creating a new handle
 103
 104 newFileHandle :: FilePath -> (MVar Handle__ -> IO ()) -> Handle__ -> IO Handle
 105 newFileHandle filepath finalizer hc = do
 106   m <- newMVar hc
 107   addMVarFinalizer m (finalizer m)
 108   return (FileHandle filepath m)
 109
 110 -- ---------------------------------------------------------------------------
 111 -- Working with Handles
 112
 113 {-
 114 In the concurrent world, handles are locked during use.  This is done
 115 by wrapping an MVar around the handle which acts as a mutex over
 116 operations on the handle.
 117
 118 To avoid races, we use the following bracketing operations.  The idea
 119 is to obtain the lock, do some operation and replace the lock again,
 120 whether the operation succeeded or failed.  We also want to handle the
 121 case where the thread receives an exception while processing the IO
 122 operation: in these cases we also want to relinquish the lock.
 123
 124 There are three versions of @withHandle@: corresponding to the three
 125 possible combinations of:
 126
 127         - the operation may side-effect the handle
 128         - the operation may return a result
 129
 130 If the operation generates an error or an exception is raised, the
 131 original handle is always replaced [ this is the case at the moment,
 132 but we might want to revisit this in the future --SDM ].
 133 -}
 134
 135 {-# INLINE withHandle #-}
 136 withHandle :: String -> Handle -> (Handle__ -> IO (Handle__,a)) -> IO a
 137 withHandle fun h@(FileHandle _ m)     act = withHandle' fun h m act
 138 withHandle fun h@(DuplexHandle _ m _) act = withHandle' fun h m act
 139
 140 withHandle' :: String -> Handle -> MVar Handle__
 141    -> (Handle__ -> IO (Handle__,a)) -> IO a
 142 withHandle' fun h m act =
 143    block $ do
 144    h_ <- takeMVar m
 145    checkBufferInvariants h_
 146    (h',v)  <- catchException (act h_)
 147                 (\ err -> putMVar m h_ >>
 148                           case err of
 149                              IOException ex -> ioError (augmentIOError ex fun h)
 150                              _ -> throw err)
 151    checkBufferInvariants h'
 152    putMVar m h'
 153    return v
 154
 155 {-# INLINE withHandle_ #-}
 156 withHandle_ :: String -> Handle -> (Handle__ -> IO a) -> IO a
 157 withHandle_ fun h@(FileHandle _ m)     act = withHandle_' fun h m act
 158 withHandle_ fun h@(DuplexHandle _ m _) act = withHandle_' fun h m act
 159
 160 withHandle_' fun h m act =
 161    block $ do
 162    h_ <- takeMVar m
 163    checkBufferInvariants h_
 164    v  <- catchException (act h_)
 165                 (\ err -> putMVar m h_ >>
 166                           case err of
 167                              IOException ex -> ioError (augmentIOError ex fun h)
 168                              _ -> throw err)
 169    checkBufferInvariants h_
 170    putMVar m h_
 171    return v
 172
 173 withAllHandles__ :: String -> Handle -> (Handle__ -> IO Handle__) -> IO ()
 174 withAllHandles__ fun h@(FileHandle _ m)     act = withHandle__' fun h m act
 175 withAllHandles__ fun h@(DuplexHandle _ r w) act = do
 176   withHandle__' fun h r act
 177   withHandle__' fun h w act
 178
 179 withHandle__' fun h m act =
 180    block $ do
 181    h_ <- takeMVar m
 182    checkBufferInvariants h_
 183    h'  <- catchException (act h_)
 184                 (\ err -> putMVar m h_ >>
 185                           case err of
 186                              IOException ex -> ioError (augmentIOError ex fun h)
 187                              _ -> throw err)
 188    checkBufferInvariants h'
 189    putMVar m h'
 190    return ()
 191
 192 augmentIOError (IOError _ iot _ str fp) fun h
 193   = IOError (Just h) iot fun str filepath
 194   where filepath
 195           | Just _ <- fp = fp
 196           | otherwise = case h of
 197                           FileHandle fp _     -> Just fp
 198                           DuplexHandle fp _ _ -> Just fp
 199
 200 -- ---------------------------------------------------------------------------
 201 -- Wrapper for write operations.
 202
 203 wantWritableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 204 wantWritableHandle fun h@(FileHandle _ m) act
 205   = wantWritableHandle' fun h m act
 206 wantWritableHandle fun h@(DuplexHandle _ _ m) act
 207   = wantWritableHandle' fun h m act
 208   -- ToDo: in the Duplex case, we don't need to checkWritableHandle
 209
 210 wantWritableHandle'
 211         :: String -> Handle -> MVar Handle__
 212         -> (Handle__ -> IO a) -> IO a
 213 wantWritableHandle' fun h m act
 214    = withHandle_' fun h m (checkWritableHandle act)
 215
 216 checkWritableHandle act handle_
 217   = case haType handle_ of
 218       ClosedHandle         -> ioe_closedHandle
 219       SemiClosedHandle     -> ioe_closedHandle
 220       ReadHandle           -> ioe_notWritable
 221       ReadWriteHandle      -> do
 222                 let ref = haBuffer handle_
 223                 buf <- readIORef ref
 224                 new_buf <-
 225                   if not (bufferIsWritable buf)
 226                      then do b <- flushReadBuffer (haFD handle_) buf
 227                              return b{ bufState=WriteBuffer }
 228                      else return buf
 229                 writeIORef ref new_buf
 230                 act handle_
 231       _other               -> act handle_
 232
 233 -- ---------------------------------------------------------------------------
 234 -- Wrapper for read operations.
 235
 236 wantReadableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 237 wantReadableHandle fun h@(FileHandle  _ m)   act
 238   = wantReadableHandle' fun h m act
 239 wantReadableHandle fun h@(DuplexHandle _ m _) act
 240   = wantReadableHandle' fun h m act
 241   -- ToDo: in the Duplex case, we don't need to checkReadableHandle
 242
 243 wantReadableHandle'
 244         :: String -> Handle -> MVar Handle__
 245         -> (Handle__ -> IO a) -> IO a
 246 wantReadableHandle' fun h m act
 247   = withHandle_' fun h m (checkReadableHandle act)
 248
 249 checkReadableHandle act handle_ =
 250     case haType handle_ of
 251       ClosedHandle         -> ioe_closedHandle
 252       SemiClosedHandle     -> ioe_closedHandle
 253       AppendHandle         -> ioe_notReadable
 254       WriteHandle          -> ioe_notReadable
 255       ReadWriteHandle      -> do
 256         let ref = haBuffer handle_
 257         buf <- readIORef ref
 258         when (bufferIsWritable buf) $ do
 259            new_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
 260            writeIORef ref new_buf{ bufState=ReadBuffer }
 261         act handle_
 262       _other               -> act handle_
 263
 264 -- ---------------------------------------------------------------------------
 265 -- Wrapper for seek operations.
 266
 267 wantSeekableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 268 wantSeekableHandle fun h@(DuplexHandle _ _ _) _act =
 269   ioException (IOError (Just h) IllegalOperation fun
 270                    "handle is not seekable" Nothing)
 271 wantSeekableHandle fun h@(FileHandle _ m) act =
 272   withHandle_' fun h m (checkSeekableHandle act)
 273
 274 checkSeekableHandle act handle_ =
 275     case haType handle_ of
 276       ClosedHandle      -> ioe_closedHandle
 277       SemiClosedHandle  -> ioe_closedHandle
 278       AppendHandle      -> ioe_notSeekable
 279       _  | haIsBin handle_ || tEXT_MODE_SEEK_ALLOWED -> act handle_
 280          | otherwise                                 -> ioe_notSeekable_notBin
 281
 282 -- -----------------------------------------------------------------------------
 283 -- Handy IOErrors
 284
 285 ioe_closedHandle, ioe_EOF,
 286   ioe_notReadable, ioe_notWritable,
 287   ioe_notSeekable, ioe_notSeekable_notBin :: IO a
 288
 289 ioe_closedHandle = ioException
 290    (IOError Nothing IllegalOperation ""
 291         "handle is closed" Nothing)
 292 ioe_EOF = ioException
 293    (IOError Nothing EOF "" "" Nothing)
 294 ioe_notReadable = ioException
 295    (IOError Nothing IllegalOperation ""
 296         "handle is not open for reading" Nothing)
 297 ioe_notWritable = ioException
 298    (IOError Nothing IllegalOperation ""
 299         "handle is not open for writing" Nothing)
 300 ioe_notSeekable = ioException
 301    (IOError Nothing IllegalOperation ""
 302         "handle is not seekable" Nothing)
 303 ioe_notSeekable_notBin = ioException
 304    (IOError Nothing IllegalOperation ""
 305       "seek operations on text-mode handles are not allowed on this platform"
 306         Nothing)
 307
 308 ioe_finalizedHandle fp = throw (IOException
 309    (IOError Nothing IllegalOperation ""
 310         "handle is finalized" (Just fp)))
 311
 312 ioe_bufsiz :: Int -> IO a
 313 ioe_bufsiz n = ioException
 314    (IOError Nothing InvalidArgument "hSetBuffering"
 315         ("illegal buffer size " ++ showsPrec 9 n []) Nothing)
 316                                 -- 9 => should be parens'ified.
 317
 318 -- -----------------------------------------------------------------------------
 319 -- Handle Finalizers
 320
 321 -- For a duplex handle, we arrange that the read side points to the write side
 322 -- (and hence keeps it alive if the read side is alive).  This is done by
 323 -- having the haOtherSide field of the read side point to the read side.
 324 -- The finalizer is then placed on the write side, and the handle only gets
 325 -- finalized once, when both sides are no longer required.
 326
 327 -- NOTE about finalized handles: It's possible that a handle can be
 328 -- finalized and then we try to use it later, for example if the
 329 -- handle is referenced from another finalizer, or from a thread that
 330 -- has become unreferenced and then resurrected (arguably in the
 331 -- latter case we shouldn't finalize the Handle...).  Anyway,
 332 -- we try to emit a helpful message which is better than nothing.
 333
 334 stdHandleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 335 stdHandleFinalizer fp m = do
 336   h_ <- takeMVar m
 337   flushWriteBufferOnly h_
 338   putMVar m (ioe_finalizedHandle fp)
 339
 340 handleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 341 handleFinalizer fp m = do
 342   handle_ <- takeMVar m
 343   case haType handle_ of
 344       ClosedHandle -> return ()
 345       _ -> do flushWriteBufferOnly handle_ `catchException` \_ -> return ()
 346                 -- ignore errors and async exceptions, and close the
 347                 -- descriptor anyway...
 348               hClose_handle_ handle_
 349               return ()
 350   putMVar m (ioe_finalizedHandle fp)
 351
 352 -- ---------------------------------------------------------------------------
 353 -- Grimy buffer operations
 354
 355 #ifdef DEBUG
 356 checkBufferInvariants h_ = do
 357  let ref = haBuffer h_
 358  Buffer{ bufWPtr=w, bufRPtr=r, bufSize=size, bufState=state } <- readIORef ref
 359  if not (
 360         size > 0
 361         && r <= w
 362         && w <= size
 363         && ( r /= w || (r == 0 && w == 0) )
 364         && ( state /= WriteBuffer || r == 0 )
 365         && ( state /= WriteBuffer || w < size ) -- write buffer is never full
 366      )
 367    then error "buffer invariant violation"
 368    else return ()
 369 #else
 370 checkBufferInvariants h_ = return ()
 371 #endif
 372
 373 newEmptyBuffer :: RawBuffer -> BufferState -> Int -> Buffer
 374 newEmptyBuffer b state size
 375   = Buffer{ bufBuf=b, bufRPtr=0, bufWPtr=0, bufSize=size, bufState=state }
 376
 377 allocateBuffer :: Int -> BufferState -> IO Buffer
 378 allocateBuffer sz@(I# size) state = IO $ \s ->
 379 #ifdef mingw32_HOST_OS
 380    -- To implement asynchronous I/O under Win32, we have to pass
 381    -- buffer references to external threads that handles the
 382    -- filling/emptying of their contents. Hence, the buffer cannot
 383    -- be moved around by the GC.
 384   case newPinnedByteArray# size s of { (# s, b #) ->
 385 #else
 386   case newByteArray# size s of { (# s, b #) ->
 387 #endif
 388   (# s, newEmptyBuffer b state sz #) }
 389
 390 writeCharIntoBuffer :: RawBuffer -> Int -> Char -> IO Int
 391 writeCharIntoBuffer slab (I# off) (C# c)
 392   = IO $ \s -> case writeCharArray# slab off c s of
 393                  s -> (# s, I# (off +# 1#) #)
 394
 395 readCharFromBuffer :: RawBuffer -> Int -> IO (Char, Int)
 396 readCharFromBuffer slab (I# off)
 397   = IO $ \s -> case readCharArray# slab off s of
 398                  (# s, c #) -> (# s, (C# c, I# (off +# 1#)) #)
 399
 400 getBuffer :: FD -> BufferState -> IO (IORef Buffer, BufferMode)
 401 getBuffer fd state = do
 402   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE state
 403   ioref  <- newIORef buffer
 404   is_tty <- fdIsTTY fd
 405
 406   let buffer_mode
 407          | is_tty    = LineBuffering
 408          | otherwise = BlockBuffering Nothing
 409
 410   return (ioref, buffer_mode)
 411
 412 mkUnBuffer :: IO (IORef Buffer)
 413 mkUnBuffer = do
 414   buffer <- allocateBuffer 1 ReadBuffer
 415   newIORef buffer
 416
 417 -- flushWriteBufferOnly flushes the buffer iff it contains pending write data.
 418 flushWriteBufferOnly :: Handle__ -> IO ()
 419 flushWriteBufferOnly h_ = do
 420   let fd = haFD h_
 421       ref = haBuffer h_
 422   buf <- readIORef ref
 423   new_buf <- if bufferIsWritable buf
 424                 then flushWriteBuffer fd (haIsStream h_) buf
 425                 else return buf
 426   writeIORef ref new_buf
 427
 428 -- flushBuffer syncs the file with the buffer, including moving the
 429 -- file pointer backwards in the case of a read buffer.
 430 flushBuffer :: Handle__ -> IO ()
 431 flushBuffer h_ = do
 432   let ref = haBuffer h_
 433   buf <- readIORef ref
 434
 435   flushed_buf <-
 436     case bufState buf of
 437       ReadBuffer  -> flushReadBuffer  (haFD h_) buf
 438       WriteBuffer -> flushWriteBuffer (haFD h_) (haIsStream h_) buf
 439
 440   writeIORef ref flushed_buf
 441
 442 -- When flushing a read buffer, we seek backwards by the number of
 443 -- characters in the buffer.  The file descriptor must therefore be
 444 -- seekable: attempting to flush the read buffer on an unseekable
 445 -- handle is not allowed.
 446
 447 flushReadBuffer :: FD -> Buffer -> IO Buffer
 448 flushReadBuffer fd buf
 449   | bufferEmpty buf = return buf
 450   | otherwise = do
 451      let off = negate (bufWPtr buf - bufRPtr buf)
 452 #    ifdef DEBUG_DUMP
 453      puts ("flushReadBuffer: new file offset = " ++ show off ++ "\n")
 454 #    endif
 455      throwErrnoIfMinus1Retry "flushReadBuffer"
 456          (c_lseek (fromIntegral fd) (fromIntegral off) sEEK_CUR)
 457      return buf{ bufWPtr=0, bufRPtr=0 }
 458
 459 flushWriteBuffer :: FD -> Bool -> Buffer -> IO Buffer
 460 flushWriteBuffer fd is_stream buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w }  =
 461   seq fd $ do -- strictness hack
 462   let bytes = w - r
 463 #ifdef DEBUG_DUMP
 464   puts ("flushWriteBuffer, fd=" ++ show fd ++ ", bytes=" ++ show bytes ++ "\n")
 465 #endif
 466   if bytes == 0
 467      then return (buf{ bufRPtr=0, bufWPtr=0 })
 468      else do
 469   res <- writeRawBuffer "flushWriteBuffer" (fromIntegral fd) is_stream b
 470                         (fromIntegral r) (fromIntegral bytes)
 471   let res' = fromIntegral res
 472   if res' < bytes
 473      then flushWriteBuffer fd is_stream (buf{ bufRPtr = r + res' })
 474      else return buf{ bufRPtr=0, bufWPtr=0 }
 475
 476 fillReadBuffer :: FD -> Bool -> Bool -> Buffer -> IO Buffer
 477 fillReadBuffer fd is_line is_stream
 478       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 479   -- buffer better be empty:
 480   assert (r == 0 && w == 0) $ do
 481   fillReadBufferLoop fd is_line is_stream buf b w size
 482
 483 -- For a line buffer, we just get the first chunk of data to arrive,
 484 -- and don't wait for the whole buffer to be full (but we *do* wait
 485 -- until some data arrives).  This isn't really line buffering, but it
 486 -- appears to be what GHC has done for a long time, and I suspect it
 487 -- is more useful than line buffering in most cases.
 488
 489 fillReadBufferLoop fd is_line is_stream buf b w size = do
 490   let bytes = size - w
 491   if bytes == 0  -- buffer full?
 492      then return buf{ bufRPtr=0, bufWPtr=w }
 493      else do
 494 #ifdef DEBUG_DUMP
 495   puts ("fillReadBufferLoop: bytes = " ++ show bytes ++ "\n")
 496 #endif
 497   res <- readRawBuffer "fillReadBuffer" fd is_stream b
 498                        (fromIntegral w) (fromIntegral bytes)
 499   let res' = fromIntegral res
 500 #ifdef DEBUG_DUMP
 501   puts ("fillReadBufferLoop:  res' = " ++ show res' ++ "\n")
 502 #endif
 503   if res' == 0
 504      then if w == 0
 505              then ioe_EOF
 506              else return buf{ bufRPtr=0, bufWPtr=w }
 507      else if res' < bytes && not is_line
 508              then fillReadBufferLoop fd is_line is_stream buf b (w+res') size
 509              else return buf{ bufRPtr=0, bufWPtr=w+res' }
 510
 511
 512 fillReadBufferWithoutBlocking :: FD -> Bool -> Buffer -> IO Buffer
 513 fillReadBufferWithoutBlocking fd is_stream
 514       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 515   -- buffer better be empty:
 516   assert (r == 0 && w == 0) $ do
 517 #ifdef DEBUG_DUMP
 518   puts ("fillReadBufferLoopNoBlock: bytes = " ++ show size ++ "\n")
 519 #endif
 520   res <- readRawBufferNoBlock "fillReadBuffer" fd is_stream b
 521                        0 (fromIntegral size)
 522   let res' = fromIntegral res
 523 #ifdef DEBUG_DUMP
 524   puts ("fillReadBufferLoopNoBlock:  res' = " ++ show res' ++ "\n")
 525 #endif
 526   return buf{ bufRPtr=0, bufWPtr=res' }
 527
 528 -- Low level routines for reading/writing to (raw)buffers:
 529
 530 #ifndef mingw32_HOST_OS
 531 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 532 readRawBuffer loc fd is_stream buf off len =
 533   throwErrnoIfMinus1RetryMayBlock loc
 534             (read_rawBuffer fd buf off len)
 535             (threadWaitRead (fromIntegral fd))
 536
 537 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 538 readRawBufferNoBlock loc fd is_stream buf off len =
 539   throwErrnoIfMinus1RetryOnBlock loc
 540             (read_rawBuffer fd buf off len)
 541             (return 0)
 542
 543 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 544 readRawBufferPtr loc fd is_stream buf off len =
 545   throwErrnoIfMinus1RetryMayBlock loc
 546             (read_off fd buf off len)
 547             (threadWaitRead (fromIntegral fd))
 548
 549 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 550 writeRawBuffer loc fd is_stream buf off len =
 551   throwErrnoIfMinus1RetryMayBlock loc
 552                 (write_rawBuffer (fromIntegral fd) buf off len)
 553                 (threadWaitWrite (fromIntegral fd))
 554
 555 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 556 writeRawBufferPtr loc fd is_stream buf off len =
 557   throwErrnoIfMinus1RetryMayBlock loc
 558                 (write_off (fromIntegral fd) buf off len)
 559                 (threadWaitWrite (fromIntegral fd))
 560
 561 foreign import ccall unsafe "__hscore_PrelHandle_read"
 562    read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 563
 564 foreign import ccall unsafe "__hscore_PrelHandle_read"
 565    read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 566
 567 foreign import ccall unsafe "__hscore_PrelHandle_write"
 568    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 569
 570 foreign import ccall unsafe "__hscore_PrelHandle_write"
 571    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 572
 573 #else /* mingw32_HOST_OS.... */
 574
 575 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 576 readRawBuffer loc fd is_stream buf off len
 577   | threaded  = blockingReadRawBuffer loc fd is_stream buf off len
 578   | otherwise = asyncReadRawBuffer loc fd is_stream buf off len
 579
 580 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 581 readRawBufferPtr loc fd is_stream buf off len
 582   | threaded  = blockingReadRawBufferPtr loc fd is_stream buf off len
 583   | otherwise = asyncReadRawBufferPtr loc fd is_stream buf off len
 584
 585 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 586 writeRawBuffer loc fd is_stream buf off len
 587   | threaded =  blockingWriteRawBuffer loc fd is_stream buf off len
 588   | otherwise = asyncWriteRawBuffer    loc fd is_stream buf off len
 589
 590 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 591 writeRawBufferPtr loc fd is_stream buf off len
 592   | threaded  = blockingWriteRawBufferPtr loc fd is_stream buf off len
 593   | otherwise = asyncWriteRawBufferPtr    loc fd is_stream buf off len
 594
 595 -- ToDo: we don't have a non-blocking primitve read on Win32
 596 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 597 readRawBufferNoBlock = readRawBufferNoBlock
 598
 599 -- Async versions of the read/write primitives, for the non-threaded RTS
 600
 601 asyncReadRawBuffer loc fd is_stream buf off len = do
 602     (l, rc) <- asyncReadBA fd (if is_stream then 1 else 0)
 603                  (fromIntegral len) off buf
 604     if l == (-1)
 605       then
 606         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 607       else return (fromIntegral l)
 608
 609 asyncReadRawBufferPtr loc fd is_stream buf off len = do
 610     (l, rc) <- asyncRead fd (if is_stream then 1 else 0)
 611                         (fromIntegral len) (buf `plusPtr` off)
 612     if l == (-1)
 613       then
 614         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 615       else return (fromIntegral l)
 616
 617 asyncWriteRawBuffer loc fd is_stream buf off len = do
 618     (l, rc) <- asyncWriteBA fd (if is_stream then 1 else 0)
 619                         (fromIntegral len) off buf
 620     if l == (-1)
 621       then
 622         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 623       else return (fromIntegral l)
 624
 625 asyncWriteRawBufferPtr loc fd is_stream buf off len = do
 626     (l, rc) <- asyncWrite fd (if is_stream then 1 else 0)
 627                   (fromIntegral len) (buf `plusPtr` off)
 628     if l == (-1)
 629       then
 630         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 631       else return (fromIntegral l)
 632
 633 -- Blocking versions of the read/write primitives, for the threaded RTS
 634
 635 blockingReadRawBuffer loc fd True buf off len =
 636   throwErrnoIfMinus1Retry loc $
 637     recv_rawBuffer fd buf off len
 638 blockingReadRawBuffer loc fd False buf off len =
 639   throwErrnoIfMinus1Retry loc $
 640     read_rawBuffer fd buf off len
 641
 642 blockingReadRawBufferPtr loc fd True buf off len =
 643   throwErrnoIfMinus1Retry loc $
 644     recv_off fd buf off len
 645 blockingReadRawBufferPtr loc fd False buf off len =
 646   throwErrnoIfMinus1Retry loc $
 647     read_off fd buf off len
 648
 649 blockingWriteRawBuffer loc fd True buf off len =
 650   throwErrnoIfMinus1Retry loc $
 651     send_rawBuffer (fromIntegral fd) buf off len
 652 blockingWriteRawBuffer loc fd False buf off len =
 653   throwErrnoIfMinus1Retry loc $
 654     write_rawBuffer (fromIntegral fd) buf off len
 655
 656 blockingWriteRawBufferPtr loc fd True buf off len =
 657   throwErrnoIfMinus1Retry loc $
 658     send_off (fromIntegral fd) buf off len
 659 blockingWriteRawBufferPtr loc fd False buf off len =
 660   throwErrnoIfMinus1Retry loc $
 661     write_off (fromIntegral fd) buf off len
 662
 663 -- NOTE: "safe" versions of the read/write calls for use by the threaded RTS.
 664 -- These calls may block, but that's ok.
 665
 666 foreign import ccall safe "__hscore_PrelHandle_read"
 667    read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 668
 669 foreign import ccall safe "__hscore_PrelHandle_read"
 670    read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 671
 672 foreign import ccall safe "__hscore_PrelHandle_write"
 673    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 674
 675 foreign import ccall safe "__hscore_PrelHandle_write"
 676    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 677
 678 foreign import ccall safe "__hscore_PrelHandle_recv"
 679    recv_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 680
 681 foreign import ccall safe "__hscore_PrelHandle_recv"
 682    recv_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 683
 684 foreign import ccall safe "__hscore_PrelHandle_send"
 685    send_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 686
 687 foreign import ccall safe "__hscore_PrelHandle_send"
 688    send_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 689
 690 foreign import ccall "rtsSupportsBoundThreads" threaded :: Bool
 691 #endif
 692
 693 -- ---------------------------------------------------------------------------
 694 -- Standard Handles
 695
 696 -- Three handles are allocated during program initialisation.  The first
 697 -- two manage input or output from the Haskell program's standard input
 698 -- or output channel respectively.  The third manages output to the
 699 -- standard error channel. These handles are initially open.
 700
 701 fd_stdin  = 0 :: FD
 702 fd_stdout = 1 :: FD
 703 fd_stderr = 2 :: FD
 704
 705 -- | A handle managing input from the Haskell program's standard input channel.
 706 stdin :: Handle
 707 stdin = unsafePerformIO $ do
 708    -- ToDo: acquire lock
 709    setNonBlockingFD fd_stdin
 710    (buf, bmode) <- getBuffer fd_stdin ReadBuffer
 711    mkStdHandle fd_stdin "<stdin>" ReadHandle buf bmode
 712
 713 -- | A handle managing output to the Haskell program's standard output channel.
 714 stdout :: Handle
 715 stdout = unsafePerformIO $ do
 716    -- ToDo: acquire lock
 717    -- We don't set non-blocking mode on stdout or sterr, because
 718    -- some shells don't recover properly.
 719    -- setNonBlockingFD fd_stdout
 720    (buf, bmode) <- getBuffer fd_stdout WriteBuffer
 721    mkStdHandle fd_stdout "<stdout>" WriteHandle buf bmode
 722
 723 -- | A handle managing output to the Haskell program's standard error channel.
 724 stderr :: Handle
 725 stderr = unsafePerformIO $ do
 726     -- ToDo: acquire lock
 727    -- We don't set non-blocking mode on stdout or sterr, because
 728    -- some shells don't recover properly.
 729    -- setNonBlockingFD fd_stderr
 730    buf <- mkUnBuffer
 731    mkStdHandle fd_stderr "<stderr>" WriteHandle buf NoBuffering
 732
 733 -- ---------------------------------------------------------------------------
 734 -- Opening and Closing Files
 735
 736 addFilePathToIOError fun fp (IOError h iot _ str _)
 737   = IOError h iot fun str (Just fp)
 738
 739 -- | Computation 'openFile' @file mode@ allocates and returns a new, open
 740 -- handle to manage the file @file@.  It manages input if @mode@
 741 -- is 'ReadMode', output if @mode@ is 'WriteMode' or 'AppendMode',
 742 -- and both input and output if mode is 'ReadWriteMode'.
 743 --
 744 -- If the file does not exist and it is opened for output, it should be
 745 -- created as a new file.  If @mode@ is 'WriteMode' and the file
 746 -- already exists, then it should be truncated to zero length.
 747 -- Some operating systems delete empty files, so there is no guarantee
 748 -- that the file will exist following an 'openFile' with @mode@
 749 -- 'WriteMode' unless it is subsequently written to successfully.
 750 -- The handle is positioned at the end of the file if @mode@ is
 751 -- 'AppendMode', and otherwise at the beginning (in which case its
 752 -- internal position is 0).
 753 -- The initial buffer mode is implementation-dependent.
 754 --
 755 -- This operation may fail with:
 756 --
 757 --  * 'isAlreadyInUseError' if the file is already open and cannot be reopened;
 758 --
 759 --  * 'isDoesNotExistError' if the file does not exist; or
 760 --
 761 --  * 'isPermissionError' if the user does not have permission to open the file.
 762 --
 763 -- Note: if you will be working with files containing binary data, you'll want to
 764 -- be using 'openBinaryFile'.
 765 openFile :: FilePath -> IOMode -> IO Handle
 766 openFile fp im =
 767   catch
 768     (openFile' fp im dEFAULT_OPEN_IN_BINARY_MODE)
 769     (\e -> ioError (addFilePathToIOError "openFile" fp e))
 770
 771 -- | Like 'openFile', but open the file in binary mode.
 772 -- On Windows, reading a file in text mode (which is the default)
 773 -- will translate CRLF to LF, and writing will translate LF to CRLF.
 774 -- This is usually what you want with text files.  With binary files
 775 -- this is undesirable; also, as usual under Microsoft operating systems,
 776 -- text mode treats control-Z as EOF.  Binary mode turns off all special
 777 -- treatment of end-of-line and end-of-file characters.
 778 -- (See also 'hSetBinaryMode'.)
 779
 780 openBinaryFile :: FilePath -> IOMode -> IO Handle
 781 openBinaryFile fp m =
 782   catch
 783     (openFile' fp m True)
 784     (\e -> ioError (addFilePathToIOError "openBinaryFile" fp e))
 785
 786 openFile' filepath mode binary =
 787   withCString filepath $ \ f ->
 788
 789     let
 790       oflags1 = case mode of
 791                   ReadMode      -> read_flags
 792 #ifdef mingw32_HOST_OS
 793                   WriteMode     -> write_flags .|. o_TRUNC
 794 #else
 795                   WriteMode     -> write_flags
 796 #endif
 797                   ReadWriteMode -> rw_flags
 798                   AppendMode    -> append_flags
 799
 800       binary_flags
 801           | binary    = o_BINARY
 802           | otherwise = 0
 803
 804       oflags = oflags1 .|. binary_flags
 805     in do
 806
 807     -- the old implementation had a complicated series of three opens,
 808     -- which is perhaps because we have to be careful not to open
 809     -- directories.  However, the man pages I've read say that open()
 810     -- always returns EISDIR if the file is a directory and was opened
 811     -- for writing, so I think we're ok with a single open() here...
 812     fd <- fromIntegral `liftM`
 813               throwErrnoIfMinus1Retry "openFile"
 814                 (c_open f (fromIntegral oflags) 0o666)
 815
 816     fd_type <- fdType fd
 817
 818     h <- openFd fd (Just fd_type) False filepath mode binary
 819             `catchException` \e -> do c_close (fromIntegral fd); throw e
 820         -- NB. don't forget to close the FD if openFd fails, otherwise
 821         -- this FD leaks.
 822         -- ASSERT: if we just created the file, then openFd won't fail
 823         -- (so we don't need to worry about removing the newly created file
 824         --  in the event of an error).
 825
 826 #ifndef mingw32_HOST_OS
 827         -- we want to truncate() if this is an open in WriteMode, but only
 828         -- if the target is a RegularFile.  ftruncate() fails on special files
 829         -- like /dev/null.
 830     if mode == WriteMode && fd_type == RegularFile
 831       then throwErrnoIf (/=0) "openFile"
 832               (c_ftruncate (fromIntegral fd) 0)
 833       else return 0
 834 #endif
 835     return h
 836
 837
 838 -- | The function creates a temporary file in ReadWrite mode.
 839 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 840 openTempFile :: FilePath   -- ^ Directory in which to create the file
 841              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 842                            -- the create file will be \"fooXXX.ext\" where XXX is some
 843                            -- random number.
 844              -> IO (FilePath, Handle)
 845 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template dEFAULT_OPEN_IN_BINARY_MODE
 846
 847 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 848 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 849 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 850
 851 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 852 openTempFile' loc tmp_dir template binary = do
 853   pid <- c_getpid
 854   findTempName pid
 855   where
 856     (prefix,suffix) = break (=='.') template
 857
 858     oflags1 = rw_flags .|. o_EXCL
 859
 860     binary_flags
 861       | binary    = o_BINARY
 862       | otherwise = 0
 863
 864     oflags = oflags1 .|. binary_flags
 865
 866     findTempName x = do
 867       fd <- withCString filepath $ \ f ->
 868               c_open f oflags 0o666
 869       if fd < 0
 870        then do
 871          errno <- getErrno
 872          if errno == eEXIST
 873            then findTempName (x+1)
 874            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 875        else do
 876          h <- openFd (fromIntegral fd) Nothing False filepath ReadWriteMode True
 877                 `catchException` \e -> do c_close (fromIntegral fd); throw e
 878          return (filepath, h)
 879       where
 880         filename        = prefix ++ show x ++ suffix
 881         filepath        = tmp_dir `joinFileName` filename
 882
 883
 884 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 885 output_flags = std_flags    .|. o_CREAT
 886 read_flags   = std_flags    .|. o_RDONLY
 887 write_flags  = output_flags .|. o_WRONLY
 888 rw_flags     = output_flags .|. o_RDWR
 889 append_flags = write_flags  .|. o_APPEND
 890
 891 -- ---------------------------------------------------------------------------
 892 -- openFd
 893
 894 openFd :: FD -> Maybe FDType -> Bool -> FilePath -> IOMode -> Bool -> IO Handle
 895 openFd fd mb_fd_type is_socket filepath mode binary = do
 896     -- turn on non-blocking mode
 897     setNonBlockingFD fd
 898
 899     let (ha_type, write) =
 900           case mode of
 901             ReadMode      -> ( ReadHandle,      False )
 902             WriteMode     -> ( WriteHandle,     True )
 903             ReadWriteMode -> ( ReadWriteHandle, True )
 904             AppendMode    -> ( AppendHandle,    True )
 905
 906     -- open() won't tell us if it was a directory if we only opened for
 907     -- reading, so check again.
 908     fd_type <-
 909       case mb_fd_type of
 910         Just x  -> return x
 911         Nothing -> fdType fd
 912
 913     case fd_type of
 914         Directory ->
 915            ioException (IOError Nothing InappropriateType "openFile"
 916                            "is a directory" Nothing)
 917
 918         -- regular files need to be locked
 919         RegularFile -> do
 920 #ifndef mingw32_HOST_OS
 921            r <- lockFile (fromIntegral fd) (fromBool write) 1{-exclusive-}
 922            when (r == -1)  $
 923                 ioException (IOError Nothing ResourceBusy "openFile"
 924                                    "file is locked" Nothing)
 925 #endif
 926            mkFileHandle fd is_socket filepath ha_type binary
 927
 928         Stream
 929            -- only *Streams* can be DuplexHandles.  Other read/write
 930            -- Handles must share a buffer.
 931            | ReadWriteHandle <- ha_type ->
 932                 mkDuplexHandle fd is_socket filepath binary
 933            | otherwise ->
 934                 mkFileHandle   fd is_socket filepath ha_type binary
 935
 936         RawDevice ->
 937                 mkFileHandle fd is_socket filepath ha_type binary
 938
 939         _ ->
 940           ioException (IOError Nothing UnsupportedOperation "openFd"
 941                                    "unknown file type" Nothing)
 942
 943 fdToHandle :: FD -> IO Handle
 944 fdToHandle fd = do
 945    mode <- fdGetMode fd
 946    let fd_str = "<file descriptor: " ++ show fd ++ ">"
 947    openFd fd Nothing False{-XXX!-} fd_str mode True{-bin mode-}
 948
 949
 950 #ifndef mingw32_HOST_OS
 951 foreign import ccall unsafe "lockFile"
 952   lockFile :: CInt -> CInt -> CInt -> IO CInt
 953
 954 foreign import ccall unsafe "unlockFile"
 955   unlockFile :: CInt -> IO CInt
 956 #endif
 957
 958 mkStdHandle :: FD -> FilePath -> HandleType -> IORef Buffer -> BufferMode
 959         -> IO Handle
 960 mkStdHandle fd filepath ha_type buf bmode = do
 961    spares <- newIORef BufferListNil
 962    newFileHandle filepath (stdHandleFinalizer filepath)
 963             (Handle__ { haFD = fd,
 964                         haType = ha_type,
 965                         haIsBin = dEFAULT_OPEN_IN_BINARY_MODE,
 966                         haIsStream = False,
 967                         haBufferMode = bmode,
 968                         haBuffer = buf,
 969                         haBuffers = spares,
 970                         haOtherSide = Nothing
 971                       })
 972
 973 mkFileHandle :: FD -> Bool -> FilePath -> HandleType -> Bool -> IO Handle
 974 mkFileHandle fd is_stream filepath ha_type binary = do
 975   (buf, bmode) <- getBuffer fd (initBufferState ha_type)
 976
 977 #ifdef mingw32_HOST_OS
 978   -- On Windows, if this is a read/write handle and we are in text mode,
 979   -- turn off buffering.  We don't correctly handle the case of switching
 980   -- from read mode to write mode on a buffered text-mode handle, see bug
 981   -- #679.
 982   bmode <- case ha_type of
 983                 ReadWriteHandle | not binary -> return NoBuffering
 984                 _other                       -> return bmode
 985 #endif
 986
 987   spares <- newIORef BufferListNil
 988   newFileHandle filepath (handleFinalizer filepath)
 989             (Handle__ { haFD = fd,
 990                         haType = ha_type,
 991                         haIsBin = binary,
 992                         haIsStream = is_stream,
 993                         haBufferMode = bmode,
 994                         haBuffer = buf,
 995                         haBuffers = spares,
 996                         haOtherSide = Nothing
 997                       })
 998
 999 mkDuplexHandle :: FD -> Bool -> FilePath -> Bool -> IO Handle
1000 mkDuplexHandle fd is_stream filepath binary = do
1001   (w_buf, w_bmode) <- getBuffer fd WriteBuffer
1002   w_spares <- newIORef BufferListNil
1003   let w_handle_ =
1004              Handle__ { haFD = fd,
1005                         haType = WriteHandle,
1006                         haIsBin = binary,
1007                         haIsStream = is_stream,
1008                         haBufferMode = w_bmode,
1009                         haBuffer = w_buf,
1010                         haBuffers = w_spares,
1011                         haOtherSide = Nothing
1012                       }
1013   write_side <- newMVar w_handle_
1014
1015   (r_buf, r_bmode) <- getBuffer fd ReadBuffer
1016   r_spares <- newIORef BufferListNil
1017   let r_handle_ =
1018              Handle__ { haFD = fd,
1019                         haType = ReadHandle,
1020                         haIsBin = binary,
1021                         haIsStream = is_stream,
1022                         haBufferMode = r_bmode,
1023                         haBuffer = r_buf,
1024                         haBuffers = r_spares,
1025                         haOtherSide = Just write_side
1026                       }
1027   read_side <- newMVar r_handle_
1028
1029   addMVarFinalizer write_side (handleFinalizer filepath write_side)
1030   return (DuplexHandle filepath read_side write_side)
1031
1032
1033 initBufferState ReadHandle = ReadBuffer
1034 initBufferState _          = WriteBuffer
1035
1036 -- ---------------------------------------------------------------------------
1037 -- Closing a handle
1038
1039 -- | Computation 'hClose' @hdl@ makes handle @hdl@ closed.  Before the
1040 -- computation finishes, if @hdl@ is writable its buffer is flushed as
1041 -- for 'hFlush'.
1042 -- Performing 'hClose' on a handle that has already been closed has no effect;
1043 -- doing so not an error.  All other operations on a closed handle will fail.
1044 -- If 'hClose' fails for any reason, any further operations (apart from
1045 -- 'hClose') on the handle will still fail as if @hdl@ had been successfully
1046 -- closed.
1047
1048 hClose :: Handle -> IO ()
1049 hClose h@(FileHandle _ m)     = hClose' h m
1050 hClose h@(DuplexHandle _ r w) = hClose' h w >> hClose' h r
1051
1052 hClose' h m = withHandle__' "hClose" h m $ hClose_help
1053
1054 -- hClose_help is also called by lazyRead (in PrelIO) when EOF is read
1055 -- or an IO error occurs on a lazy stream.  The semi-closed Handle is
1056 -- then closed immediately.  We have to be careful with DuplexHandles
1057 -- though: we have to leave the closing to the finalizer in that case,
1058 -- because the write side may still be in use.
1059 hClose_help :: Handle__ -> IO Handle__
1060 hClose_help handle_ =
1061   case haType handle_ of
1062       ClosedHandle -> return handle_
1063       _ -> do flushWriteBufferOnly handle_ -- interruptible
1064               hClose_handle_ handle_
1065
1066 hClose_handle_ handle_ = do
1067     let fd = haFD handle_
1068         c_fd = fromIntegral fd
1069
1070     -- close the file descriptor, but not when this is the read
1071     -- side of a duplex handle.
1072     case haOtherSide handle_ of
1073       Nothing ->
1074                   throwErrnoIfMinus1Retry_ "hClose"
1075 #ifdef mingw32_HOST_OS
1076                                 (closeFd (haIsStream handle_) c_fd)
1077 #else
1078                                 (c_close c_fd)
1079 #endif
1080       Just _  -> return ()
1081
1082     -- free the spare buffers
1083     writeIORef (haBuffers handle_) BufferListNil
1084
1085 #ifndef mingw32_HOST_OS
1086     -- unlock it
1087     unlockFile c_fd
1088 #endif
1089
1090     -- we must set the fd to -1, because the finalizer is going
1091     -- to run eventually and try to close/unlock it.
1092     return (handle_{ haFD        = -1,
1093                      haType      = ClosedHandle
1094                    })
1095
1096 -----------------------------------------------------------------------------
1097 -- Detecting and changing the size of a file
1098
1099 -- | For a handle @hdl@ which attached to a physical file,
1100 -- 'hFileSize' @hdl@ returns the size of that file in 8-bit bytes.
1101
1102 hFileSize :: Handle -> IO Integer
1103 hFileSize handle =
1104     withHandle_ "hFileSize" handle $ \ handle_ -> do
1105     case haType handle_ of
1106       ClosedHandle              -> ioe_closedHandle
1107       SemiClosedHandle          -> ioe_closedHandle
1108       _ -> do flushWriteBufferOnly handle_
1109               r <- fdFileSize (haFD handle_)
1110               if r /= -1
1111                  then return r
1112                  else ioException (IOError Nothing InappropriateType "hFileSize"
1113                                    "not a regular file" Nothing)
1114
1115
1116 -- | 'hSetFileSize' @hdl@ @size@ truncates the physical file with handle @hdl@ to @size@ bytes.
1117
1118 hSetFileSize :: Handle -> Integer -> IO ()
1119 hSetFileSize handle size =
1120     withHandle_ "hSetFileSize" handle $ \ handle_ -> do
1121     case haType handle_ of
1122       ClosedHandle              -> ioe_closedHandle
1123       SemiClosedHandle          -> ioe_closedHandle
1124       _ -> do flushWriteBufferOnly handle_
1125               throwErrnoIf (/=0) "hSetFileSize"
1126                  (c_ftruncate (fromIntegral (haFD handle_)) (fromIntegral size))
1127               return ()
1128
1129 -- ---------------------------------------------------------------------------
1130 -- Detecting the End of Input
1131
1132 -- | For a readable handle @hdl@, 'hIsEOF' @hdl@ returns
1133 -- 'True' if no further input can be taken from @hdl@ or for a
1134 -- physical file, if the current I\/O position is equal to the length of
1135 -- the file.  Otherwise, it returns 'False'.
1136
1137 hIsEOF :: Handle -> IO Bool
1138 hIsEOF handle =
1139   catch
1140      (do hLookAhead handle; return False)
1141      (\e -> if isEOFError e then return True else ioError e)
1142
1143 -- | The computation 'isEOF' is identical to 'hIsEOF',
1144 -- except that it works only on 'stdin'.
1145
1146 isEOF :: IO Bool
1147 isEOF = hIsEOF stdin
1148
1149 -- ---------------------------------------------------------------------------
1150 -- Looking ahead
1151
1152 -- | Computation 'hLookAhead' returns the next character from the handle
1153 -- without removing it from the input buffer, blocking until a character
1154 -- is available.
1155 --
1156 -- This operation may fail with:
1157 --
1158 --  * 'isEOFError' if the end of file has been reached.
1159
1160 hLookAhead :: Handle -> IO Char
1161 hLookAhead handle = do
1162   wantReadableHandle "hLookAhead"  handle $ \handle_ -> do
1163   let ref     = haBuffer handle_
1164       fd      = haFD handle_
1165       is_line = haBufferMode handle_ == LineBuffering
1166   buf <- readIORef ref
1167
1168   -- fill up the read buffer if necessary
1169   new_buf <- if bufferEmpty buf
1170                 then fillReadBuffer fd True (haIsStream handle_) buf
1171                 else return buf
1172
1173   writeIORef ref new_buf
1174
1175   (c,_) <- readCharFromBuffer (bufBuf buf) (bufRPtr buf)
1176   return c
1177
1178 -- ---------------------------------------------------------------------------
1179 -- Buffering Operations
1180
1181 -- Three kinds of buffering are supported: line-buffering,
1182 -- block-buffering or no-buffering.  See GHC.IOBase for definition and
1183 -- further explanation of what the type represent.
1184
1185 -- | Computation 'hSetBuffering' @hdl mode@ sets the mode of buffering for
1186 -- handle @hdl@ on subsequent reads and writes.
1187 --
1188 -- If the buffer mode is changed from 'BlockBuffering' or
1189 -- 'LineBuffering' to 'NoBuffering', then
1190 --
1191 --  * if @hdl@ is writable, the buffer is flushed as for 'hFlush';
1192 --
1193 --  * if @hdl@ is not writable, the contents of the buffer is discarded.
1194 --
1195 -- This operation may fail with:
1196 --
1197 --  * 'isPermissionError' if the handle has already been used for reading
1198 --    or writing and the implementation does not allow the buffering mode
1199 --    to be changed.
1200
1201 hSetBuffering :: Handle -> BufferMode -> IO ()
1202 hSetBuffering handle mode =
1203   withAllHandles__ "hSetBuffering" handle $ \ handle_ -> do
1204   case haType handle_ of
1205     ClosedHandle -> ioe_closedHandle
1206     _ -> do
1207          {- Note:
1208             - we flush the old buffer regardless of whether
1209               the new buffer could fit the contents of the old buffer
1210               or not.
1211             - allow a handle's buffering to change even if IO has
1212               occurred (ANSI C spec. does not allow this, nor did
1213               the previous implementation of IO.hSetBuffering).
1214             - a non-standard extension is to allow the buffering
1215               of semi-closed handles to change [sof 6/98]
1216           -}
1217           flushBuffer handle_
1218
1219           let state = initBufferState (haType handle_)
1220           new_buf <-
1221             case mode of
1222                 -- we always have a 1-character read buffer for
1223                 -- unbuffered  handles: it's needed to
1224                 -- support hLookAhead.
1225               NoBuffering            -> allocateBuffer 1 ReadBuffer
1226               LineBuffering          -> allocateBuffer dEFAULT_BUFFER_SIZE state
1227               BlockBuffering Nothing -> allocateBuffer dEFAULT_BUFFER_SIZE state
1228               BlockBuffering (Just n) | n <= 0    -> ioe_bufsiz n
1229                                       | otherwise -> allocateBuffer n state
1230           writeIORef (haBuffer handle_) new_buf
1231
1232           -- for input terminals we need to put the terminal into
1233           -- cooked or raw mode depending on the type of buffering.
1234           is_tty <- fdIsTTY (haFD handle_)
1235           when (is_tty && isReadableHandleType (haType handle_)) $
1236                 case mode of
1237 #ifndef mingw32_HOST_OS
1238         -- 'raw' mode under win32 is a bit too specialised (and troublesome
1239         -- for most common uses), so simply disable its use here.
1240                   NoBuffering -> setCooked (haFD handle_) False
1241 #else
1242                   NoBuffering -> return ()
1243 #endif
1244                   _           -> setCooked (haFD handle_) True
1245
1246           -- throw away spare buffers, they might be the wrong size
1247           writeIORef (haBuffers handle_) BufferListNil
1248
1249           return (handle_{ haBufferMode = mode })
1250
1251 -- -----------------------------------------------------------------------------
1252 -- hFlush
1253
1254 -- | The action 'hFlush' @hdl@ causes any items buffered for output
1255 -- in handle @hdl@ to be sent immediately to the operating system.
1256 --
1257 -- This operation may fail with:
1258 --
1259 --  * 'isFullError' if the device is full;
1260 --
1261 --  * 'isPermissionError' if a system resource limit would be exceeded.
1262 --    It is unspecified whether the characters in the buffer are discarded
1263 --    or retained under these circumstances.
1264
1265 hFlush :: Handle -> IO ()
1266 hFlush handle =
1267    wantWritableHandle "hFlush" handle $ \ handle_ -> do
1268    buf <- readIORef (haBuffer handle_)
1269    if bufferIsWritable buf && not (bufferEmpty buf)
1270         then do flushed_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
1271                 writeIORef (haBuffer handle_) flushed_buf
1272         else return ()
1273
1274
1275 -- -----------------------------------------------------------------------------
1276 -- Repositioning Handles
1277
1278 data HandlePosn = HandlePosn Handle HandlePosition
1279
1280 instance Eq HandlePosn where
1281     (HandlePosn h1 p1) == (HandlePosn h2 p2) = p1==p2 && h1==h2
1282
1283 instance Show HandlePosn where
1284    showsPrec p (HandlePosn h pos) =
1285         showsPrec p h . showString " at position " . shows pos
1286
1287   -- HandlePosition is the Haskell equivalent of POSIX' off_t.
1288   -- We represent it as an Integer on the Haskell side, but
1289   -- cheat slightly in that hGetPosn calls upon a C helper
1290   -- that reports the position back via (merely) an Int.
1291 type HandlePosition = Integer
1292
1293 -- | Computation 'hGetPosn' @hdl@ returns the current I\/O position of
1294 -- @hdl@ as a value of the abstract type 'HandlePosn'.
1295
1296 hGetPosn :: Handle -> IO HandlePosn
1297 hGetPosn handle = do
1298     posn <- hTell handle
1299     return (HandlePosn handle posn)
1300
1301 -- | If a call to 'hGetPosn' @hdl@ returns a position @p@,
1302 -- then computation 'hSetPosn' @p@ sets the position of @hdl@
1303 -- to the position it held at the time of the call to 'hGetPosn'.
1304 --
1305 -- This operation may fail with:
1306 --
1307 --  * 'isPermissionError' if a system resource limit would be exceeded.
1308
1309 hSetPosn :: HandlePosn -> IO ()
1310 hSetPosn (HandlePosn h i) = hSeek h AbsoluteSeek i
1311
1312 -- ---------------------------------------------------------------------------
1313 -- hSeek
1314
1315 -- | A mode that determines the effect of 'hSeek' @hdl mode i@, as follows:
1316 data SeekMode
1317   = AbsoluteSeek        -- ^ the position of @hdl@ is set to @i@.
1318   | RelativeSeek        -- ^ the position of @hdl@ is set to offset @i@
1319                         -- from the current position.
1320   | SeekFromEnd         -- ^ the position of @hdl@ is set to offset @i@
1321                         -- from the end of the file.
1322     deriving (Eq, Ord, Ix, Enum, Read, Show)
1323
1324 {- Note:
1325  - when seeking using `SeekFromEnd', positive offsets (>=0) means
1326    seeking at or past EOF.
1327
1328  - we possibly deviate from the report on the issue of seeking within
1329    the buffer and whether to flush it or not.  The report isn't exactly
1330    clear here.
1331 -}
1332
1333 -- | Computation 'hSeek' @hdl mode i@ sets the position of handle
1334 -- @hdl@ depending on @mode@.
1335 -- The offset @i@ is given in terms of 8-bit bytes.
1336 --
1337 -- If @hdl@ is block- or line-buffered, then seeking to a position which is not
1338 -- in the current buffer will first cause any items in the output buffer to be
1339 -- written to the device, and then cause the input buffer to be discarded.
1340 -- Some handles may not be seekable (see 'hIsSeekable'), or only support a
1341 -- subset of the possible positioning operations (for instance, it may only
1342 -- be possible to seek to the end of a tape, or to a positive offset from
1343 -- the beginning or current position).
1344 -- It is not possible to set a negative I\/O position, or for
1345 -- a physical file, an I\/O position beyond the current end-of-file.
1346 --
1347 -- This operation may fail with:
1348 --
1349 --  * 'isPermissionError' if a system resource limit would be exceeded.
1350
1351 hSeek :: Handle -> SeekMode -> Integer -> IO ()
1352 hSeek handle mode offset =
1353     wantSeekableHandle "hSeek" handle $ \ handle_ -> do
1354 #   ifdef DEBUG_DUMP
1355     puts ("hSeek " ++ show (mode,offset) ++ "\n")
1356 #   endif
1357     let ref = haBuffer handle_
1358     buf <- readIORef ref
1359     let r = bufRPtr buf
1360         w = bufWPtr buf
1361         fd = haFD handle_
1362
1363     let do_seek =
1364           throwErrnoIfMinus1Retry_ "hSeek"
1365             (c_lseek (fromIntegral (haFD handle_)) (fromIntegral offset) whence)
1366
1367         whence :: CInt
1368         whence = case mode of
1369                    AbsoluteSeek -> sEEK_SET
1370                    RelativeSeek -> sEEK_CUR
1371                    SeekFromEnd  -> sEEK_END
1372
1373     if bufferIsWritable buf
1374         then do new_buf <- flushWriteBuffer fd (haIsStream handle_) buf
1375                 writeIORef ref new_buf
1376                 do_seek
1377         else do
1378
1379     if mode == RelativeSeek && offset >= 0 && offset < fromIntegral (w - r)
1380         then writeIORef ref buf{ bufRPtr = r + fromIntegral offset }
1381         else do
1382
1383     new_buf <- flushReadBuffer (haFD handle_) buf
1384     writeIORef ref new_buf
1385     do_seek
1386
1387
1388 hTell :: Handle -> IO Integer
1389 hTell handle =
1390     wantSeekableHandle "hGetPosn" handle $ \ handle_ -> do
1391
1392 #if defined(mingw32_HOST_OS)
1393         -- urgh, on Windows we have to worry about \n -> \r\n translation,
1394         -- so we can't easily calculate the file position using the
1395         -- current buffer size.  Just flush instead.
1396       flushBuffer handle_
1397 #endif
1398       let fd = fromIntegral (haFD handle_)
1399       posn <- fromIntegral `liftM`
1400                 throwErrnoIfMinus1Retry "hGetPosn"
1401                    (c_lseek fd 0 sEEK_CUR)
1402
1403       let ref = haBuffer handle_
1404       buf <- readIORef ref
1405
1406       let real_posn
1407            | bufferIsWritable buf = posn + fromIntegral (bufWPtr buf)
1408            | otherwise = posn - fromIntegral (bufWPtr buf - bufRPtr buf)
1409 #     ifdef DEBUG_DUMP
1410       puts ("\nhGetPosn: (fd, posn, real_posn) = " ++ show (fd, posn, real_posn) ++ "\n")
1411       puts ("   (bufWPtr, bufRPtr) = " ++ show (bufWPtr buf, bufRPtr buf) ++ "\n")
1412 #     endif
1413       return real_posn
1414
1415 -- -----------------------------------------------------------------------------
1416 -- Handle Properties
1417
1418 -- A number of operations return information about the properties of a
1419 -- handle.  Each of these operations returns `True' if the handle has
1420 -- the specified property, and `False' otherwise.
1421
1422 hIsOpen :: Handle -> IO Bool
1423 hIsOpen handle =
1424     withHandle_ "hIsOpen" handle $ \ handle_ -> do
1425     case haType handle_ of
1426       ClosedHandle         -> return False
1427       SemiClosedHandle     -> return False
1428       _                    -> return True
1429
1430 hIsClosed :: Handle -> IO Bool
1431 hIsClosed handle =
1432     withHandle_ "hIsClosed" handle $ \ handle_ -> do
1433     case haType handle_ of
1434       ClosedHandle         -> return True
1435       _                    -> return False
1436
1437 {- not defined, nor exported, but mentioned
1438    here for documentation purposes:
1439
1440     hSemiClosed :: Handle -> IO Bool
1441     hSemiClosed h = do
1442        ho <- hIsOpen h
1443        hc <- hIsClosed h
1444        return (not (ho || hc))
1445 -}
1446
1447 hIsReadable :: Handle -> IO Bool
1448 hIsReadable (DuplexHandle _ _ _) = return True
1449 hIsReadable handle =
1450     withHandle_ "hIsReadable" handle $ \ handle_ -> do
1451     case haType handle_ of
1452       ClosedHandle         -> ioe_closedHandle
1453       SemiClosedHandle     -> ioe_closedHandle
1454       htype                -> return (isReadableHandleType htype)
1455
1456 hIsWritable :: Handle -> IO Bool
1457 hIsWritable (DuplexHandle _ _ _) = return True
1458 hIsWritable handle =
1459     withHandle_ "hIsWritable" handle $ \ handle_ -> do
1460     case haType handle_ of
1461       ClosedHandle         -> ioe_closedHandle
1462       SemiClosedHandle     -> ioe_closedHandle
1463       htype                -> return (isWritableHandleType htype)
1464
1465 -- | Computation 'hGetBuffering' @hdl@ returns the current buffering mode
1466 -- for @hdl@.
1467
1468 hGetBuffering :: Handle -> IO BufferMode
1469 hGetBuffering handle =
1470     withHandle_ "hGetBuffering" handle $ \ handle_ -> do
1471     case haType handle_ of
1472       ClosedHandle         -> ioe_closedHandle
1473       _ ->
1474            -- We're being non-standard here, and allow the buffering
1475            -- of a semi-closed handle to be queried.   -- sof 6/98
1476           return (haBufferMode handle_)  -- could be stricter..
1477
1478 hIsSeekable :: Handle -> IO Bool
1479 hIsSeekable handle =
1480     withHandle_ "hIsSeekable" handle $ \ handle_ -> do
1481     case haType handle_ of
1482       ClosedHandle         -> ioe_closedHandle
1483       SemiClosedHandle     -> ioe_closedHandle
1484       AppendHandle         -> return False
1485       _                    -> do t <- fdType (haFD handle_)
1486                                  return ((t == RegularFile    || t == RawDevice)
1487                                          && (haIsBin handle_  || tEXT_MODE_SEEK_ALLOWED))
1488
1489 -- -----------------------------------------------------------------------------
1490 -- Changing echo status (Non-standard GHC extensions)
1491
1492 -- | Set the echoing status of a handle connected to a terminal.
1493
1494 hSetEcho :: Handle -> Bool -> IO ()
1495 hSetEcho handle on = do
1496     isT   <- hIsTerminalDevice handle
1497     if not isT
1498      then return ()
1499      else
1500       withHandle_ "hSetEcho" handle $ \ handle_ -> do
1501       case haType handle_ of
1502          ClosedHandle -> ioe_closedHandle
1503          _            -> setEcho (haFD handle_) on
1504
1505 -- | Get the echoing status of a handle connected to a terminal.
1506
1507 hGetEcho :: Handle -> IO Bool
1508 hGetEcho handle = do
1509     isT   <- hIsTerminalDevice handle
1510     if not isT
1511      then return False
1512      else
1513        withHandle_ "hGetEcho" handle $ \ handle_ -> do
1514        case haType handle_ of
1515          ClosedHandle -> ioe_closedHandle
1516          _            -> getEcho (haFD handle_)
1517
1518 -- | Is the handle connected to a terminal?
1519
1520 hIsTerminalDevice :: Handle -> IO Bool
1521 hIsTerminalDevice handle = do
1522     withHandle_ "hIsTerminalDevice" handle $ \ handle_ -> do
1523      case haType handle_ of
1524        ClosedHandle -> ioe_closedHandle
1525        _            -> fdIsTTY (haFD handle_)
1526
1527 -- -----------------------------------------------------------------------------
1528 -- hSetBinaryMode
1529
1530 -- | Select binary mode ('True') or text mode ('False') on a open handle.
1531 -- (See also 'openBinaryFile'.)
1532
1533 hSetBinaryMode :: Handle -> Bool -> IO ()
1534 hSetBinaryMode handle bin =
1535   withAllHandles__ "hSetBinaryMode" handle $ \ handle_ ->
1536     do throwErrnoIfMinus1_ "hSetBinaryMode"
1537           (setmode (fromIntegral (haFD handle_)) bin)
1538        return handle_{haIsBin=bin}
1539
1540 foreign import ccall unsafe "__hscore_setmode"
1541   setmode :: CInt -> Bool -> IO CInt
1542
1543 -- -----------------------------------------------------------------------------
1544 -- Duplicating a Handle
1545
1546 -- | Returns a duplicate of the original handle, with its own buffer.
1547 -- The two Handles will share a file pointer, however.  The original
1548 -- handle's buffer is flushed, including discarding any input data,
1549 -- before the handle is duplicated.
1550
1551 hDuplicate :: Handle -> IO Handle
1552 hDuplicate h@(FileHandle path m) = do
1553   new_h_ <- withHandle' "hDuplicate" h m (dupHandle Nothing)
1554   newFileHandle path (handleFinalizer path) new_h_
1555 hDuplicate h@(DuplexHandle path r w) = do
1556   new_w_ <- withHandle' "hDuplicate" h w (dupHandle Nothing)
1557   new_w <- newMVar new_w_
1558   new_r_ <- withHandle' "hDuplicate" h r (dupHandle (Just new_w))
1559   new_r <- newMVar new_r_
1560   addMVarFinalizer new_w (handleFinalizer path new_w)
1561   return (DuplexHandle path new_r new_w)
1562
1563 dupHandle other_side h_ = do
1564   -- flush the buffer first, so we don't have to copy its contents
1565   flushBuffer h_
1566   new_fd <- throwErrnoIfMinus1 "dupHandle" $
1567                 c_dup (fromIntegral (haFD h_))
1568   dupHandle_ other_side h_ new_fd
1569
1570 dupHandleTo other_side hto_ h_ = do
1571   flushBuffer h_
1572   new_fd <- throwErrnoIfMinus1 "dupHandleTo" $
1573                 c_dup2 (fromIntegral (haFD h_)) (fromIntegral (haFD hto_))
1574   dupHandle_ other_side h_ new_fd
1575
1576 dupHandle_ other_side h_ new_fd = do
1577   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE (initBufferState (haType h_))
1578   ioref <- newIORef buffer
1579   ioref_buffers <- newIORef BufferListNil
1580
1581   let new_handle_ = h_{ haFD = fromIntegral new_fd,
1582                         haBuffer = ioref,
1583                         haBuffers = ioref_buffers,
1584                         haOtherSide = other_side }
1585   return (h_, new_handle_)
1586
1587 -- -----------------------------------------------------------------------------
1588 -- Replacing a Handle
1589
1590 {- |
1591 Makes the second handle a duplicate of the first handle.  The second
1592 handle will be closed first, if it is not already.
1593
1594 This can be used to retarget the standard Handles, for example:
1595
1596 > do h <- openFile "mystdout" WriteMode
1597 >    hDuplicateTo h stdout
1598 -}
1599
1600 hDuplicateTo :: Handle -> Handle -> IO ()
1601 hDuplicateTo h1@(FileHandle _ m1) h2@(FileHandle _ m2)  = do
1602  withHandle__' "hDuplicateTo" h2 m2 $ \h2_ -> do
1603    _ <- hClose_help h2_
1604    withHandle' "hDuplicateTo" h1 m1 (dupHandleTo Nothing h2_)
1605 hDuplicateTo h1@(DuplexHandle _ r1 w1) h2@(DuplexHandle _ r2 w2)  = do
1606  withHandle__' "hDuplicateTo" h2 w2  $ \w2_ -> do
1607    _ <- hClose_help w2_
1608    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo Nothing w2_)
1609  withHandle__' "hDuplicateTo" h2 r2  $ \r2_ -> do
1610    _ <- hClose_help r2_
1611    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo (Just w1) r2_)
1612 hDuplicateTo h1 _ =
1613    ioException (IOError (Just h1) IllegalOperation "hDuplicateTo"
1614                 "handles are incompatible" Nothing)
1615
1616 -- ---------------------------------------------------------------------------
1617 -- showing Handles.
1618 --
1619 -- | 'hShow' is in the 'IO' monad, and gives more comprehensive output
1620 -- than the (pure) instance of 'Show' for 'Handle'.
1621
1622 hShow :: Handle -> IO String
1623 hShow h@(FileHandle path _) = showHandle' path False h
1624 hShow h@(DuplexHandle path _ _) = showHandle' path True h
1625
1626 showHandle' filepath is_duplex h =
1627   withHandle_ "showHandle" h $ \hdl_ ->
1628     let
1629      showType | is_duplex = showString "duplex (read-write)"
1630               | otherwise = shows (haType hdl_)
1631     in
1632     return
1633       (( showChar '{' .
1634         showHdl (haType hdl_)
1635             (showString "loc=" . showString filepath . showChar ',' .
1636              showString "type=" . showType . showChar ',' .
1637              showString "binary=" . shows (haIsBin hdl_) . showChar ',' .
1638              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
1639       ) "")
1640    where
1641
1642     showHdl :: HandleType -> ShowS -> ShowS
1643     showHdl ht cont =
1644        case ht of
1645         ClosedHandle  -> shows ht . showString "}"
1646         _ -> cont
1647
1648     showBufMode :: Buffer -> BufferMode -> ShowS
1649     showBufMode buf bmo =
1650       case bmo of
1651         NoBuffering   -> showString "none"
1652         LineBuffering -> showString "line"
1653         BlockBuffering (Just n) -> showString "block " . showParen True (shows n)
1654         BlockBuffering Nothing  -> showString "block " . showParen True (shows def)
1655       where
1656        def :: Int
1657        def = bufSize buf
1658
1659 -- ---------------------------------------------------------------------------
1660 -- debugging
1661
1662 #if defined(DEBUG_DUMP)
1663 puts :: String -> IO ()
1664 puts s = do write_rawBuffer 1 (unsafeCoerce# (packCString# s)) 0 (fromIntegral (length s))
1665             return ()
1666 #endif
1667
1668 -- -----------------------------------------------------------------------------
1669 -- utils
1670
1671 throwErrnoIfMinus1RetryOnBlock  :: String -> IO CInt -> IO CInt -> IO CInt
1672 throwErrnoIfMinus1RetryOnBlock loc f on_block  =
1673   do
1674     res <- f
1675     if (res :: CInt) == -1
1676       then do
1677         err <- getErrno
1678         if err == eINTR
1679           then throwErrnoIfMinus1RetryOnBlock loc f on_block
1680           else if err == eWOULDBLOCK || err == eAGAIN
1681                  then do on_block
1682                  else throwErrno loc
1683       else return res
1684
1685 -- -----------------------------------------------------------------------------
1686 -- wrappers to platform-specific constants:
1687
1688 foreign import ccall unsafe "__hscore_supportsTextMode"
1689   tEXT_MODE_SEEK_ALLOWED :: Bool
1690
1691 foreign import ccall unsafe "__hscore_bufsiz"   dEFAULT_BUFFER_SIZE :: Int
1692 foreign import ccall unsafe "__hscore_seek_cur" sEEK_CUR :: CInt
1693 foreign import ccall unsafe "__hscore_seek_set" sEEK_SET :: CInt
1694 foreign import ccall unsafe "__hscore_seek_end" sEEK_END :: CInt