GHC/IOBase.lhs

   1 \begin{code}
   2 {-# OPTIONS -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.IOBase
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- Definitions for the 'IO' monad and its friends.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 module GHC.IOBase where
  18
  19 import GHC.ST
  20 import GHC.Arr  -- to derive Ix class
  21 import GHC.Enum -- to derive Enum class
  22 import GHC.STRef
  23 import GHC.Base
  24 import GHC.Num  -- To get fromInteger etc, needed because of -fno-implicit-prelude
  25 import Data.Maybe  ( Maybe(..) )
  26 import GHC.Show
  27 import GHC.List
  28 import GHC.Read
  29
  30 #ifndef __HADDOCK__
  31 import {-# SOURCE #-} Data.Dynamic
  32 #endif
  33
  34 -- ---------------------------------------------------------------------------
  35 -- The IO Monad
  36
  37 {-
  38 The IO Monad is just an instance of the ST monad, where the state is
  39 the real world.  We use the exception mechanism (in GHC.Exception) to
  40 implement IO exceptions.
  41
  42 NOTE: The IO representation is deeply wired in to various parts of the
  43 system.  The following list may or may not be exhaustive:
  44
  45 Compiler  - types of various primitives in PrimOp.lhs
  46
  47 RTS       - forceIO (StgMiscClosures.hc)
  48           - catchzh_fast, (un)?blockAsyncExceptionszh_fast, raisezh_fast
  49             (Exceptions.hc)
  50           - raiseAsync (Schedule.c)
  51
  52 Prelude   - GHC.IOBase.lhs, and several other places including
  53             GHC.Exception.lhs.
  54
  55 Libraries - parts of hslibs/lang.
  56
  57 --SDM
  58 -}
  59
  60 {-|
  61 A value of type @'IO' a@ is a computation which, when performed,
  62 does some I\/O before returning a value of type @a@.
  63
  64 There is really only one way to \"perform\" an I\/O action: bind it to
  65 @Main.main@ in your program.  When your program is run, the I\/O will
  66 be performed.  It isn't possible to perform I\/O from an arbitrary
  67 function, unless that function is itself in the 'IO' monad and called
  68 at some point, directly or indirectly, from @Main.main@.
  69
  70 'IO' is a monad, so 'IO' actions can be combined using either the do-notation
  71 or the '>>' and '>>=' operations from the 'Monad' class.
  72 -}
  73 newtype IO a = IO (State# RealWorld -> (# State# RealWorld, a #))
  74
  75 unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
  76 unIO (IO a) = a
  77
  78 instance  Functor IO where
  79    fmap f x = x >>= (return . f)
  80
  81 instance  Monad IO  where
  82     {-# INLINE return #-}
  83     {-# INLINE (>>)   #-}
  84     {-# INLINE (>>=)  #-}
  85     m >> k      =  m >>= \ _ -> k
  86     return x    = returnIO x
  87
  88     m >>= k     = bindIO m k
  89     fail s      = failIO s
  90
  91 failIO :: String -> IO a
  92 failIO s = ioError (userError s)
  93
  94 liftIO :: IO a -> State# RealWorld -> STret RealWorld a
  95 liftIO (IO m) = \s -> case m s of (# s', r #) -> STret s' r
  96
  97 bindIO :: IO a -> (a -> IO b) -> IO b
  98 bindIO (IO m) k = IO ( \ s ->
  99   case m s of
 100     (# new_s, a #) -> unIO (k a) new_s
 101   )
 102
 103 thenIO :: IO a -> IO b -> IO b
 104 thenIO (IO m) k = IO ( \ s ->
 105   case m s of
 106     (# new_s, a #) -> unIO k new_s
 107   )
 108
 109 returnIO :: a -> IO a
 110 returnIO x = IO (\ s -> (# s, x #))
 111
 112 -- ---------------------------------------------------------------------------
 113 -- Coercions between IO and ST
 114
 115 --stToIO        :: (forall s. ST s a) -> IO a
 116 stToIO        :: ST RealWorld a -> IO a
 117 stToIO (ST m) = IO m
 118
 119 ioToST        :: IO a -> ST RealWorld a
 120 ioToST (IO m) = (ST m)
 121
 122 -- ---------------------------------------------------------------------------
 123 -- Unsafe IO operations
 124
 125 {-|
 126 This is the \"back door\" into the 'IO' monad, allowing
 127 'IO' computation to be performed at any time.  For
 128 this to be safe, the 'IO' computation should be
 129 free of side effects and independent of its environment.
 130
 131 If the I\/O computation wrapped in 'unsafePerformIO'
 132 performs side effects, then the relative order in which those side
 133 effects take place (relative to the main I\/O trunk, or other calls to
 134 'unsafePerformIO') is indeterminate.  You have to be careful when
 135 writing and compiling modules that use 'unsafePerformIO':
 136
 137   * Use @{\-\# NOINLINE foo \#-\}@ as a pragma on any function @foo@
 138         that calls 'unsafePerformIO'.  If the call is inlined,
 139         the I\/O may be performed more than once.
 140
 141   * Use the compiler flag @-fno-cse@ to prevent common sub-expression
 142         elimination being performed on the module, which might combine
 143         two side effects that were meant to be separate.  A good example
 144         is using multiple global variables (like @test@ in the example below).
 145
 146   * Make sure that the either you switch off let-floating, or that the
 147         call to 'unsafePerformIO' cannot float outside a lambda.  For example,
 148         if you say:
 149         @
 150            f x = unsafePerformIO (newIORef [])
 151         @
 152         you may get only one reference cell shared between all calls to @f@.
 153         Better would be
 154         @
 155            f x = unsafePerformIO (newIORef [x])
 156         @
 157         because now it can't float outside the lambda.
 158
 159 It is less well known that
 160 'unsafePerformIO' is not type safe.  For example:
 161
 162 >     test :: IORef [a]
 163 >     test = unsafePerformIO $ newIORef []
 164 >
 165 >     main = do
 166 >             writeIORef test [42]
 167 >             bang \<- readIORef test
 168 >             print (bang :: [Char])
 169
 170 This program will core dump.  This problem with polymorphic references
 171 is well known in the ML community, and does not arise with normal
 172 monadic use of references.  There is no easy way to make it impossible
 173 once you use 'unsafePerformIO'.  Indeed, it is
 174 possible to write @coerce :: a -> b@ with the
 175 help of 'unsafePerformIO'.  So be careful!
 176 -}
 177 {-# NOINLINE unsafePerformIO #-}
 178 unsafePerformIO :: IO a -> a
 179 unsafePerformIO (IO m) = case m realWorld# of (# _, r #)   -> r
 180
 181 {-|
 182 'unsafeInterleaveIO' allows 'IO' computation to be deferred lazily.
 183 When passed a value of type @IO a@, the 'IO' will only be performed
 184 when the value of the @a@ is demanded.  This is used to implement lazy
 185 file reading, see 'System.IO.hGetContents'.
 186 -}
 187 {-# NOINLINE unsafeInterleaveIO #-}
 188 unsafeInterleaveIO :: IO a -> IO a
 189 unsafeInterleaveIO (IO m)
 190   = IO ( \ s -> let
 191                    r = case m s of (# _, res #) -> res
 192                 in
 193                 (# s, r #))
 194
 195 -- ---------------------------------------------------------------------------
 196 -- Handle type
 197
 198 data MVar a = MVar (MVar# RealWorld a)
 199 {- ^
 200 An 'MVar' (pronounced \"em-var\") is a synchronising variable, used
 201 for communication between concurrent threads.  It can be thought of
 202 as a a box, which may be empty or full.
 203 -}
 204
 205 -- pull in Eq (Mvar a) too, to avoid GHC.Conc being an orphan-instance module
 206 instance Eq (MVar a) where
 207         (MVar mvar1#) == (MVar mvar2#) = sameMVar# mvar1# mvar2#
 208
 209 --  A Handle is represented by (a reference to) a record
 210 --  containing the state of the I/O port/device. We record
 211 --  the following pieces of info:
 212
 213 --    * type (read,write,closed etc.)
 214 --    * the underlying file descriptor
 215 --    * buffering mode
 216 --    * buffer, and spare buffers
 217 --    * user-friendly name (usually the
 218 --      FilePath used when IO.openFile was called)
 219
 220 -- Note: when a Handle is garbage collected, we want to flush its buffer
 221 -- and close the OS file handle, so as to free up a (precious) resource.
 222
 223 data Handle
 224   = FileHandle                          -- A normal handle to a file
 225         !(MVar Handle__)
 226
 227   | DuplexHandle                        -- A handle to a read/write stream
 228         !(MVar Handle__)                -- The read side
 229         !(MVar Handle__)                -- The write side
 230
 231 -- NOTES:
 232 --    * A 'FileHandle' is seekable.  A 'DuplexHandle' may or may not be
 233 --      seekable.
 234
 235 instance Eq Handle where
 236  (FileHandle h1)     == (FileHandle h2)     = h1 == h2
 237  (DuplexHandle h1 _) == (DuplexHandle h2 _) = h1 == h2
 238  _ == _ = False
 239
 240 type FD = Int -- XXX ToDo: should be CInt
 241
 242 data Handle__
 243   = Handle__ {
 244       haFD          :: !FD,                  -- file descriptor
 245       haType        :: HandleType,           -- type (read/write/append etc.)
 246       haIsBin       :: Bool,                 -- binary mode?
 247       haIsStream    :: Bool,                 -- is this a stream handle?
 248       haBufferMode  :: BufferMode,           -- buffer contains read/write data?
 249       haFilePath    :: FilePath,             -- file name, possibly
 250       haBuffer      :: !(IORef Buffer),      -- the current buffer
 251       haBuffers     :: !(IORef BufferList),  -- spare buffers
 252       haOtherSide   :: Maybe (MVar Handle__) -- ptr to the write side of a
 253                                              -- duplex handle.
 254     }
 255
 256 -- ---------------------------------------------------------------------------
 257 -- Buffers
 258
 259 -- The buffer is represented by a mutable variable containing a
 260 -- record, where the record contains the raw buffer and the start/end
 261 -- points of the filled portion.  We use a mutable variable so that
 262 -- the common operation of writing (or reading) some data from (to)
 263 -- the buffer doesn't need to modify, and hence copy, the handle
 264 -- itself, it just updates the buffer.
 265
 266 -- There will be some allocation involved in a simple hPutChar in
 267 -- order to create the new Buffer structure (below), but this is
 268 -- relatively small, and this only has to be done once per write
 269 -- operation.
 270
 271 -- The buffer contains its size - we could also get the size by
 272 -- calling sizeOfMutableByteArray# on the raw buffer, but that tends
 273 -- to be rounded up to the nearest Word.
 274
 275 type RawBuffer = MutableByteArray# RealWorld
 276
 277 -- INVARIANTS on a Buffer:
 278 --
 279 --   * A handle *always* has a buffer, even if it is only 1 character long
 280 --     (an unbuffered handle needs a 1 character buffer in order to support
 281 --      hLookAhead and hIsEOF).
 282 --   * r <= w
 283 --   * if r == w, then r == 0 && w == 0
 284 --   * if state == WriteBuffer, then r == 0
 285 --   * a write buffer is never full.  If an operation
 286 --     fills up the buffer, it will always flush it before
 287 --     returning.
 288 --   * a read buffer may be full as a result of hLookAhead.  In normal
 289 --     operation, a read buffer always has at least one character of space.
 290
 291 data Buffer
 292   = Buffer {
 293         bufBuf   :: RawBuffer,
 294         bufRPtr  :: !Int,
 295         bufWPtr  :: !Int,
 296         bufSize  :: !Int,
 297         bufState :: BufferState
 298   }
 299
 300 data BufferState = ReadBuffer | WriteBuffer deriving (Eq)
 301
 302 -- we keep a few spare buffers around in a handle to avoid allocating
 303 -- a new one for each hPutStr.  These buffers are *guaranteed* to be the
 304 -- same size as the main buffer.
 305 data BufferList
 306   = BufferListNil
 307   | BufferListCons RawBuffer BufferList
 308
 309
 310 bufferIsWritable :: Buffer -> Bool
 311 bufferIsWritable Buffer{ bufState=WriteBuffer } = True
 312 bufferIsWritable _other = False
 313
 314 bufferEmpty :: Buffer -> Bool
 315 bufferEmpty Buffer{ bufRPtr=r, bufWPtr=w } = r == w
 316
 317 -- only makes sense for a write buffer
 318 bufferFull :: Buffer -> Bool
 319 bufferFull b@Buffer{ bufWPtr=w } = w >= bufSize b
 320
 321 --  Internally, we classify handles as being one
 322 --  of the following:
 323
 324 data HandleType
 325  = ClosedHandle
 326  | SemiClosedHandle
 327  | ReadHandle
 328  | WriteHandle
 329  | AppendHandle
 330  | ReadWriteHandle
 331
 332 isReadableHandleType ReadHandle         = True
 333 isReadableHandleType ReadWriteHandle    = True
 334 isReadableHandleType _                  = False
 335
 336 isWritableHandleType AppendHandle    = True
 337 isWritableHandleType WriteHandle     = True
 338 isWritableHandleType ReadWriteHandle = True
 339 isWritableHandleType _               = False
 340
 341 -- File names are specified using @FilePath@, a OS-dependent
 342 -- string that (hopefully, I guess) maps to an accessible file/object.
 343
 344 type FilePath = String
 345
 346 -- ---------------------------------------------------------------------------
 347 -- Buffering modes
 348
 349 -- Three kinds of buffering are supported: line-buffering,
 350 -- block-buffering or no-buffering.  These modes have the following
 351 -- effects. For output, items are written out from the internal
 352 -- buffer according to the buffer mode:
 353 --
 354 -- o line-buffering  the entire output buffer is written
 355 --   out whenever a newline is output, the output buffer overflows,
 356 --   a flush is issued, or the handle is closed.
 357 --
 358 -- o block-buffering the entire output buffer is written out whenever
 359 --   it overflows, a flush is issued, or the handle
 360 --   is closed.
 361 --
 362 -- o no-buffering output is written immediately, and never stored
 363 --   in the output buffer.
 364 --
 365 -- The output buffer is emptied as soon as it has been written out.
 366
 367 -- Similarly, input occurs according to the buffer mode for handle {\em hdl}.
 368
 369 -- o line-buffering when the input buffer for the handle is not empty,
 370 --   the next item is obtained from the buffer;
 371 --   otherwise, when the input buffer is empty,
 372 --   characters up to and including the next newline
 373 --   character are read into the buffer.  No characters
 374 --   are available until the newline character is
 375 --   available.
 376 --
 377 -- o block-buffering when the input buffer for the handle becomes empty,
 378 --   the next block of data is read into this buffer.
 379 --
 380 -- o no-buffering the next input item is read and returned.
 381
 382 -- For most implementations, physical files will normally be block-buffered
 383 -- and terminals will normally be line-buffered. (the IO interface provides
 384 -- operations for changing the default buffering of a handle tho.)
 385
 386 data BufferMode
 387  = NoBuffering | LineBuffering | BlockBuffering (Maybe Int)
 388    deriving (Eq, Ord, Read, Show)
 389
 390 -- ---------------------------------------------------------------------------
 391 -- IORefs
 392
 393 -- |A mutable variable in the 'IO' monad
 394 newtype IORef a = IORef (STRef RealWorld a) deriving Eq
 395
 396 -- |Build a new 'IORef'
 397 newIORef    :: a -> IO (IORef a)
 398 newIORef v = stToIO (newSTRef v) >>= \ var -> return (IORef var)
 399
 400 -- |Read the value of an 'IORef'
 401 readIORef   :: IORef a -> IO a
 402 readIORef  (IORef var) = stToIO (readSTRef var)
 403
 404 -- |Write a new value into an 'IORef'
 405 writeIORef  :: IORef a -> a -> IO ()
 406 writeIORef (IORef var) v = stToIO (writeSTRef var v)
 407
 408 -- ---------------------------------------------------------------------------
 409 -- | An 'IOArray' is a mutable, boxed, non-strict array in the 'IO' monad.
 410 -- The type arguments are as follows:
 411 --
 412 --  * @i@: the index type of the array (should be an instance of @Ix@)
 413 --
 414 --  * @e@: the element type of the array.
 415 --
 416 --
 417
 418 newtype IOArray i e = IOArray (STArray RealWorld i e) deriving Eq
 419
 420 -- |Build a new 'IOArray'
 421 newIOArray :: Ix i => (i,i) -> e -> IO (IOArray i e)
 422 {-# INLINE newIOArray #-}
 423 newIOArray lu init  = stToIO $ do {marr <- newSTArray lu init; return (IOArray marr)}
 424
 425 -- | Read a value from an 'IOArray'
 426 unsafeReadIOArray  :: Ix i => IOArray i e -> Int -> IO e
 427 {-# INLINE unsafeReadIOArray #-}
 428 unsafeReadIOArray (IOArray marr) i = stToIO (unsafeReadSTArray marr i)
 429
 430 -- | Write a new value into an 'IOArray'
 431 unsafeWriteIOArray :: Ix i => IOArray i e -> Int -> e -> IO ()
 432 {-# INLINE unsafeWriteIOArray #-}
 433 unsafeWriteIOArray (IOArray marr) i e = stToIO (unsafeWriteSTArray marr i e)
 434
 435 -- | Read a value from an 'IOArray'
 436 readIOArray  :: Ix i => IOArray i e -> i -> IO e
 437 readIOArray (IOArray marr) i = stToIO (readSTArray marr i)
 438
 439 -- | Write a new value into an 'IOArray'
 440 writeIOArray :: Ix i => IOArray i e -> i -> e -> IO ()
 441 writeIOArray (IOArray marr) i e = stToIO (writeSTArray marr i e)
 442
 443
 444 -- ---------------------------------------------------------------------------
 445 -- Show instance for Handles
 446
 447 -- handle types are 'show'n when printing error msgs, so
 448 -- we provide a more user-friendly Show instance for it
 449 -- than the derived one.
 450
 451 instance Show HandleType where
 452   showsPrec p t =
 453     case t of
 454       ClosedHandle      -> showString "closed"
 455       SemiClosedHandle  -> showString "semi-closed"
 456       ReadHandle        -> showString "readable"
 457       WriteHandle       -> showString "writable"
 458       AppendHandle      -> showString "writable (append)"
 459       ReadWriteHandle   -> showString "read-writable"
 460
 461 instance Show Handle where
 462   showsPrec p (FileHandle   h)   = showHandle p h False
 463   showsPrec p (DuplexHandle _ h) = showHandle p h True
 464
 465 showHandle p h duplex =
 466     let
 467      -- (Big) SIGH: unfolded defn of takeMVar to avoid
 468      -- an (oh-so) unfortunate module loop with GHC.Conc.
 469      hdl_ = unsafePerformIO (IO $ \ s# ->
 470              case h                 of { MVar h# ->
 471              case takeMVar# h# s#   of { (# s2# , r #) ->
 472              case putMVar# h# r s2# of { s3# ->
 473              (# s3#, r #) }}})
 474
 475      showType | duplex = showString "duplex (read-write)"
 476               | otherwise = showsPrec p (haType hdl_)
 477     in
 478     showChar '{' .
 479     showHdl (haType hdl_)
 480             (showString "loc=" . showString (haFilePath hdl_) . showChar ',' .
 481              showString "type=" . showType . showChar ',' .
 482              showString "binary=" . showsPrec p (haIsBin hdl_) . showChar ',' .
 483              showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
 484    where
 485
 486     showHdl :: HandleType -> ShowS -> ShowS
 487     showHdl ht cont =
 488        case ht of
 489         ClosedHandle  -> showsPrec p ht . showString "}"
 490         _ -> cont
 491
 492     showBufMode :: Buffer -> BufferMode -> ShowS
 493     showBufMode buf bmo =
 494       case bmo of
 495         NoBuffering   -> showString "none"
 496         LineBuffering -> showString "line"
 497         BlockBuffering (Just n) -> showString "block " . showParen True (showsPrec p n)
 498         BlockBuffering Nothing  -> showString "block " . showParen True (showsPrec p def)
 499       where
 500        def :: Int
 501        def = bufSize buf
 502
 503 -- ------------------------------------------------------------------------
 504 -- Exception datatype and operations
 505
 506 -- |The type of exceptions.  Every kind of system-generated exception
 507 -- has a constructor in the 'Exception' type, and values of other
 508 -- types may be injected into 'Exception' by coercing them to
 509 -- 'Dynamic' (see the section on Dynamic Exceptions: "Control.Exception\#DynamicExceptions").
 510 data Exception
 511   = ArithException      ArithException
 512         -- ^Exceptions raised by arithmetic
 513         -- operations.  (NOTE: GHC currently does not throw
 514         -- 'ArithException's except for 'DivideByZero').
 515   | ArrayException      ArrayException
 516         -- ^Exceptions raised by array-related
 517         -- operations.  (NOTE: GHC currently does not throw
 518         -- 'ArrayException's).
 519   | AssertionFailed     String
 520         -- ^This exception is thrown by the
 521         -- 'assert' operation when the condition
 522         -- fails.  The 'String' argument contains the
 523         -- location of the assertion in the source program.
 524   | AsyncException      AsyncException
 525         -- ^Asynchronous exceptions (see section on Asynchronous Exceptions: "Control.Exception\#AsynchronousExceptions").
 526   | BlockedOnDeadMVar
 527         -- ^The current thread was executing a call to
 528         -- 'takeMVar' that could never return, because there are no other
 529         -- references to this 'MVar'.
 530   | Deadlock
 531         -- ^There are no runnable threads, so the program is
 532         -- deadlocked.  The 'Deadlock' exception is
 533         -- raised in the main thread only (see also: "Control.Concurrent").
 534   | DynException        Dynamic
 535         -- ^Dynamically typed exceptions (see section on Dynamic Exceptions: "Control.Exception\#DynamicExceptions").
 536   | ErrorCall           String
 537         -- ^The 'ErrorCall' exception is thrown by 'error'.  The 'String'
 538         -- argument of 'ErrorCall' is the string passed to 'error' when it was
 539         -- called.
 540   | ExitException       ExitCode
 541         -- ^The 'ExitException' exception is thrown by 'System.exitWith' (and
 542         -- 'System.exitFailure').  The 'ExitCode' argument is the value passed
 543         -- to 'System.exitWith'.  An unhandled 'ExitException' exception in the
 544         -- main thread will cause the program to be terminated with the given
 545         -- exit code.
 546   | IOException         IOException
 547         -- ^These are the standard IO exceptions generated by
 548         -- Haskell\'s @IO@ operations.  See also "System.IO.Error".
 549   | NoMethodError       String
 550         -- ^An attempt was made to invoke a class method which has
 551         -- no definition in this instance, and there was no default
 552         -- definition given in the class declaration.  GHC issues a
 553         -- warning when you compile an instance which has missing
 554         -- methods.
 555   | NonTermination
 556         -- ^The current thread is stuck in an infinite loop.  This
 557         -- exception may or may not be thrown when the program is
 558         -- non-terminating.
 559   | PatternMatchFail    String
 560         -- ^A pattern matching failure.  The 'String' argument should contain a
 561         -- descriptive message including the function name, source file
 562         -- and line number.
 563   | RecConError         String
 564         -- ^An attempt was made to evaluate a field of a record
 565         -- for which no value was given at construction time.  The
 566         -- 'String' argument gives the location of the
 567         -- record construction in the source program.
 568   | RecSelError         String
 569         -- ^A field selection was attempted on a constructor that
 570         -- doesn\'t have the requested field.  This can happen with
 571         -- multi-constructor records when one or more fields are
 572         -- missing from some of the constructors.  The
 573         -- 'String' argument gives the location of the
 574         -- record selection in the source program.
 575   | RecUpdError         String
 576         -- ^An attempt was made to update a field in a record,
 577         -- where the record doesn\'t have the requested field.  This can
 578         -- only occur with multi-constructor records, when one or more
 579         -- fields are missing from some of the constructors.  The
 580         -- 'String' argument gives the location of the
 581         -- record update in the source program.
 582
 583 -- |The type of arithmetic exceptions
 584 data ArithException
 585   = Overflow
 586   | Underflow
 587   | LossOfPrecision
 588   | DivideByZero
 589   | Denormal
 590   deriving (Eq, Ord)
 591
 592
 593 -- |Asynchronous exceptions
 594 data AsyncException
 595   = StackOverflow
 596         -- ^The current thread\'s stack exceeded its limit.
 597         -- Since an exception has been raised, the thread\'s stack
 598         -- will certainly be below its limit again, but the
 599         -- programmer should take remedial action
 600         -- immediately.
 601   | HeapOverflow
 602         -- ^The program\'s heap is reaching its limit, and
 603         -- the program should take action to reduce the amount of
 604         -- live data it has. Notes:
 605         --
 606         --      * It is undefined which thread receives this exception.
 607         --
 608         --      * GHC currently does not throw 'HeapOverflow' exceptions.
 609   | ThreadKilled
 610         -- ^This exception is raised by another thread
 611         -- calling 'killThread', or by the system
 612         -- if it needs to terminate the thread for some
 613         -- reason.
 614   deriving (Eq, Ord)
 615
 616 -- | Exceptions generated by array operations
 617 data ArrayException
 618   = IndexOutOfBounds    String
 619         -- ^An attempt was made to index an array outside
 620         -- its declared bounds.
 621   | UndefinedElement    String
 622         -- ^An attempt was made to evaluate an element of an
 623         -- array that had not been initialized.
 624   deriving (Eq, Ord)
 625
 626 stackOverflow, heapOverflow :: Exception -- for the RTS
 627 stackOverflow = AsyncException StackOverflow
 628 heapOverflow  = AsyncException HeapOverflow
 629
 630 instance Show ArithException where
 631   showsPrec _ Overflow        = showString "arithmetic overflow"
 632   showsPrec _ Underflow       = showString "arithmetic underflow"
 633   showsPrec _ LossOfPrecision = showString "loss of precision"
 634   showsPrec _ DivideByZero    = showString "divide by zero"
 635   showsPrec _ Denormal        = showString "denormal"
 636
 637 instance Show AsyncException where
 638   showsPrec _ StackOverflow   = showString "stack overflow"
 639   showsPrec _ HeapOverflow    = showString "heap overflow"
 640   showsPrec _ ThreadKilled    = showString "thread killed"
 641
 642 instance Show ArrayException where
 643   showsPrec _ (IndexOutOfBounds s)
 644         = showString "array index out of range"
 645         . (if not (null s) then showString ": " . showString s
 646                            else id)
 647   showsPrec _ (UndefinedElement s)
 648         = showString "undefined array element"
 649         . (if not (null s) then showString ": " . showString s
 650                            else id)
 651
 652 instance Show Exception where
 653   showsPrec _ (IOException err)          = shows err
 654   showsPrec _ (ArithException err)       = shows err
 655   showsPrec _ (ArrayException err)       = shows err
 656   showsPrec _ (ErrorCall err)            = showString err
 657   showsPrec _ (ExitException err)        = showString "exit: " . shows err
 658   showsPrec _ (NoMethodError err)        = showString err
 659   showsPrec _ (PatternMatchFail err)     = showString err
 660   showsPrec _ (RecSelError err)          = showString err
 661   showsPrec _ (RecConError err)          = showString err
 662   showsPrec _ (RecUpdError err)          = showString err
 663   showsPrec _ (AssertionFailed err)      = showString err
 664   showsPrec _ (DynException _err)        = showString "unknown exception"
 665   showsPrec _ (AsyncException e)         = shows e
 666   showsPrec _ (BlockedOnDeadMVar)        = showString "thread blocked indefinitely"
 667   showsPrec _ (NonTermination)           = showString "<<loop>>"
 668   showsPrec _ (Deadlock)                 = showString "<<deadlock>>"
 669
 670 instance Eq Exception where
 671   IOException e1      == IOException e2      = e1 == e2
 672   ArithException e1   == ArithException e2   = e1 == e2
 673   ArrayException e1   == ArrayException e2   = e1 == e2
 674   ErrorCall e1        == ErrorCall e2        = e1 == e2
 675   ExitException e1    == ExitException e2    = e1 == e2
 676   NoMethodError e1    == NoMethodError e2    = e1 == e2
 677   PatternMatchFail e1 == PatternMatchFail e2 = e1 == e2
 678   RecSelError e1      == RecSelError e2      = e1 == e2
 679   RecConError e1      == RecConError e2      = e1 == e2
 680   RecUpdError e1      == RecUpdError e2      = e1 == e2
 681   AssertionFailed e1  == AssertionFailed e2  = e1 == e2
 682   DynException _      == DynException _      = False -- incomparable
 683   AsyncException e1   == AsyncException e2   = e1 == e2
 684   BlockedOnDeadMVar   == BlockedOnDeadMVar   = True
 685   NonTermination      == NonTermination      = True
 686   Deadlock            == Deadlock            = True
 687   _                   == _                   = False
 688
 689 -- -----------------------------------------------------------------------------
 690 -- The ExitCode type
 691
 692 -- The `ExitCode' type defines the exit codes that a program
 693 -- can return.  `ExitSuccess' indicates successful termination;
 694 -- and `ExitFailure code' indicates program failure
 695 -- with value `code'.  The exact interpretation of `code'
 696 -- is operating-system dependent.  In particular, some values of
 697 -- `code' may be prohibited (e.g. 0 on a POSIX-compliant system).
 698
 699 -- We need it here because it is used in ExitException in the
 700 -- Exception datatype (above).
 701
 702 data ExitCode = ExitSuccess | ExitFailure Int
 703                 deriving (Eq, Ord, Read, Show)
 704
 705 -- --------------------------------------------------------------------------
 706 -- Primitive throw
 707
 708 -- | Throw an exception.  Exceptions may be thrown from purely
 709 -- functional code, but may only be caught within the 'IO' monad.
 710 throw :: Exception -> a
 711 throw exception = raise# exception
 712
 713 -- | A variant of 'throw' that can be used within the 'IO' monad.
 714 --
 715 -- Although 'throwIO' has a type that is an instance of the type of 'throw', the
 716 -- two functions are subtly different:
 717 --
 718 -- > throw e   `seq` return ()  ===> throw e
 719 -- > throwIO e `seq` return ()  ===> return ()
 720 --
 721 -- The first example will cause the exception @e@ to be raised,
 722 -- whereas the second one won\'t.  In fact, 'throwIO' will only cause
 723 -- an exception to be raised when it is used within the 'IO' monad.
 724 -- The 'throwIO' variant should be used in preference to 'throw' to
 725 -- raise an exception within the 'IO' monad because it guarantees
 726 -- ordering with respect to other 'IO' operations, whereas 'throw'
 727 -- does not.
 728 throwIO         :: Exception -> IO a
 729 throwIO err     =  IO $ \s -> throw err s
 730
 731 ioException     :: IOException -> IO a
 732 ioException err =  IO $ \s -> throw (IOException err) s
 733
 734 ioError         :: IOError -> IO a
 735 ioError         =  ioException
 736
 737 -- ---------------------------------------------------------------------------
 738 -- IOError type
 739
 740 -- | The Haskell 98 type for exceptions in the @IO@ monad.
 741 -- In Haskell 98, this is an opaque type.
 742 type IOError = IOException
 743
 744 -- |Exceptions that occur in the @IO@ monad.
 745 -- An @IOException@ records a more specific error type, a descriptive
 746 -- string and maybe the handle that was used when the error was
 747 -- flagged.
 748 data IOException
 749  = IOError {
 750      ioe_handle   :: Maybe Handle,   -- the handle used by the action flagging
 751                                      -- the error.
 752      ioe_type     :: IOErrorType,    -- what it was.
 753      ioe_location :: String,         -- location.
 754      ioe_description :: String,      -- error type specific information.
 755      ioe_filename :: Maybe FilePath  -- filename the error is related to.
 756    }
 757
 758 instance Eq IOException where
 759   (IOError h1 e1 loc1 str1 fn1) == (IOError h2 e2 loc2 str2 fn2) =
 760     e1==e2 && str1==str2 && h1==h2 && loc1==loc2 && fn1==fn2
 761
 762 data IOErrorType
 763   -- Haskell 98:
 764   = AlreadyExists
 765   | NoSuchThing
 766   | ResourceBusy
 767   | ResourceExhausted
 768   | EOF
 769   | IllegalOperation
 770   | PermissionDenied
 771   | UserError
 772   -- GHC only:
 773   | UnsatisfiedConstraints
 774   | SystemError
 775   | ProtocolError
 776   | OtherError
 777   | InvalidArgument
 778   | InappropriateType
 779   | HardwareFault
 780   | UnsupportedOperation
 781   | TimeExpired
 782   | ResourceVanished
 783   | Interrupted
 784   | DynIOError Dynamic -- cheap&cheerful extensible IO error type.
 785
 786 instance Eq IOErrorType where
 787    x == y =
 788      case x of
 789        DynIOError{} -> False -- from a strictness POV, compatible with a derived Eq inst?
 790        _ -> getTag x ==# getTag y
 791
 792 instance Show IOErrorType where
 793   showsPrec _ e =
 794     showString $
 795     case e of
 796       AlreadyExists     -> "already exists"
 797       NoSuchThing       -> "does not exist"
 798       ResourceBusy      -> "resource busy"
 799       ResourceExhausted -> "resource exhausted"
 800       EOF               -> "end of file"
 801       IllegalOperation  -> "illegal operation"
 802       PermissionDenied  -> "permission denied"
 803       UserError         -> "user error"
 804       HardwareFault     -> "hardware fault"
 805       InappropriateType -> "inappropriate type"
 806       Interrupted       -> "interrupted"
 807       InvalidArgument   -> "invalid argument"
 808       OtherError        -> "failed"
 809       ProtocolError     -> "protocol error"
 810       ResourceVanished  -> "resource vanished"
 811       SystemError       -> "system error"
 812       TimeExpired       -> "timeout"
 813       UnsatisfiedConstraints -> "unsatisified constraints" -- ultra-precise!
 814       UnsupportedOperation -> "unsupported operation"
 815       DynIOError{}      -> "unknown IO error"
 816
 817 userError       :: String  -> IOError
 818 userError str   =  IOError Nothing UserError "" str Nothing
 819
 820 -- ---------------------------------------------------------------------------
 821 -- Showing IOErrors
 822
 823 instance Show IOException where
 824     showsPrec p (IOError hdl iot loc s fn) =
 825       showsPrec p iot .
 826       (case loc of
 827          "" -> id
 828          _  -> showString "\nAction: " . showString loc) .
 829       (case hdl of
 830         Nothing -> id
 831         Just h  -> showString "\nHandle: " . showsPrec p h) .
 832       (case s of
 833          "" -> id
 834          _  -> showString "\nReason: " . showString s) .
 835       (case fn of
 836          Nothing -> id
 837          Just name -> showString "\nFile: " . showString name)
 838
 839 -- -----------------------------------------------------------------------------
 840 -- IOMode type
 841
 842 data IOMode      =  ReadMode | WriteMode | AppendMode | ReadWriteMode
 843                     deriving (Eq, Ord, Ix, Enum, Read, Show)
 844 \end{code}