GHC/Handle.hs

   1 {-# OPTIONS_GHC -fno-implicit-prelude -#include "HsBase.h" #-}
   2 {-# OPTIONS_HADDOCK hide #-}
   3
   4 #undef DEBUG_DUMP
   5 #undef DEBUG
   6
   7 -----------------------------------------------------------------------------
   8 -- |
   9 -- Module      :  GHC.Handle
  10 -- Copyright   :  (c) The University of Glasgow, 1994-2001
  11 -- License     :  see libraries/base/LICENSE
  12 --
  13 -- Maintainer  :  libraries@haskell.org
  14 -- Stability   :  internal
  15 -- Portability :  non-portable
  16 --
  17 -- This module defines the basic operations on I\/O \"handles\".
  18 --
  19 -----------------------------------------------------------------------------
  20
  21 -- #hide
  22 module GHC.Handle (
  23   withHandle, withHandle', withHandle_,
  24   wantWritableHandle, wantReadableHandle, wantSeekableHandle,
  25
  26   newEmptyBuffer, allocateBuffer, readCharFromBuffer, writeCharIntoBuffer,
  27   flushWriteBufferOnly, flushWriteBuffer, flushReadBuffer,
  28   fillReadBuffer, fillReadBufferWithoutBlocking,
  29   readRawBuffer, readRawBufferPtr,
  30   readRawBufferNoBlock, readRawBufferPtrNoBlock,
  31   writeRawBuffer, writeRawBufferPtr,
  32
  33 #ifndef mingw32_HOST_OS
  34   unlockFile,
  35 #endif
  36
  37   ioe_closedHandle, ioe_EOF, ioe_notReadable, ioe_notWritable,
  38
  39   stdin, stdout, stderr,
  40   IOMode(..), openFile, openBinaryFile, fdToHandle_stat, fdToHandle, fdToHandle',
  41   hFileSize, hSetFileSize, hIsEOF, isEOF, hLookAhead, hSetBuffering, hSetBinaryMode,
  42   hFlush, hDuplicate, hDuplicateTo,
  43
  44   hClose, hClose_help,
  45
  46   HandlePosition, HandlePosn(..), hGetPosn, hSetPosn,
  47   SeekMode(..), hSeek, hTell,
  48
  49   hIsOpen, hIsClosed, hIsReadable, hIsWritable, hGetBuffering, hIsSeekable,
  50   hSetEcho, hGetEcho, hIsTerminalDevice,
  51
  52   hShow,
  53
  54 #ifdef DEBUG_DUMP
  55   puts,
  56 #endif
  57
  58  ) where
  59
  60 import Control.Monad
  61 import Data.Bits
  62 import Data.Maybe
  63 import Foreign
  64 import Foreign.C
  65 import System.IO.Error
  66 import System.Posix.Internals
  67 import System.Posix.Types
  68
  69 import GHC.Real
  70
  71 import GHC.Arr
  72 import GHC.Base
  73 import GHC.Read         ( Read )
  74 import GHC.List
  75 import GHC.IOBase
  76 import GHC.Exception
  77 import GHC.Enum
  78 import GHC.Num          ( Integer(..), Num(..) )
  79 import GHC.Show
  80 import GHC.Real         ( toInteger )
  81 #if defined(DEBUG_DUMP)
  82 import GHC.Pack
  83 #endif
  84
  85 import GHC.Conc
  86
  87 -- -----------------------------------------------------------------------------
  88 -- TODO:
  89
  90 -- hWaitForInput blocks (should use a timeout)
  91
  92 -- unbuffered hGetLine is a bit dodgy
  93
  94 -- hSetBuffering: can't change buffering on a stream,
  95 --      when the read buffer is non-empty? (no way to flush the buffer)
  96
  97 -- ---------------------------------------------------------------------------
  98 -- Are files opened by default in text or binary mode, if the user doesn't
  99 -- specify?
 100
 101 dEFAULT_OPEN_IN_BINARY_MODE = False :: Bool
 102
 103 -- ---------------------------------------------------------------------------
 104 -- Creating a new handle
 105
 106 newFileHandle :: FilePath -> (MVar Handle__ -> IO ()) -> Handle__ -> IO Handle
 107 newFileHandle filepath finalizer hc = do
 108   m <- newMVar hc
 109   addMVarFinalizer m (finalizer m)
 110   return (FileHandle filepath m)
 111
 112 -- ---------------------------------------------------------------------------
 113 -- Working with Handles
 114
 115 {-
 116 In the concurrent world, handles are locked during use.  This is done
 117 by wrapping an MVar around the handle which acts as a mutex over
 118 operations on the handle.
 119
 120 To avoid races, we use the following bracketing operations.  The idea
 121 is to obtain the lock, do some operation and replace the lock again,
 122 whether the operation succeeded or failed.  We also want to handle the
 123 case where the thread receives an exception while processing the IO
 124 operation: in these cases we also want to relinquish the lock.
 125
 126 There are three versions of @withHandle@: corresponding to the three
 127 possible combinations of:
 128
 129         - the operation may side-effect the handle
 130         - the operation may return a result
 131
 132 If the operation generates an error or an exception is raised, the
 133 original handle is always replaced [ this is the case at the moment,
 134 but we might want to revisit this in the future --SDM ].
 135 -}
 136
 137 {-# INLINE withHandle #-}
 138 withHandle :: String -> Handle -> (Handle__ -> IO (Handle__,a)) -> IO a
 139 withHandle fun h@(FileHandle _ m)     act = withHandle' fun h m act
 140 withHandle fun h@(DuplexHandle _ m _) act = withHandle' fun h m act
 141
 142 withHandle' :: String -> Handle -> MVar Handle__
 143    -> (Handle__ -> IO (Handle__,a)) -> IO a
 144 withHandle' fun h m act =
 145    block $ do
 146    h_ <- takeMVar m
 147    checkBufferInvariants h_
 148    (h',v)  <- catchException (act h_)
 149                 (\ err -> putMVar m h_ >>
 150                           case err of
 151                              IOException ex -> ioError (augmentIOError ex fun h)
 152                              _ -> throw err)
 153    checkBufferInvariants h'
 154    putMVar m h'
 155    return v
 156
 157 {-# INLINE withHandle_ #-}
 158 withHandle_ :: String -> Handle -> (Handle__ -> IO a) -> IO a
 159 withHandle_ fun h@(FileHandle _ m)     act = withHandle_' fun h m act
 160 withHandle_ fun h@(DuplexHandle _ m _) act = withHandle_' fun h m act
 161
 162 withHandle_' :: String -> Handle -> MVar Handle__ -> (Handle__ -> IO a) -> IO a
 163 withHandle_' fun h m act =
 164    block $ do
 165    h_ <- takeMVar m
 166    checkBufferInvariants h_
 167    v  <- catchException (act h_)
 168                 (\ err -> putMVar m h_ >>
 169                           case err of
 170                              IOException ex -> ioError (augmentIOError ex fun h)
 171                              _ -> throw err)
 172    checkBufferInvariants h_
 173    putMVar m h_
 174    return v
 175
 176 withAllHandles__ :: String -> Handle -> (Handle__ -> IO Handle__) -> IO ()
 177 withAllHandles__ fun h@(FileHandle _ m)     act = withHandle__' fun h m act
 178 withAllHandles__ fun h@(DuplexHandle _ r w) act = do
 179   withHandle__' fun h r act
 180   withHandle__' fun h w act
 181
 182 withHandle__' fun h m act =
 183    block $ do
 184    h_ <- takeMVar m
 185    checkBufferInvariants h_
 186    h'  <- catchException (act h_)
 187                 (\ err -> putMVar m h_ >>
 188                           case err of
 189                              IOException ex -> ioError (augmentIOError ex fun h)
 190                              _ -> throw err)
 191    checkBufferInvariants h'
 192    putMVar m h'
 193    return ()
 194
 195 augmentIOError (IOError _ iot _ str fp) fun h
 196   = IOError (Just h) iot fun str filepath
 197   where filepath
 198           | Just _ <- fp = fp
 199           | otherwise = case h of
 200                           FileHandle fp _     -> Just fp
 201                           DuplexHandle fp _ _ -> Just fp
 202
 203 -- ---------------------------------------------------------------------------
 204 -- Wrapper for write operations.
 205
 206 wantWritableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 207 wantWritableHandle fun h@(FileHandle _ m) act
 208   = wantWritableHandle' fun h m act
 209 wantWritableHandle fun h@(DuplexHandle _ _ m) act
 210   = wantWritableHandle' fun h m act
 211   -- ToDo: in the Duplex case, we don't need to checkWritableHandle
 212
 213 wantWritableHandle'
 214         :: String -> Handle -> MVar Handle__
 215         -> (Handle__ -> IO a) -> IO a
 216 wantWritableHandle' fun h m act
 217    = withHandle_' fun h m (checkWritableHandle act)
 218
 219 checkWritableHandle act handle_
 220   = case haType handle_ of
 221       ClosedHandle         -> ioe_closedHandle
 222       SemiClosedHandle     -> ioe_closedHandle
 223       ReadHandle           -> ioe_notWritable
 224       ReadWriteHandle      -> do
 225                 let ref = haBuffer handle_
 226                 buf <- readIORef ref
 227                 new_buf <-
 228                   if not (bufferIsWritable buf)
 229                      then do b <- flushReadBuffer (haFD handle_) buf
 230                              return b{ bufState=WriteBuffer }
 231                      else return buf
 232                 writeIORef ref new_buf
 233                 act handle_
 234       _other               -> act handle_
 235
 236 -- ---------------------------------------------------------------------------
 237 -- Wrapper for read operations.
 238
 239 wantReadableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 240 wantReadableHandle fun h@(FileHandle  _ m)   act
 241   = wantReadableHandle' fun h m act
 242 wantReadableHandle fun h@(DuplexHandle _ m _) act
 243   = wantReadableHandle' fun h m act
 244   -- ToDo: in the Duplex case, we don't need to checkReadableHandle
 245
 246 wantReadableHandle'
 247         :: String -> Handle -> MVar Handle__
 248         -> (Handle__ -> IO a) -> IO a
 249 wantReadableHandle' fun h m act
 250   = withHandle_' fun h m (checkReadableHandle act)
 251
 252 checkReadableHandle act handle_ =
 253     case haType handle_ of
 254       ClosedHandle         -> ioe_closedHandle
 255       SemiClosedHandle     -> ioe_closedHandle
 256       AppendHandle         -> ioe_notReadable
 257       WriteHandle          -> ioe_notReadable
 258       ReadWriteHandle      -> do
 259         let ref = haBuffer handle_
 260         buf <- readIORef ref
 261         when (bufferIsWritable buf) $ do
 262            new_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
 263            writeIORef ref new_buf{ bufState=ReadBuffer }
 264         act handle_
 265       _other               -> act handle_
 266
 267 -- ---------------------------------------------------------------------------
 268 -- Wrapper for seek operations.
 269
 270 wantSeekableHandle :: String -> Handle -> (Handle__ -> IO a) -> IO a
 271 wantSeekableHandle fun h@(DuplexHandle _ _ _) _act =
 272   ioException (IOError (Just h) IllegalOperation fun
 273                    "handle is not seekable" Nothing)
 274 wantSeekableHandle fun h@(FileHandle _ m) act =
 275   withHandle_' fun h m (checkSeekableHandle act)
 276
 277 checkSeekableHandle act handle_ =
 278     case haType handle_ of
 279       ClosedHandle      -> ioe_closedHandle
 280       SemiClosedHandle  -> ioe_closedHandle
 281       AppendHandle      -> ioe_notSeekable
 282       _  | haIsBin handle_ || tEXT_MODE_SEEK_ALLOWED -> act handle_
 283          | otherwise                                 -> ioe_notSeekable_notBin
 284
 285 -- -----------------------------------------------------------------------------
 286 -- Handy IOErrors
 287
 288 ioe_closedHandle, ioe_EOF,
 289   ioe_notReadable, ioe_notWritable,
 290   ioe_notSeekable, ioe_notSeekable_notBin :: IO a
 291
 292 ioe_closedHandle = ioException
 293    (IOError Nothing IllegalOperation ""
 294         "handle is closed" Nothing)
 295 ioe_EOF = ioException
 296    (IOError Nothing EOF "" "" Nothing)
 297 ioe_notReadable = ioException
 298    (IOError Nothing IllegalOperation ""
 299         "handle is not open for reading" Nothing)
 300 ioe_notWritable = ioException
 301    (IOError Nothing IllegalOperation ""
 302         "handle is not open for writing" Nothing)
 303 ioe_notSeekable = ioException
 304    (IOError Nothing IllegalOperation ""
 305         "handle is not seekable" Nothing)
 306 ioe_notSeekable_notBin = ioException
 307    (IOError Nothing IllegalOperation ""
 308       "seek operations on text-mode handles are not allowed on this platform"
 309         Nothing)
 310
 311 ioe_finalizedHandle fp = throw (IOException
 312    (IOError Nothing IllegalOperation ""
 313         "handle is finalized" (Just fp)))
 314
 315 ioe_bufsiz :: Int -> IO a
 316 ioe_bufsiz n = ioException
 317    (IOError Nothing InvalidArgument "hSetBuffering"
 318         ("illegal buffer size " ++ showsPrec 9 n []) Nothing)
 319                                 -- 9 => should be parens'ified.
 320
 321 -- -----------------------------------------------------------------------------
 322 -- Handle Finalizers
 323
 324 -- For a duplex handle, we arrange that the read side points to the write side
 325 -- (and hence keeps it alive if the read side is alive).  This is done by
 326 -- having the haOtherSide field of the read side point to the read side.
 327 -- The finalizer is then placed on the write side, and the handle only gets
 328 -- finalized once, when both sides are no longer required.
 329
 330 -- NOTE about finalized handles: It's possible that a handle can be
 331 -- finalized and then we try to use it later, for example if the
 332 -- handle is referenced from another finalizer, or from a thread that
 333 -- has become unreferenced and then resurrected (arguably in the
 334 -- latter case we shouldn't finalize the Handle...).  Anyway,
 335 -- we try to emit a helpful message which is better than nothing.
 336
 337 stdHandleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 338 stdHandleFinalizer fp m = do
 339   h_ <- takeMVar m
 340   flushWriteBufferOnly h_
 341   putMVar m (ioe_finalizedHandle fp)
 342
 343 handleFinalizer :: FilePath -> MVar Handle__ -> IO ()
 344 handleFinalizer fp m = do
 345   handle_ <- takeMVar m
 346   case haType handle_ of
 347       ClosedHandle -> return ()
 348       _ -> do flushWriteBufferOnly handle_ `catchException` \_ -> return ()
 349                 -- ignore errors and async exceptions, and close the
 350                 -- descriptor anyway...
 351               hClose_handle_ handle_
 352               return ()
 353   putMVar m (ioe_finalizedHandle fp)
 354
 355 -- ---------------------------------------------------------------------------
 356 -- Grimy buffer operations
 357
 358 #ifdef DEBUG
 359 checkBufferInvariants h_ = do
 360  let ref = haBuffer h_
 361  Buffer{ bufWPtr=w, bufRPtr=r, bufSize=size, bufState=state } <- readIORef ref
 362  if not (
 363         size > 0
 364         && r <= w
 365         && w <= size
 366         && ( r /= w || (r == 0 && w == 0) )
 367         && ( state /= WriteBuffer || r == 0 )
 368         && ( state /= WriteBuffer || w < size ) -- write buffer is never full
 369      )
 370    then error "buffer invariant violation"
 371    else return ()
 372 #else
 373 checkBufferInvariants h_ = return ()
 374 #endif
 375
 376 newEmptyBuffer :: RawBuffer -> BufferState -> Int -> Buffer
 377 newEmptyBuffer b state size
 378   = Buffer{ bufBuf=b, bufRPtr=0, bufWPtr=0, bufSize=size, bufState=state }
 379
 380 allocateBuffer :: Int -> BufferState -> IO Buffer
 381 allocateBuffer sz@(I# size) state = IO $ \s ->
 382    -- We sometimes need to pass the address of this buffer to
 383    -- a "safe" foreign call, hence it must be immovable.
 384   case newPinnedByteArray# size s of { (# s, b #) ->
 385   (# s, newEmptyBuffer b state sz #) }
 386
 387 writeCharIntoBuffer :: RawBuffer -> Int -> Char -> IO Int
 388 writeCharIntoBuffer slab (I# off) (C# c)
 389   = IO $ \s -> case writeCharArray# slab off c s of
 390                  s -> (# s, I# (off +# 1#) #)
 391
 392 readCharFromBuffer :: RawBuffer -> Int -> IO (Char, Int)
 393 readCharFromBuffer slab (I# off)
 394   = IO $ \s -> case readCharArray# slab off s of
 395                  (# s, c #) -> (# s, (C# c, I# (off +# 1#)) #)
 396
 397 getBuffer :: FD -> BufferState -> IO (IORef Buffer, BufferMode)
 398 getBuffer fd state = do
 399   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE state
 400   ioref  <- newIORef buffer
 401   is_tty <- fdIsTTY fd
 402
 403   let buffer_mode
 404          | is_tty    = LineBuffering
 405          | otherwise = BlockBuffering Nothing
 406
 407   return (ioref, buffer_mode)
 408
 409 mkUnBuffer :: IO (IORef Buffer)
 410 mkUnBuffer = do
 411   buffer <- allocateBuffer 1 ReadBuffer
 412   newIORef buffer
 413
 414 -- flushWriteBufferOnly flushes the buffer iff it contains pending write data.
 415 flushWriteBufferOnly :: Handle__ -> IO ()
 416 flushWriteBufferOnly h_ = do
 417   let fd = haFD h_
 418       ref = haBuffer h_
 419   buf <- readIORef ref
 420   new_buf <- if bufferIsWritable buf
 421                 then flushWriteBuffer fd (haIsStream h_) buf
 422                 else return buf
 423   writeIORef ref new_buf
 424
 425 -- flushBuffer syncs the file with the buffer, including moving the
 426 -- file pointer backwards in the case of a read buffer.
 427 flushBuffer :: Handle__ -> IO ()
 428 flushBuffer h_ = do
 429   let ref = haBuffer h_
 430   buf <- readIORef ref
 431
 432   flushed_buf <-
 433     case bufState buf of
 434       ReadBuffer  -> flushReadBuffer  (haFD h_) buf
 435       WriteBuffer -> flushWriteBuffer (haFD h_) (haIsStream h_) buf
 436
 437   writeIORef ref flushed_buf
 438
 439 -- When flushing a read buffer, we seek backwards by the number of
 440 -- characters in the buffer.  The file descriptor must therefore be
 441 -- seekable: attempting to flush the read buffer on an unseekable
 442 -- handle is not allowed.
 443
 444 flushReadBuffer :: FD -> Buffer -> IO Buffer
 445 flushReadBuffer fd buf
 446   | bufferEmpty buf = return buf
 447   | otherwise = do
 448      let off = negate (bufWPtr buf - bufRPtr buf)
 449 #    ifdef DEBUG_DUMP
 450      puts ("flushReadBuffer: new file offset = " ++ show off ++ "\n")
 451 #    endif
 452      throwErrnoIfMinus1Retry "flushReadBuffer"
 453          (c_lseek fd (fromIntegral off) sEEK_CUR)
 454      return buf{ bufWPtr=0, bufRPtr=0 }
 455
 456 flushWriteBuffer :: FD -> Bool -> Buffer -> IO Buffer
 457 flushWriteBuffer fd is_stream buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w }  =
 458   seq fd $ do -- strictness hack
 459   let bytes = w - r
 460 #ifdef DEBUG_DUMP
 461   puts ("flushWriteBuffer, fd=" ++ show fd ++ ", bytes=" ++ show bytes ++ "\n")
 462 #endif
 463   if bytes == 0
 464      then return (buf{ bufRPtr=0, bufWPtr=0 })
 465      else do
 466   res <- writeRawBuffer "flushWriteBuffer" fd is_stream b
 467                         (fromIntegral r) (fromIntegral bytes)
 468   let res' = fromIntegral res
 469   if res' < bytes
 470      then flushWriteBuffer fd is_stream (buf{ bufRPtr = r + res' })
 471      else return buf{ bufRPtr=0, bufWPtr=0 }
 472
 473 fillReadBuffer :: FD -> Bool -> Bool -> Buffer -> IO Buffer
 474 fillReadBuffer fd is_line is_stream
 475       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 476   -- buffer better be empty:
 477   assert (r == 0 && w == 0) $ do
 478   fillReadBufferLoop fd is_line is_stream buf b w size
 479
 480 -- For a line buffer, we just get the first chunk of data to arrive,
 481 -- and don't wait for the whole buffer to be full (but we *do* wait
 482 -- until some data arrives).  This isn't really line buffering, but it
 483 -- appears to be what GHC has done for a long time, and I suspect it
 484 -- is more useful than line buffering in most cases.
 485
 486 fillReadBufferLoop fd is_line is_stream buf b w size = do
 487   let bytes = size - w
 488   if bytes == 0  -- buffer full?
 489      then return buf{ bufRPtr=0, bufWPtr=w }
 490      else do
 491 #ifdef DEBUG_DUMP
 492   puts ("fillReadBufferLoop: bytes = " ++ show bytes ++ "\n")
 493 #endif
 494   res <- readRawBuffer "fillReadBuffer" fd is_stream b
 495                        (fromIntegral w) (fromIntegral bytes)
 496   let res' = fromIntegral res
 497 #ifdef DEBUG_DUMP
 498   puts ("fillReadBufferLoop:  res' = " ++ show res' ++ "\n")
 499 #endif
 500   if res' == 0
 501      then if w == 0
 502              then ioe_EOF
 503              else return buf{ bufRPtr=0, bufWPtr=w }
 504      else if res' < bytes && not is_line
 505              then fillReadBufferLoop fd is_line is_stream buf b (w+res') size
 506              else return buf{ bufRPtr=0, bufWPtr=w+res' }
 507
 508
 509 fillReadBufferWithoutBlocking :: FD -> Bool -> Buffer -> IO Buffer
 510 fillReadBufferWithoutBlocking fd is_stream
 511       buf@Buffer{ bufBuf=b, bufRPtr=r, bufWPtr=w, bufSize=size } =
 512   -- buffer better be empty:
 513   assert (r == 0 && w == 0) $ do
 514 #ifdef DEBUG_DUMP
 515   puts ("fillReadBufferLoopNoBlock: bytes = " ++ show size ++ "\n")
 516 #endif
 517   res <- readRawBufferNoBlock "fillReadBuffer" fd is_stream b
 518                        0 (fromIntegral size)
 519   let res' = fromIntegral res
 520 #ifdef DEBUG_DUMP
 521   puts ("fillReadBufferLoopNoBlock:  res' = " ++ show res' ++ "\n")
 522 #endif
 523   return buf{ bufRPtr=0, bufWPtr=res' }
 524
 525 -- Low level routines for reading/writing to (raw)buffers:
 526
 527 #ifndef mingw32_HOST_OS
 528
 529 {-
 530 NOTE [nonblock]:
 531
 532 Unix has broken semantics when it comes to non-blocking I/O: you can
 533 set the O_NONBLOCK flag on an FD, but it applies to the all other FDs
 534 attached to the same underlying file, pipe or TTY; there's no way to
 535 have private non-blocking behaviour for an FD.  See bug #724.
 536
 537 We fix this by only setting O_NONBLOCK on FDs that we create; FDs that
 538 come from external sources or are exposed externally are left in
 539 blocking mode.  This solution has some problems though.  We can't
 540 completely simulate a non-blocking read without O_NONBLOCK: several
 541 cases are wrong here.  The cases that are wrong:
 542
 543   * reading/writing to a blocking FD in non-threaded mode.
 544     In threaded mode, we just make a safe call to read().
 545     In non-threaded mode we call select() before attempting to read,
 546     but that leaves a small race window where the data can be read
 547     from the file descriptor before we issue our blocking read().
 548   * readRawBufferNoBlock for a blocking FD
 549 -}
 550
 551 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 552 readRawBuffer loc fd is_nonblock buf off len
 553   | is_nonblock  = unsafe_read
 554   | threaded     = safe_read
 555   | otherwise    = do r <- throwErrnoIfMinus1 loc
 556                                 (fdReady (fromIntegral fd) 0 0 False)
 557                       if r /= 0
 558                         then unsafe_read
 559                         else do threadWaitRead (fromIntegral fd); unsafe_read
 560   where
 561     do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 562                             (threadWaitRead (fromIntegral fd))
 563     unsafe_read = do_read (read_rawBuffer fd buf off len)
 564     safe_read   = do_read (safe_read_rawBuffer fd buf off len)
 565
 566 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 567 readRawBufferPtr loc fd is_nonblock buf off len
 568   | is_nonblock  = unsafe_read
 569   | threaded     = safe_read
 570   | otherwise    = do r <- throwErrnoIfMinus1 loc
 571                                 (fdReady (fromIntegral fd) 0 0 False)
 572                       if r /= 0
 573                         then unsafe_read
 574                         else do threadWaitRead (fromIntegral fd); unsafe_read
 575   where
 576         do_read call = throwErrnoIfMinus1RetryMayBlock loc call
 577                                 (threadWaitRead (fromIntegral fd))
 578         unsafe_read = do_read (read_off fd buf off len)
 579         safe_read   = do_read (safe_read_off fd buf off len)
 580
 581 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 582 readRawBufferNoBlock loc fd is_nonblock buf off len
 583   | is_nonblock  = unsafe_read
 584   | otherwise    = do r <- fdReady (fromIntegral fd) 0 0 False
 585                       if r /= 0 then safe_read
 586                                 else return 0
 587        -- XXX see note [nonblock]
 588  where
 589    do_read call = throwErrnoIfMinus1RetryOnBlock loc call (return 0)
 590    unsafe_read  = do_read (read_rawBuffer fd buf off len)
 591    safe_read    = do_read (safe_read_rawBuffer fd buf off len)
 592
 593 readRawBufferPtrNoBlock :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 594 readRawBufferPtrNoBlock loc fd is_nonblock buf off len
 595   | is_nonblock  = unsafe_read
 596   | otherwise    = do r <- fdReady (fromIntegral fd) 0 0 False
 597                       if r /= 0 then safe_read
 598                                 else return 0
 599        -- XXX see note [nonblock]
 600  where
 601    do_read call = throwErrnoIfMinus1RetryOnBlock loc call (return 0)
 602    unsafe_read  = do_read (read_off fd buf off len)
 603    safe_read    = do_read (safe_read_off fd buf off len)
 604
 605 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 606 writeRawBuffer loc fd is_nonblock buf off len
 607   | is_nonblock = unsafe_write
 608   | threaded    = safe_write
 609   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 610                      if r /= 0
 611                         then safe_write
 612                         else do threadWaitWrite (fromIntegral fd); unsafe_write
 613   where
 614     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 615                         (threadWaitWrite (fromIntegral fd))
 616     unsafe_write = do_write (write_rawBuffer fd buf off len)
 617     safe_write   = do_write (safe_write_rawBuffer (fromIntegral fd) buf off len)
 618
 619 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 620 writeRawBufferPtr loc fd is_nonblock buf off len
 621   | is_nonblock = unsafe_write
 622   | threaded    = safe_write
 623   | otherwise   = do r <- fdReady (fromIntegral fd) 1 0 False
 624                      if r /= 0
 625                         then safe_write
 626                         else do threadWaitWrite (fromIntegral fd); unsafe_write
 627   where
 628     do_write call = throwErrnoIfMinus1RetryMayBlock loc call
 629                         (threadWaitWrite (fromIntegral fd))
 630     unsafe_write  = do_write (write_off fd buf off len)
 631     safe_write    = do_write (safe_write_off (fromIntegral fd) buf off len)
 632
 633 foreign import ccall unsafe "__hscore_PrelHandle_read"
 634    read_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 635
 636 foreign import ccall unsafe "__hscore_PrelHandle_read"
 637    read_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 638
 639 foreign import ccall unsafe "__hscore_PrelHandle_write"
 640    write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 641
 642 foreign import ccall unsafe "__hscore_PrelHandle_write"
 643    write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 644
 645 foreign import ccall safe "fdReady"
 646   fdReady :: CInt -> CInt -> CInt -> Bool -> IO CInt
 647
 648 #else /* mingw32_HOST_OS.... */
 649
 650 readRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 651 readRawBuffer loc fd is_stream buf off len
 652   | threaded  = blockingReadRawBuffer loc fd is_stream buf off len
 653   | otherwise = asyncReadRawBuffer loc fd is_stream buf off len
 654
 655 readRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 656 readRawBufferPtr loc fd is_stream buf off len
 657   | threaded  = blockingReadRawBufferPtr loc fd is_stream buf off len
 658   | otherwise = asyncReadRawBufferPtr loc fd is_stream buf off len
 659
 660 writeRawBuffer :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 661 writeRawBuffer loc fd is_stream buf off len
 662   | threaded =  blockingWriteRawBuffer loc fd is_stream buf off len
 663   | otherwise = asyncWriteRawBuffer    loc fd is_stream buf off len
 664
 665 writeRawBufferPtr :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 666 writeRawBufferPtr loc fd is_stream buf off len
 667   | threaded  = blockingWriteRawBufferPtr loc fd is_stream buf off len
 668   | otherwise = asyncWriteRawBufferPtr    loc fd is_stream buf off len
 669
 670 -- ToDo: we don't have a non-blocking primitve read on Win32
 671 readRawBufferNoBlock :: String -> FD -> Bool -> RawBuffer -> Int -> CInt -> IO CInt
 672 readRawBufferNoBlock = readRawBuffer
 673
 674 readRawBufferPtrNoBlock :: String -> FD -> Bool -> Ptr CChar -> Int -> CInt -> IO CInt
 675 readRawBufferPtrNoBlock = readRawBufferPtr
 676 -- Async versions of the read/write primitives, for the non-threaded RTS
 677
 678 asyncReadRawBuffer loc fd is_stream buf off len = do
 679     (l, rc) <- asyncReadBA (fromIntegral fd) (if is_stream then 1 else 0)
 680                  (fromIntegral len) off buf
 681     if l == (-1)
 682       then
 683         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 684       else return (fromIntegral l)
 685
 686 asyncReadRawBufferPtr loc fd is_stream buf off len = do
 687     (l, rc) <- asyncRead (fromIntegral fd) (if is_stream then 1 else 0)
 688                         (fromIntegral len) (buf `plusPtr` off)
 689     if l == (-1)
 690       then
 691         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 692       else return (fromIntegral l)
 693
 694 asyncWriteRawBuffer loc fd is_stream buf off len = do
 695     (l, rc) <- asyncWriteBA (fromIntegral fd) (if is_stream then 1 else 0)
 696                         (fromIntegral len) off buf
 697     if l == (-1)
 698       then
 699         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 700       else return (fromIntegral l)
 701
 702 asyncWriteRawBufferPtr loc fd is_stream buf off len = do
 703     (l, rc) <- asyncWrite (fromIntegral fd) (if is_stream then 1 else 0)
 704                   (fromIntegral len) (buf `plusPtr` off)
 705     if l == (-1)
 706       then
 707         ioError (errnoToIOError loc (Errno (fromIntegral rc)) Nothing Nothing)
 708       else return (fromIntegral l)
 709
 710 -- Blocking versions of the read/write primitives, for the threaded RTS
 711
 712 blockingReadRawBuffer loc fd True buf off len =
 713   throwErrnoIfMinus1Retry loc $
 714     safe_recv_rawBuffer fd buf off len
 715 blockingReadRawBuffer loc fd False buf off len =
 716   throwErrnoIfMinus1Retry loc $
 717     safe_read_rawBuffer fd buf off len
 718
 719 blockingReadRawBufferPtr loc fd True buf off len =
 720   throwErrnoIfMinus1Retry loc $
 721     safe_recv_off fd buf off len
 722 blockingReadRawBufferPtr loc fd False buf off len =
 723   throwErrnoIfMinus1Retry loc $
 724     safe_read_off fd buf off len
 725
 726 blockingWriteRawBuffer loc fd True buf off len =
 727   throwErrnoIfMinus1Retry loc $
 728     safe_send_rawBuffer fd buf off len
 729 blockingWriteRawBuffer loc fd False buf off len =
 730   throwErrnoIfMinus1Retry loc $
 731     safe_write_rawBuffer fd buf off len
 732
 733 blockingWriteRawBufferPtr loc fd True buf off len =
 734   throwErrnoIfMinus1Retry loc $
 735     safe_send_off fd buf off len
 736 blockingWriteRawBufferPtr loc fd False buf off len =
 737   throwErrnoIfMinus1Retry loc $
 738     safe_write_off fd buf off len
 739
 740 -- NOTE: "safe" versions of the read/write calls for use by the threaded RTS.
 741 -- These calls may block, but that's ok.
 742
 743 foreign import ccall safe "__hscore_PrelHandle_recv"
 744    safe_recv_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 745
 746 foreign import ccall safe "__hscore_PrelHandle_recv"
 747    safe_recv_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 748
 749 foreign import ccall safe "__hscore_PrelHandle_send"
 750    safe_send_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 751
 752 foreign import ccall safe "__hscore_PrelHandle_send"
 753    safe_send_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 754
 755 #endif
 756
 757 foreign import ccall "rtsSupportsBoundThreads" threaded :: Bool
 758
 759 foreign import ccall safe "__hscore_PrelHandle_read"
 760    safe_read_rawBuffer :: FD -> RawBuffer -> Int -> CInt -> IO CInt
 761
 762 foreign import ccall safe "__hscore_PrelHandle_read"
 763    safe_read_off :: FD -> Ptr CChar -> Int -> CInt -> IO CInt
 764
 765 foreign import ccall safe "__hscore_PrelHandle_write"
 766    safe_write_rawBuffer :: CInt -> RawBuffer -> Int -> CInt -> IO CInt
 767
 768 foreign import ccall safe "__hscore_PrelHandle_write"
 769    safe_write_off :: CInt -> Ptr CChar -> Int -> CInt -> IO CInt
 770
 771 -- ---------------------------------------------------------------------------
 772 -- Standard Handles
 773
 774 -- Three handles are allocated during program initialisation.  The first
 775 -- two manage input or output from the Haskell program's standard input
 776 -- or output channel respectively.  The third manages output to the
 777 -- standard error channel. These handles are initially open.
 778
 779 fd_stdin  = 0 :: FD
 780 fd_stdout = 1 :: FD
 781 fd_stderr = 2 :: FD
 782
 783 -- | A handle managing input from the Haskell program's standard input channel.
 784 stdin :: Handle
 785 stdin = unsafePerformIO $ do
 786    -- ToDo: acquire lock
 787    -- We don't set non-blocking mode on standard handles, because it may
 788    -- confuse other applications attached to the same TTY/pipe
 789    -- see Note [nonblock]
 790    (buf, bmode) <- getBuffer fd_stdin ReadBuffer
 791    mkStdHandle fd_stdin "<stdin>" ReadHandle buf bmode
 792
 793 -- | A handle managing output to the Haskell program's standard output channel.
 794 stdout :: Handle
 795 stdout = unsafePerformIO $ do
 796    -- ToDo: acquire lock
 797    -- We don't set non-blocking mode on standard handles, because it may
 798    -- confuse other applications attached to the same TTY/pipe
 799    -- see Note [nonblock]
 800    (buf, bmode) <- getBuffer fd_stdout WriteBuffer
 801    mkStdHandle fd_stdout "<stdout>" WriteHandle buf bmode
 802
 803 -- | A handle managing output to the Haskell program's standard error channel.
 804 stderr :: Handle
 805 stderr = unsafePerformIO $ do
 806     -- ToDo: acquire lock
 807    -- We don't set non-blocking mode on standard handles, because it may
 808    -- confuse other applications attached to the same TTY/pipe
 809    -- see Note [nonblock]
 810    buf <- mkUnBuffer
 811    mkStdHandle fd_stderr "<stderr>" WriteHandle buf NoBuffering
 812
 813 -- ---------------------------------------------------------------------------
 814 -- Opening and Closing Files
 815
 816 addFilePathToIOError fun fp (IOError h iot _ str _)
 817   = IOError h iot fun str (Just fp)
 818
 819 -- | Computation 'openFile' @file mode@ allocates and returns a new, open
 820 -- handle to manage the file @file@.  It manages input if @mode@
 821 -- is 'ReadMode', output if @mode@ is 'WriteMode' or 'AppendMode',
 822 -- and both input and output if mode is 'ReadWriteMode'.
 823 --
 824 -- If the file does not exist and it is opened for output, it should be
 825 -- created as a new file.  If @mode@ is 'WriteMode' and the file
 826 -- already exists, then it should be truncated to zero length.
 827 -- Some operating systems delete empty files, so there is no guarantee
 828 -- that the file will exist following an 'openFile' with @mode@
 829 -- 'WriteMode' unless it is subsequently written to successfully.
 830 -- The handle is positioned at the end of the file if @mode@ is
 831 -- 'AppendMode', and otherwise at the beginning (in which case its
 832 -- internal position is 0).
 833 -- The initial buffer mode is implementation-dependent.
 834 --
 835 -- This operation may fail with:
 836 --
 837 --  * 'isAlreadyInUseError' if the file is already open and cannot be reopened;
 838 --
 839 --  * 'isDoesNotExistError' if the file does not exist; or
 840 --
 841 --  * 'isPermissionError' if the user does not have permission to open the file.
 842 --
 843 -- Note: if you will be working with files containing binary data, you'll want to
 844 -- be using 'openBinaryFile'.
 845 openFile :: FilePath -> IOMode -> IO Handle
 846 openFile fp im =
 847   catch
 848     (openFile' fp im dEFAULT_OPEN_IN_BINARY_MODE)
 849     (\e -> ioError (addFilePathToIOError "openFile" fp e))
 850
 851 -- | Like 'openFile', but open the file in binary mode.
 852 -- On Windows, reading a file in text mode (which is the default)
 853 -- will translate CRLF to LF, and writing will translate LF to CRLF.
 854 -- This is usually what you want with text files.  With binary files
 855 -- this is undesirable; also, as usual under Microsoft operating systems,
 856 -- text mode treats control-Z as EOF.  Binary mode turns off all special
 857 -- treatment of end-of-line and end-of-file characters.
 858 -- (See also 'hSetBinaryMode'.)
 859
 860 openBinaryFile :: FilePath -> IOMode -> IO Handle
 861 openBinaryFile fp m =
 862   catch
 863     (openFile' fp m True)
 864     (\e -> ioError (addFilePathToIOError "openBinaryFile" fp e))
 865
 866 openFile' filepath mode binary =
 867   withCString filepath $ \ f ->
 868
 869     let
 870       oflags1 = case mode of
 871                   ReadMode      -> read_flags
 872 #ifdef mingw32_HOST_OS
 873                   WriteMode     -> write_flags .|. o_TRUNC
 874 #else
 875                   WriteMode     -> write_flags
 876 #endif
 877                   ReadWriteMode -> rw_flags
 878                   AppendMode    -> append_flags
 879
 880       binary_flags
 881           | binary    = o_BINARY
 882           | otherwise = 0
 883
 884       oflags = oflags1 .|. binary_flags
 885     in do
 886
 887     -- the old implementation had a complicated series of three opens,
 888     -- which is perhaps because we have to be careful not to open
 889     -- directories.  However, the man pages I've read say that open()
 890     -- always returns EISDIR if the file is a directory and was opened
 891     -- for writing, so I think we're ok with a single open() here...
 892     fd <- throwErrnoIfMinus1Retry "openFile"
 893                 (c_open f (fromIntegral oflags) 0o666)
 894
 895     stat@(fd_type,_,_) <- fdStat fd
 896
 897     h <- fdToHandle_stat fd (Just stat) False filepath mode binary
 898             `catchException` \e -> do c_close fd; throw e
 899         -- NB. don't forget to close the FD if fdToHandle' fails, otherwise
 900         -- this FD leaks.
 901         -- ASSERT: if we just created the file, then fdToHandle' won't fail
 902         -- (so we don't need to worry about removing the newly created file
 903         --  in the event of an error).
 904
 905 #ifndef mingw32_HOST_OS
 906         -- we want to truncate() if this is an open in WriteMode, but only
 907         -- if the target is a RegularFile.  ftruncate() fails on special files
 908         -- like /dev/null.
 909     if mode == WriteMode && fd_type == RegularFile
 910       then throwErrnoIf (/=0) "openFile"
 911               (c_ftruncate fd 0)
 912       else return 0
 913 #endif
 914     return h
 915
 916
 917 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 918 output_flags = std_flags    .|. o_CREAT
 919 read_flags   = std_flags    .|. o_RDONLY
 920 write_flags  = output_flags .|. o_WRONLY
 921 rw_flags     = output_flags .|. o_RDWR
 922 append_flags = write_flags  .|. o_APPEND
 923
 924 -- ---------------------------------------------------------------------------
 925 -- fdToHandle
 926
 927 fdToHandle_stat :: FD
 928             -> Maybe (FDType, CDev, CIno)
 929             -> Bool
 930             -> FilePath
 931             -> IOMode
 932             -> Bool
 933             -> IO Handle
 934
 935 fdToHandle_stat fd mb_stat is_socket filepath mode binary = do
 936     -- turn on non-blocking mode
 937     setNonBlockingFD fd
 938
 939 #ifdef mingw32_HOST_OS
 940     -- On Windows, the is_stream flag indicates that the Handle is a socket
 941     let is_stream = is_socket
 942 #else
 943     -- On Unix, the is_stream flag indicates that the FD is non-blocking
 944     let is_stream = True
 945 #endif
 946
 947     let (ha_type, write) =
 948           case mode of
 949             ReadMode      -> ( ReadHandle,      False )
 950             WriteMode     -> ( WriteHandle,     True )
 951             ReadWriteMode -> ( ReadWriteHandle, True )
 952             AppendMode    -> ( AppendHandle,    True )
 953
 954     -- open() won't tell us if it was a directory if we only opened for
 955     -- reading, so check again.
 956     (fd_type,dev,ino) <-
 957       case mb_stat of
 958         Just x  -> return x
 959         Nothing -> fdStat fd
 960
 961     case fd_type of
 962         Directory ->
 963            ioException (IOError Nothing InappropriateType "openFile"
 964                            "is a directory" Nothing)
 965
 966         -- regular files need to be locked
 967         RegularFile -> do
 968 #ifndef mingw32_HOST_OS
 969            r <- lockFile fd dev ino (fromBool write)
 970            when (r == -1)  $
 971                 ioException (IOError Nothing ResourceBusy "openFile"
 972                                    "file is locked" Nothing)
 973 #endif
 974            mkFileHandle fd is_stream filepath ha_type binary
 975
 976         Stream
 977            -- only *Streams* can be DuplexHandles.  Other read/write
 978            -- Handles must share a buffer.
 979            | ReadWriteHandle <- ha_type ->
 980                 mkDuplexHandle fd is_stream filepath binary
 981            | otherwise ->
 982                 mkFileHandle   fd is_stream filepath ha_type binary
 983
 984         RawDevice ->
 985                 mkFileHandle fd is_stream filepath ha_type binary
 986
 987 -- | Old API kept to avoid breaking clients
 988 fdToHandle' :: FD -> Maybe FDType -> Bool -> FilePath  -> IOMode -> Bool
 989             -> IO Handle
 990 fdToHandle' fd mb_type is_socket filepath mode binary
 991  = do
 992        let mb_stat = case mb_type of
 993                         Nothing          -> Nothing
 994                           -- fdToHandle_stat will do the stat:
 995                         Just RegularFile -> Nothing
 996                           -- no stat required for streams etc.:
 997                         Just other       -> Just (other,0,0)
 998        fdToHandle_stat fd mb_stat is_socket filepath mode binary
 999
1000 fdToHandle :: FD -> IO Handle
1001 fdToHandle fd = do
1002    mode <- fdGetMode fd
1003    let fd_str = "<file descriptor: " ++ show fd ++ ">"
1004    fdToHandle_stat fd Nothing False{-XXX!-} fd_str mode True{-bin mode-}
1005
1006
1007 #ifndef mingw32_HOST_OS
1008 foreign import ccall unsafe "lockFile"
1009   lockFile :: CInt -> CDev -> CIno -> CInt -> IO CInt
1010
1011 foreign import ccall unsafe "unlockFile"
1012   unlockFile :: CInt -> IO CInt
1013 #endif
1014
1015 mkStdHandle :: FD -> FilePath -> HandleType -> IORef Buffer -> BufferMode
1016         -> IO Handle
1017 mkStdHandle fd filepath ha_type buf bmode = do
1018    spares <- newIORef BufferListNil
1019    newFileHandle filepath (stdHandleFinalizer filepath)
1020             (Handle__ { haFD = fd,
1021                         haType = ha_type,
1022                         haIsBin = dEFAULT_OPEN_IN_BINARY_MODE,
1023                         haIsStream = False, -- means FD is blocking on Unix
1024                         haBufferMode = bmode,
1025                         haBuffer = buf,
1026                         haBuffers = spares,
1027                         haOtherSide = Nothing
1028                       })
1029
1030 mkFileHandle :: FD -> Bool -> FilePath -> HandleType -> Bool -> IO Handle
1031 mkFileHandle fd is_stream filepath ha_type binary = do
1032   (buf, bmode) <- getBuffer fd (initBufferState ha_type)
1033
1034 #ifdef mingw32_HOST_OS
1035   -- On Windows, if this is a read/write handle and we are in text mode,
1036   -- turn off buffering.  We don't correctly handle the case of switching
1037   -- from read mode to write mode on a buffered text-mode handle, see bug
1038   -- \#679.
1039   bmode <- case ha_type of
1040                 ReadWriteHandle | not binary -> return NoBuffering
1041                 _other                       -> return bmode
1042 #endif
1043
1044   spares <- newIORef BufferListNil
1045   newFileHandle filepath (handleFinalizer filepath)
1046             (Handle__ { haFD = fd,
1047                         haType = ha_type,
1048                         haIsBin = binary,
1049                         haIsStream = is_stream,
1050                         haBufferMode = bmode,
1051                         haBuffer = buf,
1052                         haBuffers = spares,
1053                         haOtherSide = Nothing
1054                       })
1055
1056 mkDuplexHandle :: FD -> Bool -> FilePath -> Bool -> IO Handle
1057 mkDuplexHandle fd is_stream filepath binary = do
1058   (w_buf, w_bmode) <- getBuffer fd WriteBuffer
1059   w_spares <- newIORef BufferListNil
1060   let w_handle_ =
1061              Handle__ { haFD = fd,
1062                         haType = WriteHandle,
1063                         haIsBin = binary,
1064                         haIsStream = is_stream,
1065                         haBufferMode = w_bmode,
1066                         haBuffer = w_buf,
1067                         haBuffers = w_spares,
1068                         haOtherSide = Nothing
1069                       }
1070   write_side <- newMVar w_handle_
1071
1072   (r_buf, r_bmode) <- getBuffer fd ReadBuffer
1073   r_spares <- newIORef BufferListNil
1074   let r_handle_ =
1075              Handle__ { haFD = fd,
1076                         haType = ReadHandle,
1077                         haIsBin = binary,
1078                         haIsStream = is_stream,
1079                         haBufferMode = r_bmode,
1080                         haBuffer = r_buf,
1081                         haBuffers = r_spares,
1082                         haOtherSide = Just write_side
1083                       }
1084   read_side <- newMVar r_handle_
1085
1086   addMVarFinalizer write_side (handleFinalizer filepath write_side)
1087   return (DuplexHandle filepath read_side write_side)
1088
1089
1090 initBufferState ReadHandle = ReadBuffer
1091 initBufferState _          = WriteBuffer
1092
1093 -- ---------------------------------------------------------------------------
1094 -- Closing a handle
1095
1096 -- | Computation 'hClose' @hdl@ makes handle @hdl@ closed.  Before the
1097 -- computation finishes, if @hdl@ is writable its buffer is flushed as
1098 -- for 'hFlush'.
1099 -- Performing 'hClose' on a handle that has already been closed has no effect;
1100 -- doing so is not an error.  All other operations on a closed handle will fail.
1101 -- If 'hClose' fails for any reason, any further operations (apart from
1102 -- 'hClose') on the handle will still fail as if @hdl@ had been successfully
1103 -- closed.
1104
1105 hClose :: Handle -> IO ()
1106 hClose h@(FileHandle _ m)     = do
1107   mb_exc <- hClose' h m
1108   case mb_exc of
1109     Nothing -> return ()
1110     Just e  -> throwIO e
1111 hClose h@(DuplexHandle _ r w) = do
1112   mb_exc1 <- hClose' h w
1113   mb_exc2 <- hClose' h r
1114   case (do mb_exc1; mb_exc2) of
1115      Nothing -> return ()
1116      Just e  -> throwIO e
1117
1118 hClose' h m = withHandle' "hClose" h m $ hClose_help
1119
1120 -- hClose_help is also called by lazyRead (in PrelIO) when EOF is read
1121 -- or an IO error occurs on a lazy stream.  The semi-closed Handle is
1122 -- then closed immediately.  We have to be careful with DuplexHandles
1123 -- though: we have to leave the closing to the finalizer in that case,
1124 -- because the write side may still be in use.
1125 hClose_help :: Handle__ -> IO (Handle__, Maybe Exception)
1126 hClose_help handle_ =
1127   case haType handle_ of
1128       ClosedHandle -> return (handle_,Nothing)
1129       _ -> do flushWriteBufferOnly handle_ -- interruptible
1130               hClose_handle_ handle_
1131
1132 hClose_handle_ handle_ = do
1133     let fd = haFD handle_
1134
1135     -- close the file descriptor, but not when this is the read
1136     -- side of a duplex handle.
1137     -- If an exception is raised by the close(), we want to continue
1138     -- to close the handle and release the lock if it has one, then
1139     -- we return the exception to the caller of hClose_help which can
1140     -- raise it if necessary.
1141     maybe_exception <-
1142       case haOtherSide handle_ of
1143         Nothing -> (do
1144                       throwErrnoIfMinus1Retry_ "hClose"
1145 #ifdef mingw32_HOST_OS
1146                                 (closeFd (haIsStream handle_) fd)
1147 #else
1148                                 (c_close fd)
1149 #endif
1150                       return Nothing
1151                     )
1152                      `catchException` \e -> return (Just e)
1153
1154         Just _  -> return Nothing
1155
1156     -- free the spare buffers
1157     writeIORef (haBuffers handle_) BufferListNil
1158     writeIORef (haBuffer  handle_) noBuffer
1159
1160 #ifndef mingw32_HOST_OS
1161     -- unlock it
1162     unlockFile fd
1163 #endif
1164
1165     -- we must set the fd to -1, because the finalizer is going
1166     -- to run eventually and try to close/unlock it.
1167     return (handle_{ haFD        = -1,
1168                      haType      = ClosedHandle
1169                    },
1170             maybe_exception)
1171
1172 {-# NOINLINE noBuffer #-}
1173 noBuffer = unsafePerformIO $ allocateBuffer 1 ReadBuffer
1174
1175 -----------------------------------------------------------------------------
1176 -- Detecting and changing the size of a file
1177
1178 -- | For a handle @hdl@ which attached to a physical file,
1179 -- 'hFileSize' @hdl@ returns the size of that file in 8-bit bytes.
1180
1181 hFileSize :: Handle -> IO Integer
1182 hFileSize handle =
1183     withHandle_ "hFileSize" handle $ \ handle_ -> do
1184     case haType handle_ of
1185       ClosedHandle              -> ioe_closedHandle
1186       SemiClosedHandle          -> ioe_closedHandle
1187       _ -> do flushWriteBufferOnly handle_
1188               r <- fdFileSize (haFD handle_)
1189               if r /= -1
1190                  then return r
1191                  else ioException (IOError Nothing InappropriateType "hFileSize"
1192                                    "not a regular file" Nothing)
1193
1194
1195 -- | 'hSetFileSize' @hdl@ @size@ truncates the physical file with handle @hdl@ to @size@ bytes.
1196
1197 hSetFileSize :: Handle -> Integer -> IO ()
1198 hSetFileSize handle size =
1199     withHandle_ "hSetFileSize" handle $ \ handle_ -> do
1200     case haType handle_ of
1201       ClosedHandle              -> ioe_closedHandle
1202       SemiClosedHandle          -> ioe_closedHandle
1203       _ -> do flushWriteBufferOnly handle_
1204               throwErrnoIf (/=0) "hSetFileSize"
1205                  (c_ftruncate (haFD handle_) (fromIntegral size))
1206               return ()
1207
1208 -- ---------------------------------------------------------------------------
1209 -- Detecting the End of Input
1210
1211 -- | For a readable handle @hdl@, 'hIsEOF' @hdl@ returns
1212 -- 'True' if no further input can be taken from @hdl@ or for a
1213 -- physical file, if the current I\/O position is equal to the length of
1214 -- the file.  Otherwise, it returns 'False'.
1215 --
1216 -- NOTE: 'hIsEOF' may block, because it is the same as calling
1217 -- 'hLookAhead' and checking for an EOF exception.
1218
1219 hIsEOF :: Handle -> IO Bool
1220 hIsEOF handle =
1221   catch
1222      (do hLookAhead handle; return False)
1223      (\e -> if isEOFError e then return True else ioError e)
1224
1225 -- | The computation 'isEOF' is identical to 'hIsEOF',
1226 -- except that it works only on 'stdin'.
1227
1228 isEOF :: IO Bool
1229 isEOF = hIsEOF stdin
1230
1231 -- ---------------------------------------------------------------------------
1232 -- Looking ahead
1233
1234 -- | Computation 'hLookAhead' returns the next character from the handle
1235 -- without removing it from the input buffer, blocking until a character
1236 -- is available.
1237 --
1238 -- This operation may fail with:
1239 --
1240 --  * 'isEOFError' if the end of file has been reached.
1241
1242 hLookAhead :: Handle -> IO Char
1243 hLookAhead handle = do
1244   wantReadableHandle "hLookAhead"  handle $ \handle_ -> do
1245   let ref     = haBuffer handle_
1246       fd      = haFD handle_
1247       is_line = haBufferMode handle_ == LineBuffering
1248   buf <- readIORef ref
1249
1250   -- fill up the read buffer if necessary
1251   new_buf <- if bufferEmpty buf
1252                 then fillReadBuffer fd True (haIsStream handle_) buf
1253                 else return buf
1254
1255   writeIORef ref new_buf
1256
1257   (c,_) <- readCharFromBuffer (bufBuf buf) (bufRPtr buf)
1258   return c
1259
1260 -- ---------------------------------------------------------------------------
1261 -- Buffering Operations
1262
1263 -- Three kinds of buffering are supported: line-buffering,
1264 -- block-buffering or no-buffering.  See GHC.IOBase for definition and
1265 -- further explanation of what the type represent.
1266
1267 -- | Computation 'hSetBuffering' @hdl mode@ sets the mode of buffering for
1268 -- handle @hdl@ on subsequent reads and writes.
1269 --
1270 -- If the buffer mode is changed from 'BlockBuffering' or
1271 -- 'LineBuffering' to 'NoBuffering', then
1272 --
1273 --  * if @hdl@ is writable, the buffer is flushed as for 'hFlush';
1274 --
1275 --  * if @hdl@ is not writable, the contents of the buffer is discarded.
1276 --
1277 -- This operation may fail with:
1278 --
1279 --  * 'isPermissionError' if the handle has already been used for reading
1280 --    or writing and the implementation does not allow the buffering mode
1281 --    to be changed.
1282
1283 hSetBuffering :: Handle -> BufferMode -> IO ()
1284 hSetBuffering handle mode =
1285   withAllHandles__ "hSetBuffering" handle $ \ handle_ -> do
1286   case haType handle_ of
1287     ClosedHandle -> ioe_closedHandle
1288     _ -> do
1289          {- Note:
1290             - we flush the old buffer regardless of whether
1291               the new buffer could fit the contents of the old buffer
1292               or not.
1293             - allow a handle's buffering to change even if IO has
1294               occurred (ANSI C spec. does not allow this, nor did
1295               the previous implementation of IO.hSetBuffering).
1296             - a non-standard extension is to allow the buffering
1297               of semi-closed handles to change [sof 6/98]
1298           -}
1299           flushBuffer handle_
1300
1301           let state = initBufferState (haType handle_)
1302           new_buf <-
1303             case mode of
1304                 -- we always have a 1-character read buffer for
1305                 -- unbuffered  handles: it's needed to
1306                 -- support hLookAhead.
1307               NoBuffering            -> allocateBuffer 1 ReadBuffer
1308               LineBuffering          -> allocateBuffer dEFAULT_BUFFER_SIZE state
1309               BlockBuffering Nothing -> allocateBuffer dEFAULT_BUFFER_SIZE state
1310               BlockBuffering (Just n) | n <= 0    -> ioe_bufsiz n
1311                                       | otherwise -> allocateBuffer n state
1312           writeIORef (haBuffer handle_) new_buf
1313
1314           -- for input terminals we need to put the terminal into
1315           -- cooked or raw mode depending on the type of buffering.
1316           is_tty <- fdIsTTY (haFD handle_)
1317           when (is_tty && isReadableHandleType (haType handle_)) $
1318                 case mode of
1319 #ifndef mingw32_HOST_OS
1320         -- 'raw' mode under win32 is a bit too specialised (and troublesome
1321         -- for most common uses), so simply disable its use here.
1322                   NoBuffering -> setCooked (haFD handle_) False
1323 #else
1324                   NoBuffering -> return ()
1325 #endif
1326                   _           -> setCooked (haFD handle_) True
1327
1328           -- throw away spare buffers, they might be the wrong size
1329           writeIORef (haBuffers handle_) BufferListNil
1330
1331           return (handle_{ haBufferMode = mode })
1332
1333 -- -----------------------------------------------------------------------------
1334 -- hFlush
1335
1336 -- | The action 'hFlush' @hdl@ causes any items buffered for output
1337 -- in handle @hdl@ to be sent immediately to the operating system.
1338 --
1339 -- This operation may fail with:
1340 --
1341 --  * 'isFullError' if the device is full;
1342 --
1343 --  * 'isPermissionError' if a system resource limit would be exceeded.
1344 --    It is unspecified whether the characters in the buffer are discarded
1345 --    or retained under these circumstances.
1346
1347 hFlush :: Handle -> IO ()
1348 hFlush handle =
1349    wantWritableHandle "hFlush" handle $ \ handle_ -> do
1350    buf <- readIORef (haBuffer handle_)
1351    if bufferIsWritable buf && not (bufferEmpty buf)
1352         then do flushed_buf <- flushWriteBuffer (haFD handle_) (haIsStream handle_) buf
1353                 writeIORef (haBuffer handle_) flushed_buf
1354         else return ()
1355
1356
1357 -- -----------------------------------------------------------------------------
1358 -- Repositioning Handles
1359
1360 data HandlePosn = HandlePosn Handle HandlePosition
1361
1362 instance Eq HandlePosn where
1363     (HandlePosn h1 p1) == (HandlePosn h2 p2) = p1==p2 && h1==h2
1364
1365 instance Show HandlePosn where
1366    showsPrec p (HandlePosn h pos) =
1367         showsPrec p h . showString " at position " . shows pos
1368
1369   -- HandlePosition is the Haskell equivalent of POSIX' off_t.
1370   -- We represent it as an Integer on the Haskell side, but
1371   -- cheat slightly in that hGetPosn calls upon a C helper
1372   -- that reports the position back via (merely) an Int.
1373 type HandlePosition = Integer
1374
1375 -- | Computation 'hGetPosn' @hdl@ returns the current I\/O position of
1376 -- @hdl@ as a value of the abstract type 'HandlePosn'.
1377
1378 hGetPosn :: Handle -> IO HandlePosn
1379 hGetPosn handle = do
1380     posn <- hTell handle
1381     return (HandlePosn handle posn)
1382
1383 -- | If a call to 'hGetPosn' @hdl@ returns a position @p@,
1384 -- then computation 'hSetPosn' @p@ sets the position of @hdl@
1385 -- to the position it held at the time of the call to 'hGetPosn'.
1386 --
1387 -- This operation may fail with:
1388 --
1389 --  * 'isPermissionError' if a system resource limit would be exceeded.
1390
1391 hSetPosn :: HandlePosn -> IO ()
1392 hSetPosn (HandlePosn h i) = hSeek h AbsoluteSeek i
1393
1394 -- ---------------------------------------------------------------------------
1395 -- hSeek
1396
1397 -- | A mode that determines the effect of 'hSeek' @hdl mode i@, as follows:
1398 data SeekMode
1399   = AbsoluteSeek        -- ^ the position of @hdl@ is set to @i@.
1400   | RelativeSeek        -- ^ the position of @hdl@ is set to offset @i@
1401                         -- from the current position.
1402   | SeekFromEnd         -- ^ the position of @hdl@ is set to offset @i@
1403                         -- from the end of the file.
1404     deriving (Eq, Ord, Ix, Enum, Read, Show)
1405
1406 {- Note:
1407  - when seeking using `SeekFromEnd', positive offsets (>=0) means
1408    seeking at or past EOF.
1409
1410  - we possibly deviate from the report on the issue of seeking within
1411    the buffer and whether to flush it or not.  The report isn't exactly
1412    clear here.
1413 -}
1414
1415 -- | Computation 'hSeek' @hdl mode i@ sets the position of handle
1416 -- @hdl@ depending on @mode@.
1417 -- The offset @i@ is given in terms of 8-bit bytes.
1418 --
1419 -- If @hdl@ is block- or line-buffered, then seeking to a position which is not
1420 -- in the current buffer will first cause any items in the output buffer to be
1421 -- written to the device, and then cause the input buffer to be discarded.
1422 -- Some handles may not be seekable (see 'hIsSeekable'), or only support a
1423 -- subset of the possible positioning operations (for instance, it may only
1424 -- be possible to seek to the end of a tape, or to a positive offset from
1425 -- the beginning or current position).
1426 -- It is not possible to set a negative I\/O position, or for
1427 -- a physical file, an I\/O position beyond the current end-of-file.
1428 --
1429 -- This operation may fail with:
1430 --
1431 --  * 'isPermissionError' if a system resource limit would be exceeded.
1432
1433 hSeek :: Handle -> SeekMode -> Integer -> IO ()
1434 hSeek handle mode offset =
1435     wantSeekableHandle "hSeek" handle $ \ handle_ -> do
1436 #   ifdef DEBUG_DUMP
1437     puts ("hSeek " ++ show (mode,offset) ++ "\n")
1438 #   endif
1439     let ref = haBuffer handle_
1440     buf <- readIORef ref
1441     let r = bufRPtr buf
1442         w = bufWPtr buf
1443         fd = haFD handle_
1444
1445     let do_seek =
1446           throwErrnoIfMinus1Retry_ "hSeek"
1447             (c_lseek (haFD handle_) (fromIntegral offset) whence)
1448
1449         whence :: CInt
1450         whence = case mode of
1451                    AbsoluteSeek -> sEEK_SET
1452                    RelativeSeek -> sEEK_CUR
1453                    SeekFromEnd  -> sEEK_END
1454
1455     if bufferIsWritable buf
1456         then do new_buf <- flushWriteBuffer fd (haIsStream handle_) buf
1457                 writeIORef ref new_buf
1458                 do_seek
1459         else do
1460
1461     if mode == RelativeSeek && offset >= 0 && offset < fromIntegral (w - r)
1462         then writeIORef ref buf{ bufRPtr = r + fromIntegral offset }
1463         else do
1464
1465     new_buf <- flushReadBuffer (haFD handle_) buf
1466     writeIORef ref new_buf
1467     do_seek
1468
1469
1470 hTell :: Handle -> IO Integer
1471 hTell handle =
1472     wantSeekableHandle "hGetPosn" handle $ \ handle_ -> do
1473
1474 #if defined(mingw32_HOST_OS)
1475         -- urgh, on Windows we have to worry about \n -> \r\n translation,
1476         -- so we can't easily calculate the file position using the
1477         -- current buffer size.  Just flush instead.
1478       flushBuffer handle_
1479 #endif
1480       let fd = haFD handle_
1481       posn <- fromIntegral `liftM`
1482                 throwErrnoIfMinus1Retry "hGetPosn"
1483                    (c_lseek fd 0 sEEK_CUR)
1484
1485       let ref = haBuffer handle_
1486       buf <- readIORef ref
1487
1488       let real_posn
1489            | bufferIsWritable buf = posn + fromIntegral (bufWPtr buf)
1490            | otherwise = posn - fromIntegral (bufWPtr buf - bufRPtr buf)
1491 #     ifdef DEBUG_DUMP
1492       puts ("\nhGetPosn: (fd, posn, real_posn) = " ++ show (fd, posn, real_posn) ++ "\n")
1493       puts ("   (bufWPtr, bufRPtr) = " ++ show (bufWPtr buf, bufRPtr buf) ++ "\n")
1494 #     endif
1495       return real_posn
1496
1497 -- -----------------------------------------------------------------------------
1498 -- Handle Properties
1499
1500 -- A number of operations return information about the properties of a
1501 -- handle.  Each of these operations returns `True' if the handle has
1502 -- the specified property, and `False' otherwise.
1503
1504 hIsOpen :: Handle -> IO Bool
1505 hIsOpen handle =
1506     withHandle_ "hIsOpen" handle $ \ handle_ -> do
1507     case haType handle_ of
1508       ClosedHandle         -> return False
1509       SemiClosedHandle     -> return False
1510       _                    -> return True
1511
1512 hIsClosed :: Handle -> IO Bool
1513 hIsClosed handle =
1514     withHandle_ "hIsClosed" handle $ \ handle_ -> do
1515     case haType handle_ of
1516       ClosedHandle         -> return True
1517       _                    -> return False
1518
1519 {- not defined, nor exported, but mentioned
1520    here for documentation purposes:
1521
1522     hSemiClosed :: Handle -> IO Bool
1523     hSemiClosed h = do
1524        ho <- hIsOpen h
1525        hc <- hIsClosed h
1526        return (not (ho || hc))
1527 -}
1528
1529 hIsReadable :: Handle -> IO Bool
1530 hIsReadable (DuplexHandle _ _ _) = return True
1531 hIsReadable handle =
1532     withHandle_ "hIsReadable" handle $ \ handle_ -> do
1533     case haType handle_ of
1534       ClosedHandle         -> ioe_closedHandle
1535       SemiClosedHandle     -> ioe_closedHandle
1536       htype                -> return (isReadableHandleType htype)
1537
1538 hIsWritable :: Handle -> IO Bool
1539 hIsWritable (DuplexHandle _ _ _) = return True
1540 hIsWritable handle =
1541     withHandle_ "hIsWritable" handle $ \ handle_ -> do
1542     case haType handle_ of
1543       ClosedHandle         -> ioe_closedHandle
1544       SemiClosedHandle     -> ioe_closedHandle
1545       htype                -> return (isWritableHandleType htype)
1546
1547 -- | Computation 'hGetBuffering' @hdl@ returns the current buffering mode
1548 -- for @hdl@.
1549
1550 hGetBuffering :: Handle -> IO BufferMode
1551 hGetBuffering handle =
1552     withHandle_ "hGetBuffering" handle $ \ handle_ -> do
1553     case haType handle_ of
1554       ClosedHandle         -> ioe_closedHandle
1555       _ ->
1556            -- We're being non-standard here, and allow the buffering
1557            -- of a semi-closed handle to be queried.   -- sof 6/98
1558           return (haBufferMode handle_)  -- could be stricter..
1559
1560 hIsSeekable :: Handle -> IO Bool
1561 hIsSeekable handle =
1562     withHandle_ "hIsSeekable" handle $ \ handle_ -> do
1563     case haType handle_ of
1564       ClosedHandle         -> ioe_closedHandle
1565       SemiClosedHandle     -> ioe_closedHandle
1566       AppendHandle         -> return False
1567       _                    -> do t <- fdType (haFD handle_)
1568                                  return ((t == RegularFile    || t == RawDevice)
1569                                          && (haIsBin handle_  || tEXT_MODE_SEEK_ALLOWED))
1570
1571 -- -----------------------------------------------------------------------------
1572 -- Changing echo status (Non-standard GHC extensions)
1573
1574 -- | Set the echoing status of a handle connected to a terminal.
1575
1576 hSetEcho :: Handle -> Bool -> IO ()
1577 hSetEcho handle on = do
1578     isT   <- hIsTerminalDevice handle
1579     if not isT
1580      then return ()
1581      else
1582       withHandle_ "hSetEcho" handle $ \ handle_ -> do
1583       case haType handle_ of
1584          ClosedHandle -> ioe_closedHandle
1585          _            -> setEcho (haFD handle_) on
1586
1587 -- | Get the echoing status of a handle connected to a terminal.
1588
1589 hGetEcho :: Handle -> IO Bool
1590 hGetEcho handle = do
1591     isT   <- hIsTerminalDevice handle
1592     if not isT
1593      then return False
1594      else
1595        withHandle_ "hGetEcho" handle $ \ handle_ -> do
1596        case haType handle_ of
1597          ClosedHandle -> ioe_closedHandle
1598          _            -> getEcho (haFD handle_)
1599
1600 -- | Is the handle connected to a terminal?
1601
1602 hIsTerminalDevice :: Handle -> IO Bool
1603 hIsTerminalDevice handle = do
1604     withHandle_ "hIsTerminalDevice" handle $ \ handle_ -> do
1605      case haType handle_ of
1606        ClosedHandle -> ioe_closedHandle
1607        _            -> fdIsTTY (haFD handle_)
1608
1609 -- -----------------------------------------------------------------------------
1610 -- hSetBinaryMode
1611
1612 -- | Select binary mode ('True') or text mode ('False') on a open handle.
1613 -- (See also 'openBinaryFile'.)
1614
1615 hSetBinaryMode :: Handle -> Bool -> IO ()
1616 hSetBinaryMode handle bin =
1617   withAllHandles__ "hSetBinaryMode" handle $ \ handle_ ->
1618     do throwErrnoIfMinus1_ "hSetBinaryMode"
1619           (setmode (haFD handle_) bin)
1620        return handle_{haIsBin=bin}
1621
1622 foreign import ccall unsafe "__hscore_setmode"
1623   setmode :: CInt -> Bool -> IO CInt
1624
1625 -- -----------------------------------------------------------------------------
1626 -- Duplicating a Handle
1627
1628 -- | Returns a duplicate of the original handle, with its own buffer.
1629 -- The two Handles will share a file pointer, however.  The original
1630 -- handle's buffer is flushed, including discarding any input data,
1631 -- before the handle is duplicated.
1632
1633 hDuplicate :: Handle -> IO Handle
1634 hDuplicate h@(FileHandle path m) = do
1635   new_h_ <- withHandle' "hDuplicate" h m (dupHandle h Nothing)
1636   newFileHandle path (handleFinalizer path) new_h_
1637 hDuplicate h@(DuplexHandle path r w) = do
1638   new_w_ <- withHandle' "hDuplicate" h w (dupHandle h Nothing)
1639   new_w <- newMVar new_w_
1640   new_r_ <- withHandle' "hDuplicate" h r (dupHandle h (Just new_w))
1641   new_r <- newMVar new_r_
1642   addMVarFinalizer new_w (handleFinalizer path new_w)
1643   return (DuplexHandle path new_r new_w)
1644
1645 dupHandle :: Handle -> Maybe (MVar Handle__) -> Handle__
1646           -> IO (Handle__, Handle__)
1647 dupHandle h other_side h_ = do
1648   -- flush the buffer first, so we don't have to copy its contents
1649   flushBuffer h_
1650   new_fd <- case other_side of
1651                 Nothing -> throwErrnoIfMinus1 "dupHandle" $ c_dup (haFD h_)
1652                 Just r -> withHandle_' "dupHandle" h r (return . haFD)
1653   dupHandle_ other_side h_ new_fd
1654
1655 dupHandleTo other_side hto_ h_ = do
1656   flushBuffer h_
1657   -- Windows' dup2 does not return the new descriptor, unlike Unix
1658   throwErrnoIfMinus1 "dupHandleTo" $
1659         c_dup2 (haFD h_) (haFD hto_)
1660   dupHandle_ other_side h_ (haFD hto_)
1661
1662 dupHandle_ :: Maybe (MVar Handle__) -> Handle__ -> FD
1663            -> IO (Handle__, Handle__)
1664 dupHandle_ other_side h_ new_fd = do
1665   buffer <- allocateBuffer dEFAULT_BUFFER_SIZE (initBufferState (haType h_))
1666   ioref <- newIORef buffer
1667   ioref_buffers <- newIORef BufferListNil
1668
1669   let new_handle_ = h_{ haFD = new_fd,
1670                         haBuffer = ioref,
1671                         haBuffers = ioref_buffers,
1672                         haOtherSide = other_side }
1673   return (h_, new_handle_)
1674
1675 -- -----------------------------------------------------------------------------
1676 -- Replacing a Handle
1677
1678 {- |
1679 Makes the second handle a duplicate of the first handle.  The second
1680 handle will be closed first, if it is not already.
1681
1682 This can be used to retarget the standard Handles, for example:
1683
1684 > do h <- openFile "mystdout" WriteMode
1685 >    hDuplicateTo h stdout
1686 -}
1687
1688 hDuplicateTo :: Handle -> Handle -> IO ()
1689 hDuplicateTo h1@(FileHandle _ m1) h2@(FileHandle _ m2)  = do
1690  withHandle__' "hDuplicateTo" h2 m2 $ \h2_ -> do
1691    _ <- hClose_help h2_
1692    withHandle' "hDuplicateTo" h1 m1 (dupHandleTo Nothing h2_)
1693 hDuplicateTo h1@(DuplexHandle _ r1 w1) h2@(DuplexHandle _ r2 w2)  = do
1694  withHandle__' "hDuplicateTo" h2 w2  $ \w2_ -> do
1695    _ <- hClose_help w2_
1696    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo Nothing w2_)
1697  withHandle__' "hDuplicateTo" h2 r2  $ \r2_ -> do
1698    _ <- hClose_help r2_
1699    withHandle' "hDuplicateTo" h1 r1 (dupHandleTo (Just w1) r2_)
1700 hDuplicateTo h1 _ =
1701    ioException (IOError (Just h1) IllegalOperation "hDuplicateTo"
1702                 "handles are incompatible" Nothing)
1703
1704 -- ---------------------------------------------------------------------------
1705 -- showing Handles.
1706 --
1707 -- | 'hShow' is in the 'IO' monad, and gives more comprehensive output
1708 -- than the (pure) instance of 'Show' for 'Handle'.
1709
1710 hShow :: Handle -> IO String
1711 hShow h@(FileHandle path _) = showHandle' path False h
1712 hShow h@(DuplexHandle path _ _) = showHandle' path True h
1713
1714 showHandle' filepath is_duplex h =
1715   withHandle_ "showHandle" h $ \hdl_ ->
1716     let
1717      showType | is_duplex = showString "duplex (read-write)"
1718               | otherwise = shows (haType hdl_)
1719     in
1720     return
1721       (( showChar '{' .
1722         showHdl (haType hdl_)
1723             (showString "loc=" . showString filepath . showChar ',' .
1724              showString "type=" . showType . showChar ',' .
1725              showString "binary=" . shows (haIsBin hdl_) . showChar ',' .
1726              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
1727       ) "")
1728    where
1729
1730     showHdl :: HandleType -> ShowS -> ShowS
1731     showHdl ht cont =
1732        case ht of
1733         ClosedHandle  -> shows ht . showString "}"
1734         _ -> cont
1735
1736     showBufMode :: Buffer -> BufferMode -> ShowS
1737     showBufMode buf bmo =
1738       case bmo of
1739         NoBuffering   -> showString "none"
1740         LineBuffering -> showString "line"
1741         BlockBuffering (Just n) -> showString "block " . showParen True (shows n)
1742         BlockBuffering Nothing  -> showString "block " . showParen True (shows def)
1743       where
1744        def :: Int
1745        def = bufSize buf
1746
1747 -- ---------------------------------------------------------------------------
1748 -- debugging
1749
1750 #if defined(DEBUG_DUMP)
1751 puts :: String -> IO ()
1752 puts s = do write_rawBuffer 1 (unsafeCoerce# (packCString# s)) 0 (fromIntegral (length s))
1753             return ()
1754 #endif
1755
1756 -- -----------------------------------------------------------------------------
1757 -- utils
1758
1759 throwErrnoIfMinus1RetryOnBlock  :: String -> IO CInt -> IO CInt -> IO CInt
1760 throwErrnoIfMinus1RetryOnBlock loc f on_block  =
1761   do
1762     res <- f
1763     if (res :: CInt) == -1
1764       then do
1765         err <- getErrno
1766         if err == eINTR
1767           then throwErrnoIfMinus1RetryOnBlock loc f on_block
1768           else if err == eWOULDBLOCK || err == eAGAIN
1769                  then do on_block
1770                  else throwErrno loc
1771       else return res
1772
1773 -- -----------------------------------------------------------------------------
1774 -- wrappers to platform-specific constants:
1775
1776 foreign import ccall unsafe "__hscore_supportsTextMode"
1777   tEXT_MODE_SEEK_ALLOWED :: Bool
1778
1779 foreign import ccall unsafe "__hscore_bufsiz"   dEFAULT_BUFFER_SIZE :: Int
1780 foreign import ccall unsafe "__hscore_seek_cur" sEEK_CUR :: CInt
1781 foreign import ccall unsafe "__hscore_seek_set" sEEK_SET :: CInt
1782 foreign import ccall unsafe "__hscore_seek_end" sEEK_END :: CInt