System/IO.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  System.IO
   5 -- Copyright   :  (c) The University of Glasgow 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  libraries@haskell.org
   9 -- Stability   :  stable
  10 -- Portability :  portable
  11 --
  12 -- The standard IO library.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module System.IO (
  17     -- * The IO monad
  18
  19     IO,                        -- instance MonadFix
  20     fixIO,                     -- :: (a -> IO a) -> IO a
  21
  22     -- * Files and handles
  23
  24     FilePath,                  -- :: String
  25
  26     Handle,             -- abstract, instance of: Eq, Show.
  27
  28     -- ** Standard handles
  29
  30     -- | Three handles are allocated during program initialisation,
  31     -- and are initially open.
  32
  33     stdin, stdout, stderr,   -- :: Handle
  34
  35     -- * Opening and closing files
  36
  37     -- ** Opening files
  38
  39     withFile,
  40     openFile,                  -- :: FilePath -> IOMode -> IO Handle
  41     IOMode(ReadMode,WriteMode,AppendMode,ReadWriteMode),
  42
  43     -- ** Closing files
  44
  45     hClose,                    -- :: Handle -> IO ()
  46
  47     -- ** Special cases
  48
  49     -- | These functions are also exported by the "Prelude".
  50
  51     readFile,                  -- :: FilePath -> IO String
  52     writeFile,                 -- :: FilePath -> String -> IO ()
  53     appendFile,                -- :: FilePath -> String -> IO ()
  54
  55     -- ** File locking
  56
  57     -- $locking
  58
  59     -- * Operations on handles
  60
  61     -- ** Determining and changing the size of a file
  62
  63     hFileSize,                 -- :: Handle -> IO Integer
  64 #ifdef __GLASGOW_HASKELL__
  65     hSetFileSize,              -- :: Handle -> Integer -> IO ()
  66 #endif
  67
  68     -- ** Detecting the end of input
  69
  70     hIsEOF,                    -- :: Handle -> IO Bool
  71     isEOF,                     -- :: IO Bool
  72
  73     -- ** Buffering operations
  74
  75     BufferMode(NoBuffering,LineBuffering,BlockBuffering),
  76     hSetBuffering,             -- :: Handle -> BufferMode -> IO ()
  77     hGetBuffering,             -- :: Handle -> IO BufferMode
  78     hFlush,                    -- :: Handle -> IO ()
  79
  80     -- ** Repositioning handles
  81
  82     hGetPosn,                  -- :: Handle -> IO HandlePosn
  83     hSetPosn,                  -- :: HandlePosn -> IO ()
  84     HandlePosn,                -- abstract, instance of: Eq, Show.
  85
  86     hSeek,                     -- :: Handle -> SeekMode -> Integer -> IO ()
  87     SeekMode(AbsoluteSeek,RelativeSeek,SeekFromEnd),
  88 #if !defined(__NHC__)
  89     hTell,                     -- :: Handle -> IO Integer
  90 #endif
  91
  92     -- ** Handle properties
  93
  94     hIsOpen, hIsClosed,        -- :: Handle -> IO Bool
  95     hIsReadable, hIsWritable,  -- :: Handle -> IO Bool
  96     hIsSeekable,               -- :: Handle -> IO Bool
  97
  98     -- ** Terminal operations (not portable: GHC\/Hugs only)
  99
 100 #if !defined(__NHC__)
 101     hIsTerminalDevice,          -- :: Handle -> IO Bool
 102
 103     hSetEcho,                   -- :: Handle -> Bool -> IO ()
 104     hGetEcho,                   -- :: Handle -> IO Bool
 105 #endif
 106
 107     -- ** Showing handle state (not portable: GHC only)
 108
 109 #ifdef __GLASGOW_HASKELL__
 110     hShow,                      -- :: Handle -> IO String
 111 #endif
 112
 113     -- * Text input and output
 114
 115     -- ** Text input
 116
 117     hWaitForInput,             -- :: Handle -> Int -> IO Bool
 118     hReady,                    -- :: Handle -> IO Bool
 119     hGetChar,                  -- :: Handle -> IO Char
 120     hGetLine,                  -- :: Handle -> IO [Char]
 121     hLookAhead,                -- :: Handle -> IO Char
 122     hGetContents,              -- :: Handle -> IO [Char]
 123
 124     -- ** Text output
 125
 126     hPutChar,                  -- :: Handle -> Char -> IO ()
 127     hPutStr,                   -- :: Handle -> [Char] -> IO ()
 128     hPutStrLn,                 -- :: Handle -> [Char] -> IO ()
 129     hPrint,                    -- :: Show a => Handle -> a -> IO ()
 130
 131     -- ** Special cases for standard input and output
 132
 133     -- | These functions are also exported by the "Prelude".
 134
 135     interact,                  -- :: (String -> String) -> IO ()
 136     putChar,                   -- :: Char   -> IO ()
 137     putStr,                    -- :: String -> IO ()
 138     putStrLn,                  -- :: String -> IO ()
 139     print,                     -- :: Show a => a -> IO ()
 140     getChar,                   -- :: IO Char
 141     getLine,                   -- :: IO String
 142     getContents,               -- :: IO String
 143     readIO,                    -- :: Read a => String -> IO a
 144     readLn,                    -- :: Read a => IO a
 145
 146     -- * Binary input and output
 147
 148     withBinaryFile,
 149     openBinaryFile,            -- :: FilePath -> IOMode -> IO Handle
 150     hSetBinaryMode,            -- :: Handle -> Bool -> IO ()
 151     hPutBuf,                   -- :: Handle -> Ptr a -> Int -> IO ()
 152     hGetBuf,                   -- :: Handle -> Ptr a -> Int -> IO Int
 153 #if !defined(__NHC__) && !defined(__HUGS__)
 154     hPutBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 155     hGetBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 156 #endif
 157
 158     -- * Temporary files
 159
 160     openTempFile,
 161     openBinaryTempFile,
 162   ) where
 163
 164 import Control.Exception.Base
 165
 166 #ifndef __NHC__
 167 import Data.Bits
 168 import Data.List
 169 import Data.Maybe
 170 import Foreign.C.Error
 171 import Foreign.C.String
 172 import System.Posix.Internals
 173 #endif
 174
 175 #ifdef __GLASGOW_HASKELL__
 176 import GHC.Base
 177 import GHC.IOBase       -- Together these four Prelude modules define
 178 import GHC.Handle       -- all the stuff exported by IO for the GHC version
 179 import GHC.IO
 180 import GHC.Exception
 181 import GHC.Num
 182 import Text.Read
 183 import GHC.Show
 184 #endif
 185
 186 #ifdef __HUGS__
 187 import Hugs.IO
 188 import Hugs.IOExts
 189 import Hugs.IORef
 190 import System.IO.Unsafe ( unsafeInterleaveIO )
 191 #endif
 192
 193 #ifdef __NHC__
 194 import IO
 195   ( Handle ()
 196   , HandlePosn ()
 197   , IOMode (ReadMode,WriteMode,AppendMode,ReadWriteMode)
 198   , BufferMode (NoBuffering,LineBuffering,BlockBuffering)
 199   , SeekMode (AbsoluteSeek,RelativeSeek,SeekFromEnd)
 200   , stdin, stdout, stderr
 201   , openFile                  -- :: FilePath -> IOMode -> IO Handle
 202   , hClose                    -- :: Handle -> IO ()
 203   , hFileSize                 -- :: Handle -> IO Integer
 204   , hIsEOF                    -- :: Handle -> IO Bool
 205   , isEOF                     -- :: IO Bool
 206   , hSetBuffering             -- :: Handle -> BufferMode -> IO ()
 207   , hGetBuffering             -- :: Handle -> IO BufferMode
 208   , hFlush                    -- :: Handle -> IO ()
 209   , hGetPosn                  -- :: Handle -> IO HandlePosn
 210   , hSetPosn                  -- :: HandlePosn -> IO ()
 211   , hSeek                     -- :: Handle -> SeekMode -> Integer -> IO ()
 212   , hWaitForInput             -- :: Handle -> Int -> IO Bool
 213   , hGetChar                  -- :: Handle -> IO Char
 214   , hGetLine                  -- :: Handle -> IO [Char]
 215   , hLookAhead                -- :: Handle -> IO Char
 216   , hGetContents              -- :: Handle -> IO [Char]
 217   , hPutChar                  -- :: Handle -> Char -> IO ()
 218   , hPutStr                   -- :: Handle -> [Char] -> IO ()
 219   , hPutStrLn                 -- :: Handle -> [Char] -> IO ()
 220   , hPrint                    -- :: Handle -> [Char] -> IO ()
 221   , hReady                    -- :: Handle -> [Char] -> IO ()
 222   , hIsOpen, hIsClosed        -- :: Handle -> IO Bool
 223   , hIsReadable, hIsWritable  -- :: Handle -> IO Bool
 224   , hIsSeekable               -- :: Handle -> IO Bool
 225   , bracket
 226
 227   , IO ()
 228   , FilePath                  -- :: String
 229   )
 230 import NHC.IOExtras (fixIO, hPutBuf, hGetBuf)
 231 import NHC.FFI (Ptr)
 232 #endif
 233
 234 -- -----------------------------------------------------------------------------
 235 -- Standard IO
 236
 237 #ifdef __GLASGOW_HASKELL__
 238 -- | Write a character to the standard output device
 239 -- (same as 'hPutChar' 'stdout').
 240
 241 putChar         :: Char -> IO ()
 242 putChar c       =  hPutChar stdout c
 243
 244 -- | Write a string to the standard output device
 245 -- (same as 'hPutStr' 'stdout').
 246
 247 putStr          :: String -> IO ()
 248 putStr s        =  hPutStr stdout s
 249
 250 -- | The same as 'putStr', but adds a newline character.
 251
 252 putStrLn        :: String -> IO ()
 253 putStrLn s      =  do putStr s
 254                       putChar '\n'
 255
 256 -- | The 'print' function outputs a value of any printable type to the
 257 -- standard output device.
 258 -- Printable types are those that are instances of class 'Show'; 'print'
 259 -- converts values to strings for output using the 'show' operation and
 260 -- adds a newline.
 261 --
 262 -- For example, a program to print the first 20 integers and their
 263 -- powers of 2 could be written as:
 264 --
 265 -- > main = print ([(n, 2^n) | n <- [0..19]])
 266
 267 print           :: Show a => a -> IO ()
 268 print x         =  putStrLn (show x)
 269
 270 -- | Read a character from the standard input device
 271 -- (same as 'hGetChar' 'stdin').
 272
 273 getChar         :: IO Char
 274 getChar         =  hGetChar stdin
 275
 276 -- | Read a line from the standard input device
 277 -- (same as 'hGetLine' 'stdin').
 278
 279 getLine         :: IO String
 280 getLine         =  hGetLine stdin
 281
 282 -- | The 'getContents' operation returns all user input as a single string,
 283 -- which is read lazily as it is needed
 284 -- (same as 'hGetContents' 'stdin').
 285
 286 getContents     :: IO String
 287 getContents     =  hGetContents stdin
 288
 289 -- | The 'interact' function takes a function of type @String->String@
 290 -- as its argument.  The entire input from the standard input device is
 291 -- passed to this function as its argument, and the resulting string is
 292 -- output on the standard output device.
 293
 294 interact        ::  (String -> String) -> IO ()
 295 interact f      =   do s <- getContents
 296                        putStr (f s)
 297
 298 -- | The 'readFile' function reads a file and
 299 -- returns the contents of the file as a string.
 300 -- The file is read lazily, on demand, as with 'getContents'.
 301
 302 readFile        :: FilePath -> IO String
 303 readFile name   =  openFile name ReadMode >>= hGetContents
 304
 305 -- | The computation 'writeFile' @file str@ function writes the string @str@,
 306 -- to the file @file@.
 307 writeFile :: FilePath -> String -> IO ()
 308 writeFile f txt = withFile f WriteMode (\ hdl -> hPutStr hdl txt)
 309
 310 -- | The computation 'appendFile' @file str@ function appends the string @str@,
 311 -- to the file @file@.
 312 --
 313 -- Note that 'writeFile' and 'appendFile' write a literal string
 314 -- to a file.  To write a value of any printable type, as with 'print',
 315 -- use the 'show' function to convert the value to a string first.
 316 --
 317 -- > main = appendFile "squares" (show [(x,x*x) | x <- [0,0.1..2]])
 318
 319 appendFile      :: FilePath -> String -> IO ()
 320 appendFile f txt = withFile f AppendMode (\ hdl -> hPutStr hdl txt)
 321
 322 -- | The 'readLn' function combines 'getLine' and 'readIO'.
 323
 324 readLn          :: Read a => IO a
 325 readLn          =  do l <- getLine
 326                       r <- readIO l
 327                       return r
 328
 329 -- | The 'readIO' function is similar to 'read' except that it signals
 330 -- parse failure to the 'IO' monad instead of terminating the program.
 331
 332 readIO          :: Read a => String -> IO a
 333 readIO s        =  case (do { (x,t) <- reads s ;
 334                               ("","") <- lex t ;
 335                               return x }) of
 336                         [x]    -> return x
 337                         []     -> ioError (userError "Prelude.readIO: no parse")
 338                         _      -> ioError (userError "Prelude.readIO: ambiguous parse")
 339 #endif  /* __GLASGOW_HASKELL__ */
 340
 341 #ifndef __NHC__
 342 -- | Computation 'hReady' @hdl@ indicates whether at least one item is
 343 -- available for input from handle @hdl@.
 344 --
 345 -- This operation may fail with:
 346 --
 347 --  * 'System.IO.Error.isEOFError' if the end of file has been reached.
 348
 349 hReady          :: Handle -> IO Bool
 350 hReady h        =  hWaitForInput h 0
 351
 352 -- | The same as 'hPutStr', but adds a newline character.
 353
 354 hPutStrLn       :: Handle -> String -> IO ()
 355 hPutStrLn hndl str = do
 356  hPutStr  hndl str
 357  hPutChar hndl '\n'
 358
 359 -- | Computation 'hPrint' @hdl t@ writes the string representation of @t@
 360 -- given by the 'shows' function to the file or channel managed by @hdl@
 361 -- and appends a newline.
 362 --
 363 -- This operation may fail with:
 364 --
 365 --  * 'System.IO.Error.isFullError' if the device is full; or
 366 --
 367 --  * 'System.IO.Error.isPermissionError' if another system resource limit would be exceeded.
 368
 369 hPrint          :: Show a => Handle -> a -> IO ()
 370 hPrint hdl      =  hPutStrLn hdl . show
 371 #endif /* !__NHC__ */
 372
 373 -- | @'withFile' name mode act@ opens a file using 'openFile' and passes
 374 -- the resulting handle to the computation @act@.  The handle will be
 375 -- closed on exit from 'withFile', whether by normal termination or by
 376 -- raising an exception.
 377 withFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 378 withFile name mode = bracket (openFile name mode) hClose
 379
 380 -- | @'withBinaryFile' name mode act@ opens a file using 'openBinaryFile'
 381 -- and passes the resulting handle to the computation @act@.  The handle
 382 -- will be closed on exit from 'withBinaryFile', whether by normal
 383 -- termination or by raising an exception.
 384 withBinaryFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 385 withBinaryFile name mode = bracket (openBinaryFile name mode) hClose
 386
 387 -- ---------------------------------------------------------------------------
 388 -- fixIO
 389
 390 #if defined(__GLASGOW_HASKELL__) || defined(__HUGS__)
 391 fixIO :: (a -> IO a) -> IO a
 392 fixIO k = do
 393     ref <- newIORef (throw NonTermination)
 394     ans <- unsafeInterleaveIO (readIORef ref)
 395     result <- k ans
 396     writeIORef ref result
 397     return result
 398
 399 -- NOTE: we do our own explicit black holing here, because GHC's lazy
 400 -- blackholing isn't enough.  In an infinite loop, GHC may run the IO
 401 -- computation a few times before it notices the loop, which is wrong.
 402 #endif
 403
 404 #if defined(__NHC__)
 405 -- Assume a unix platform, where text and binary I/O are identical.
 406 openBinaryFile = openFile
 407 hSetBinaryMode _ _ = return ()
 408 #endif
 409
 410 -- | The function creates a temporary file in ReadWrite mode.
 411 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 412 --
 413 -- The file is creates with permissions such that only the current
 414 -- user can read\/write it.
 415 --
 416 -- With some exceptions (see below), the file will be created securely
 417 -- in the sense that an attacker should not be able to cause
 418 -- openTempFile to overwrite another file on the filesystem using your
 419 -- credentials, by putting symbolic links (on Unix) in the place where
 420 -- the temporary file is to be created.  On Unix the @O_CREAT@ and
 421 -- @O_EXCL@ flags are used to prevent this attack, but note that
 422 -- @O_EXCL@ is sometimes not supported on NFS filesystems, so if you
 423 -- rely on this behaviour it is best to use local filesystems only.
 424 --
 425 openTempFile :: FilePath   -- ^ Directory in which to create the file
 426              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 427                            -- the created file will be \"fooXXX.ext\" where XXX is some
 428                            -- random number.
 429              -> IO (FilePath, Handle)
 430 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template False
 431
 432 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 433 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 434 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 435
 436 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 437 openTempFile' loc tmp_dir template binary = do
 438   pid <- c_getpid
 439   findTempName pid
 440   where
 441     -- We split off the last extension, so we can use .foo.ext files
 442     -- for temporary files (hidden on Unix OSes). Unfortunately we're
 443     -- below filepath in the hierarchy here.
 444     (prefix,suffix) =
 445        case break (== '.') $ reverse template of
 446          -- First case: template contains no '.'s. Just re-reverse it.
 447          (rev_suffix, "")       -> (reverse rev_suffix, "")
 448          -- Second case: template contains at least one '.'. Strip the
 449          -- dot from the prefix and prepend it to the suffix (if we don't
 450          -- do this, the unique number will get added after the '.' and
 451          -- thus be part of the extension, which is wrong.)
 452          (rev_suffix, '.':rest) -> (reverse rest, '.':reverse rev_suffix)
 453          -- Otherwise, something is wrong, because (break (== '.')) should
 454          -- always return a pair with either the empty string or a string
 455          -- beginning with '.' as the second component.
 456          _                      -> error "bug in System.IO.openTempFile"
 457
 458 #ifndef __NHC__
 459     oflags1 = rw_flags .|. o_EXCL
 460
 461     binary_flags
 462       | binary    = o_BINARY
 463       | otherwise = 0
 464
 465     oflags = oflags1 .|. binary_flags
 466 #endif
 467
 468 #ifdef __NHC__
 469     findTempName x = do h <- openFile filepath ReadWriteMode
 470                         return (filepath, h)
 471 #else
 472     findTempName x = do
 473       fd <- withCString filepath $ \ f ->
 474               c_open f oflags 0o600
 475       if fd < 0
 476        then do
 477          errno <- getErrno
 478          if errno == eEXIST
 479            then findTempName (x+1)
 480            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 481        else do
 482          -- XXX We want to tell fdToHandle what the filepath is,
 483          -- as any exceptions etc will only be able to report the
 484          -- fd currently
 485          h <- fdToHandle fd `onException` c_close fd
 486          return (filepath, h)
 487 #endif
 488       where
 489         filename        = prefix ++ show x ++ suffix
 490         filepath        = tmp_dir `combine` filename
 491
 492         -- XXX bits copied from System.FilePath, since that's not available here
 493         combine a b
 494                   | null b = a
 495                   | null a = b
 496                   | last a == pathSeparator = a ++ b
 497                   | otherwise = a ++ [pathSeparator] ++ b
 498
 499 #if __HUGS__
 500         fdToHandle fd   = openFd (fromIntegral fd) False ReadWriteMode binary
 501 #endif
 502
 503 -- XXX Should use filepath library
 504 pathSeparator :: Char
 505 #ifdef mingw32_HOST_OS
 506 pathSeparator = '\\'
 507 #else
 508 pathSeparator = '/'
 509 #endif
 510
 511 #ifndef __NHC__
 512 -- XXX Copied from GHC.Handle
 513 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 514 output_flags = std_flags    .|. o_CREAT
 515 read_flags   = std_flags    .|. o_RDONLY
 516 write_flags  = output_flags .|. o_WRONLY
 517 rw_flags     = output_flags .|. o_RDWR
 518 append_flags = write_flags  .|. o_APPEND
 519 #endif
 520
 521 #ifdef __NHC__
 522 foreign import ccall "getpid" c_getpid :: IO Int
 523 #endif
 524
 525 -- $locking
 526 -- Implementations should enforce as far as possible, at least locally to the
 527 -- Haskell process, multiple-reader single-writer locking on files.
 528 -- That is, /there may either be many handles on the same file which manage
 529 -- input, or just one handle on the file which manages output/.  If any
 530 -- open or semi-closed handle is managing a file for output, no new
 531 -- handle can be allocated for that file.  If any open or semi-closed
 532 -- handle is managing a file for input, new handles can only be allocated
 533 -- if they do not manage output.  Whether two files are the same is
 534 -- implementation-dependent, but they should normally be the same if they
 535 -- have the same absolute path name and neither has been renamed, for
 536 -- example.
 537 --
 538 -- /Warning/: the 'readFile' operation holds a semi-closed handle on
 539 -- the file until the entire contents of the file have been consumed.
 540 -- It follows that an attempt to write to a file (using 'writeFile', for
 541 -- example) that was earlier opened by 'readFile' will usually result in
 542 -- failure with 'System.IO.Error.isAlreadyInUseError'.