GHC/Num.lhs

   1 \begin{code}
   2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.Num
   6 -- Copyright   :  (c) The University of Glasgow 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- The 'Num' class and the 'Integer' type.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 #include "MachDeps.h"
  18 #if SIZEOF_HSWORD == 4
  19 #define LEFTMOST_BIT 2147483648
  20 #define DIGITS       9
  21 #define BASE         1000000000
  22 #elif SIZEOF_HSWORD == 8
  23 #define LEFTMOST_BIT 9223372036854775808
  24 #define DIGITS       18
  25 #define BASE         1000000000000000000
  26 #else
  27 #error Please define LEFTMOST_BIT to be 2^(SIZEOF_HSWORD*8-1)
  28 -- DIGITS should be the largest integer such that 10^DIGITS < LEFTMOST_BIT
  29 -- BASE should be 10^DIGITS. Note that ^ is not available yet.
  30 #endif
  31
  32 -- #hide
  33 module GHC.Num where
  34
  35 import GHC.Base
  36 import GHC.Enum
  37 import GHC.Show
  38
  39 infixl 7  *
  40 infixl 6  +, -
  41
  42 default ()              -- Double isn't available yet,
  43                         -- and we shouldn't be using defaults anyway
  44 \end{code}
  45
  46 %*********************************************************
  47 %*                                                      *
  48 \subsection{Standard numeric class}
  49 %*                                                      *
  50 %*********************************************************
  51
  52 \begin{code}
  53 -- | Basic numeric class.
  54 --
  55 -- Minimal complete definition: all except 'negate' or @(-)@
  56 class  (Eq a, Show a) => Num a  where
  57     (+), (-), (*)       :: a -> a -> a
  58     -- | Unary negation.
  59     negate              :: a -> a
  60     -- | Absolute value.
  61     abs                 :: a -> a
  62     -- | Sign of a number.
  63     -- The functions 'abs' and 'signum' should satisfy the law:
  64     --
  65     -- > abs x * signum x == x
  66     --
  67     -- For real numbers, the 'signum' is either @-1@ (negative), @0@ (zero)
  68     -- or @1@ (positive).
  69     signum              :: a -> a
  70     -- | Conversion from an 'Integer'.
  71     -- An integer literal represents the application of the function
  72     -- 'fromInteger' to the appropriate value of type 'Integer',
  73     -- so such literals have type @('Num' a) => a@.
  74     fromInteger         :: Integer -> a
  75
  76     x - y               = x + negate y
  77     negate x            = 0 - x
  78
  79 -- | the same as @'flip' ('-')@.
  80 --
  81 -- Because @-@ is treated specially in the Haskell grammar,
  82 -- @(-@ /e/@)@ is not a section, but an application of prefix negation.
  83 -- However, @('subtract'@ /exp/@)@ is equivalent to the disallowed section.
  84 {-# INLINE subtract #-}
  85 subtract :: (Num a) => a -> a -> a
  86 subtract x y = y - x
  87 \end{code}
  88
  89
  90 %*********************************************************
  91 %*                                                      *
  92 \subsection{Instances for @Int@}
  93 %*                                                      *
  94 %*********************************************************
  95
  96 \begin{code}
  97 instance  Num Int  where
  98     (+)    = plusInt
  99     (-)    = minusInt
 100     negate = negateInt
 101     (*)    = timesInt
 102     abs n  = if n `geInt` 0 then n else negateInt n
 103
 104     signum n | n `ltInt` 0 = negateInt 1
 105              | n `eqInt` 0 = 0
 106              | otherwise   = 1
 107
 108     fromInteger = integer2Int
 109
 110 quotRemInt :: Int -> Int -> (Int, Int)
 111 quotRemInt a@(I# _) b@(I# _) = (a `quotInt` b, a `remInt` b)
 112     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
 113
 114 divModInt ::  Int -> Int -> (Int, Int)
 115 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
 116     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
 117 \end{code}
 118
 119 %*********************************************************
 120 %*                                                      *
 121 \subsection{The @Integer@ type}
 122 %*                                                      *
 123 %*********************************************************
 124
 125 \begin{code}
 126 -- | Arbitrary-precision integers.
 127 data Integer
 128    = S# Int#                            -- small integers
 129 #ifndef ILX
 130    | J# Int# ByteArray#                 -- large integers
 131 #else
 132    | J# Void BigInteger                 -- .NET big ints
 133
 134 foreign type dotnet "BigInteger" BigInteger
 135 #endif
 136 \end{code}
 137
 138 Convenient boxed Integer PrimOps.
 139
 140 \begin{code}
 141 zeroInteger :: Integer
 142 zeroInteger = S# 0#
 143
 144 int2Integer :: Int -> Integer
 145 {-# INLINE int2Integer #-}
 146 int2Integer (I# i) = S# i
 147
 148 integer2Int :: Integer -> Int
 149 integer2Int (S# i)   = I# i
 150 integer2Int (J# s d) = case (integer2Int# s d) of { n# -> I# n# }
 151
 152 toBig (S# i)     = case int2Integer# i of { (# s, d #) -> J# s d }
 153 toBig i@(J# _ _) = i
 154 \end{code}
 155
 156
 157 %*********************************************************
 158 %*                                                      *
 159 \subsection{Dividing @Integers@}
 160 %*                                                      *
 161 %*********************************************************
 162
 163 \begin{code}
 164 quotRemInteger :: Integer -> Integer -> (Integer, Integer)
 165 quotRemInteger a@(S# (-LEFTMOST_BIT#)) b = quotRemInteger (toBig a) b
 166 quotRemInteger (S# i) (S# j)
 167   = case quotRemInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j )
 168 quotRemInteger i1@(J# _ _) i2@(S# _) = quotRemInteger i1 (toBig i2)
 169 quotRemInteger i1@(S# _) i2@(J# _ _) = quotRemInteger (toBig i1) i2
 170 quotRemInteger (J# s1 d1) (J# s2 d2)
 171   = case (quotRemInteger# s1 d1 s2 d2) of
 172           (# s3, d3, s4, d4 #)
 173             -> (J# s3 d3, J# s4 d4)
 174
 175 divModInteger a@(S# (-LEFTMOST_BIT#)) b = divModInteger (toBig a) b
 176 divModInteger (S# i) (S# j)
 177   = case divModInt (I# i) (I# j) of ( I# i, I# j ) -> ( S# i, S# j)
 178 divModInteger i1@(J# _ _) i2@(S# _) = divModInteger i1 (toBig i2)
 179 divModInteger i1@(S# _) i2@(J# _ _) = divModInteger (toBig i1) i2
 180 divModInteger (J# s1 d1) (J# s2 d2)
 181   = case (divModInteger# s1 d1 s2 d2) of
 182           (# s3, d3, s4, d4 #)
 183             -> (J# s3 d3, J# s4 d4)
 184
 185 remInteger :: Integer -> Integer -> Integer
 186 remInteger ia ib
 187  | ib == 0 = error "Prelude.Integral.rem{Integer}: divide by 0"
 188 remInteger a@(S# (-LEFTMOST_BIT#)) b = remInteger (toBig a) b
 189 remInteger (S# a) (S# b) = S# (remInt# a b)
 190 {- Special case doesn't work, because a 1-element J# has the range
 191    -(2^32-1) -- 2^32-1, whereas S# has the range -2^31 -- (2^31-1)
 192 remInteger ia@(S# a) (J# sb b)
 193   | sb ==# 1#  = S# (remInt# a (word2Int# (integer2Word# sb b)))
 194   | sb ==# -1# = S# (remInt# a (0# -# (word2Int# (integer2Word# sb b))))
 195   | 0# <# sb   = ia
 196   | otherwise  = S# (0# -# a)
 197 -}
 198 remInteger ia@(S# _) ib@(J# _ _) = remInteger (toBig ia) ib
 199 remInteger (J# sa a) (S# b)
 200   = case int2Integer# b of { (# sb, b #) ->
 201     case remInteger# sa a sb b of { (# sr, r #) ->
 202     S# (integer2Int# sr r) }}
 203 remInteger (J# sa a) (J# sb b)
 204   = case remInteger# sa a sb b of (# sr, r #) -> J# sr r
 205
 206 quotInteger :: Integer -> Integer -> Integer
 207 quotInteger ia ib
 208  | ib == 0 = error "Prelude.Integral.quot{Integer}: divide by 0"
 209 quotInteger a@(S# (-LEFTMOST_BIT#)) b = quotInteger (toBig a) b
 210 quotInteger (S# a) (S# b) = S# (quotInt# a b)
 211 {- Special case disabled, see remInteger above
 212 quotInteger (S# a) (J# sb b)
 213   | sb ==# 1#  = S# (quotInt# a (word2Int# (integer2Word# sb b)))
 214   | sb ==# -1# = S# (quotInt# a (0# -# (word2Int# (integer2Word# sb b))))
 215   | otherwise  = zeroInteger
 216 -}
 217 quotInteger ia@(S# _) ib@(J# _ _) = quotInteger (toBig ia) ib
 218 quotInteger (J# sa a) (S# b)
 219   = case int2Integer# b of { (# sb, b #) ->
 220     case quotInteger# sa a sb b of (# sq, q #) -> J# sq q }
 221 quotInteger (J# sa a) (J# sb b)
 222   = case quotInteger# sa a sb b of (# sg, g #) -> J# sg g
 223 \end{code}
 224
 225
 226
 227 \begin{code}
 228 gcdInteger :: Integer -> Integer -> Integer
 229 -- SUP: Do we really need the first two cases?
 230 gcdInteger a@(S# (-LEFTMOST_BIT#)) b = gcdInteger (toBig a) b
 231 gcdInteger a b@(S# (-LEFTMOST_BIT#)) = gcdInteger a (toBig b)
 232 gcdInteger (S# a) (S# b) = case gcdInt (I# a) (I# b) of { I# c -> S# c }
 233 gcdInteger ia@(S# 0#) ib@(J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
 234 gcdInteger ia@(S# a)  ib@(J# sb b)
 235   | a  ==# 0#  = abs ib
 236   | sb ==# 0#  = abs ia
 237   | otherwise  = S# (gcdIntegerInt# absSb b absA)
 238        where absA  = if a  <# 0# then negateInt# a  else a
 239              absSb = if sb <# 0# then negateInt# sb else sb
 240 gcdInteger ia@(J# _ _) ib@(S# _) = gcdInteger ib ia
 241 gcdInteger (J# 0# _) (J# 0# _) = error "GHC.Num.gcdInteger: gcd 0 0 is undefined"
 242 gcdInteger (J# sa a) (J# sb b)
 243   = case gcdInteger# sa a sb b of (# sg, g #) -> J# sg g
 244
 245 lcmInteger :: Integer -> Integer -> Integer
 246 lcmInteger a 0
 247   = zeroInteger
 248 lcmInteger 0 b
 249   = zeroInteger
 250 lcmInteger a b
 251   = (divExact aa (gcdInteger aa ab)) * ab
 252   where aa = abs a
 253         ab = abs b
 254
 255 divExact :: Integer -> Integer -> Integer
 256 divExact a@(S# (-LEFTMOST_BIT#)) b = divExact (toBig a) b
 257 divExact (S# a) (S# b) = S# (quotInt# a b)
 258 divExact (S# a) (J# sb b)
 259   = S# (quotInt# a (integer2Int# sb b))
 260 divExact (J# sa a) (S# b)
 261   = case int2Integer# b of
 262      (# sb, b #) -> case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 263 divExact (J# sa a) (J# sb b)
 264   = case divExactInteger# sa a sb b of (# sd, d #) -> J# sd d
 265 \end{code}
 266
 267
 268 %*********************************************************
 269 %*                                                      *
 270 \subsection{The @Integer@ instances for @Eq@, @Ord@}
 271 %*                                                      *
 272 %*********************************************************
 273
 274 \begin{code}
 275 instance  Eq Integer  where
 276     (S# i)     ==  (S# j)     = i ==# j
 277     (S# i)     ==  (J# s d)   = cmpIntegerInt# s d i ==# 0#
 278     (J# s d)   ==  (S# i)     = cmpIntegerInt# s d i ==# 0#
 279     (J# s1 d1) ==  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ==# 0#
 280
 281     (S# i)     /=  (S# j)     = i /=# j
 282     (S# i)     /=  (J# s d)   = cmpIntegerInt# s d i /=# 0#
 283     (J# s d)   /=  (S# i)     = cmpIntegerInt# s d i /=# 0#
 284     (J# s1 d1) /=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) /=# 0#
 285
 286 ------------------------------------------------------------------------
 287 instance  Ord Integer  where
 288     (S# i)     <=  (S# j)     = i <=# j
 289     (J# s d)   <=  (S# i)     = cmpIntegerInt# s d i <=# 0#
 290     (S# i)     <=  (J# s d)   = cmpIntegerInt# s d i >=# 0#
 291     (J# s1 d1) <=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <=# 0#
 292
 293     (S# i)     >   (S# j)     = i ># j
 294     (J# s d)   >   (S# i)     = cmpIntegerInt# s d i ># 0#
 295     (S# i)     >   (J# s d)   = cmpIntegerInt# s d i <# 0#
 296     (J# s1 d1) >   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) ># 0#
 297
 298     (S# i)     <   (S# j)     = i <# j
 299     (J# s d)   <   (S# i)     = cmpIntegerInt# s d i <# 0#
 300     (S# i)     <   (J# s d)   = cmpIntegerInt# s d i ># 0#
 301     (J# s1 d1) <   (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) <# 0#
 302
 303     (S# i)     >=  (S# j)     = i >=# j
 304     (J# s d)   >=  (S# i)     = cmpIntegerInt# s d i >=# 0#
 305     (S# i)     >=  (J# s d)   = cmpIntegerInt# s d i <=# 0#
 306     (J# s1 d1) >=  (J# s2 d2) = (cmpInteger# s1 d1 s2 d2) >=# 0#
 307
 308     compare (S# i)  (S# j)
 309        | i ==# j = EQ
 310        | i <=# j = LT
 311        | otherwise = GT
 312     compare (J# s d) (S# i)
 313        = case cmpIntegerInt# s d i of { res# ->
 314          if res# <# 0# then LT else
 315          if res# ># 0# then GT else EQ
 316          }
 317     compare (S# i) (J# s d)
 318        = case cmpIntegerInt# s d i of { res# ->
 319          if res# ># 0# then LT else
 320          if res# <# 0# then GT else EQ
 321          }
 322     compare (J# s1 d1) (J# s2 d2)
 323        = case cmpInteger# s1 d1 s2 d2 of { res# ->
 324          if res# <# 0# then LT else
 325          if res# ># 0# then GT else EQ
 326          }
 327 \end{code}
 328
 329
 330 %*********************************************************
 331 %*                                                      *
 332 \subsection{The @Integer@ instances for @Num@}
 333 %*                                                      *
 334 %*********************************************************
 335
 336 \begin{code}
 337 instance  Num Integer  where
 338     (+) = plusInteger
 339     (-) = minusInteger
 340     (*) = timesInteger
 341     negate         = negateInteger
 342     fromInteger x  =  x
 343
 344     -- ORIG: abs n = if n >= 0 then n else -n
 345     abs (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 346     abs (S# i) = case abs (I# i) of I# j -> S# j
 347     abs n@(J# s d) = if (s >=# 0#) then n else J# (negateInt# s) d
 348
 349     signum (S# i) = case signum (I# i) of I# j -> S# j
 350     signum (J# s d)
 351       = let
 352             cmp = cmpIntegerInt# s d 0#
 353         in
 354         if      cmp >#  0# then S# 1#
 355         else if cmp ==# 0# then S# 0#
 356         else                    S# (negateInt# 1#)
 357
 358 plusInteger i1@(S# i) i2@(S# j)  = case addIntC# i j of { (# r, c #) ->
 359                                    if c ==# 0# then S# r
 360                                    else toBig i1 + toBig i2 }
 361 plusInteger i1@(J# _ _) i2@(S# _) = i1 + toBig i2
 362 plusInteger i1@(S# _) i2@(J# _ _) = toBig i1 + i2
 363 plusInteger (J# s1 d1) (J# s2 d2) = case plusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 364
 365 minusInteger i1@(S# i) i2@(S# j)   = case subIntC# i j of { (# r, c #) ->
 366                                      if c ==# 0# then S# r
 367                                      else toBig i1 - toBig i2 }
 368 minusInteger i1@(J# _ _) i2@(S# _) = i1 - toBig i2
 369 minusInteger i1@(S# _) i2@(J# _ _) = toBig i1 - i2
 370 minusInteger (J# s1 d1) (J# s2 d2) = case minusInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 371
 372 timesInteger i1@(S# i) i2@(S# j)   = if   mulIntMayOflo# i j ==# 0#
 373                                      then S# (i *# j)
 374                                      else toBig i1 * toBig i2
 375 timesInteger i1@(J# _ _) i2@(S# _) = i1 * toBig i2
 376 timesInteger i1@(S# _) i2@(J# _ _) = toBig i1 * i2
 377 timesInteger (J# s1 d1) (J# s2 d2) = case timesInteger# s1 d1 s2 d2 of (# s, d #) -> J# s d
 378
 379 negateInteger (S# (-LEFTMOST_BIT#)) = LEFTMOST_BIT
 380 negateInteger (S# i)              = S# (negateInt# i)
 381 negateInteger (J# s d)            = J# (negateInt# s) d
 382 \end{code}
 383
 384
 385 %*********************************************************
 386 %*                                                      *
 387 \subsection{The @Integer@ instance for @Enum@}
 388 %*                                                      *
 389 %*********************************************************
 390
 391 \begin{code}
 392 instance  Enum Integer  where
 393     succ x               = x + 1
 394     pred x               = x - 1
 395     toEnum n             = int2Integer n
 396     fromEnum n           = integer2Int n
 397
 398     {-# INLINE enumFrom #-}
 399     {-# INLINE enumFromThen #-}
 400     {-# INLINE enumFromTo #-}
 401     {-# INLINE enumFromThenTo #-}
 402     enumFrom x             = enumDeltaInteger  x 1
 403     enumFromThen x y       = enumDeltaInteger  x (y-x)
 404     enumFromTo x lim       = enumDeltaToInteger x 1     lim
 405     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
 406
 407 {-# RULES
 408 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
 409 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
 410 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
 411 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
 412  #-}
 413
 414 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
 415 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
 416
 417 enumDeltaInteger :: Integer -> Integer -> [Integer]
 418 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
 419
 420 enumDeltaToIntegerFB c n x delta lim
 421   | delta >= 0 = up_fb c n x delta lim
 422   | otherwise  = dn_fb c n x delta lim
 423
 424 enumDeltaToInteger x delta lim
 425   | delta >= 0 = up_list x delta lim
 426   | otherwise  = dn_list x delta lim
 427
 428 up_fb c n x delta lim = go (x::Integer)
 429                       where
 430                         go x | x > lim   = n
 431                              | otherwise = x `c` go (x+delta)
 432 dn_fb c n x delta lim = go (x::Integer)
 433                       where
 434                         go x | x < lim   = n
 435                              | otherwise = x `c` go (x+delta)
 436
 437 up_list x delta lim = go (x::Integer)
 438                     where
 439                         go x | x > lim   = []
 440                              | otherwise = x : go (x+delta)
 441 dn_list x delta lim = go (x::Integer)
 442                     where
 443                         go x | x < lim   = []
 444                              | otherwise = x : go (x+delta)
 445
 446 \end{code}
 447
 448
 449 %*********************************************************
 450 %*                                                      *
 451 \subsection{The @Integer@ instances for @Show@}
 452 %*                                                      *
 453 %*********************************************************
 454
 455 \begin{code}
 456 instance Show Integer where
 457     showsPrec p n r
 458         | p > 6 && n < 0 = '(' : jtos n (')' : r)
 459                 -- Minor point: testing p first gives better code
 460                 -- in the not-uncommon case where the p argument
 461                 -- is a constant
 462         | otherwise      = jtos n r
 463     showList = showList__ (showsPrec 0)
 464
 465 -- Divide an conquer implementation of string conversion
 466 jtos :: Integer -> String -> String
 467 jtos n cs
 468     | n < 0     = '-' : jtos' (-n) cs
 469     | otherwise = jtos' n cs
 470     where
 471     jtos' :: Integer -> String -> String
 472     jtos' n cs
 473         | n < BASE  = jhead (fromInteger n) cs
 474         | otherwise = jprinth (jsplitf (BASE*BASE) n) cs
 475
 476     -- Split n into digits in base p. We first split n into digits
 477     -- in base p*p and then split each of these digits into two.
 478     -- Note that the first 'digit' modulo p*p may have a leading zero
 479     -- in base p that we need to drop - this is what jsplith takes care of.
 480     -- jsplitb the handles the remaining digits.
 481     jsplitf :: Integer -> Integer -> [Integer]
 482     jsplitf p n
 483         | p > n     = [n]
 484         | otherwise = jsplith p (jsplitf (p*p) n)
 485
 486     jsplith :: Integer -> [Integer] -> [Integer]
 487     jsplith p (n:ns) =
 488         if q > 0 then fromInteger q : fromInteger r : jsplitb p ns
 489                  else fromInteger r : jsplitb p ns
 490         where
 491         (q, r) = n `quotRemInteger` p
 492
 493     jsplitb :: Integer -> [Integer] -> [Integer]
 494     jsplitb p []     = []
 495     jsplitb p (n:ns) = q : r : jsplitb p ns
 496         where
 497         (q, r) = n `quotRemInteger` p
 498
 499     -- Convert a number that has been split into digits in base BASE^2
 500     -- this includes a last splitting step and then conversion of digits
 501     -- that all fit into a machine word.
 502     jprinth :: [Integer] -> String -> String
 503     jprinth (n:ns) cs =
 504         if q > 0 then jhead q $ jblock r $ jprintb ns cs
 505                  else jhead r $ jprintb ns cs
 506         where
 507         (q', r') = n `quotRemInteger` BASE
 508         q = fromInteger q'
 509         r = fromInteger r'
 510
 511     jprintb :: [Integer] -> String -> String
 512     jprintb []     cs = cs
 513     jprintb (n:ns) cs = jblock q $ jblock r $ jprintb ns cs
 514         where
 515         (q', r') = n `quotRemInteger` BASE
 516         q = fromInteger q'
 517         r = fromInteger r'
 518
 519     -- Convert an integer that fits into a machine word. Again, we have two
 520     -- functions, one that drops leading zeros (jhead) and one that doesn't
 521     -- (jblock)
 522     jhead :: Int -> String -> String
 523     jhead n cs
 524         | n < 10    = case unsafeChr (ord '0' + n) of
 525             c@(C# _) -> c : cs
 526         | otherwise = case unsafeChr (ord '0' + r) of
 527             c@(C# _) -> jhead q (c : cs)
 528         where
 529         (q, r) = n `quotRemInt` 10
 530
 531     jblock = jblock' {- ' -} DIGITS
 532
 533     jblock' :: Int -> Int -> String -> String
 534     jblock' d n cs
 535         | d == 1    = case unsafeChr (ord '0' + n) of
 536              c@(C# _) -> c : cs
 537         | otherwise = case unsafeChr (ord '0' + r) of
 538              c@(C# _) -> jblock' (d - 1) q (c : cs)
 539         where
 540         (q, r) = n `quotRemInt` 10
 541
 542 \end{code}