GHC/Real.lhs

   1 \begin{code}
   2 {-# OPTIONS -fno-implicit-prelude #-}
   3 -----------------------------------------------------------------------------
   4 -- |
   5 -- Module      :  GHC.Real
   6 -- Copyright   :  (c) The FFI Task Force, 1994-2002
   7 -- License     :  see libraries/base/LICENSE
   8 --
   9 -- Maintainer  :  cvs-ghc@haskell.org
  10 -- Stability   :  internal
  11 -- Portability :  non-portable (GHC Extensions)
  12 --
  13 -- The types 'Ratio' and 'Rational', and the classes 'Real', 'Fractional',
  14 -- 'Integral', and 'RealFrac'.
  15 --
  16 -----------------------------------------------------------------------------
  17
  18 module GHC.Real where
  19
  20 import {-# SOURCE #-} GHC.Err
  21 import GHC.Base
  22 import GHC.Num
  23 import GHC.List
  24 import GHC.Enum
  25 import GHC.Show
  26
  27 infixr 8  ^, ^^
  28 infixl 7  /, `quot`, `rem`, `div`, `mod`
  29 infixl 7  %
  30
  31 default ()              -- Double isn't available yet,
  32                         -- and we shouldn't be using defaults anyway
  33 \end{code}
  34
  35
  36 %*********************************************************
  37 %*                                                      *
  38 \subsection{The @Ratio@ and @Rational@ types}
  39 %*                                                      *
  40 %*********************************************************
  41
  42 \begin{code}
  43 data  (Integral a)      => Ratio a = !a :% !a  deriving (Eq)
  44
  45 -- | Arbitrary-precision rational numbers, represented as a ratio of
  46 -- two 'Integer' values.  A rational number may be constructed using
  47 -- the '%' operator.
  48 type  Rational          =  Ratio Integer
  49
  50 ratioPrec, ratioPrec1 :: Int
  51 ratioPrec  = 7  -- Precedence of ':%' constructor
  52 ratioPrec1 = ratioPrec + 1
  53
  54 infinity, notANumber :: Rational
  55 infinity   = 1 :% 0
  56 notANumber = 0 :% 0
  57
  58 -- Use :%, not % for Inf/NaN; the latter would
  59 -- immediately lead to a runtime error, because it normalises.
  60 \end{code}
  61
  62
  63 \begin{code}
  64 {-# SPECIALISE (%) :: Integer -> Integer -> Rational #-}
  65 (%)                     :: (Integral a) => a -> a -> Ratio a
  66 numerator, denominator  :: (Integral a) => Ratio a -> a
  67 \end{code}
  68
  69 \tr{reduce} is a subsidiary function used only in this module .
  70 It normalises a ratio by dividing both numerator and denominator by
  71 their greatest common divisor.
  72
  73 \begin{code}
  74 reduce ::  (Integral a) => a -> a -> Ratio a
  75 {-# SPECIALISE reduce :: Integer -> Integer -> Rational #-}
  76 reduce _ 0              =  error "Ratio.%: zero denominator"
  77 reduce x y              =  (x `quot` d) :% (y `quot` d)
  78                            where d = gcd x y
  79 \end{code}
  80
  81 \begin{code}
  82 x % y                   =  reduce (x * signum y) (abs y)
  83
  84 numerator   (x :% _)    =  x
  85 denominator (_ :% y)    =  y
  86 \end{code}
  87
  88
  89 %*********************************************************
  90 %*                                                      *
  91 \subsection{Standard numeric classes}
  92 %*                                                      *
  93 %*********************************************************
  94
  95 \begin{code}
  96 class  (Num a, Ord a) => Real a  where
  97     toRational          ::  a -> Rational
  98
  99 class  (Real a, Enum a) => Integral a  where
 100     quot, rem, div, mod :: a -> a -> a
 101     quotRem, divMod     :: a -> a -> (a,a)
 102     toInteger           :: a -> Integer
 103
 104     n `quot` d          =  q  where (q,_) = quotRem n d
 105     n `rem` d           =  r  where (_,r) = quotRem n d
 106     n `div` d           =  q  where (q,_) = divMod n d
 107     n `mod` d           =  r  where (_,r) = divMod n d
 108     divMod n d          =  if signum r == negate (signum d) then (q-1, r+d) else qr
 109                            where qr@(q,r) = quotRem n d
 110
 111 class  (Num a) => Fractional a  where
 112     (/)                 :: a -> a -> a
 113     recip               :: a -> a
 114     fromRational        :: Rational -> a
 115
 116     recip x             =  1 / x
 117     x / y               = x * recip y
 118
 119 class  (Real a, Fractional a) => RealFrac a  where
 120     properFraction      :: (Integral b) => a -> (b,a)
 121     truncate, round     :: (Integral b) => a -> b
 122     ceiling, floor      :: (Integral b) => a -> b
 123
 124     truncate x          =  m  where (m,_) = properFraction x
 125
 126     round x             =  let (n,r) = properFraction x
 127                                m     = if r < 0 then n - 1 else n + 1
 128                            in case signum (abs r - 0.5) of
 129                                 -1 -> n
 130                                 0  -> if even n then n else m
 131                                 1  -> m
 132
 133     ceiling x           =  if r > 0 then n + 1 else n
 134                            where (n,r) = properFraction x
 135
 136     floor x             =  if r < 0 then n - 1 else n
 137                            where (n,r) = properFraction x
 138 \end{code}
 139
 140
 141 These 'numeric' enumerations come straight from the Report
 142
 143 \begin{code}
 144 numericEnumFrom         :: (Fractional a) => a -> [a]
 145 numericEnumFrom         =  iterate (+1)
 146
 147 numericEnumFromThen     :: (Fractional a) => a -> a -> [a]
 148 numericEnumFromThen n m =  iterate (+(m-n)) n
 149
 150 numericEnumFromTo       :: (Ord a, Fractional a) => a -> a -> [a]
 151 numericEnumFromTo n m   = takeWhile (<= m + 1/2) (numericEnumFrom n)
 152
 153 numericEnumFromThenTo   :: (Ord a, Fractional a) => a -> a -> a -> [a]
 154 numericEnumFromThenTo e1 e2 e3 = takeWhile pred (numericEnumFromThen e1 e2)
 155                                 where
 156                                  mid = (e2 - e1) / 2
 157                                  pred | e2 > e1   = (<= e3 + mid)
 158                                       | otherwise = (>= e3 + mid)
 159 \end{code}
 160
 161
 162 %*********************************************************
 163 %*                                                      *
 164 \subsection{Instances for @Int@}
 165 %*                                                      *
 166 %*********************************************************
 167
 168 \begin{code}
 169 instance  Real Int  where
 170     toRational x        =  toInteger x % 1
 171
 172 instance  Integral Int  where
 173     toInteger i = int2Integer i  -- give back a full-blown Integer
 174
 175     -- Following chks for zero divisor are non-standard (WDP)
 176     a `quot` b  =  if b /= 0
 177                    then a `quotInt` b
 178                    else error "Prelude.Integral.quot{Int}: divide by 0"
 179     a `rem` b   =  if b /= 0
 180                    then a `remInt` b
 181                    else error "Prelude.Integral.rem{Int}: divide by 0"
 182
 183     x `div` y = x `divInt` y
 184     x `mod` y = x `modInt` y
 185
 186     a `quotRem` b = a `quotRemInt` b
 187     a `divMod`  b = a `divModInt`  b
 188 \end{code}
 189
 190
 191 %*********************************************************
 192 %*                                                      *
 193 \subsection{Instances for @Integer@}
 194 %*                                                      *
 195 %*********************************************************
 196
 197 \begin{code}
 198 instance  Real Integer  where
 199     toRational x        =  x % 1
 200
 201 instance  Integral Integer where
 202     toInteger n      = n
 203
 204     n `quot` d = n `quotInteger` d
 205     n `rem`  d = n `remInteger`  d
 206
 207     n `div` d   =  q  where (q,_) = divMod n d
 208     n `mod` d   =  r  where (_,r) = divMod n d
 209
 210     a `divMod` b = a `divModInteger` b
 211     a `quotRem` b = a `quotRemInteger` b
 212 \end{code}
 213
 214
 215 %*********************************************************
 216 %*                                                      *
 217 \subsection{Instances for @Ratio@}
 218 %*                                                      *
 219 %*********************************************************
 220
 221 \begin{code}
 222 instance  (Integral a)  => Ord (Ratio a)  where
 223     {-# SPECIALIZE instance Ord Rational #-}
 224     (x:%y) <= (x':%y')  =  x * y' <= x' * y
 225     (x:%y) <  (x':%y')  =  x * y' <  x' * y
 226
 227 instance  (Integral a)  => Num (Ratio a)  where
 228     {-# SPECIALIZE instance Num Rational #-}
 229     (x:%y) + (x':%y')   =  reduce (x*y' + x'*y) (y*y')
 230     (x:%y) - (x':%y')   =  reduce (x*y' - x'*y) (y*y')
 231     (x:%y) * (x':%y')   =  reduce (x * x') (y * y')
 232     negate (x:%y)       =  (-x) :% y
 233     abs (x:%y)          =  abs x :% y
 234     signum (x:%_)       =  signum x :% 1
 235     fromInteger x       =  fromInteger x :% 1
 236
 237 instance  (Integral a)  => Fractional (Ratio a)  where
 238     {-# SPECIALIZE instance Fractional Rational #-}
 239     (x:%y) / (x':%y')   =  (x*y') % (y*x')
 240     recip (x:%y)        =  y % x
 241     fromRational (x:%y) =  fromInteger x :% fromInteger y
 242
 243 instance  (Integral a)  => Real (Ratio a)  where
 244     {-# SPECIALIZE instance Real Rational #-}
 245     toRational (x:%y)   =  toInteger x :% toInteger y
 246
 247 instance  (Integral a)  => RealFrac (Ratio a)  where
 248     {-# SPECIALIZE instance RealFrac Rational #-}
 249     properFraction (x:%y) = (fromInteger (toInteger q), r:%y)
 250                           where (q,r) = quotRem x y
 251
 252 instance  (Integral a)  => Show (Ratio a)  where
 253     {-# SPECIALIZE instance Show Rational #-}
 254     showsPrec p (x:%y)  =  showParen (p > ratioPrec) $
 255                            showsPrec ratioPrec1 x .
 256                            showString " % " .
 257                            showsPrec ratioPrec1 y
 258
 259 instance  (Integral a)  => Enum (Ratio a)  where
 260     {-# SPECIALIZE instance Enum Rational #-}
 261     succ x              =  x + 1
 262     pred x              =  x - 1
 263
 264     toEnum n            =  fromInteger (int2Integer n) :% 1
 265     fromEnum            =  fromInteger . truncate
 266
 267     enumFrom            =  numericEnumFrom
 268     enumFromThen        =  numericEnumFromThen
 269     enumFromTo          =  numericEnumFromTo
 270     enumFromThenTo      =  numericEnumFromThenTo
 271 \end{code}
 272
 273
 274 %*********************************************************
 275 %*                                                      *
 276 \subsection{Coercions}
 277 %*                                                      *
 278 %*********************************************************
 279
 280 \begin{code}
 281 fromIntegral :: (Integral a, Num b) => a -> b
 282 fromIntegral = fromInteger . toInteger
 283
 284 {-# RULES
 285 "fromIntegral/Int->Int" fromIntegral = id :: Int -> Int
 286     #-}
 287
 288 realToFrac :: (Real a, Fractional b) => a -> b
 289 realToFrac = fromRational . toRational
 290
 291 {-# RULES
 292 "realToFrac/Int->Int" realToFrac = id :: Int -> Int
 293     #-}
 294 \end{code}
 295
 296 %*********************************************************
 297 %*                                                      *
 298 \subsection{Overloaded numeric functions}
 299 %*                                                      *
 300 %*********************************************************
 301
 302 \begin{code}
 303 showSigned :: (Real a) => (a -> ShowS) -> Int -> a -> ShowS
 304 showSigned showPos p x
 305    | x < 0     = showParen (p > 6) (showChar '-' . showPos (-x))
 306    | otherwise = showPos x
 307
 308 even, odd       :: (Integral a) => a -> Bool
 309 even n          =  n `rem` 2 == 0
 310 odd             =  not . even
 311
 312 -------------------------------------------------------
 313 {-# SPECIALISE (^) ::
 314         Integer -> Integer -> Integer,
 315         Integer -> Int -> Integer,
 316         Int -> Int -> Int #-}
 317 (^)             :: (Num a, Integral b) => a -> b -> a
 318 _ ^ 0           =  1
 319 x ^ n | n > 0   =  f x (n-1) x
 320                    where f _ 0 y = y
 321                          f a d y = g a d  where
 322                                    g b i | even i  = g (b*b) (i `quot` 2)
 323                                          | otherwise = f b (i-1) (b*y)
 324 _ ^ _           = error "Prelude.^: negative exponent"
 325
 326 {-# SPECIALISE (^^) ::
 327         Rational -> Int -> Rational #-}
 328 (^^)            :: (Fractional a, Integral b) => a -> b -> a
 329 x ^^ n          =  if n >= 0 then x^n else recip (x^(negate n))
 330
 331
 332 -------------------------------------------------------
 333 gcd             :: (Integral a) => a -> a -> a
 334 gcd 0 0         =  error "Prelude.gcd: gcd 0 0 is undefined"
 335 gcd x y         =  gcd' (abs x) (abs y)
 336                    where gcd' a 0  =  a
 337                          gcd' a b  =  gcd' b (a `rem` b)
 338
 339 lcm             :: (Integral a) => a -> a -> a
 340 {-# SPECIALISE lcm :: Int -> Int -> Int #-}
 341 lcm _ 0         =  0
 342 lcm 0 _         =  0
 343 lcm x y         =  abs ((x `quot` (gcd x y)) * y)
 344
 345
 346 {-# RULES
 347 "gcd/Int->Int->Int"             gcd = gcdInt
 348 "gcd/Integer->Integer->Integer" gcd = gcdInteger
 349 "lcm/Integer->Integer->Integer" lcm = lcmInteger
 350  #-}
 351
 352 integralEnumFrom :: (Integral a, Bounded a) => a -> [a]
 353 integralEnumFrom n = map fromInteger [toInteger n .. toInteger (maxBound `asTypeOf` n)]
 354
 355 integralEnumFromThen :: (Integral a, Bounded a) => a -> a -> [a]
 356 integralEnumFromThen n1 n2
 357   | i_n2 >= i_n1  = map fromInteger [i_n1, i_n2 .. toInteger (maxBound `asTypeOf` n1)]
 358   | otherwise     = map fromInteger [i_n1, i_n2 .. toInteger (minBound `asTypeOf` n1)]
 359   where
 360     i_n1 = toInteger n1
 361     i_n2 = toInteger n2
 362
 363 integralEnumFromTo :: Integral a => a -> a -> [a]
 364 integralEnumFromTo n m = map fromInteger [toInteger n .. toInteger m]
 365
 366 integralEnumFromThenTo :: Integral a => a -> a -> a -> [a]
 367 integralEnumFromThenTo n1 n2 m
 368   = map fromInteger [toInteger n1, toInteger n2 .. toInteger m]
 369 \end{code}