System/Mem/Weak.hs

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  System.Mem.Weak
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable
  10 --
  11 -- In general terms, a weak pointer is a reference to an object that is
  12 -- not followed by the garbage collector - that is, the existence of a
  13 -- weak pointer to an object has no effect on the lifetime of that
  14 -- object.  A weak pointer can be de-referenced to find out
  15 -- whether the object it refers to is still alive or not, and if so
  16 -- to return the object itself.
  17 --
  18 -- Weak pointers are particularly useful for caches and memo tables.
  19 -- To build a memo table, you build a data structure
  20 -- mapping from the function argument (the key) to its result (the
  21 -- value).  When you apply the function to a new argument you first
  22 -- check whether the key\/value pair is already in the memo table.
  23 -- The key point is that the memo table itself should not keep the
  24 -- key and value alive.  So the table should contain a weak pointer
  25 -- to the key, not an ordinary pointer.  The pointer to the value must
  26 -- not be weak, because the only reference to the value might indeed be
  27 -- from the memo table.
  28 --
  29 -- So it looks as if the memo table will keep all its values
  30 -- alive for ever.  One way to solve this is to purge the table
  31 -- occasionally, by deleting entries whose keys have died.
  32 --
  33 -- The weak pointers in this library
  34 -- support another approach, called /finalization/.
  35 -- When the key referred to by a weak pointer dies, the storage manager
  36 -- arranges to run a programmer-specified finalizer.  In the case of memo
  37 -- tables, for example, the finalizer could remove the key\/value pair
  38 -- from the memo table.
  39 --
  40 -- Another difficulty with the memo table is that the value of a
  41 -- key\/value pair might itself contain a pointer to the key.
  42 -- So the memo table keeps the value alive, which keeps the key alive,
  43 -- even though there may be no other references to the key so both should
  44 -- die.  The weak pointers in this library provide a slight
  45 -- generalisation of the basic weak-pointer idea, in which each
  46 -- weak pointer actually contains both a key and a value.
  47 --
  48 -----------------------------------------------------------------------------
  49
  50 module System.Mem.Weak (
  51         -- * The @Weak@ type
  52         Weak,                   -- abstract
  53
  54         -- * The general interface
  55         mkWeak,                 -- :: k -> v -> Maybe (IO ()) -> IO (Weak v)
  56         deRefWeak,              -- :: Weak v -> IO (Maybe v)
  57         finalize,               -- :: Weak v -> IO ()
  58
  59         -- * Specialised versions
  60         mkWeakPtr,              -- :: k -> Maybe (IO ()) -> IO (Weak k)
  61         addFinalizer,           -- :: key -> IO () -> IO ()
  62         mkWeakPair,             -- :: k -> v -> Maybe (IO ()) -> IO (Weak (k,v))
  63         -- replaceFinaliser     -- :: Weak v -> IO () -> IO ()
  64
  65         -- * A precise semantics
  66
  67         -- $precise
  68    ) where
  69
  70 import Prelude
  71
  72 import Data.Dynamic
  73
  74 #ifdef __HUGS__
  75 import Hugs.Weak
  76 #endif
  77
  78 #ifdef __GLASGOW_HASKELL__
  79 import GHC.Base
  80 import GHC.IOBase
  81 import GHC.Weak
  82
  83 {-|
  84 Dereferences a weak pointer.  If the key is still alive, then
  85 @'Just' v@ is returned (where @v@ is the /value/ in the weak pointer), otherwise
  86 'Nothing' is returned.
  87
  88 The return value of 'deRefWeak' depends on when the garbage collector
  89 runs, hence it is in the 'IO' monad.
  90 -}
  91 deRefWeak :: Weak v -> IO (Maybe v)
  92 deRefWeak (Weak w) = IO $ \s ->
  93    case deRefWeak# w s of
  94         (# s1, flag, p #) -> case flag of
  95                                 0# -> (# s1, Nothing #)
  96                                 _  -> (# s1, Just p #)
  97
  98 -- | A specialised version of 'mkWeak' where the value is actually a pair
  99 -- of the key and value passed to 'mkWeakPair':
 100 --
 101 -- > mkWeakPair key val finalizer = mkWeak key (key,val) finalizer
 102 --
 103 -- The advantage of this is that the key can be retrieved by 'deRefWeak'
 104 -- in addition to the value.
 105 mkWeakPair :: k -> v -> Maybe (IO ()) -> IO (Weak (k,v))
 106 mkWeakPair key val finalizer = mkWeak key (key,val) finalizer
 107
 108 -- | Causes a the finalizer associated with a weak pointer to be run
 109 -- immediately.
 110 finalize :: Weak v -> IO ()
 111 finalize (Weak w) = IO $ \s ->
 112    case finalizeWeak# w s of
 113         (# s1, 0#, _ #) -> (# s1, () #) -- already dead, or no finaliser
 114         (# s1, _,  f #) -> f s1
 115 #endif
 116
 117 #include "Dynamic.h"
 118 INSTANCE_TYPEABLE1(Weak,weakTc,"Weak")
 119
 120 {- $precise
 121
 122 The above informal specification is fine for simple situations, but
 123 matters can get complicated.  In particular, it needs to be clear
 124 exactly when a key dies, so that any weak pointers that refer to it
 125 can be finalized.  Suppose, for example, the value of one weak pointer
 126 refers to the key of another...does that keep the key alive?
 127
 128 The behaviour is simply this:
 129
 130  *  If a weak pointer (object) refers to an /unreachable/
 131     key, it may be finalized.
 132
 133  *  Finalization means (a) arrange that subsequent calls
 134     to 'deRefWeak' return 'Nothing'; and (b) run the finalizer.
 135
 136 This behaviour depends on what it means for a key to be reachable.
 137 Informally, something is reachable if it can be reached by following
 138 ordinary pointers from the root set, but not following weak pointers.
 139 We define reachability more precisely as follows A heap object is
 140 reachable if:
 141
 142  * It is a member of the /root set/.
 143
 144  * It is directly pointed to by a reachable object, other than
 145    a weak pointer object.
 146
 147  * It is a weak pointer object whose key is reachable.
 148
 149  * It is the value or finalizer of an object whose key is reachable.
 150 -}