GHC/Real.lhs

   1 \begin{code}
   2 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   3 {-# OPTIONS_HADDOCK hide #-}
   4 -----------------------------------------------------------------------------
   5 -- |
   6 -- Module      :  GHC.Real
   7 -- Copyright   :  (c) The University of Glasgow, 1994-2002
   8 -- License     :  see libraries/base/LICENSE
   9 --
  10 -- Maintainer  :  cvs-ghc@haskell.org
  11 -- Stability   :  internal
  12 -- Portability :  non-portable (GHC Extensions)
  13 --
  14 -- The types 'Ratio' and 'Rational', and the classes 'Real', 'Fractional',
  15 -- 'Integral', and 'RealFrac'.
  16 --
  17 -----------------------------------------------------------------------------
  18
  19 -- #hide
  20 module GHC.Real where
  21
  22 import GHC.Base
  23 import GHC.Num
  24 import GHC.List
  25 import GHC.Enum
  26 import GHC.Show
  27 import GHC.Err
  28
  29 infixr 8  ^, ^^
  30 infixl 7  /, `quot`, `rem`, `div`, `mod`
  31 infixl 7  %
  32
  33 default ()              -- Double isn't available yet,
  34                         -- and we shouldn't be using defaults anyway
  35 \end{code}
  36
  37
  38 %*********************************************************
  39 %*                                                      *
  40 \subsection{The @Ratio@ and @Rational@ types}
  41 %*                                                      *
  42 %*********************************************************
  43
  44 \begin{code}
  45 -- | Rational numbers, with numerator and denominator of some 'Integral' type.
  46 data  (Integral a)      => Ratio a = !a :% !a  deriving (Eq)
  47
  48 -- | Arbitrary-precision rational numbers, represented as a ratio of
  49 -- two 'Integer' values.  A rational number may be constructed using
  50 -- the '%' operator.
  51 type  Rational          =  Ratio Integer
  52
  53 ratioPrec, ratioPrec1 :: Int
  54 ratioPrec  = 7  -- Precedence of ':%' constructor
  55 ratioPrec1 = ratioPrec + 1
  56
  57 infinity, notANumber :: Rational
  58 infinity   = 1 :% 0
  59 notANumber = 0 :% 0
  60
  61 -- Use :%, not % for Inf/NaN; the latter would
  62 -- immediately lead to a runtime error, because it normalises.
  63 \end{code}
  64
  65
  66 \begin{code}
  67 -- | Forms the ratio of two integral numbers.
  68 {-# SPECIALISE (%) :: Integer -> Integer -> Rational #-}
  69 (%)                     :: (Integral a) => a -> a -> Ratio a
  70
  71 -- | Extract the numerator of the ratio in reduced form:
  72 -- the numerator and denominator have no common factor and the denominator
  73 -- is positive.
  74 numerator       :: (Integral a) => Ratio a -> a
  75
  76 -- | Extract the denominator of the ratio in reduced form:
  77 -- the numerator and denominator have no common factor and the denominator
  78 -- is positive.
  79 denominator     :: (Integral a) => Ratio a -> a
  80 \end{code}
  81
  82 \tr{reduce} is a subsidiary function used only in this module .
  83 It normalises a ratio by dividing both numerator and denominator by
  84 their greatest common divisor.
  85
  86 \begin{code}
  87 reduce ::  (Integral a) => a -> a -> Ratio a
  88 {-# SPECIALISE reduce :: Integer -> Integer -> Rational #-}
  89 reduce _ 0              =  error "Ratio.%: zero denominator"
  90 reduce x y              =  (x `quot` d) :% (y `quot` d)
  91                            where d = gcd x y
  92 \end{code}
  93
  94 \begin{code}
  95 x % y                   =  reduce (x * signum y) (abs y)
  96
  97 numerator   (x :% _)    =  x
  98 denominator (_ :% y)    =  y
  99 \end{code}
 100
 101
 102 %*********************************************************
 103 %*                                                      *
 104 \subsection{Standard numeric classes}
 105 %*                                                      *
 106 %*********************************************************
 107
 108 \begin{code}
 109 class  (Num a, Ord a) => Real a  where
 110     -- | the rational equivalent of its real argument with full precision
 111     toRational          ::  a -> Rational
 112
 113 -- | Integral numbers, supporting integer division.
 114 --
 115 -- Minimal complete definition: 'quotRem' and 'toInteger'
 116 class  (Real a, Enum a) => Integral a  where
 117     -- | integer division truncated toward zero
 118     quot                :: a -> a -> a
 119     -- | integer remainder, satisfying
 120     --
 121     -- > (x `quot` y)*y + (x `rem` y) == x
 122     rem                 :: a -> a -> a
 123     -- | integer division truncated toward negative infinity
 124     div                 :: a -> a -> a
 125     -- | integer modulus, satisfying
 126     --
 127     -- > (x `div` y)*y + (x `mod` y) == x
 128     mod                 :: a -> a -> a
 129     -- | simultaneous 'quot' and 'rem'
 130     quotRem             :: a -> a -> (a,a)
 131     -- | simultaneous 'div' and 'mod'
 132     divMod              :: a -> a -> (a,a)
 133     -- | conversion to 'Integer'
 134     toInteger           :: a -> Integer
 135
 136     {-# INLINE quot #-}
 137     {-# INLINE rem #-}
 138     {-# INLINE div #-}
 139     {-# INLINE mod #-}
 140     n `quot` d          =  q  where (q,_) = quotRem n d
 141     n `rem` d           =  r  where (_,r) = quotRem n d
 142     n `div` d           =  q  where (q,_) = divMod n d
 143     n `mod` d           =  r  where (_,r) = divMod n d
 144
 145     divMod n d          =  if signum r == negate (signum d) then (q-1, r+d) else qr
 146                            where qr@(q,r) = quotRem n d
 147
 148 -- | Fractional numbers, supporting real division.
 149 --
 150 -- Minimal complete definition: 'fromRational' and ('recip' or @('/')@)
 151 class  (Num a) => Fractional a  where
 152     -- | fractional division
 153     (/)                 :: a -> a -> a
 154     -- | reciprocal fraction
 155     recip               :: a -> a
 156     -- | Conversion from a 'Rational' (that is @'Ratio' 'Integer'@).
 157     -- A floating literal stands for an application of 'fromRational'
 158     -- to a value of type 'Rational', so such literals have type
 159     -- @('Fractional' a) => a@.
 160     fromRational        :: Rational -> a
 161
 162     {-# INLINE recip #-}
 163     {-# INLINE (/) #-}
 164     recip x             =  1 / x
 165     x / y               = x * recip y
 166
 167 -- | Extracting components of fractions.
 168 --
 169 -- Minimal complete definition: 'properFraction'
 170 class  (Real a, Fractional a) => RealFrac a  where
 171     -- | The function 'properFraction' takes a real fractional number @x@
 172     -- and returns a pair @(n,f)@ such that @x = n+f@, and:
 173     --
 174     -- * @n@ is an integral number with the same sign as @x@; and
 175     --
 176     -- * @f@ is a fraction with the same type and sign as @x@,
 177     --   and with absolute value less than @1@.
 178     --
 179     -- The default definitions of the 'ceiling', 'floor', 'truncate'
 180     -- and 'round' functions are in terms of 'properFraction'.
 181     properFraction      :: (Integral b) => a -> (b,a)
 182     -- | @'truncate' x@ returns the integer nearest @x@ between zero and @x@
 183     truncate            :: (Integral b) => a -> b
 184     -- | @'round' x@ returns the nearest integer to @x@;
 185     --   the even integer if @x@ is equidistant between two integers
 186     round               :: (Integral b) => a -> b
 187     -- | @'ceiling' x@ returns the least integer not less than @x@
 188     ceiling             :: (Integral b) => a -> b
 189     -- | @'floor' x@ returns the greatest integer not greater than @x@
 190     floor               :: (Integral b) => a -> b
 191
 192     {-# INLINE truncate #-}
 193     truncate x          =  m  where (m,_) = properFraction x
 194
 195     round x             =  let (n,r) = properFraction x
 196                                m     = if r < 0 then n - 1 else n + 1
 197                            in case signum (abs r - 0.5) of
 198                                 -1 -> n
 199                                 0  -> if even n then n else m
 200                                 1  -> m
 201                                 _  -> error "round default defn: Bad value"
 202
 203     ceiling x           =  if r > 0 then n + 1 else n
 204                            where (n,r) = properFraction x
 205
 206     floor x             =  if r < 0 then n - 1 else n
 207                            where (n,r) = properFraction x
 208 \end{code}
 209
 210
 211 These 'numeric' enumerations come straight from the Report
 212
 213 \begin{code}
 214 numericEnumFrom         :: (Fractional a) => a -> [a]
 215 numericEnumFrom n       =  n `seq` (n : numericEnumFrom (n + 1))
 216
 217 numericEnumFromThen     :: (Fractional a) => a -> a -> [a]
 218 numericEnumFromThen n m = n `seq` m `seq` (n : numericEnumFromThen m (m+m-n))
 219
 220 numericEnumFromTo       :: (Ord a, Fractional a) => a -> a -> [a]
 221 numericEnumFromTo n m   = takeWhile (<= m + 1/2) (numericEnumFrom n)
 222
 223 numericEnumFromThenTo   :: (Ord a, Fractional a) => a -> a -> a -> [a]
 224 numericEnumFromThenTo e1 e2 e3
 225     = takeWhile predicate (numericEnumFromThen e1 e2)
 226                                 where
 227                                  mid = (e2 - e1) / 2
 228                                  predicate | e2 >= e1  = (<= e3 + mid)
 229                                            | otherwise = (>= e3 + mid)
 230 \end{code}
 231
 232
 233 %*********************************************************
 234 %*                                                      *
 235 \subsection{Instances for @Int@}
 236 %*                                                      *
 237 %*********************************************************
 238
 239 \begin{code}
 240 instance  Real Int  where
 241     toRational x        =  toInteger x % 1
 242
 243 instance  Integral Int  where
 244     toInteger (I# i) = smallInteger i
 245
 246     a `quot` b
 247      | b == 0                     = divZeroError
 248      | a == minBound && b == (-1) = overflowError
 249      | otherwise                  =  a `quotInt` b
 250
 251     a `rem` b
 252      | b == 0                     = divZeroError
 253      | a == minBound && b == (-1) = overflowError
 254      | otherwise                  =  a `remInt` b
 255
 256     a `div` b
 257      | b == 0                     = divZeroError
 258      | a == minBound && b == (-1) = overflowError
 259      | otherwise                  =  a `divInt` b
 260
 261     a `mod` b
 262      | b == 0                     = divZeroError
 263      | a == minBound && b == (-1) = overflowError
 264      | otherwise                  =  a `modInt` b
 265
 266     a `quotRem` b
 267      | b == 0                     = divZeroError
 268      | a == minBound && b == (-1) = overflowError
 269      | otherwise                  =  a `quotRemInt` b
 270
 271     a `divMod` b
 272      | b == 0                     = divZeroError
 273      | a == minBound && b == (-1) = overflowError
 274      | otherwise                  =  a `divModInt` b
 275 \end{code}
 276
 277
 278 %*********************************************************
 279 %*                                                      *
 280 \subsection{Instances for @Integer@}
 281 %*                                                      *
 282 %*********************************************************
 283
 284 \begin{code}
 285 instance  Real Integer  where
 286     toRational x        =  x % 1
 287
 288 instance  Integral Integer where
 289     toInteger n      = n
 290
 291     _ `quot` 0 = divZeroError
 292     n `quot` d = n `quotInteger` d
 293
 294     _ `rem` 0 = divZeroError
 295     n `rem`  d = n `remInteger`  d
 296
 297     _ `divMod` 0 = divZeroError
 298     a `divMod` b = case a `divModInteger` b of
 299                    (# x, y #) -> (x, y)
 300
 301     _ `quotRem` 0 = divZeroError
 302     a `quotRem` b = case a `quotRemInteger` b of
 303                     (# q, r #) -> (q, r)
 304
 305     -- use the defaults for div & mod
 306 \end{code}
 307
 308
 309 %*********************************************************
 310 %*                                                      *
 311 \subsection{Instances for @Ratio@}
 312 %*                                                      *
 313 %*********************************************************
 314
 315 \begin{code}
 316 instance  (Integral a)  => Ord (Ratio a)  where
 317     {-# SPECIALIZE instance Ord Rational #-}
 318     (x:%y) <= (x':%y')  =  x * y' <= x' * y
 319     (x:%y) <  (x':%y')  =  x * y' <  x' * y
 320
 321 instance  (Integral a)  => Num (Ratio a)  where
 322     {-# SPECIALIZE instance Num Rational #-}
 323     (x:%y) + (x':%y')   =  reduce (x*y' + x'*y) (y*y')
 324     (x:%y) - (x':%y')   =  reduce (x*y' - x'*y) (y*y')
 325     (x:%y) * (x':%y')   =  reduce (x * x') (y * y')
 326     negate (x:%y)       =  (-x) :% y
 327     abs (x:%y)          =  abs x :% y
 328     signum (x:%_)       =  signum x :% 1
 329     fromInteger x       =  fromInteger x :% 1
 330
 331 instance  (Integral a)  => Fractional (Ratio a)  where
 332     {-# SPECIALIZE instance Fractional Rational #-}
 333     (x:%y) / (x':%y')   =  (x*y') % (y*x')
 334     recip (x:%y)        =  y % x
 335     fromRational (x:%y) =  fromInteger x :% fromInteger y
 336
 337 instance  (Integral a)  => Real (Ratio a)  where
 338     {-# SPECIALIZE instance Real Rational #-}
 339     toRational (x:%y)   =  toInteger x :% toInteger y
 340
 341 instance  (Integral a)  => RealFrac (Ratio a)  where
 342     {-# SPECIALIZE instance RealFrac Rational #-}
 343     properFraction (x:%y) = (fromInteger (toInteger q), r:%y)
 344                           where (q,r) = quotRem x y
 345
 346 instance  (Integral a)  => Show (Ratio a)  where
 347     {-# SPECIALIZE instance Show Rational #-}
 348     showsPrec p (x:%y)  =  showParen (p > ratioPrec) $
 349                            showsPrec ratioPrec1 x .
 350                            showString " % " .
 351                            -- H98 report has spaces round the %
 352                            -- but we removed them [May 04]
 353                            -- and added them again for consistency with
 354                            -- Haskell 98 [Sep 08, #1920]
 355                            showsPrec ratioPrec1 y
 356
 357 instance  (Integral a)  => Enum (Ratio a)  where
 358     {-# SPECIALIZE instance Enum Rational #-}
 359     succ x              =  x + 1
 360     pred x              =  x - 1
 361
 362     toEnum n            =  fromIntegral n :% 1
 363     fromEnum            =  fromInteger . truncate
 364
 365     enumFrom            =  numericEnumFrom
 366     enumFromThen        =  numericEnumFromThen
 367     enumFromTo          =  numericEnumFromTo
 368     enumFromThenTo      =  numericEnumFromThenTo
 369 \end{code}
 370
 371
 372 %*********************************************************
 373 %*                                                      *
 374 \subsection{Coercions}
 375 %*                                                      *
 376 %*********************************************************
 377
 378 \begin{code}
 379 -- | general coercion from integral types
 380 fromIntegral :: (Integral a, Num b) => a -> b
 381 fromIntegral = fromInteger . toInteger
 382
 383 {-# RULES
 384 "fromIntegral/Int->Int" fromIntegral = id :: Int -> Int
 385     #-}
 386
 387 -- | general coercion to fractional types
 388 realToFrac :: (Real a, Fractional b) => a -> b
 389 realToFrac = fromRational . toRational
 390
 391 {-# RULES
 392 "realToFrac/Int->Int" realToFrac = id :: Int -> Int
 393     #-}
 394 \end{code}
 395
 396 %*********************************************************
 397 %*                                                      *
 398 \subsection{Overloaded numeric functions}
 399 %*                                                      *
 400 %*********************************************************
 401
 402 \begin{code}
 403 -- | Converts a possibly-negative 'Real' value to a string.
 404 showSigned :: (Real a)
 405   => (a -> ShowS)       -- ^ a function that can show unsigned values
 406   -> Int                -- ^ the precedence of the enclosing context
 407   -> a                  -- ^ the value to show
 408   -> ShowS
 409 showSigned showPos p x
 410    | x < 0     = showParen (p > 6) (showChar '-' . showPos (-x))
 411    | otherwise = showPos x
 412
 413 even, odd       :: (Integral a) => a -> Bool
 414 even n          =  n `rem` 2 == 0
 415 odd             =  not . even
 416
 417 -------------------------------------------------------
 418 -- | raise a number to a non-negative integral power
 419 {-# SPECIALISE (^) ::
 420         Integer -> Integer -> Integer,
 421         Integer -> Int -> Integer,
 422         Int -> Int -> Int #-}
 423 (^) :: (Num a, Integral b) => a -> b -> a
 424 x0 ^ y0 | y0 < 0    = error "Negative exponent"
 425         | y0 == 0   = 1
 426         | otherwise = f x0 y0
 427     where -- f : x0 ^ y0 = x ^ y
 428           f x y | even y    = f (x * x) (y `quot` 2)
 429                 | y == 1    = x
 430                 | otherwise = g (x * x) ((y - 1) `quot` 2) x
 431           -- g : x0 ^ y0 = (x ^ y) * z
 432           g x y z | even y = g (x * x) (y `quot` 2) z
 433                   | y == 1 = x * z
 434                   | otherwise = g (x * x) ((y - 1) `quot` 2) (x * z)
 435
 436 -- | raise a number to an integral power
 437 {-# SPECIALISE (^^) ::
 438         Rational -> Int -> Rational #-}
 439 (^^)            :: (Fractional a, Integral b) => a -> b -> a
 440 x ^^ n          =  if n >= 0 then x^n else recip (x^(negate n))
 441
 442
 443 -------------------------------------------------------
 444 -- | @'gcd' x y@ is the greatest (positive) integer that divides both @x@
 445 -- and @y@; for example @'gcd' (-3) 6@ = @3@, @'gcd' (-3) (-6)@ = @3@,
 446 -- @'gcd' 0 4@ = @4@.  @'gcd' 0 0@ raises a runtime error.
 447 gcd             :: (Integral a) => a -> a -> a
 448 gcd 0 0         =  error "Prelude.gcd: gcd 0 0 is undefined"
 449 gcd x y         =  gcd' (abs x) (abs y)
 450                    where gcd' a 0  =  a
 451                          gcd' a b  =  gcd' b (a `rem` b)
 452
 453 -- | @'lcm' x y@ is the smallest positive integer that both @x@ and @y@ divide.
 454 lcm             :: (Integral a) => a -> a -> a
 455 {-# SPECIALISE lcm :: Int -> Int -> Int #-}
 456 lcm _ 0         =  0
 457 lcm 0 _         =  0
 458 lcm x y         =  abs ((x `quot` (gcd x y)) * y)
 459
 460 #ifdef OPTIMISE_INTEGER_GCD_LCM
 461 {-# RULES
 462 "gcd/Int->Int->Int"             gcd = gcdInt
 463 "gcd/Integer->Integer->Integer" gcd = gcdInteger'
 464 "lcm/Integer->Integer->Integer" lcm = lcmInteger
 465  #-}
 466
 467 gcdInteger' :: Integer -> Integer -> Integer
 468 gcdInteger' 0 0 = error "GHC.Real.gcdInteger': gcd 0 0 is undefined"
 469 gcdInteger' a b = gcdInteger a b
 470
 471 gcdInt :: Int -> Int -> Int
 472 gcdInt 0 0 = error "GHC.Real.gcdInt: gcd 0 0 is undefined"
 473 gcdInt a b = fromIntegral (gcdInteger (fromIntegral a) (fromIntegral b))
 474 #endif
 475
 476 integralEnumFrom :: (Integral a, Bounded a) => a -> [a]
 477 integralEnumFrom n = map fromInteger [toInteger n .. toInteger (maxBound `asTypeOf` n)]
 478
 479 integralEnumFromThen :: (Integral a, Bounded a) => a -> a -> [a]
 480 integralEnumFromThen n1 n2
 481   | i_n2 >= i_n1  = map fromInteger [i_n1, i_n2 .. toInteger (maxBound `asTypeOf` n1)]
 482   | otherwise     = map fromInteger [i_n1, i_n2 .. toInteger (minBound `asTypeOf` n1)]
 483   where
 484     i_n1 = toInteger n1
 485     i_n2 = toInteger n2
 486
 487 integralEnumFromTo :: Integral a => a -> a -> [a]
 488 integralEnumFromTo n m = map fromInteger [toInteger n .. toInteger m]
 489
 490 integralEnumFromThenTo :: Integral a => a -> a -> a -> [a]
 491 integralEnumFromThenTo n1 n2 m
 492   = map fromInteger [toInteger n1, toInteger n2 .. toInteger m]
 493 \end{code}