GHC/List.lhs

   1 \begin{code}
   2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.List
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- The List data type and its operations
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 -- #hide
  18 module GHC.List (
  19    -- [] (..),          -- Not Haskell 98; built in syntax
  20
  21    map, (++), filter, concat,
  22    head, last, tail, init, null, length, (!!),
  23    foldl, scanl, scanl1, foldr, foldr1, scanr, scanr1,
  24    iterate, repeat, replicate, cycle,
  25    take, drop, splitAt, takeWhile, dropWhile, span, break,
  26    reverse, and, or,
  27    any, all, elem, notElem, lookup,
  28    concatMap,
  29    zip, zip3, zipWith, zipWith3, unzip, unzip3,
  30    errorEmptyList,
  31
  32 #ifndef USE_REPORT_PRELUDE
  33    -- non-standard, but hidden when creating the Prelude
  34    -- export list.
  35    takeUInt_append
  36 #endif
  37
  38  ) where
  39
  40 import {-# SOURCE #-} GHC.Err ( error )
  41 import Data.Tuple()     -- Instances
  42 import Data.Maybe
  43 import GHC.Base
  44
  45 infixl 9  !!
  46 infix  4 `elem`, `notElem`
  47 \end{code}
  48
  49 %*********************************************************
  50 %*                                                      *
  51 \subsection{List-manipulation functions}
  52 %*                                                      *
  53 %*********************************************************
  54
  55 \begin{code}
  56 -- | Extract the first element of a list, which must be non-empty.
  57 head                    :: [a] -> a
  58 head (x:_)              =  x
  59 head []                 =  badHead
  60
  61 badHead = errorEmptyList "head"
  62
  63 -- This rule is useful in cases like
  64 --      head [y | (x,y) <- ps, x==t]
  65 {-# RULES
  66 "head/build"    forall (g::forall b.(a->b->b)->b->b) .
  67                 head (build g) = g (\x _ -> x) badHead
  68 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) .
  69                 head (augment g xs) = g (\x _ -> x) (head xs)
  70  #-}
  71
  72 -- | Extract the elements after the head of a list, which must be non-empty.
  73 tail                    :: [a] -> [a]
  74 tail (_:xs)             =  xs
  75 tail []                 =  errorEmptyList "tail"
  76
  77 -- | Extract the last element of a list, which must be finite and non-empty.
  78 last                    :: [a] -> a
  79 #ifdef USE_REPORT_PRELUDE
  80 last [x]                =  x
  81 last (_:xs)             =  last xs
  82 last []                 =  errorEmptyList "last"
  83 #else
  84 -- eliminate repeated cases
  85 last []                 =  errorEmptyList "last"
  86 last (x:xs)             =  last' x xs
  87   where last' y []     = y
  88         last' _ (y:ys) = last' y ys
  89 #endif
  90
  91 -- | Return all the elements of a list except the last one.
  92 -- The list must be finite and non-empty.
  93 init                    :: [a] -> [a]
  94 #ifdef USE_REPORT_PRELUDE
  95 init [x]                =  []
  96 init (x:xs)             =  x : init xs
  97 init []                 =  errorEmptyList "init"
  98 #else
  99 -- eliminate repeated cases
 100 init []                 =  errorEmptyList "init"
 101 init (x:xs)             =  init' x xs
 102   where init' _ []     = []
 103         init' y (z:zs) = y : init' z zs
 104 #endif
 105
 106 -- | Test whether a list is empty.
 107 null                    :: [a] -> Bool
 108 null []                 =  True
 109 null (_:_)              =  False
 110
 111 -- | 'length' returns the length of a finite list as an 'Int'.
 112 -- It is an instance of the more general 'Data.List.genericLength',
 113 -- the result type of which may be any kind of number.
 114 length                  :: [a] -> Int
 115 length l                =  len l 0#
 116   where
 117     len :: [a] -> Int# -> Int
 118     len []     a# = I# a#
 119     len (_:xs) a# = len xs (a# +# 1#)
 120
 121 -- | 'filter', applied to a predicate and a list, returns the list of
 122 -- those elements that satisfy the predicate; i.e.,
 123 --
 124 -- > filter p xs = [ x | x <- xs, p x]
 125
 126 filter :: (a -> Bool) -> [a] -> [a]
 127 filter _pred []    = []
 128 filter pred (x:xs)
 129   | pred x         = x : filter pred xs
 130   | otherwise      = filter pred xs
 131
 132 {-# NOINLINE [0] filterFB #-}
 133 filterFB c p x r | p x       = x `c` r
 134                  | otherwise = r
 135
 136 {-# RULES
 137 "filter"     [~1] forall p xs.  filter p xs = build (\c n -> foldr (filterFB c p) n xs)
 138 "filterList" [1]  forall p.     foldr (filterFB (:) p) [] = filter p
 139 "filterFB"        forall c p q. filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
 140  #-}
 141
 142 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
 143 --     filterFB (filterFB c p) q a b
 144 --   = if q a then filterFB c p a b else b
 145 --   = if q a then (if p a then c a b else b) else b
 146 --   = if q a && p a then c a b else b
 147 --   = filterFB c (\x -> q x && p x) a b
 148 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
 149 -- gave rise to a live bug report.  SLPJ.
 150
 151
 152 -- | 'foldl', applied to a binary operator, a starting value (typically
 153 -- the left-identity of the operator), and a list, reduces the list
 154 -- using the binary operator, from left to right:
 155 --
 156 -- > foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
 157 --
 158 -- The list must be finite.
 159
 160 -- We write foldl as a non-recursive thing, so that it
 161 -- can be inlined, and then (often) strictness-analysed,
 162 -- and hence the classic space leak on foldl (+) 0 xs
 163
 164 foldl        :: (a -> b -> a) -> a -> [b] -> a
 165 foldl f z xs = lgo z xs
 166              where
 167                 lgo z []     =  z
 168                 lgo z (x:xs) = lgo (f z x) xs
 169
 170 -- | 'scanl' is similar to 'foldl', but returns a list of successive
 171 -- reduced values from the left:
 172 --
 173 -- > scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
 174 --
 175 -- Note that
 176 --
 177 -- > last (scanl f z xs) == foldl f z xs.
 178
 179 scanl                   :: (a -> b -> a) -> a -> [b] -> [a]
 180 scanl f q ls            =  q : (case ls of
 181                                 []   -> []
 182                                 x:xs -> scanl f (f q x) xs)
 183
 184 -- | 'scanl1' is a variant of 'scanl' that has no starting value argument:
 185 --
 186 -- > scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
 187
 188 scanl1                  :: (a -> a -> a) -> [a] -> [a]
 189 scanl1 f (x:xs)         =  scanl f x xs
 190 scanl1 _ []             =  []
 191
 192 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
 193 -- above functions.
 194
 195 -- | 'foldr1' is a variant of 'foldr' that has no starting value argument,
 196 -- and thus must be applied to non-empty lists.
 197
 198 foldr1                  :: (a -> a -> a) -> [a] -> a
 199 foldr1 _ [x]            =  x
 200 foldr1 f (x:xs)         =  f x (foldr1 f xs)
 201 foldr1 _ []             =  errorEmptyList "foldr1"
 202
 203 -- | 'scanr' is the right-to-left dual of 'scanl'.
 204 -- Note that
 205 --
 206 -- > head (scanr f z xs) == foldr f z xs.
 207
 208 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
 209 scanr _ q0 []           =  [q0]
 210 scanr f q0 (x:xs)       =  f x q : qs
 211                            where qs@(q:_) = scanr f q0 xs
 212
 213 -- | 'scanr1' is a variant of 'scanr' that has no starting value argument.
 214
 215 scanr1                  :: (a -> a -> a) -> [a] -> [a]
 216 scanr1 f []             =  []
 217 scanr1 f [x]            =  [x]
 218 scanr1 f (x:xs)         =  f x q : qs
 219                            where qs@(q:_) = scanr1 f xs
 220
 221 -- | 'iterate' @f x@ returns an infinite list of repeated applications
 222 -- of @f@ to @x@:
 223 --
 224 -- > iterate f x == [x, f x, f (f x), ...]
 225
 226 iterate :: (a -> a) -> a -> [a]
 227 iterate f x =  x : iterate f (f x)
 228
 229 iterateFB c f x = x `c` iterateFB c f (f x)
 230
 231
 232 {-# RULES
 233 "iterate"    [~1] forall f x.   iterate f x = build (\c _n -> iterateFB c f x)
 234 "iterateFB"  [1]                iterateFB (:) = iterate
 235  #-}
 236
 237
 238 -- | 'repeat' @x@ is an infinite list, with @x@ the value of every element.
 239 repeat :: a -> [a]
 240 {-# INLINE [0] repeat #-}
 241 -- The pragma just gives the rules more chance to fire
 242 repeat x = xs where xs = x : xs
 243
 244 {-# INLINE [0] repeatFB #-}     -- ditto
 245 repeatFB c x = xs where xs = x `c` xs
 246
 247
 248 {-# RULES
 249 "repeat"    [~1] forall x. repeat x = build (\c _n -> repeatFB c x)
 250 "repeatFB"  [1]  repeatFB (:)       = repeat
 251  #-}
 252
 253 -- | 'replicate' @n x@ is a list of length @n@ with @x@ the value of
 254 -- every element.
 255 -- It is an instance of the more general 'Data.List.genericReplicate',
 256 -- in which @n@ may be of any integral type.
 257 {-# INLINE replicate #-}
 258 replicate               :: Int -> a -> [a]
 259 replicate n x           =  take n (repeat x)
 260
 261 -- | 'cycle' ties a finite list into a circular one, or equivalently,
 262 -- the infinite repetition of the original list.  It is the identity
 263 -- on infinite lists.
 264
 265 cycle                   :: [a] -> [a]
 266 cycle []                = error "Prelude.cycle: empty list"
 267 cycle xs                = xs' where xs' = xs ++ xs'
 268
 269 -- | 'takeWhile', applied to a predicate @p@ and a list @xs@, returns the
 270 -- longest prefix (possibly empty) of @xs@ of elements that satisfy @p@:
 271 --
 272 -- > takeWhile (< 3) [1,2,3,4,1,2,3,4] == [1,2]
 273 -- > takeWhile (< 9) [1,2,3] == [1,2,3]
 274 -- > takeWhile (< 0) [1,2,3] == []
 275 --
 276
 277 takeWhile               :: (a -> Bool) -> [a] -> [a]
 278 takeWhile _ []          =  []
 279 takeWhile p (x:xs)
 280             | p x       =  x : takeWhile p xs
 281             | otherwise =  []
 282
 283 -- | 'dropWhile' @p xs@ returns the suffix remaining after 'takeWhile' @p xs@:
 284 --
 285 -- > dropWhile (< 3) [1,2,3,4,5,1,2,3] == [3,4,5,1,2,3]
 286 -- > dropWhile (< 9) [1,2,3] == []
 287 -- > dropWhile (< 0) [1,2,3] == [1,2,3]
 288 --
 289
 290 dropWhile               :: (a -> Bool) -> [a] -> [a]
 291 dropWhile _ []          =  []
 292 dropWhile p xs@(x:xs')
 293             | p x       =  dropWhile p xs'
 294             | otherwise =  xs
 295
 296 -- | 'take' @n@, applied to a list @xs@, returns the prefix of @xs@
 297 -- of length @n@, or @xs@ itself if @n > 'length' xs@:
 298 --
 299 -- > take 5 "Hello World!" == "Hello"
 300 -- > take 3 [1,2,3,4,5] == [1,2,3]
 301 -- > take 3 [1,2] == [1,2]
 302 -- > take 3 [] == []
 303 -- > take (-1) [1,2] == []
 304 -- > take 0 [1,2] == []
 305 --
 306 -- It is an instance of the more general 'Data.List.genericTake',
 307 -- in which @n@ may be of any integral type.
 308 take                   :: Int -> [a] -> [a]
 309
 310 -- | 'drop' @n xs@ returns the suffix of @xs@
 311 -- after the first @n@ elements, or @[]@ if @n > 'length' xs@:
 312 --
 313 -- > drop 6 "Hello World!" == "World!"
 314 -- > drop 3 [1,2,3,4,5] == [4,5]
 315 -- > drop 3 [1,2] == []
 316 -- > drop 3 [] == []
 317 -- > drop (-1) [1,2] == [1,2]
 318 -- > drop 0 [1,2] == [1,2]
 319 --
 320 -- It is an instance of the more general 'Data.List.genericDrop',
 321 -- in which @n@ may be of any integral type.
 322 drop                   :: Int -> [a] -> [a]
 323
 324 -- | 'splitAt' @n xs@ returns a tuple where first element is @xs@ prefix of
 325 -- length @n@ and second element is the remainder of the list:
 326 --
 327 -- > splitAt 6 "Hello World!" == ("Hello ","World!")
 328 -- > splitAt 3 [1,2,3,4,5] == ([1,2,3],[4,5])
 329 -- > splitAt 1 [1,2,3] == ([1],[2,3])
 330 -- > splitAt 3 [1,2,3] == ([1,2,3],[])
 331 -- > splitAt 4 [1,2,3] == ([1,2,3],[])
 332 -- > splitAt 0 [1,2,3] == ([],[1,2,3])
 333 -- > splitAt (-1) [1,2,3] == ([],[1,2,3])
 334 --
 335 -- It is equivalent to @('take' n xs, 'drop' n xs)@.
 336 -- 'splitAt' is an instance of the more general 'Data.List.genericSplitAt',
 337 -- in which @n@ may be of any integral type.
 338 splitAt                :: Int -> [a] -> ([a],[a])
 339
 340 #ifdef USE_REPORT_PRELUDE
 341 take n _      | n <= 0 =  []
 342 take _ []              =  []
 343 take n (x:xs)          =  x : take (n-1) xs
 344
 345 drop n xs     | n <= 0 =  xs
 346 drop _ []              =  []
 347 drop n (_:xs)          =  drop (n-1) xs
 348
 349 splitAt n xs           =  (take n xs, drop n xs)
 350
 351 #else /* hack away */
 352 {-# RULES
 353 "take"     [~1] forall n xs . take n xs = case n of I# n# -> build (\c nil -> foldr (takeFB c nil) (takeConst nil) xs n#)
 354 "takeList"  [1] forall n xs . foldr (takeFB (:) []) (takeConst []) xs n = takeUInt n xs
 355  #-}
 356
 357 {-# NOINLINE [0] takeConst #-}
 358 -- just a version of const that doesn't get inlined too early, so we
 359 -- can spot it in rules.  Also we need a type sig due to the unboxed Int#.
 360 takeConst :: a -> Int# -> a
 361 takeConst x _ = x
 362
 363 {-# NOINLINE [0] takeFB #-}
 364 takeFB :: (a -> b -> c) -> c -> a -> (Int# -> b) -> Int# -> c
 365 takeFB c n x xs m | m <=# 0#  = n
 366                   | otherwise = x `c` xs (m -# 1#)
 367
 368 {-# INLINE [0] take #-}
 369 take (I# n#) xs = takeUInt n# xs
 370
 371 -- The general code for take, below, checks n <= maxInt
 372 -- No need to check for maxInt overflow when specialised
 373 -- at type Int or Int# since the Int must be <= maxInt
 374
 375 takeUInt :: Int# -> [b] -> [b]
 376 takeUInt n xs
 377   | n >=# 0#  =  take_unsafe_UInt n xs
 378   | otherwise =  []
 379
 380 take_unsafe_UInt :: Int# -> [b] -> [b]
 381 take_unsafe_UInt 0#  _  = []
 382 take_unsafe_UInt m   ls =
 383   case ls of
 384     []     -> []
 385     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
 386
 387 takeUInt_append :: Int# -> [b] -> [b] -> [b]
 388 takeUInt_append n xs rs
 389   | n >=# 0#  =  take_unsafe_UInt_append n xs rs
 390   | otherwise =  []
 391
 392 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
 393 take_unsafe_UInt_append 0#  _ rs  = rs
 394 take_unsafe_UInt_append m  ls rs  =
 395   case ls of
 396     []     -> rs
 397     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
 398
 399 drop (I# n#) ls
 400   | n# <# 0#    = ls
 401   | otherwise   = drop# n# ls
 402     where
 403         drop# :: Int# -> [a] -> [a]
 404         drop# 0# xs      = xs
 405         drop# _  xs@[]   = xs
 406         drop# m# (_:xs)  = drop# (m# -# 1#) xs
 407
 408 splitAt (I# n#) ls
 409   | n# <# 0#    = ([], ls)
 410   | otherwise   = splitAt# n# ls
 411     where
 412         splitAt# :: Int# -> [a] -> ([a], [a])
 413         splitAt# 0# xs     = ([], xs)
 414         splitAt# _  xs@[]  = (xs, xs)
 415         splitAt# m# (x:xs) = (x:xs', xs'')
 416           where
 417             (xs', xs'') = splitAt# (m# -# 1#) xs
 418
 419 #endif /* USE_REPORT_PRELUDE */
 420
 421 -- | 'span', applied to a predicate @p@ and a list @xs@, returns a tuple where
 422 -- first element is longest prefix (possibly empty) of @xs@ of elements that
 423 -- satisfy @p@ and second element is the remainder of the list:
 424 --
 425 -- > span (< 3) [1,2,3,4,1,2,3,4] == ([1,2],[3,4,1,2,3,4])
 426 -- > span (< 9) [1,2,3] == ([1,2,3],[])
 427 -- > span (< 0) [1,2,3] == ([],[1,2,3])
 428 --
 429 -- 'span' @p xs@ is equivalent to @('takeWhile' p xs, 'dropWhile' p xs)@
 430
 431 span                    :: (a -> Bool) -> [a] -> ([a],[a])
 432 span _ xs@[]            =  (xs, xs)
 433 span p xs@(x:xs')
 434          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
 435          | otherwise    =  ([],xs)
 436
 437 -- | 'break', applied to a predicate @p@ and a list @xs@, returns a tuple where
 438 -- first element is longest prefix (possibly empty) of @xs@ of elements that
 439 -- /do not satisfy/ @p@ and second element is the remainder of the list:
 440 --
 441 -- > break (> 3) [1,2,3,4,1,2,3,4] == ([1,2,3],[4,1,2,3,4])
 442 -- > break (< 9) [1,2,3] == ([],[1,2,3])
 443 -- > break (> 9) [1,2,3] == ([1,2,3],[])
 444 --
 445 -- 'break' @p@ is equivalent to @'span' ('not' . p)@.
 446
 447 break                   :: (a -> Bool) -> [a] -> ([a],[a])
 448 #ifdef USE_REPORT_PRELUDE
 449 break p                 =  span (not . p)
 450 #else
 451 -- HBC version (stolen)
 452 break _ xs@[]           =  (xs, xs)
 453 break p xs@(x:xs')
 454            | p x        =  ([],xs)
 455            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
 456 #endif
 457
 458 -- | 'reverse' @xs@ returns the elements of @xs@ in reverse order.
 459 -- @xs@ must be finite.
 460 reverse                 :: [a] -> [a]
 461 #ifdef USE_REPORT_PRELUDE
 462 reverse                 =  foldl (flip (:)) []
 463 #else
 464 reverse l =  rev l []
 465   where
 466     rev []     a = a
 467     rev (x:xs) a = rev xs (x:a)
 468 #endif
 469
 470 -- | 'and' returns the conjunction of a Boolean list.  For the result to be
 471 -- 'True', the list must be finite; 'False', however, results from a 'False'
 472 -- value at a finite index of a finite or infinite list.
 473 and                     :: [Bool] -> Bool
 474
 475 -- | 'or' returns the disjunction of a Boolean list.  For the result to be
 476 -- 'False', the list must be finite; 'True', however, results from a 'True'
 477 -- value at a finite index of a finite or infinite list.
 478 or                      :: [Bool] -> Bool
 479 #ifdef USE_REPORT_PRELUDE
 480 and                     =  foldr (&&) True
 481 or                      =  foldr (||) False
 482 #else
 483 and []          =  True
 484 and (x:xs)      =  x && and xs
 485 or []           =  False
 486 or (x:xs)       =  x || or xs
 487
 488 {-# RULES
 489 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) .
 490                 and (build g) = g (&&) True
 491 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) .
 492                 or (build g) = g (||) False
 493  #-}
 494 #endif
 495
 496 -- | Applied to a predicate and a list, 'any' determines if any element
 497 -- of the list satisfies the predicate.
 498 any                     :: (a -> Bool) -> [a] -> Bool
 499
 500 -- | Applied to a predicate and a list, 'all' determines if all elements
 501 -- of the list satisfy the predicate.
 502 all                     :: (a -> Bool) -> [a] -> Bool
 503 #ifdef USE_REPORT_PRELUDE
 504 any p                   =  or . map p
 505 all p                   =  and . map p
 506 #else
 507 any _ []        = False
 508 any p (x:xs)    = p x || any p xs
 509
 510 all _ []        =  True
 511 all p (x:xs)    =  p x && all p xs
 512 {-# RULES
 513 "any/build"     forall p (g::forall b.(a->b->b)->b->b) .
 514                 any p (build g) = g ((||) . p) False
 515 "all/build"     forall p (g::forall b.(a->b->b)->b->b) .
 516                 all p (build g) = g ((&&) . p) True
 517  #-}
 518 #endif
 519
 520 -- | 'elem' is the list membership predicate, usually written in infix form,
 521 -- e.g., @x `elem` xs@.
 522 elem                    :: (Eq a) => a -> [a] -> Bool
 523
 524 -- | 'notElem' is the negation of 'elem'.
 525 notElem                 :: (Eq a) => a -> [a] -> Bool
 526 #ifdef USE_REPORT_PRELUDE
 527 elem x                  =  any (== x)
 528 notElem x               =  all (/= x)
 529 #else
 530 elem _ []       = False
 531 elem x (y:ys)   = x==y || elem x ys
 532
 533 notElem _ []    =  True
 534 notElem x (y:ys)=  x /= y && notElem x ys
 535 #endif
 536
 537 -- | 'lookup' @key assocs@ looks up a key in an association list.
 538 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
 539 lookup _key []          =  Nothing
 540 lookup  key ((x,y):xys)
 541     | key == x          =  Just y
 542     | otherwise         =  lookup key xys
 543
 544 -- | Map a function over a list and concatenate the results.
 545 concatMap               :: (a -> [b]) -> [a] -> [b]
 546 concatMap f             =  foldr ((++) . f) []
 547
 548 -- | Concatenate a list of lists.
 549 concat :: [[a]] -> [a]
 550 concat = foldr (++) []
 551
 552 {-# RULES
 553   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
 554 -- We don't bother to turn non-fusible applications of concat back into concat
 555  #-}
 556
 557 \end{code}
 558
 559
 560 \begin{code}
 561 -- | List index (subscript) operator, starting from 0.
 562 -- It is an instance of the more general 'Data.List.genericIndex',
 563 -- which takes an index of any integral type.
 564 (!!)                    :: [a] -> Int -> a
 565 #ifdef USE_REPORT_PRELUDE
 566 xs     !! n | n < 0 =  error "Prelude.!!: negative index"
 567 []     !! _         =  error "Prelude.!!: index too large"
 568 (x:_)  !! 0         =  x
 569 (_:xs) !! n         =  xs !! (n-1)
 570 #else
 571 -- HBC version (stolen), then unboxified
 572 -- The semantics is not quite the same for error conditions
 573 -- in the more efficient version.
 574 --
 575 xs !! (I# n) | n <# 0#   =  error "Prelude.(!!): negative index\n"
 576              | otherwise =  sub xs n
 577                          where
 578                             sub :: [a] -> Int# -> a
 579                             sub []     _ = error "Prelude.(!!): index too large\n"
 580                             sub (y:ys) n = if n ==# 0#
 581                                            then y
 582                                            else sub ys (n -# 1#)
 583 #endif
 584 \end{code}
 585
 586
 587 %*********************************************************
 588 %*                                                      *
 589 \subsection{The zip family}
 590 %*                                                      *
 591 %*********************************************************
 592
 593 \begin{code}
 594 foldr2 _k z []    _ys    = z
 595 foldr2 _k z _xs   []     = z
 596 foldr2 k z (x:xs) (y:ys) = k x y (foldr2 k z xs ys)
 597
 598 foldr2_left _k  z _x _r []     = z
 599 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
 600
 601 foldr2_right _k z  _y _r []     = z
 602 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
 603
 604 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
 605 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
 606 {-# RULES
 607 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) .
 608                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
 609
 610 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) .
 611                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
 612  #-}
 613 \end{code}
 614
 615 The foldr2/right rule isn't exactly right, because it changes
 616 the strictness of foldr2 (and thereby zip)
 617
 618 E.g. main = print (null (zip nonobviousNil (build undefined)))
 619           where   nonobviousNil = f 3
 620                   f n = if n == 0 then [] else f (n-1)
 621
 622 I'm going to leave it though.
 623
 624
 625 Zips for larger tuples are in the List module.
 626
 627 \begin{code}
 628 ----------------------------------------------
 629 -- | 'zip' takes two lists and returns a list of corresponding pairs.
 630 -- If one input list is short, excess elements of the longer list are
 631 -- discarded.
 632 zip :: [a] -> [b] -> [(a,b)]
 633 zip (a:as) (b:bs) = (a,b) : zip as bs
 634 zip _      _      = []
 635
 636 {-# INLINE [0] zipFB #-}
 637 zipFB c x y r = (x,y) `c` r
 638
 639 {-# RULES
 640 "zip"      [~1] forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
 641 "zipList"  [1]  foldr2 (zipFB (:)) []   = zip
 642  #-}
 643 \end{code}
 644
 645 \begin{code}
 646 ----------------------------------------------
 647 -- | 'zip3' takes three lists and returns a list of triples, analogous to
 648 -- 'zip'.
 649 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
 650 -- Specification
 651 -- zip3 =  zipWith3 (,,)
 652 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
 653 zip3 _      _      _      = []
 654 \end{code}
 655
 656
 657 -- The zipWith family generalises the zip family by zipping with the
 658 -- function given as the first argument, instead of a tupling function.
 659
 660 \begin{code}
 661 ----------------------------------------------
 662 -- | 'zipWith' generalises 'zip' by zipping with the function given
 663 -- as the first argument, instead of a tupling function.
 664 -- For example, @'zipWith' (+)@ is applied to two lists to produce the
 665 -- list of corresponding sums.
 666 zipWith :: (a->b->c) -> [a]->[b]->[c]
 667 zipWith f (a:as) (b:bs) = f a b : zipWith f as bs
 668 zipWith _ _      _      = []
 669
 670 {-# INLINE [0] zipWithFB #-}
 671 zipWithFB c f x y r = (x `f` y) `c` r
 672
 673 {-# RULES
 674 "zipWith"       [~1] forall f xs ys.    zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
 675 "zipWithList"   [1]  forall f.  foldr2 (zipWithFB (:) f) [] = zipWith f
 676   #-}
 677 \end{code}
 678
 679 \begin{code}
 680 -- | The 'zipWith3' function takes a function which combines three
 681 -- elements, as well as three lists and returns a list of their point-wise
 682 -- combination, analogous to 'zipWith'.
 683 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
 684 zipWith3 z (a:as) (b:bs) (c:cs)
 685                         =  z a b c : zipWith3 z as bs cs
 686 zipWith3 _ _ _ _        =  []
 687
 688 -- | 'unzip' transforms a list of pairs into a list of first components
 689 -- and a list of second components.
 690 unzip    :: [(a,b)] -> ([a],[b])
 691 {-# INLINE unzip #-}
 692 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
 693
 694 -- | The 'unzip3' function takes a list of triples and returns three
 695 -- lists, analogous to 'unzip'.
 696 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
 697 {-# INLINE unzip3 #-}
 698 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
 699                   ([],[],[])
 700 \end{code}
 701
 702
 703 %*********************************************************
 704 %*                                                      *
 705 \subsection{Error code}
 706 %*                                                      *
 707 %*********************************************************
 708
 709 Common up near identical calls to `error' to reduce the number
 710 constant strings created when compiled:
 711
 712 \begin{code}
 713 errorEmptyList :: String -> a
 714 errorEmptyList fun =
 715   error (prel_list_str ++ fun ++ ": empty list")
 716
 717 prel_list_str :: String
 718 prel_list_str = "Prelude."
 719 \end{code}