System/CPUTime.hsc

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  System.CPUTime
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  provisional
   9 -- Portability :  portable
  10 --
  11 -- The standard CPUTime library.
  12 --
  13 -----------------------------------------------------------------------------
  14
  15 module System.CPUTime
  16         (
  17          getCPUTime,       -- :: IO Integer
  18          cpuTimePrecision  -- :: Integer
  19         ) where
  20
  21 import Prelude
  22
  23 import Data.Ratio
  24
  25 #ifdef __HUGS__
  26 import Hugs.Time ( getCPUTime, clockTicks )
  27 #endif
  28
  29 #ifdef __NHC__
  30 import CPUTime ( getCPUTime, cpuTimePrecision )
  31 #endif
  32
  33 #ifdef __GLASGOW_HASKELL__
  34 import Foreign
  35 import Foreign.C
  36
  37 #include "HsBaseConfig.h"
  38
  39 -- For _SC_CLK_TCK
  40 #if HAVE_UNISTD_H
  41 #include <unistd.h>
  42 #endif
  43
  44 -- For struct rusage
  45 #if !defined(mingw32_HOST_OS) && !defined(irix_HOST_OS)
  46 # if HAVE_SYS_RESOURCE_H
  47 #  include <sys/resource.h>
  48 # endif
  49 #endif
  50
  51 -- For FILETIME etc. on Windows
  52 #if HAVE_WINDOWS_H
  53 #include <windows.h>
  54 #endif
  55
  56 -- for CLK_TCK
  57 #if HAVE_TIME_H
  58 #include <time.h>
  59 #endif
  60
  61 #endif
  62
  63 #if !defined(mingw32_HOST_OS) && !defined(cygwin32_HOST_OS)
  64 realToInteger :: Real a => a -> Integer
  65 realToInteger ct = round (realToFrac ct :: Double)
  66   -- CTime, CClock, CUShort etc are in Real but not Fractional,
  67   -- so we must convert to Double before we can round it
  68 #endif
  69
  70 #ifdef __GLASGOW_HASKELL__
  71 -- -----------------------------------------------------------------------------
  72 -- |Computation 'getCPUTime' returns the number of picoseconds CPU time
  73 -- used by the current program.  The precision of this result is
  74 -- implementation-dependent.
  75
  76 getCPUTime :: IO Integer
  77 getCPUTime = do
  78
  79 #if !defined(mingw32_HOST_OS) && !defined(cygwin32_HOST_OS)
  80 -- getrusage() is right royal pain to deal with when targetting multiple
  81 -- versions of Solaris, since some versions supply it in libc (2.3 and 2.5),
  82 -- while 2.4 has got it in libucb (I wouldn't be too surprised if it was back
  83 -- again in libucb in 2.6..)
  84 --
  85 -- Avoid the problem by resorting to times() instead.
  86 --
  87 #if defined(HAVE_GETRUSAGE) && ! irix_HOST_OS && ! solaris2_HOST_OS
  88     allocaBytes (#const sizeof(struct rusage)) $ \ p_rusage -> do
  89     getrusage (#const RUSAGE_SELF) p_rusage
  90
  91     let ru_utime = (#ptr struct rusage, ru_utime) p_rusage
  92     let ru_stime = (#ptr struct rusage, ru_stime) p_rusage
  93     u_sec  <- (#peek struct timeval,tv_sec)  ru_utime :: IO CTime
  94     u_usec <- (#peek struct timeval,tv_usec) ru_utime :: IO CTime
  95     s_sec  <- (#peek struct timeval,tv_sec)  ru_stime :: IO CTime
  96     s_usec <- (#peek struct timeval,tv_usec) ru_stime :: IO CTime
  97     return ((realToInteger u_sec * 1000000 + realToInteger u_usec +
  98              realToInteger s_sec * 1000000 + realToInteger s_usec)
  99                 * 1000000)
 100
 101 type CRUsage = ()
 102 foreign import ccall unsafe getrusage :: CInt -> Ptr CRUsage -> IO CInt
 103 #else
 104 # if defined(HAVE_TIMES)
 105     allocaBytes (#const sizeof(struct tms)) $ \ p_tms -> do
 106     times p_tms
 107     u_ticks  <- (#peek struct tms,tms_utime) p_tms :: IO CClock
 108     s_ticks  <- (#peek struct tms,tms_stime) p_tms :: IO CClock
 109     return (( (realToInteger u_ticks + realToInteger s_ticks) * 1000000000000)
 110                         `div` fromIntegral clockTicks)
 111
 112 type CTms = ()
 113 foreign import ccall unsafe times :: Ptr CTms -> IO CClock
 114 # else
 115     ioException (IOError Nothing UnsupportedOperation
 116                          "getCPUTime"
 117                          "can't get CPU time"
 118                          Nothing)
 119 # endif
 120 #endif
 121
 122 #else /* win32 */
 123      -- NOTE: GetProcessTimes() is only supported on NT-based OSes.
 124      -- The counts reported by GetProcessTimes() are in 100-ns (10^-7) units.
 125     allocaBytes (#const sizeof(FILETIME)) $ \ p_creationTime -> do
 126     allocaBytes (#const sizeof(FILETIME)) $ \ p_exitTime -> do
 127     allocaBytes (#const sizeof(FILETIME)) $ \ p_kernelTime -> do
 128     allocaBytes (#const sizeof(FILETIME)) $ \ p_userTime -> do
 129     pid <- getCurrentProcess
 130     ok <- getProcessTimes pid p_creationTime p_exitTime p_kernelTime p_userTime
 131     if toBool ok then do
 132       ut <- ft2psecs p_userTime
 133       kt <- ft2psecs p_kernelTime
 134       return (ut + kt)
 135      else return 0
 136   where
 137         ft2psecs :: Ptr FILETIME -> IO Integer
 138         ft2psecs ft = do
 139           high <- (#peek FILETIME,dwHighDateTime) ft :: IO Word32
 140           low  <- (#peek FILETIME,dwLowDateTime)  ft :: IO Word32
 141             -- Convert 100-ns units to picosecs (10^-12)
 142             -- => multiply by 10^5.
 143           return (((fromIntegral high) * (2^(32::Int)) + (fromIntegral low)) * 100000)
 144
 145     -- ToDo: pin down elapsed times to just the OS thread(s) that
 146     -- are evaluating/managing Haskell code.
 147
 148 type FILETIME = ()
 149 type HANDLE = ()
 150 -- need proper Haskell names (initial lower-case character)
 151 foreign import stdcall unsafe "GetCurrentProcess" getCurrentProcess :: IO (Ptr HANDLE)
 152 foreign import stdcall unsafe "GetProcessTimes" getProcessTimes :: Ptr HANDLE -> Ptr FILETIME -> Ptr FILETIME -> Ptr FILETIME -> Ptr FILETIME -> IO CInt
 153
 154 #endif /* not _WIN32 */
 155 #endif /* __GLASGOW_HASKELL__ */
 156
 157 -- |The 'cpuTimePrecision' constant is the smallest measurable difference
 158 -- in CPU time that the implementation can record, and is given as an
 159 -- integral number of picoseconds.
 160
 161 #ifndef __NHC__
 162 cpuTimePrecision :: Integer
 163 cpuTimePrecision = round ((1000000000000::Integer) % fromIntegral (clockTicks))
 164 #endif
 165
 166 #ifdef __GLASGOW_HASKELL__
 167 clockTicks :: Int
 168 clockTicks =
 169 #if defined(CLK_TCK)
 170     (#const CLK_TCK)
 171 #else
 172     unsafePerformIO (sysconf (#const _SC_CLK_TCK) >>= return . fromIntegral)
 173 foreign import ccall unsafe sysconf :: CInt -> IO CLong
 174 #endif
 175 #endif /* __GLASGOW_HASKELL__ */