GHC/PArr.hs

   1 {-# OPTIONS_GHC -fparr -funbox-strict-fields #-}
   2
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.PArr
   6 -- Copyright   :  (c) 2001-2002 Manuel M T Chakravarty & Gabriele Keller
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  Manuel M. T. Chakravarty <chak@cse.unsw.edu.au>
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 --  Basic implementation of Parallel Arrays.
  14 --
  15 --  This module has two functions: (1) It defines the interface to the
  16 --  parallel array extension of the Prelude and (2) it provides a vanilla
  17 --  implementation of parallel arrays that does not require to flatten the
  18 --  array code.  The implementation is not very optimised.
  19 --
  20 --- DOCU ----------------------------------------------------------------------
  21 --
  22 --  Language: Haskell 98 plus unboxed values and parallel arrays
  23 --
  24 --  The semantic difference between standard Haskell arrays (aka "lazy
  25 --  arrays") and parallel arrays (aka "strict arrays") is that the evaluation
  26 --  of two different elements of a lazy array is independent, whereas in a
  27 --  strict array either non or all elements are evaluated.  In other words,
  28 --  when a parallel array is evaluated to WHNF, all its elements will be
  29 --  evaluated to WHNF.  The name parallel array indicates that all array
  30 --  elements may, in general, be evaluated to WHNF in parallel without any
  31 --  need to resort to speculative evaluation.  This parallel evaluation
  32 --  semantics is also beneficial in the sequential case, as it facilitates
  33 --  loop-based array processing as known from classic array-based languages,
  34 --  such as Fortran.
  35 --
  36 --  The interface of this module is essentially a variant of the list
  37 --  component of the Prelude, but also includes some functions (such as
  38 --  permutations) that are not provided for lists.  The following list
  39 --  operations are not supported on parallel arrays, as they would require the
  40 --  availability of infinite parallel arrays: `iterate', `repeat', and `cycle'.
  41 --
  42 --  The current implementation is quite simple and entirely based on boxed
  43 --  arrays.  One disadvantage of boxed arrays is that they require to
  44 --  immediately initialise all newly allocated arrays with an error thunk to
  45 --  keep the garbage collector happy, even if it is guaranteed that the array
  46 --  is fully initialised with different values before passing over the
  47 --  user-visible interface boundary.  Currently, no effort is made to use
  48 --  raw memory copy operations to speed things up.
  49 --
  50 --- TODO ----------------------------------------------------------------------
  51 --
  52 --  * We probably want a standard library `PArray' in addition to the prelude
  53 --    extension in the same way as the standard library `List' complements the
  54 --    list functions from the prelude.
  55 --
  56 --  * Currently, functions that emphasis the constructor-based definition of
  57 --    lists (such as, head, last, tail, and init) are not supported.
  58 --
  59 --    Is it worthwhile to support the string processing functions lines,
  60 --    words, unlines, and unwords?  (Currently, they are not implemented.)
  61 --
  62 --    It can, however, be argued that it would be worthwhile to include them
  63 --    for completeness' sake; maybe only in the standard library `PArray'.
  64 --
  65 --  * Prescans are often more useful for array programming than scans.  Shall
  66 --    we include them into the Prelude or the library?
  67 --
  68 --  * Due to the use of the iterator `loop', we could define some fusion rules
  69 --    in this module.
  70 --
  71 --  * We might want to add bounds checks that can be deactivated.
  72 --
  73
  74 module GHC.PArr (
  75   -- [::],              -- Built-in syntax
  76
  77   mapP,                 -- :: (a -> b) -> [:a:] -> [:b:]
  78   (+:+),                -- :: [:a:] -> [:a:] -> [:a:]
  79   filterP,              -- :: (a -> Bool) -> [:a:] -> [:a:]
  80   concatP,              -- :: [:[:a:]:] -> [:a:]
  81   concatMapP,           -- :: (a -> [:b:]) -> [:a:] -> [:b:]
  82 --  head, last, tail, init,   -- it's not wise to use them on arrays
  83   nullP,                -- :: [:a:] -> Bool
  84   lengthP,              -- :: [:a:] -> Int
  85   (!:),                 -- :: [:a:] -> Int -> a
  86   foldlP,               -- :: (a -> b -> a) -> a -> [:b:] -> a
  87   foldl1P,              -- :: (a -> a -> a) ->      [:a:] -> a
  88   scanlP,               -- :: (a -> b -> a) -> a -> [:b:] -> [:a:]
  89   scanl1P,              -- :: (a -> a -> a) ->      [:a:] -> [:a:]
  90   foldrP,               -- :: (a -> b -> b) -> b -> [:a:] -> b
  91   foldr1P,              -- :: (a -> a -> a) ->      [:a:] -> a
  92   scanrP,               -- :: (a -> b -> b) -> b -> [:a:] -> [:b:]
  93   scanr1P,              -- :: (a -> a -> a) ->      [:a:] -> [:a:]
  94 --  iterate, repeat,          -- parallel arrays must be finite
  95   singletonP,           -- :: a -> [:a:]
  96   emptyP,               -- :: [:a:]
  97   replicateP,           -- :: Int -> a -> [:a:]
  98 --  cycle,                    -- parallel arrays must be finite
  99   takeP,                -- :: Int -> [:a:] -> [:a:]
 100   dropP,                -- :: Int -> [:a:] -> [:a:]
 101   splitAtP,             -- :: Int -> [:a:] -> ([:a:],[:a:])
 102   takeWhileP,           -- :: (a -> Bool) -> [:a:] -> [:a:]
 103   dropWhileP,           -- :: (a -> Bool) -> [:a:] -> [:a:]
 104   spanP,                -- :: (a -> Bool) -> [:a:] -> ([:a:], [:a:])
 105   breakP,               -- :: (a -> Bool) -> [:a:] -> ([:a:], [:a:])
 106 --  lines, words, unlines, unwords,  -- is string processing really needed
 107   reverseP,             -- :: [:a:] -> [:a:]
 108   andP,                 -- :: [:Bool:] -> Bool
 109   orP,                  -- :: [:Bool:] -> Bool
 110   anyP,                 -- :: (a -> Bool) -> [:a:] -> Bool
 111   allP,                 -- :: (a -> Bool) -> [:a:] -> Bool
 112   elemP,                -- :: (Eq a) => a -> [:a:] -> Bool
 113   notElemP,             -- :: (Eq a) => a -> [:a:] -> Bool
 114   lookupP,              -- :: (Eq a) => a -> [:(a, b):] -> Maybe b
 115   sumP,                 -- :: (Num a) => [:a:] -> a
 116   productP,             -- :: (Num a) => [:a:] -> a
 117   maximumP,             -- :: (Ord a) => [:a:] -> a
 118   minimumP,             -- :: (Ord a) => [:a:] -> a
 119   zipP,                 -- :: [:a:] -> [:b:]          -> [:(a, b)   :]
 120   zip3P,                -- :: [:a:] -> [:b:] -> [:c:] -> [:(a, b, c):]
 121   zipWithP,             -- :: (a -> b -> c)      -> [:a:] -> [:b:] -> [:c:]
 122   zipWith3P,            -- :: (a -> b -> c -> d) -> [:a:]->[:b:]->[:c:]->[:d:]
 123   unzipP,               -- :: [:(a, b)   :] -> ([:a:], [:b:])
 124   unzip3P,              -- :: [:(a, b, c):] -> ([:a:], [:b:], [:c:])
 125
 126   -- overloaded functions
 127   --
 128   enumFromToP,          -- :: Enum a => a -> a      -> [:a:]
 129   enumFromThenToP,      -- :: Enum a => a -> a -> a -> [:a:]
 130
 131   -- the following functions are not available on lists
 132   --
 133   toP,                  -- :: [a] -> [:a:]
 134   fromP,                -- :: [:a:] -> [a]
 135   sliceP,               -- :: Int -> Int -> [:e:] -> [:e:]
 136   foldP,                -- :: (e -> e -> e) -> e -> [:e:] -> e
 137   fold1P,               -- :: (e -> e -> e) ->      [:e:] -> e
 138   permuteP,             -- :: [:Int:] -> [:e:] ->          [:e:]
 139   bpermuteP,            -- :: [:Int:] -> [:e:] ->          [:e:]
 140   dpermuteP,            -- :: [:Int:] -> [:e:] -> [:e:] -> [:e:]
 141   crossP,               -- :: [:a:] -> [:b:] -> [:(a, b):]
 142   crossMapP,            -- :: [:a:] -> (a -> [:b:]) -> [:(a, b):]
 143   indexOfP              -- :: (a -> Bool) -> [:a:] -> [:Int:]
 144 ) where
 145
 146 #ifndef __HADDOCK__
 147
 148 import Prelude
 149
 150 import GHC.ST   ( ST(..), STRep, runST )
 151 import GHC.Exts ( Int#, Array#, Int(I#), MutableArray#, newArray#,
 152                   unsafeFreezeArray#, indexArray#, writeArray#, (<#), (>=#) )
 153
 154 infixl 9  !:
 155 infixr 5  +:+
 156 infix  4  `elemP`, `notElemP`
 157
 158
 159 -- representation of parallel arrays
 160 -- ---------------------------------
 161
 162 -- this rather straight forward implementation maps parallel arrays to the
 163 -- internal representation used for standard Haskell arrays in GHC's Prelude
 164 -- (EXPORTED ABSTRACTLY)
 165 --
 166 -- * This definition *must* be kept in sync with `TysWiredIn.parrTyCon'!
 167 --
 168 data [::] e = PArr Int# (Array# e)
 169
 170
 171 -- exported operations on parallel arrays
 172 -- --------------------------------------
 173
 174 -- operations corresponding to list operations
 175 --
 176
 177 mapP   :: (a -> b) -> [:a:] -> [:b:]
 178 mapP f  = fst . loop (mapEFL f) noAL
 179
 180 (+:+)     :: [:a:] -> [:a:] -> [:a:]
 181 a1 +:+ a2  = fst $ loop (mapEFL sel) noAL (enumFromToP 0 (len1 + len2 - 1))
 182                        -- we can't use the [:x..y:] form here for tedious
 183                        -- reasons to do with the typechecker and the fact that
 184                        -- `enumFromToP' is defined in the same module
 185              where
 186                len1 = lengthP a1
 187                len2 = lengthP a2
 188                --
 189                sel i | i < len1  = a1!:i
 190                      | otherwise = a2!:(i - len1)
 191
 192 filterP   :: (a -> Bool) -> [:a:] -> [:a:]
 193 filterP p  = fst . loop (filterEFL p) noAL
 194
 195 concatP     :: [:[:a:]:] -> [:a:]
 196 concatP xss  = foldlP (+:+) [::] xss
 197
 198 concatMapP   :: (a -> [:b:]) -> [:a:] -> [:b:]
 199 concatMapP f  = concatP . mapP f
 200
 201 --  head, last, tail, init,   -- it's not wise to use them on arrays
 202
 203 nullP      :: [:a:] -> Bool
 204 nullP [::]  = True
 205 nullP _     = False
 206
 207 lengthP             :: [:a:] -> Int
 208 lengthP (PArr n# _)  = I# n#
 209
 210 (!:) :: [:a:] -> Int -> a
 211 (!:)  = indexPArr
 212
 213 foldlP     :: (a -> b -> a) -> a -> [:b:] -> a
 214 foldlP f z  = snd . loop (foldEFL (flip f)) z
 215
 216 foldl1P        :: (a -> a -> a) -> [:a:] -> a
 217 foldl1P f [::]  = error "Prelude.foldl1P: empty array"
 218 foldl1P f a     = snd $ loopFromTo 1 (lengthP a - 1) (foldEFL f) (a!:0) a
 219
 220 scanlP     :: (a -> b -> a) -> a -> [:b:] -> [:a:]
 221 scanlP f z  = fst . loop (scanEFL (flip f)) z
 222
 223 scanl1P        :: (a -> a -> a) -> [:a:] -> [:a:]
 224 scanl1P f [::]  = error "Prelude.scanl1P: empty array"
 225 scanl1P f a     = fst $ loopFromTo 1 (lengthP a - 1) (scanEFL f) (a!:0) a
 226
 227 foldrP :: (a -> b -> b) -> b -> [:a:] -> b
 228 foldrP  = error "Prelude.foldrP: not implemented yet" -- FIXME
 229
 230 foldr1P :: (a -> a -> a) -> [:a:] -> a
 231 foldr1P  = error "Prelude.foldr1P: not implemented yet" -- FIXME
 232
 233 scanrP :: (a -> b -> b) -> b -> [:a:] -> [:b:]
 234 scanrP  = error "Prelude.scanrP: not implemented yet" -- FIXME
 235
 236 scanr1P :: (a -> a -> a) -> [:a:] -> [:a:]
 237 scanr1P  = error "Prelude.scanr1P: not implemented yet" -- FIXME
 238
 239 --  iterate, repeat           -- parallel arrays must be finite
 240
 241 singletonP             :: a -> [:a:]
 242 {-# INLINE singletonP #-}
 243 singletonP e = replicateP 1 e
 244
 245 emptyP :: [:a:]
 246 emptyP = error "emptyP in GHC.PArr: not yet implemented"
 247
 248 replicateP             :: Int -> a -> [:a:]
 249 {-# INLINE replicateP #-}
 250 replicateP n e  = runST (do
 251   marr# <- newArray n e
 252   mkPArr n marr#)
 253
 254 --  cycle                     -- parallel arrays must be finite
 255
 256 takeP   :: Int -> [:a:] -> [:a:]
 257 takeP n  = sliceP 0 (n - 1)
 258
 259 dropP     :: Int -> [:a:] -> [:a:]
 260 dropP n a  = sliceP n (lengthP a - 1) a
 261
 262 splitAtP      :: Int -> [:a:] -> ([:a:],[:a:])
 263 splitAtP n xs  = (takeP n xs, dropP n xs)
 264
 265 takeWhileP :: (a -> Bool) -> [:a:] -> [:a:]
 266 takeWhileP  = error "Prelude.takeWhileP: not implemented yet" -- FIXME
 267
 268 dropWhileP :: (a -> Bool) -> [:a:] -> [:a:]
 269 dropWhileP  = error "Prelude.dropWhileP: not implemented yet" -- FIXME
 270
 271 spanP :: (a -> Bool) -> [:a:] -> ([:a:], [:a:])
 272 spanP  = error "Prelude.spanP: not implemented yet" -- FIXME
 273
 274 breakP   :: (a -> Bool) -> [:a:] -> ([:a:], [:a:])
 275 breakP p  = spanP (not . p)
 276
 277 --  lines, words, unlines, unwords,  -- is string processing really needed
 278
 279 reverseP   :: [:a:] -> [:a:]
 280 reverseP a  = permuteP (enumFromThenToP (len - 1) (len - 2) 0) a
 281                        -- we can't use the [:x, y..z:] form here for tedious
 282                        -- reasons to do with the typechecker and the fact that
 283                        -- `enumFromThenToP' is defined in the same module
 284               where
 285                 len = lengthP a
 286
 287 andP :: [:Bool:] -> Bool
 288 andP  = foldP (&&) True
 289
 290 orP :: [:Bool:] -> Bool
 291 orP  = foldP (||) True
 292
 293 anyP   :: (a -> Bool) -> [:a:] -> Bool
 294 anyP p  = orP . mapP p
 295
 296 allP :: (a -> Bool) -> [:a:] -> Bool
 297 allP p  = andP . mapP p
 298
 299 elemP   :: (Eq a) => a -> [:a:] -> Bool
 300 elemP x  = anyP (== x)
 301
 302 notElemP   :: (Eq a) => a -> [:a:] -> Bool
 303 notElemP x  = allP (/= x)
 304
 305 lookupP :: (Eq a) => a -> [:(a, b):] -> Maybe b
 306 lookupP  = error "Prelude.lookupP: not implemented yet" -- FIXME
 307
 308 sumP :: (Num a) => [:a:] -> a
 309 sumP  = foldP (+) 0
 310
 311 productP :: (Num a) => [:a:] -> a
 312 productP  = foldP (*) 1
 313
 314 maximumP      :: (Ord a) => [:a:] -> a
 315 maximumP [::]  = error "Prelude.maximumP: empty parallel array"
 316 maximumP xs    = fold1P max xs
 317
 318 minimumP :: (Ord a) => [:a:] -> a
 319 minimumP [::]  = error "Prelude.minimumP: empty parallel array"
 320 minimumP xs    = fold1P min xs
 321
 322 zipP :: [:a:] -> [:b:] -> [:(a, b):]
 323 zipP  = zipWithP (,)
 324
 325 zip3P :: [:a:] -> [:b:] -> [:c:] -> [:(a, b, c):]
 326 zip3P  = zipWith3P (,,)
 327
 328 zipWithP         :: (a -> b -> c) -> [:a:] -> [:b:] -> [:c:]
 329 zipWithP f a1 a2  = let
 330                       len1 = lengthP a1
 331                       len2 = lengthP a2
 332                       len  = len1 `min` len2
 333                     in
 334                     fst $ loopFromTo 0 (len - 1) combine 0 a1
 335                     where
 336                       combine e1 i = (Just $ f e1 (a2!:i), i + 1)
 337
 338 zipWith3P :: (a -> b -> c -> d) -> [:a:]->[:b:]->[:c:]->[:d:]
 339 zipWith3P f a1 a2 a3 = let
 340                         len1 = lengthP a1
 341                         len2 = lengthP a2
 342                         len3 = lengthP a3
 343                         len  = len1 `min` len2 `min` len3
 344                       in
 345                       fst $ loopFromTo 0 (len - 1) combine 0 a1
 346                       where
 347                         combine e1 i = (Just $ f e1 (a2!:i) (a3!:i), i + 1)
 348
 349 unzipP   :: [:(a, b):] -> ([:a:], [:b:])
 350 unzipP a  = (fst $ loop (mapEFL fst) noAL a, fst $ loop (mapEFL snd) noAL a)
 351 -- FIXME: these two functions should be optimised using a tupled custom loop
 352 unzip3P   :: [:(a, b, c):] -> ([:a:], [:b:], [:c:])
 353 unzip3P a  = (fst $ loop (mapEFL fst3) noAL a,
 354               fst $ loop (mapEFL snd3) noAL a,
 355               fst $ loop (mapEFL trd3) noAL a)
 356              where
 357                fst3 (a, _, _) = a
 358                snd3 (_, b, _) = b
 359                trd3 (_, _, c) = c
 360
 361 -- instances
 362 --
 363
 364 instance Eq a => Eq [:a:] where
 365   a1 == a2 | lengthP a1 == lengthP a2 = andP (zipWithP (==) a1 a2)
 366            | otherwise                = False
 367
 368 instance Ord a => Ord [:a:] where
 369   compare a1 a2 = case foldlP combineOrdering EQ (zipWithP compare a1 a2) of
 370                     EQ | lengthP a1 == lengthP a2 -> EQ
 371                        | lengthP a1 <  lengthP a2 -> LT
 372                        | otherwise                -> GT
 373                   where
 374                     combineOrdering EQ    EQ    = EQ
 375                     combineOrdering EQ    other = other
 376                     combineOrdering other _     = other
 377
 378 instance Functor [::] where
 379   fmap = mapP
 380
 381 instance Monad [::] where
 382   m >>= k  = foldrP ((+:+) . k      ) [::] m
 383   m >>  k  = foldrP ((+:+) . const k) [::] m
 384   return x = [:x:]
 385   fail _   = [::]
 386
 387 instance Show a => Show [:a:]  where
 388   showsPrec _  = showPArr . fromP
 389     where
 390       showPArr []     s = "[::]" ++ s
 391       showPArr (x:xs) s = "[:" ++ shows x (showPArr' xs s)
 392
 393       showPArr' []     s = ":]" ++ s
 394       showPArr' (y:ys) s = ',' : shows y (showPArr' ys s)
 395
 396 instance Read a => Read [:a:]  where
 397   readsPrec _ a = [(toP v, rest) | (v, rest) <- readPArr a]
 398     where
 399       readPArr = readParen False (\r -> do
 400                                           ("[:",s) <- lex r
 401                                           readPArr1 s)
 402       readPArr1 s =
 403         (do { (":]", t) <- lex s; return ([], t) }) ++
 404         (do { (x, t) <- reads s; (xs, u) <- readPArr2 t; return (x:xs, u) })
 405
 406       readPArr2 s =
 407         (do { (":]", t) <- lex s; return ([], t) }) ++
 408         (do { (",", t) <- lex s; (x, u) <- reads t; (xs, v) <- readPArr2 u;
 409               return (x:xs, v) })
 410
 411 -- overloaded functions
 412 --
 413
 414 -- Ideally, we would like `enumFromToP' and `enumFromThenToP' to be members of
 415 -- `Enum'.  On the other hand, we really do not want to change `Enum'.  Thus,
 416 -- for the moment, we hope that the compiler is sufficiently clever to
 417 -- properly fuse the following definitions.
 418
 419 enumFromToP     :: Enum a => a -> a -> [:a:]
 420 enumFromToP x y  = mapP toEnum (eftInt (fromEnum x) (fromEnum y))
 421   where
 422     eftInt x y = scanlP (+) x $ replicateP (y - x + 1) 1
 423
 424 enumFromThenToP       :: Enum a => a -> a -> a -> [:a:]
 425 enumFromThenToP x y z  =
 426   mapP toEnum (efttInt (fromEnum x) (fromEnum y) (fromEnum z))
 427   where
 428     efttInt x y z = scanlP (+) x $
 429                       replicateP (abs (z - x) `div` abs delta + 1) delta
 430       where
 431        delta = y - x
 432
 433 -- the following functions are not available on lists
 434 --
 435
 436 -- create an array from a list (EXPORTED)
 437 --
 438 toP   :: [a] -> [:a:]
 439 toP l  = fst $ loop store l (replicateP (length l) ())
 440          where
 441            store _ (x:xs) = (Just x, xs)
 442
 443 -- convert an array to a list (EXPORTED)
 444 --
 445 fromP   :: [:a:] -> [a]
 446 fromP a  = [a!:i | i <- [0..lengthP a - 1]]
 447
 448 -- cut a subarray out of an array (EXPORTED)
 449 --
 450 sliceP :: Int -> Int -> [:e:] -> [:e:]
 451 sliceP from to a =
 452   fst $ loopFromTo (0 `max` from) (to `min` (lengthP a - 1)) (mapEFL id) noAL a
 453
 454 -- parallel folding (EXPORTED)
 455 --
 456 -- * the first argument must be associative; otherwise, the result is undefined
 457 --
 458 foldP :: (e -> e -> e) -> e -> [:e:] -> e
 459 foldP  = foldlP
 460
 461 -- parallel folding without explicit neutral (EXPORTED)
 462 --
 463 -- * the first argument must be associative; otherwise, the result is undefined
 464 --
 465 fold1P :: (e -> e -> e) -> [:e:] -> e
 466 fold1P  = foldl1P
 467
 468 -- permute an array according to the permutation vector in the first argument
 469 -- (EXPORTED)
 470 --
 471 permuteP       :: [:Int:] -> [:e:] -> [:e:]
 472 permuteP is es
 473   | isLen /= esLen = error "GHC.PArr: arguments must be of the same length"
 474   | otherwise      = runST (do
 475                        marr <- newArray isLen noElem
 476                        permute marr is es
 477                        mkPArr isLen marr)
 478   where
 479     noElem = error "GHC.PArr.permuteP: I do not exist!"
 480              -- unlike standard Haskell arrays, this value represents an
 481              -- internal error
 482     isLen = lengthP is
 483     esLen = lengthP es
 484
 485 -- permute an array according to the back-permutation vector in the first
 486 -- argument (EXPORTED)
 487 --
 488 -- * the permutation vector must represent a surjective function; otherwise,
 489 --   the result is undefined
 490 --
 491 bpermuteP       :: [:Int:] -> [:e:] -> [:e:]
 492 bpermuteP is es  = fst $ loop (mapEFL (es!:)) noAL is
 493
 494 -- permute an array according to the permutation vector in the first
 495 -- argument, which need not be surjective (EXPORTED)
 496 --
 497 -- * any elements in the result that are not covered by the permutation
 498 --   vector assume the value of the corresponding position of the third
 499 --   argument
 500 --
 501 dpermuteP :: [:Int:] -> [:e:] -> [:e:] -> [:e:]
 502 dpermuteP is es dft
 503   | isLen /= esLen = error "GHC.PArr: arguments must be of the same length"
 504   | otherwise      = runST (do
 505                        marr <- newArray dftLen noElem
 506                        trans 0 (isLen - 1) marr dft copyOne noAL
 507                        permute marr is es
 508                        mkPArr dftLen marr)
 509   where
 510     noElem = error "GHC.PArr.permuteP: I do not exist!"
 511              -- unlike standard Haskell arrays, this value represents an
 512              -- internal error
 513     isLen  = lengthP is
 514     esLen  = lengthP es
 515     dftLen = lengthP dft
 516
 517     copyOne e _ = (Just e, noAL)
 518
 519 -- computes the cross combination of two arrays (EXPORTED)
 520 --
 521 crossP       :: [:a:] -> [:b:] -> [:(a, b):]
 522 crossP a1 a2  = fst $ loop combine (0, 0) $ replicateP len ()
 523                 where
 524                   len1 = lengthP a1
 525                   len2 = lengthP a2
 526                   len  = len1 * len2
 527                   --
 528                   combine _ (i, j) = (Just $ (a1!:i, a2!:j), next)
 529                                      where
 530                                        next | (i + 1) == len1 = (0    , j + 1)
 531                                             | otherwise       = (i + 1, j)
 532
 533 {- An alternative implementation
 534    * The one above is certainly better for flattened code, but here where we
 535      are handling boxed arrays, the trade off is less clear.  However, I
 536      think, the above one is still better.
 537
 538 crossP a1 a2  = let
 539                   len1 = lengthP a1
 540                   len2 = lengthP a2
 541                   x1   = concatP $ mapP (replicateP len2) a1
 542                   x2   = concatP $ replicateP len1 a2
 543                 in
 544                 zipP x1 x2
 545  -}
 546
 547 -- |Compute a cross of an array and the arrays produced by the given function
 548 -- for the elements of the first array.
 549 --
 550 crossMapP :: [:a:] -> (a -> [:b:]) -> [:(a, b):]
 551 crossMapP a f = let
 552                   bs   = mapP f a
 553                   segd = mapP lengthP bs
 554                   as   = zipWithP replicateP segd a
 555                 in
 556                 zipP (concatP as) (concatP bs)
 557
 558 {- The following may seem more straight forward, but the above is very cheap
 559    with segmented arrays, as `mapP lengthP', `zipP', and `concatP' are
 560    constant time, and `map f' uses the lifted version of `f'.
 561
 562 crossMapP a f = concatP $ mapP (\x -> mapP ((,) x) (f x)) a
 563
 564  -}
 565
 566 -- computes an index array for all elements of the second argument for which
 567 -- the predicate yields `True' (EXPORTED)
 568 --
 569 indexOfP     :: (a -> Bool) -> [:a:] -> [:Int:]
 570 indexOfP p a  = fst $ loop calcIdx 0 a
 571                 where
 572                   calcIdx e idx | p e       = (Just idx, idx + 1)
 573                                 | otherwise = (Nothing , idx    )
 574
 575
 576 -- auxiliary functions
 577 -- -------------------
 578
 579 -- internally used mutable boxed arrays
 580 --
 581 data MPArr s e = MPArr Int# (MutableArray# s e)
 582
 583 -- allocate a new mutable array that is pre-initialised with a given value
 584 --
 585 newArray             :: Int -> e -> ST s (MPArr s e)
 586 {-# INLINE newArray #-}
 587 newArray (I# n#) e  = ST $ \s1# ->
 588   case newArray# n# e s1# of { (# s2#, marr# #) ->
 589   (# s2#, MPArr n# marr# #)}
 590
 591 -- convert a mutable array into the external parallel array representation
 592 --
 593 mkPArr                           :: Int -> MPArr s e -> ST s [:e:]
 594 {-# INLINE mkPArr #-}
 595 mkPArr (I# n#) (MPArr _ marr#)  = ST $ \s1# ->
 596   case unsafeFreezeArray# marr# s1#   of { (# s2#, arr# #) ->
 597   (# s2#, PArr n# arr# #) }
 598
 599 -- general array iterator
 600 --
 601 -- * corresponds to `loopA' from ``Functional Array Fusion'', Chakravarty &
 602 --   Keller, ICFP 2001
 603 --
 604 loop :: (e -> acc -> (Maybe e', acc))    -- mapping & folding, once per element
 605      -> acc                              -- initial acc value
 606      -> [:e:]                            -- input array
 607      -> ([:e':], acc)
 608 {-# INLINE loop #-}
 609 loop mf acc arr = loopFromTo 0 (lengthP arr - 1) mf acc arr
 610
 611 -- general array iterator with bounds
 612 --
 613 loopFromTo :: Int                        -- from index
 614            -> Int                        -- to index
 615            -> (e -> acc -> (Maybe e', acc))
 616            -> acc
 617            -> [:e:]
 618            -> ([:e':], acc)
 619 {-# INLINE loopFromTo #-}
 620 loopFromTo from to mf start arr = runST (do
 621   marr      <- newArray (to - from + 1) noElem
 622   (n', acc) <- trans from to marr arr mf start
 623   arr       <- mkPArr n' marr
 624   return (arr, acc))
 625   where
 626     noElem = error "GHC.PArr.loopFromTo: I do not exist!"
 627              -- unlike standard Haskell arrays, this value represents an
 628              -- internal error
 629
 630 -- actual loop body of `loop'
 631 --
 632 -- * for this to be really efficient, it has to be translated with the
 633 --   constructor specialisation phase "SpecConstr" switched on; as of GHC 5.03
 634 --   this requires an optimisation level of at least -O2
 635 --
 636 trans :: Int                            -- index of first elem to process
 637       -> Int                            -- index of last elem to process
 638       -> MPArr s e'                     -- destination array
 639       -> [:e:]                          -- source array
 640       -> (e -> acc -> (Maybe e', acc))  -- mutator
 641       -> acc                            -- initial accumulator
 642       -> ST s (Int, acc)                -- final destination length/final acc
 643 {-# INLINE trans #-}
 644 trans from to marr arr mf start = trans' from 0 start
 645   where
 646     trans' arrOff marrOff acc
 647       | arrOff > to = return (marrOff, acc)
 648       | otherwise   = do
 649                         let (oe', acc') = mf (arr `indexPArr` arrOff) acc
 650                         marrOff' <- case oe' of
 651                                       Nothing -> return marrOff
 652                                       Just e' -> do
 653                                         writeMPArr marr marrOff e'
 654                                         return $ marrOff + 1
 655                         trans' (arrOff + 1) marrOff' acc'
 656
 657 -- Permute the given elements into the mutable array.
 658 --
 659 permute :: MPArr s e -> [:Int:] -> [:e:] -> ST s ()
 660 permute marr is es = perm 0
 661   where
 662     perm i
 663       | i == n = return ()
 664       | otherwise  = writeMPArr marr (is!:i) (es!:i) >> perm (i + 1)
 665       where
 666         n = lengthP is
 667
 668
 669 -- common patterns for using `loop'
 670 --
 671
 672 -- initial value for the accumulator when the accumulator is not needed
 673 --
 674 noAL :: ()
 675 noAL  = ()
 676
 677 -- `loop' mutator maps a function over array elements
 678 --
 679 mapEFL   :: (e -> e') -> (e -> () -> (Maybe e', ()))
 680 {-# INLINE mapEFL #-}
 681 mapEFL f  = \e a -> (Just $ f e, ())
 682
 683 -- `loop' mutator that filter elements according to a predicate
 684 --
 685 filterEFL   :: (e -> Bool) -> (e -> () -> (Maybe e, ()))
 686 {-# INLINE filterEFL #-}
 687 filterEFL p  = \e a -> if p e then (Just e, ()) else (Nothing, ())
 688
 689 -- `loop' mutator for array folding
 690 --
 691 foldEFL   :: (e -> acc -> acc) -> (e -> acc -> (Maybe (), acc))
 692 {-# INLINE foldEFL #-}
 693 foldEFL f  = \e a -> (Nothing, f e a)
 694
 695 -- `loop' mutator for array scanning
 696 --
 697 scanEFL   :: (e -> acc -> acc) -> (e -> acc -> (Maybe acc, acc))
 698 {-# INLINE scanEFL #-}
 699 scanEFL f  = \e a -> (Just a, f e a)
 700
 701 -- elementary array operations
 702 --
 703
 704 -- unlifted array indexing
 705 --
 706 indexPArr                       :: [:e:] -> Int -> e
 707 {-# INLINE indexPArr #-}
 708 indexPArr (PArr n# arr#) (I# i#)
 709   | i# >=# 0# && i# <# n# =
 710     case indexArray# arr# i# of (# e #) -> e
 711   | otherwise = error $ "indexPArr: out of bounds parallel array index; " ++
 712                         "idx = " ++ show (I# i#) ++ ", arr len = "
 713                         ++ show (I# n#)
 714
 715 -- encapsulate writing into a mutable array into the `ST' monad
 716 --
 717 writeMPArr                           :: MPArr s e -> Int -> e -> ST s ()
 718 {-# INLINE writeMPArr #-}
 719 writeMPArr (MPArr n# marr#) (I# i#) e
 720   | i# >=# 0# && i# <# n# =
 721     ST $ \s# ->
 722     case writeArray# marr# i# e s# of s'# -> (# s'#, () #)
 723   | otherwise = error $ "writeMPArr: out of bounds parallel array index; " ++
 724                         "idx = " ++ show (I# i#) ++ ", arr len = "
 725                         ++ show (I# n#)
 726
 727 #endif /* __HADDOCK__ */
 728