System/IO.hs

   1 {-# OPTIONS_GHC -XNoImplicitPrelude #-}
   2 -----------------------------------------------------------------------------
   3 -- |
   4 -- Module      :  System.IO
   5 -- Copyright   :  (c) The University of Glasgow 2001
   6 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   7 --
   8 -- Maintainer  :  libraries@haskell.org
   9 -- Stability   :  stable
  10 -- Portability :  portable
  11 --
  12 -- The standard IO library.
  13 --
  14 -----------------------------------------------------------------------------
  15
  16 module System.IO (
  17     -- * The IO monad
  18
  19     IO,                        -- instance MonadFix
  20     fixIO,                     -- :: (a -> IO a) -> IO a
  21
  22     -- * Files and handles
  23
  24     FilePath,                  -- :: String
  25
  26     Handle,             -- abstract, instance of: Eq, Show.
  27
  28     -- ** Standard handles
  29
  30     -- | Three handles are allocated during program initialisation,
  31     -- and are initially open.
  32
  33     stdin, stdout, stderr,   -- :: Handle
  34
  35     -- * Opening and closing files
  36
  37     -- ** Opening files
  38
  39     withFile,
  40     openFile,                  -- :: FilePath -> IOMode -> IO Handle
  41     IOMode(ReadMode,WriteMode,AppendMode,ReadWriteMode),
  42
  43     -- ** Closing files
  44
  45     hClose,                    -- :: Handle -> IO ()
  46
  47     -- ** Special cases
  48
  49     -- | These functions are also exported by the "Prelude".
  50
  51     readFile,                  -- :: FilePath -> IO String
  52     writeFile,                 -- :: FilePath -> String -> IO ()
  53     appendFile,                -- :: FilePath -> String -> IO ()
  54
  55     -- ** File locking
  56
  57     -- $locking
  58
  59     -- * Operations on handles
  60
  61     -- ** Determining and changing the size of a file
  62
  63     hFileSize,                 -- :: Handle -> IO Integer
  64 #ifdef __GLASGOW_HASKELL__
  65     hSetFileSize,              -- :: Handle -> Integer -> IO ()
  66 #endif
  67
  68     -- ** Detecting the end of input
  69
  70     hIsEOF,                    -- :: Handle -> IO Bool
  71     isEOF,                     -- :: IO Bool
  72
  73     -- ** Buffering operations
  74
  75     BufferMode(NoBuffering,LineBuffering,BlockBuffering),
  76     hSetBuffering,             -- :: Handle -> BufferMode -> IO ()
  77     hGetBuffering,             -- :: Handle -> IO BufferMode
  78     hFlush,                    -- :: Handle -> IO ()
  79
  80     -- ** Repositioning handles
  81
  82     hGetPosn,                  -- :: Handle -> IO HandlePosn
  83     hSetPosn,                  -- :: HandlePosn -> IO ()
  84     HandlePosn,                -- abstract, instance of: Eq, Show.
  85
  86     hSeek,                     -- :: Handle -> SeekMode -> Integer -> IO ()
  87     SeekMode(AbsoluteSeek,RelativeSeek,SeekFromEnd),
  88 #if !defined(__NHC__)
  89     hTell,                     -- :: Handle -> IO Integer
  90 #endif
  91
  92     -- ** Handle properties
  93
  94     hIsOpen, hIsClosed,        -- :: Handle -> IO Bool
  95     hIsReadable, hIsWritable,  -- :: Handle -> IO Bool
  96     hIsSeekable,               -- :: Handle -> IO Bool
  97
  98     -- ** Terminal operations (not portable: GHC\/Hugs only)
  99
 100 #if !defined(__NHC__)
 101     hIsTerminalDevice,          -- :: Handle -> IO Bool
 102
 103     hSetEcho,                   -- :: Handle -> Bool -> IO ()
 104     hGetEcho,                   -- :: Handle -> IO Bool
 105 #endif
 106
 107     -- ** Showing handle state (not portable: GHC only)
 108
 109 #ifdef __GLASGOW_HASKELL__
 110     hShow,                      -- :: Handle -> IO String
 111 #endif
 112
 113     -- * Text input and output
 114
 115     -- ** Text input
 116
 117     hWaitForInput,             -- :: Handle -> Int -> IO Bool
 118     hReady,                    -- :: Handle -> IO Bool
 119     hGetChar,                  -- :: Handle -> IO Char
 120     hGetLine,                  -- :: Handle -> IO [Char]
 121     hLookAhead,                -- :: Handle -> IO Char
 122     hGetContents,              -- :: Handle -> IO [Char]
 123
 124     -- ** Text output
 125
 126     hPutChar,                  -- :: Handle -> Char -> IO ()
 127     hPutStr,                   -- :: Handle -> [Char] -> IO ()
 128     hPutStrLn,                 -- :: Handle -> [Char] -> IO ()
 129     hPrint,                    -- :: Show a => Handle -> a -> IO ()
 130
 131     -- ** Special cases for standard input and output
 132
 133     -- | These functions are also exported by the "Prelude".
 134
 135     interact,                  -- :: (String -> String) -> IO ()
 136     putChar,                   -- :: Char   -> IO ()
 137     putStr,                    -- :: String -> IO ()
 138     putStrLn,                  -- :: String -> IO ()
 139     print,                     -- :: Show a => a -> IO ()
 140     getChar,                   -- :: IO Char
 141     getLine,                   -- :: IO String
 142     getContents,               -- :: IO String
 143     readIO,                    -- :: Read a => String -> IO a
 144     readLn,                    -- :: Read a => IO a
 145
 146     -- * Binary input and output
 147
 148     withBinaryFile,
 149     openBinaryFile,            -- :: FilePath -> IOMode -> IO Handle
 150     hSetBinaryMode,            -- :: Handle -> Bool -> IO ()
 151     hPutBuf,                   -- :: Handle -> Ptr a -> Int -> IO ()
 152     hGetBuf,                   -- :: Handle -> Ptr a -> Int -> IO Int
 153 #if !defined(__NHC__) && !defined(__HUGS__)
 154     hPutBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 155     hGetBufNonBlocking,        -- :: Handle -> Ptr a -> Int -> IO Int
 156 #endif
 157
 158     -- * Temporary files
 159
 160     openTempFile,
 161     openBinaryTempFile,
 162
 163 #if !defined(__NHC__) && !defined(__HUGS__)
 164     -- * Unicode encoding\/decoding
 165
 166     -- | A text-mode 'Handle' has an associated 'TextEncoding', which
 167     -- is used to decode bytes into Unicode characters when reading,
 168     -- and encode Unicode characters into bytes when writing.
 169     --
 170     -- The default 'TextEncoding' is the same as the default encoding
 171     -- on your system, which is also available as 'localeEncoding'.
 172     -- (GHC note: on Windows, currently 'localeEncoding' is always
 173     -- 'latin1'; there is no support for encoding and decoding using
 174     -- the ANSI code page).
 175     --
 176     -- Encoding and decoding errors are always detected and reported,
 177     -- except during lazy I/O ('hGetContents', 'getContents', and
 178     -- 'readFile'), where a decoding error merely results in
 179     -- termination of the character stream, as with other I/O errors.
 180
 181     hSetEncoding,
 182     hGetEncoding,
 183
 184     -- ** Unicode encodings
 185     TextEncoding,
 186     latin1,
 187     utf8, utf8_bom,
 188     utf16, utf16le, utf16be,
 189     utf32, utf32le, utf32be,
 190     localeEncoding,
 191     mkTextEncoding,
 192 #endif
 193
 194 #if !defined(__NHC__) && !defined(__HUGS__)
 195     -- * Newline conversion
 196
 197     -- | In Haskell, a newline is always represented by the character
 198     -- '\n'.  However, in files and external character streams, a
 199     -- newline may be represented by another character sequence, such
 200     -- as '\r\n'.
 201     --
 202     -- A text-mode 'Handle' has an associated 'NewlineMode' that
 203     -- specifies how to transate newline characters.  The
 204     -- 'NewlineMode' specifies the input and output translation
 205     -- separately, so that for instance you can translate '\r\n'
 206     -- to '\n' on input, but leave newlines as '\n' on output.
 207     --
 208     -- The default 'NewlineMode' for a 'Handle' is
 209     -- 'nativeNewlineMode', which does no translation on Unix systems,
 210     -- but translates '\r\n' to '\n' and back on Windows.
 211     --
 212     -- Binary-mode 'Handle's do no newline translation at all.
 213     --
 214     hSetNewlineMode,
 215     Newline(..), nativeNewline,
 216     NewlineMode(..),
 217     noNewlineTranslation, universalNewlineMode, nativeNewlineMode,
 218 #endif
 219   ) where
 220
 221 import Control.Exception.Base
 222
 223 #ifndef __NHC__
 224 import Data.Bits
 225 import Data.List
 226 import Data.Maybe
 227 import Foreign.C.Error
 228 import Foreign.C.Types
 229 import System.Posix.Internals
 230 #endif
 231
 232 #ifdef __GLASGOW_HASKELL__
 233 import GHC.Base
 234 import GHC.IO hiding ( onException )
 235 import GHC.IO.IOMode
 236 import GHC.IO.Handle.FD
 237 import GHC.IO.Handle
 238 import GHC.IORef
 239 import GHC.IO.Exception ( userError )
 240 import GHC.IO.Encoding
 241 import GHC.Exception
 242 import GHC.Num
 243 import Text.Read
 244 import GHC.Show
 245 #endif
 246
 247 #ifdef __HUGS__
 248 import Hugs.IO
 249 import Hugs.IOExts
 250 import Hugs.IORef
 251 import System.IO.Unsafe ( unsafeInterleaveIO )
 252 #endif
 253
 254 #ifdef __NHC__
 255 import IO
 256   ( Handle ()
 257   , HandlePosn ()
 258   , IOMode (ReadMode,WriteMode,AppendMode,ReadWriteMode)
 259   , BufferMode (NoBuffering,LineBuffering,BlockBuffering)
 260   , SeekMode (AbsoluteSeek,RelativeSeek,SeekFromEnd)
 261   , stdin, stdout, stderr
 262   , openFile                  -- :: FilePath -> IOMode -> IO Handle
 263   , hClose                    -- :: Handle -> IO ()
 264   , hFileSize                 -- :: Handle -> IO Integer
 265   , hIsEOF                    -- :: Handle -> IO Bool
 266   , isEOF                     -- :: IO Bool
 267   , hSetBuffering             -- :: Handle -> BufferMode -> IO ()
 268   , hGetBuffering             -- :: Handle -> IO BufferMode
 269   , hFlush                    -- :: Handle -> IO ()
 270   , hGetPosn                  -- :: Handle -> IO HandlePosn
 271   , hSetPosn                  -- :: HandlePosn -> IO ()
 272   , hSeek                     -- :: Handle -> SeekMode -> Integer -> IO ()
 273   , hWaitForInput             -- :: Handle -> Int -> IO Bool
 274   , hGetChar                  -- :: Handle -> IO Char
 275   , hGetLine                  -- :: Handle -> IO [Char]
 276   , hLookAhead                -- :: Handle -> IO Char
 277   , hGetContents              -- :: Handle -> IO [Char]
 278   , hPutChar                  -- :: Handle -> Char -> IO ()
 279   , hPutStr                   -- :: Handle -> [Char] -> IO ()
 280   , hPutStrLn                 -- :: Handle -> [Char] -> IO ()
 281   , hPrint                    -- :: Handle -> [Char] -> IO ()
 282   , hReady                    -- :: Handle -> [Char] -> IO ()
 283   , hIsOpen, hIsClosed        -- :: Handle -> IO Bool
 284   , hIsReadable, hIsWritable  -- :: Handle -> IO Bool
 285   , hIsSeekable               -- :: Handle -> IO Bool
 286   , bracket
 287
 288   , IO ()
 289   , FilePath                  -- :: String
 290   )
 291 import NHC.IOExtras (fixIO, hPutBuf, hGetBuf)
 292 import NHC.FFI (Ptr)
 293 #endif
 294
 295 -- -----------------------------------------------------------------------------
 296 -- Standard IO
 297
 298 #ifdef __GLASGOW_HASKELL__
 299 -- | Write a character to the standard output device
 300 -- (same as 'hPutChar' 'stdout').
 301
 302 putChar         :: Char -> IO ()
 303 putChar c       =  hPutChar stdout c
 304
 305 -- | Write a string to the standard output device
 306 -- (same as 'hPutStr' 'stdout').
 307
 308 putStr          :: String -> IO ()
 309 putStr s        =  hPutStr stdout s
 310
 311 -- | The same as 'putStr', but adds a newline character.
 312
 313 putStrLn        :: String -> IO ()
 314 putStrLn s      =  do putStr s
 315                       putChar '\n'
 316
 317 -- | The 'print' function outputs a value of any printable type to the
 318 -- standard output device.
 319 -- Printable types are those that are instances of class 'Show'; 'print'
 320 -- converts values to strings for output using the 'show' operation and
 321 -- adds a newline.
 322 --
 323 -- For example, a program to print the first 20 integers and their
 324 -- powers of 2 could be written as:
 325 --
 326 -- > main = print ([(n, 2^n) | n <- [0..19]])
 327
 328 print           :: Show a => a -> IO ()
 329 print x         =  putStrLn (show x)
 330
 331 -- | Read a character from the standard input device
 332 -- (same as 'hGetChar' 'stdin').
 333
 334 getChar         :: IO Char
 335 getChar         =  hGetChar stdin
 336
 337 -- | Read a line from the standard input device
 338 -- (same as 'hGetLine' 'stdin').
 339
 340 getLine         :: IO String
 341 getLine         =  hGetLine stdin
 342
 343 -- | The 'getContents' operation returns all user input as a single string,
 344 -- which is read lazily as it is needed
 345 -- (same as 'hGetContents' 'stdin').
 346
 347 getContents     :: IO String
 348 getContents     =  hGetContents stdin
 349
 350 -- | The 'interact' function takes a function of type @String->String@
 351 -- as its argument.  The entire input from the standard input device is
 352 -- passed to this function as its argument, and the resulting string is
 353 -- output on the standard output device.
 354
 355 interact        ::  (String -> String) -> IO ()
 356 interact f      =   do s <- getContents
 357                        putStr (f s)
 358
 359 -- | The 'readFile' function reads a file and
 360 -- returns the contents of the file as a string.
 361 -- The file is read lazily, on demand, as with 'getContents'.
 362
 363 readFile        :: FilePath -> IO String
 364 readFile name   =  openFile name ReadMode >>= hGetContents
 365
 366 -- | The computation 'writeFile' @file str@ function writes the string @str@,
 367 -- to the file @file@.
 368 writeFile :: FilePath -> String -> IO ()
 369 writeFile f txt = withFile f WriteMode (\ hdl -> hPutStr hdl txt)
 370
 371 -- | The computation 'appendFile' @file str@ function appends the string @str@,
 372 -- to the file @file@.
 373 --
 374 -- Note that 'writeFile' and 'appendFile' write a literal string
 375 -- to a file.  To write a value of any printable type, as with 'print',
 376 -- use the 'show' function to convert the value to a string first.
 377 --
 378 -- > main = appendFile "squares" (show [(x,x*x) | x <- [0,0.1..2]])
 379
 380 appendFile      :: FilePath -> String -> IO ()
 381 appendFile f txt = withFile f AppendMode (\ hdl -> hPutStr hdl txt)
 382
 383 -- | The 'readLn' function combines 'getLine' and 'readIO'.
 384
 385 readLn          :: Read a => IO a
 386 readLn          =  do l <- getLine
 387                       r <- readIO l
 388                       return r
 389
 390 -- | The 'readIO' function is similar to 'read' except that it signals
 391 -- parse failure to the 'IO' monad instead of terminating the program.
 392
 393 readIO          :: Read a => String -> IO a
 394 readIO s        =  case (do { (x,t) <- reads s ;
 395                               ("","") <- lex t ;
 396                               return x }) of
 397                         [x]    -> return x
 398                         []     -> ioError (userError "Prelude.readIO: no parse")
 399                         _      -> ioError (userError "Prelude.readIO: ambiguous parse")
 400 #endif  /* __GLASGOW_HASKELL__ */
 401
 402 #ifndef __NHC__
 403 -- | Computation 'hReady' @hdl@ indicates whether at least one item is
 404 -- available for input from handle @hdl@.
 405 --
 406 -- This operation may fail with:
 407 --
 408 --  * 'System.IO.Error.isEOFError' if the end of file has been reached.
 409
 410 hReady          :: Handle -> IO Bool
 411 hReady h        =  hWaitForInput h 0
 412
 413 -- | The same as 'hPutStr', but adds a newline character.
 414
 415 hPutStrLn       :: Handle -> String -> IO ()
 416 hPutStrLn hndl str = do
 417  hPutStr  hndl str
 418  hPutChar hndl '\n'
 419
 420 -- | Computation 'hPrint' @hdl t@ writes the string representation of @t@
 421 -- given by the 'shows' function to the file or channel managed by @hdl@
 422 -- and appends a newline.
 423 --
 424 -- This operation may fail with:
 425 --
 426 --  * 'System.IO.Error.isFullError' if the device is full; or
 427 --
 428 --  * 'System.IO.Error.isPermissionError' if another system resource limit would be exceeded.
 429
 430 hPrint          :: Show a => Handle -> a -> IO ()
 431 hPrint hdl      =  hPutStrLn hdl . show
 432 #endif /* !__NHC__ */
 433
 434 -- | @'withFile' name mode act@ opens a file using 'openFile' and passes
 435 -- the resulting handle to the computation @act@.  The handle will be
 436 -- closed on exit from 'withFile', whether by normal termination or by
 437 -- raising an exception.
 438 withFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 439 withFile name mode = bracket (openFile name mode) hClose
 440
 441 -- | @'withBinaryFile' name mode act@ opens a file using 'openBinaryFile'
 442 -- and passes the resulting handle to the computation @act@.  The handle
 443 -- will be closed on exit from 'withBinaryFile', whether by normal
 444 -- termination or by raising an exception.
 445 withBinaryFile :: FilePath -> IOMode -> (Handle -> IO r) -> IO r
 446 withBinaryFile name mode = bracket (openBinaryFile name mode) hClose
 447
 448 -- ---------------------------------------------------------------------------
 449 -- fixIO
 450
 451 #if defined(__GLASGOW_HASKELL__) || defined(__HUGS__)
 452 fixIO :: (a -> IO a) -> IO a
 453 fixIO k = do
 454     ref <- newIORef (throw NonTermination)
 455     ans <- unsafeInterleaveIO (readIORef ref)
 456     result <- k ans
 457     writeIORef ref result
 458     return result
 459
 460 -- NOTE: we do our own explicit black holing here, because GHC's lazy
 461 -- blackholing isn't enough.  In an infinite loop, GHC may run the IO
 462 -- computation a few times before it notices the loop, which is wrong.
 463 #endif
 464
 465 #if defined(__NHC__)
 466 -- Assume a unix platform, where text and binary I/O are identical.
 467 openBinaryFile = openFile
 468 hSetBinaryMode _ _ = return ()
 469 #endif
 470
 471 -- | The function creates a temporary file in ReadWrite mode.
 472 -- The created file isn\'t deleted automatically, so you need to delete it manually.
 473 --
 474 -- The file is creates with permissions such that only the current
 475 -- user can read\/write it.
 476 --
 477 -- With some exceptions (see below), the file will be created securely
 478 -- in the sense that an attacker should not be able to cause
 479 -- openTempFile to overwrite another file on the filesystem using your
 480 -- credentials, by putting symbolic links (on Unix) in the place where
 481 -- the temporary file is to be created.  On Unix the @O_CREAT@ and
 482 -- @O_EXCL@ flags are used to prevent this attack, but note that
 483 -- @O_EXCL@ is sometimes not supported on NFS filesystems, so if you
 484 -- rely on this behaviour it is best to use local filesystems only.
 485 --
 486 openTempFile :: FilePath   -- ^ Directory in which to create the file
 487              -> String     -- ^ File name template. If the template is \"foo.ext\" then
 488                            -- the created file will be \"fooXXX.ext\" where XXX is some
 489                            -- random number.
 490              -> IO (FilePath, Handle)
 491 openTempFile tmp_dir template = openTempFile' "openTempFile" tmp_dir template False
 492
 493 -- | Like 'openTempFile', but opens the file in binary mode. See 'openBinaryFile' for more comments.
 494 openBinaryTempFile :: FilePath -> String -> IO (FilePath, Handle)
 495 openBinaryTempFile tmp_dir template = openTempFile' "openBinaryTempFile" tmp_dir template True
 496
 497 openTempFile' :: String -> FilePath -> String -> Bool -> IO (FilePath, Handle)
 498 openTempFile' loc tmp_dir template binary = do
 499   pid <- c_getpid
 500   findTempName pid
 501   where
 502     -- We split off the last extension, so we can use .foo.ext files
 503     -- for temporary files (hidden on Unix OSes). Unfortunately we're
 504     -- below filepath in the hierarchy here.
 505     (prefix,suffix) =
 506        case break (== '.') $ reverse template of
 507          -- First case: template contains no '.'s. Just re-reverse it.
 508          (rev_suffix, "")       -> (reverse rev_suffix, "")
 509          -- Second case: template contains at least one '.'. Strip the
 510          -- dot from the prefix and prepend it to the suffix (if we don't
 511          -- do this, the unique number will get added after the '.' and
 512          -- thus be part of the extension, which is wrong.)
 513          (rev_suffix, '.':rest) -> (reverse rest, '.':reverse rev_suffix)
 514          -- Otherwise, something is wrong, because (break (== '.')) should
 515          -- always return a pair with either the empty string or a string
 516          -- beginning with '.' as the second component.
 517          _                      -> error "bug in System.IO.openTempFile"
 518
 519 #ifndef __NHC__
 520     oflags1 = rw_flags .|. o_EXCL
 521
 522     binary_flags
 523       | binary    = o_BINARY
 524       | otherwise = 0
 525
 526     oflags = oflags1 .|. binary_flags
 527 #endif
 528
 529 #ifdef __NHC__
 530     findTempName x = do h <- openFile filepath ReadWriteMode
 531                         return (filepath, h)
 532 #else
 533     findTempName x = do
 534       fd <- withFilePath filepath $ \ f ->
 535               c_open f oflags 0o600
 536       if fd < 0
 537        then do
 538          errno <- getErrno
 539          if errno == eEXIST
 540            then findTempName (x+1)
 541            else ioError (errnoToIOError loc errno Nothing (Just tmp_dir))
 542        else do
 543          -- XXX We want to tell fdToHandle what the filepath is,
 544          -- as any exceptions etc will only be able to report the
 545          -- fd currently
 546          h <- fdToHandle fd `onException` c_close fd
 547          return (filepath, h)
 548 #endif
 549       where
 550         filename        = prefix ++ show x ++ suffix
 551         filepath        = tmp_dir `combine` filename
 552
 553         -- XXX bits copied from System.FilePath, since that's not available here
 554         combine a b
 555                   | null b = a
 556                   | null a = b
 557                   | last a == pathSeparator = a ++ b
 558                   | otherwise = a ++ [pathSeparator] ++ b
 559
 560 #if __HUGS__
 561         fdToHandle fd   = openFd (fromIntegral fd) False ReadWriteMode binary
 562 #endif
 563
 564 -- XXX Should use filepath library
 565 pathSeparator :: Char
 566 #ifdef mingw32_HOST_OS
 567 pathSeparator = '\\'
 568 #else
 569 pathSeparator = '/'
 570 #endif
 571
 572 #ifndef __NHC__
 573 -- XXX Copied from GHC.Handle
 574 std_flags, output_flags, rw_flags :: CInt
 575 std_flags    = o_NONBLOCK   .|. o_NOCTTY
 576 output_flags = std_flags    .|. o_CREAT
 577 rw_flags     = output_flags .|. o_RDWR
 578 #endif
 579
 580 #ifdef __NHC__
 581 foreign import ccall "getpid" c_getpid :: IO Int
 582 #endif
 583
 584 -- $locking
 585 -- Implementations should enforce as far as possible, at least locally to the
 586 -- Haskell process, multiple-reader single-writer locking on files.
 587 -- That is, /there may either be many handles on the same file which manage
 588 -- input, or just one handle on the file which manages output/.  If any
 589 -- open or semi-closed handle is managing a file for output, no new
 590 -- handle can be allocated for that file.  If any open or semi-closed
 591 -- handle is managing a file for input, new handles can only be allocated
 592 -- if they do not manage output.  Whether two files are the same is
 593 -- implementation-dependent, but they should normally be the same if they
 594 -- have the same absolute path name and neither has been renamed, for
 595 -- example.
 596 --
 597 -- /Warning/: the 'readFile' operation holds a semi-closed handle on
 598 -- the file until the entire contents of the file have been consumed.
 599 -- It follows that an attempt to write to a file (using 'writeFile', for
 600 -- example) that was earlier opened by 'readFile' will usually result in
 601 -- failure with 'System.IO.Error.isAlreadyInUseError'.