Ordering has now moved to ghc-prim
[ghc-base.git] / GHC / Num.lhs
1 \begin{code}
2 {-# OPTIONS_GHC -fno-implicit-prelude #-}
3 {-# OPTIONS_HADDOCK hide #-}
4 -----------------------------------------------------------------------------
5 -- |
6 -- Module      :  GHC.Num
7 -- Copyright   :  (c) The University of Glasgow 1994-2002
8 -- License     :  see libraries/base/LICENSE
9 -- 
10 -- Maintainer  :  cvs-ghc@haskell.org
11 -- Stability   :  internal
12 -- Portability :  non-portable (GHC Extensions)
13 --
14 -- The 'Num' class and the 'Integer' type.
15 --
16 -----------------------------------------------------------------------------
17
18 #include "MachDeps.h"
19 #if SIZEOF_HSWORD == 4
20 #define DIGITS       9
21 #define BASE         1000000000
22 #elif SIZEOF_HSWORD == 8
23 #define DIGITS       18
24 #define BASE         1000000000000000000
25 #else
26 #error Please define DIGITS and BASE
27 -- DIGITS should be the largest integer such that
28 --     10^DIGITS < 2^(SIZEOF_HSWORD * 8 - 1)
29 -- BASE should be 10^DIGITS. Note that ^ is not available yet.
30 #endif
31
32 -- #hide
33 module GHC.Num (module GHC.Num, module GHC.Integer) where
34
35 import GHC.Base
36 import GHC.Enum
37 import GHC.Show
38 import GHC.Integer
39
40 infixl 7  *
41 infixl 6  +, -
42
43 default ()              -- Double isn't available yet, 
44                         -- and we shouldn't be using defaults anyway
45 \end{code}
46
47 %*********************************************************
48 %*                                                      *
49 \subsection{Standard numeric class}
50 %*                                                      *
51 %*********************************************************
52
53 \begin{code}
54 -- | Basic numeric class.
55 --
56 -- Minimal complete definition: all except 'negate' or @(-)@
57 class  (Eq a, Show a) => Num a  where
58     (+), (-), (*)       :: a -> a -> a
59     -- | Unary negation.
60     negate              :: a -> a
61     -- | Absolute value.
62     abs                 :: a -> a
63     -- | Sign of a number.
64     -- The functions 'abs' and 'signum' should satisfy the law: 
65     --
66     -- > abs x * signum x == x
67     --
68     -- For real numbers, the 'signum' is either @-1@ (negative), @0@ (zero)
69     -- or @1@ (positive).
70     signum              :: a -> a
71     -- | Conversion from an 'Integer'.
72     -- An integer literal represents the application of the function
73     -- 'fromInteger' to the appropriate value of type 'Integer',
74     -- so such literals have type @('Num' a) => a@.
75     fromInteger         :: Integer -> a
76
77     x - y               = x + negate y
78     negate x            = 0 - x
79
80 -- | the same as @'flip' ('-')@.
81 --
82 -- Because @-@ is treated specially in the Haskell grammar,
83 -- @(-@ /e/@)@ is not a section, but an application of prefix negation.
84 -- However, @('subtract'@ /exp/@)@ is equivalent to the disallowed section.
85 {-# INLINE subtract #-}
86 subtract :: (Num a) => a -> a -> a
87 subtract x y = y - x
88 \end{code}
89
90
91 %*********************************************************
92 %*                                                      *
93 \subsection{Instances for @Int@}
94 %*                                                      *
95 %*********************************************************
96
97 \begin{code}
98 instance  Num Int  where
99     (+)    = plusInt
100     (-)    = minusInt
101     negate = negateInt
102     (*)    = timesInt
103     abs n  = if n `geInt` 0 then n else negateInt n
104
105     signum n | n `ltInt` 0 = negateInt 1
106              | n `eqInt` 0 = 0
107              | otherwise   = 1
108
109     fromInteger i = I# (toInt# i)
110
111 quotRemInt :: Int -> Int -> (Int, Int)
112 quotRemInt a@(I# _) b@(I# _) = (a `quotInt` b, a `remInt` b)
113     -- OK, so I made it a little stricter.  Shoot me.  (WDP 94/10)
114
115 divModInt ::  Int -> Int -> (Int, Int)
116 divModInt x@(I# _) y@(I# _) = (x `divInt` y, x `modInt` y)
117     -- Stricter.  Sorry if you don't like it.  (WDP 94/10)
118 \end{code}
119
120 %*********************************************************
121 %*                                                      *
122 \subsection{The @Integer@ instances for @Eq@, @Ord@}
123 %*                                                      *
124 %*********************************************************
125
126 \begin{code}
127 instance  Eq Integer  where
128     (==) = eqInteger
129     (/=) = neqInteger
130
131 ------------------------------------------------------------------------
132 instance Ord Integer where
133     (<=) = leInteger
134     (>)  = gtInteger
135     (<)  = ltInteger
136     (>=) = geInteger
137     compare = compareInteger
138 \end{code}
139
140
141 %*********************************************************
142 %*                                                      *
143 \subsection{The @Integer@ instances for @Show@}
144 %*                                                      *
145 %*********************************************************
146
147 \begin{code}
148 instance Show Integer where
149     showsPrec p n r
150         | p > 6 && n < 0 = '(' : integerToString n (')' : r)
151         -- Minor point: testing p first gives better code
152         -- in the not-uncommon case where the p argument
153         -- is a constant
154         | otherwise = integerToString n r
155     showList = showList__ (showsPrec 0)
156
157 -- Divide an conquer implementation of string conversion
158 integerToString :: Integer -> String -> String
159 integerToString n cs
160     | n < 0     = '-' : integerToString' (-n) cs
161     | otherwise = integerToString' n cs
162     where
163     integerToString' :: Integer -> String -> String
164     integerToString' n cs
165         | n < BASE  = jhead (fromInteger n) cs
166         | otherwise = jprinth (jsplitf (BASE*BASE) n) cs
167
168     -- Split n into digits in base p. We first split n into digits
169     -- in base p*p and then split each of these digits into two.
170     -- Note that the first 'digit' modulo p*p may have a leading zero
171     -- in base p that we need to drop - this is what jsplith takes care of.
172     -- jsplitb the handles the remaining digits.
173     jsplitf :: Integer -> Integer -> [Integer]
174     jsplitf p n
175         | p > n     = [n]
176         | otherwise = jsplith p (jsplitf (p*p) n)
177
178     jsplith :: Integer -> [Integer] -> [Integer]
179     jsplith p (n:ns) =
180         case n `quotRemInteger` p of
181         (# q, r #) ->
182             if q > 0 then fromInteger q : fromInteger r : jsplitb p ns
183                      else fromInteger r : jsplitb p ns
184
185     jsplitb :: Integer -> [Integer] -> [Integer]
186     jsplitb p []     = []
187     jsplitb p (n:ns) = case n `quotRemInteger` p of
188                        (# q, r #) ->
189                            q : r : jsplitb p ns
190
191     -- Convert a number that has been split into digits in base BASE^2
192     -- this includes a last splitting step and then conversion of digits
193     -- that all fit into a machine word.
194     jprinth :: [Integer] -> String -> String
195     jprinth (n:ns) cs =
196         case n `quotRemInteger` BASE of
197         (# q', r' #) ->
198             let q = fromInteger q'
199                 r = fromInteger r'
200             in if q > 0 then jhead q $ jblock r $ jprintb ns cs
201                         else jhead r $ jprintb ns cs
202
203     jprintb :: [Integer] -> String -> String
204     jprintb []     cs = cs
205     jprintb (n:ns) cs = case n `quotRemInteger` BASE of
206                         (# q', r' #) ->
207                             let q = fromInteger q'
208                                 r = fromInteger r'
209                             in jblock q $ jblock r $ jprintb ns cs
210
211     -- Convert an integer that fits into a machine word. Again, we have two
212     -- functions, one that drops leading zeros (jhead) and one that doesn't
213     -- (jblock)
214     jhead :: Int -> String -> String
215     jhead n cs
216         | n < 10    = case unsafeChr (ord '0' + n) of
217             c@(C# _) -> c : cs
218         | otherwise = case unsafeChr (ord '0' + r) of
219             c@(C# _) -> jhead q (c : cs)
220         where
221         (q, r) = n `quotRemInt` 10
222
223     jblock = jblock' {- ' -} DIGITS
224
225     jblock' :: Int -> Int -> String -> String
226     jblock' d n cs
227         | d == 1    = case unsafeChr (ord '0' + n) of
228              c@(C# _) -> c : cs
229         | otherwise = case unsafeChr (ord '0' + r) of
230              c@(C# _) -> jblock' (d - 1) q (c : cs)
231         where
232         (q, r) = n `quotRemInt` 10
233 \end{code}
234
235
236 %*********************************************************
237 %*                                                      *
238 \subsection{The @Integer@ instances for @Num@}
239 %*                                                      *
240 %*********************************************************
241
242 \begin{code}
243 instance  Num Integer  where
244     (+) = plusInteger
245     (-) = minusInteger
246     (*) = timesInteger
247     negate         = negateInteger
248     fromInteger x  =  x
249
250     abs = absInteger
251     signum = signumInteger
252 \end{code}
253
254
255 %*********************************************************
256 %*                                                      *
257 \subsection{The @Integer@ instance for @Enum@}
258 %*                                                      *
259 %*********************************************************
260
261 \begin{code}
262 instance  Enum Integer  where
263     succ x               = x + 1
264     pred x               = x - 1
265     toEnum (I# n)        = smallInteger n
266     fromEnum n           = I# (toInt# n)
267
268     {-# INLINE enumFrom #-}
269     {-# INLINE enumFromThen #-}
270     {-# INLINE enumFromTo #-}
271     {-# INLINE enumFromThenTo #-}
272     enumFrom x             = enumDeltaInteger  x 1
273     enumFromThen x y       = enumDeltaInteger  x (y-x)
274     enumFromTo x lim       = enumDeltaToInteger x 1     lim
275     enumFromThenTo x y lim = enumDeltaToInteger x (y-x) lim
276
277 {-# RULES
278 "enumDeltaInteger"      [~1] forall x y.  enumDeltaInteger x y     = build (\c _ -> enumDeltaIntegerFB c x y)
279 "efdtInteger"           [~1] forall x y l.enumDeltaToInteger x y l = build (\c n -> enumDeltaToIntegerFB c n x y l)
280 "enumDeltaInteger"      [1] enumDeltaIntegerFB   (:)    = enumDeltaInteger
281 "enumDeltaToInteger"    [1] enumDeltaToIntegerFB (:) [] = enumDeltaToInteger
282  #-}
283
284 enumDeltaIntegerFB :: (Integer -> b -> b) -> Integer -> Integer -> b
285 enumDeltaIntegerFB c x d = x `c` enumDeltaIntegerFB c (x+d) d
286
287 enumDeltaInteger :: Integer -> Integer -> [Integer]
288 enumDeltaInteger x d = x : enumDeltaInteger (x+d) d
289
290 enumDeltaToIntegerFB c n x delta lim
291   | delta >= 0 = up_fb c n x delta lim
292   | otherwise  = dn_fb c n x delta lim
293
294 enumDeltaToInteger x delta lim
295   | delta >= 0 = up_list x delta lim
296   | otherwise  = dn_list x delta lim
297
298 up_fb c n x delta lim = go (x::Integer)
299                       where
300                         go x | x > lim   = n
301                              | otherwise = x `c` go (x+delta)
302 dn_fb c n x delta lim = go (x::Integer)
303                       where
304                         go x | x < lim   = n
305                              | otherwise = x `c` go (x+delta)
306
307 up_list x delta lim = go (x::Integer)
308                     where
309                         go x | x > lim   = []
310                              | otherwise = x : go (x+delta)
311 dn_list x delta lim = go (x::Integer)
312                     where
313                         go x | x < lim   = []
314                              | otherwise = x : go (x+delta)
315
316 \end{code}
317