System/Time.hsc

   1 -----------------------------------------------------------------------------
   2 --
   3 -- Module      :  System.Time
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/core/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  provisional
   9 -- Portability :  portable
  10 --
  11 -- $Id: Time.hsc,v 1.7 2002/02/05 17:32:27 simonmar Exp $
  12 --
  13 -- The standard Time library.
  14 --
  15 -----------------------------------------------------------------------------
  16
  17 {-
  18 Haskell 98 Time of Day Library
  19 ------------------------------
  20
  21 The Time library provides standard functionality for clock times,
  22 including timezone information (i.e, the functionality of "time.h",
  23 adapted to the Haskell environment), It follows RFC 1129 in its use of
  24 Coordinated Universal Time (UTC).
  25
  26 2000/06/17 <michael.weber@post.rwth-aachen.de>:
  27 RESTRICTIONS:
  28   * min./max. time diff currently is restricted to
  29     [minBound::Int, maxBound::Int]
  30
  31   * surely other restrictions wrt. min/max bounds
  32
  33
  34 NOTES:
  35   * printing times
  36
  37     `showTime' (used in `instance Show ClockTime') always prints time
  38     converted to the local timezone (even if it is taken from
  39     `(toClockTime . toUTCTime)'), whereas `calendarTimeToString'
  40     honors the tzone & tz fields and prints UTC or whatever timezone
  41     is stored inside CalendarTime.
  42
  43     Maybe `showTime' should be changed to use UTC, since it would
  44     better correspond to the actual representation of `ClockTime'
  45     (can be done by replacing localtime(3) by gmtime(3)).
  46
  47
  48 BUGS:
  49   * add proper handling of microsecs, currently, they're mostly
  50     ignored
  51
  52   * `formatFOO' case of `%s' is currently broken...
  53
  54
  55 TODO:
  56   * check for unusual date cases, like 1970/1/1 00:00h, and conversions
  57     between different timezone's etc.
  58
  59   * check, what needs to be in the IO monad, the current situation
  60     seems to be a bit inconsistent to me
  61
  62   * check whether `isDst = -1' works as expected on other arch's
  63     (Solaris anyone?)
  64
  65   * add functions to parse strings to `CalendarTime' (some day...)
  66
  67   * implement padding capabilities ("%_", "%-") in `formatFOO'
  68
  69   * add rfc822 timezone (+0200 is CEST) representation ("%z") in `formatFOO'
  70 -}
  71
  72 module System.Time
  73      (
  74         Month(..)
  75      ,  Day(..)
  76
  77      ,  ClockTime(..) -- non-standard, lib. report gives this as abstract
  78         -- instance Eq, Ord
  79         -- instance Show (non-standard)
  80
  81      ,  getClockTime
  82
  83      ,  TimeDiff(..)
  84      ,  noTimeDiff      -- non-standard (but useful when constructing TimeDiff vals.)
  85      ,  diffClockTimes
  86      ,  addToClockTime
  87
  88      ,  normalizeTimeDiff -- non-standard
  89      ,  timeDiffToString  -- non-standard
  90      ,  formatTimeDiff    -- non-standard
  91
  92      ,  CalendarTime(..)
  93      ,  toCalendarTime
  94      ,  toUTCTime
  95      ,  toClockTime
  96      ,  calendarTimeToString
  97      ,  formatCalendarTime
  98
  99      ) where
 100
 101 #include "HsCore.h"
 102
 103 import Prelude
 104
 105 import Data.Ix
 106 import System.Locale
 107 import System.IO.Unsafe
 108
 109 import Foreign
 110 import Foreign.C
 111
 112 -- One way to partition and give name to chunks of a year and a week:
 113
 114 data Month
 115  = January   | February | March    | April
 116  | May       | June     | July     | August
 117  | September | October  | November | December
 118  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 119
 120 data Day
 121  = Sunday   | Monday | Tuesday | Wednesday
 122  | Thursday | Friday | Saturday
 123  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 124
 125 -- @ClockTime@ is an abstract type, used for the internal clock time.
 126 -- Clock times may be compared, converted to strings, or converted to an
 127 -- external calendar time @CalendarTime@.
 128
 129 data ClockTime = TOD Integer            -- Seconds since 00:00:00 on 1 Jan 1970
 130                      Integer            -- Picoseconds with the specified second
 131                deriving (Eq, Ord)
 132
 133 -- When a ClockTime is shown, it is converted to a CalendarTime in the current
 134 -- timezone and then printed.  FIXME: This is arguably wrong, since we can't
 135 -- get the current timezone without being in the IO monad.
 136
 137 instance Show ClockTime where
 138     showsPrec _ t = showString (calendarTimeToString
 139                                  (unsafePerformIO (toCalendarTime t)))
 140
 141 {-
 142 @CalendarTime@ is a user-readable and manipulable
 143 representation of the internal $ClockTime$ type.  The
 144 numeric fields have the following ranges.
 145
 146 \begin{verbatim}
 147 Value         Range             Comments
 148 -----         -----             --------
 149
 150 year    -maxInt .. maxInt       [Pre-Gregorian dates are inaccurate]
 151 mon           0 .. 11           [Jan = 0, Dec = 11]
 152 day           1 .. 31
 153 hour          0 .. 23
 154 min           0 .. 59
 155 sec           0 .. 61           [Allows for two leap seconds]
 156 picosec       0 .. (10^12)-1    [This could be over-precise?]
 157 wday          0 .. 6            [Sunday = 0, Saturday = 6]
 158 yday          0 .. 365          [364 in non-Leap years]
 159 tz       -43200 .. 43200        [Variation from UTC in seconds]
 160 \end{verbatim}
 161
 162 The {\em tzname} field is the name of the time zone.  The {\em isdst}
 163 field indicates whether Daylight Savings Time would be in effect.
 164 -}
 165
 166 data CalendarTime
 167  = CalendarTime  {
 168      ctYear    :: Int,
 169      ctMonth   :: Month,
 170      ctDay     :: Int,
 171      ctHour    :: Int,
 172      ctMin     :: Int,
 173      ctSec     :: Int,
 174      ctPicosec :: Integer,
 175      ctWDay    :: Day,
 176      ctYDay    :: Int,
 177      ctTZName  :: String,
 178      ctTZ      :: Int,
 179      ctIsDST   :: Bool
 180  }
 181  deriving (Eq,Ord,Read,Show)
 182
 183 -- The @TimeDiff@ type records the difference between two clock times in
 184 -- a user-readable way.
 185
 186 data TimeDiff
 187  = TimeDiff {
 188      tdYear    :: Int,
 189      tdMonth   :: Int,
 190      tdDay     :: Int,
 191      tdHour    :: Int,
 192      tdMin     :: Int,
 193      tdSec     :: Int,
 194      tdPicosec :: Integer -- not standard
 195    }
 196    deriving (Eq,Ord,Read,Show)
 197
 198 noTimeDiff :: TimeDiff
 199 noTimeDiff = TimeDiff 0 0 0 0 0 0 0
 200
 201 -- -----------------------------------------------------------------------------
 202 -- getClockTime returns the current time in its internal representation.
 203
 204 #if HAVE_GETTIMEOFDAY
 205 getClockTime = do
 206   allocaBytes (#const sizeof(struct timeval)) $ \ p_timeval -> do
 207     throwErrnoIfMinus1_ "getClockTime" $ gettimeofday p_timeval nullPtr
 208     sec  <- (#peek struct timeval,tv_sec)  p_timeval :: IO CTime
 209     usec <- (#peek struct timeval,tv_usec) p_timeval :: IO CTime
 210     return (TOD (fromIntegral sec) ((fromIntegral usec) * 1000000))
 211
 212 #elif HAVE_FTIME
 213 getClockTime = do
 214   allocaBytes (#const sizeof(struct timeb)) $ \ p_timeb -> do
 215   ftime p_timeb
 216   sec  <- (#peek struct timeb,time) p_timeb :: IO CTime
 217   msec <- (#peek struct timeb,millitm) p_timeb :: IO CUShort
 218   return (TOD (fromIntegral sec) (fromIntegral msec * 1000000000))
 219
 220 #else /* use POSIX time() */
 221 getClockTime = do
 222     secs <- time nullPtr -- can't fail, according to POSIX
 223     return (TOD (fromIntegral secs) 0)
 224
 225 #endif
 226
 227 -- -----------------------------------------------------------------------------
 228 -- addToClockTime d t adds a time difference d and a
 229 -- clock time t to yield a new clock time.  The difference d
 230 -- may be either positive or negative.  diffClockTimes t1 t2 returns
 231 -- the difference between two clock times t1 and t2 as a TimeDiff.
 232
 233 addToClockTime  :: TimeDiff  -> ClockTime -> ClockTime
 234 addToClockTime (TimeDiff year mon day hour min sec psec)
 235                (TOD c_sec c_psec) =
 236         let
 237           sec_diff = toInteger sec +
 238                      60 * toInteger min +
 239                      3600 * toInteger hour +
 240                      24 * 3600 * toInteger day
 241           cal      = toUTCTime (TOD (c_sec + sec_diff) (c_psec + psec))
 242                                                        -- FIXME! ^^^^
 243           new_mon  = fromEnum (ctMonth cal) + r_mon
 244           (month', yr_diff)
 245             | new_mon < 0  = (toEnum (12 + new_mon), (-1))
 246             | new_mon > 11 = (toEnum (new_mon `mod` 12), 1)
 247             | otherwise    = (toEnum new_mon, 0)
 248
 249           (r_yr, r_mon) = mon `quotRem` 12
 250
 251           year' = ctYear cal + year + r_yr + yr_diff
 252         in
 253         toClockTime cal{ctMonth=month', ctYear=year'}
 254
 255 diffClockTimes  :: ClockTime -> ClockTime -> TimeDiff
 256 -- diffClockTimes is meant to be the dual to `addToClockTime'.
 257 -- If you want to have the TimeDiff properly splitted, use
 258 -- `normalizeTimeDiff' on this function's result
 259 --
 260 -- CAVEAT: see comment of normalizeTimeDiff
 261 diffClockTimes (TOD sa pa) (TOD sb pb) =
 262     noTimeDiff{ tdSec     = fromIntegral (sa - sb)
 263                 -- FIXME: can handle just 68 years...
 264               , tdPicosec = pa - pb
 265               }
 266
 267
 268 normalizeTimeDiff :: TimeDiff -> TimeDiff
 269 -- FIXME: handle psecs properly
 270 -- FIXME: ?should be called by formatTimeDiff automagically?
 271 --
 272 -- when applied to something coming out of `diffClockTimes', you loose
 273 -- the duality to `addToClockTime', since a year does not always have
 274 -- 365 days, etc.
 275 --
 276 -- apply this function as late as possible to prevent those "rounding"
 277 -- errors
 278 normalizeTimeDiff td =
 279   let
 280       rest0 = tdSec td
 281                + 60 * (tdMin td
 282                     + 60 * (tdHour td
 283                          + 24 * (tdDay td
 284                               + 30 * (tdMonth td
 285                                    + 365 * tdYear td))))
 286
 287       (diffYears,  rest1)    = rest0 `quotRem` (365 * 24 * 3600)
 288       (diffMonths, rest2)    = rest1 `quotRem` (30 * 24 * 3600)
 289       (diffDays,   rest3)    = rest2 `quotRem` (24 * 3600)
 290       (diffHours,  rest4)    = rest3 `quotRem` 3600
 291       (diffMins,   diffSecs) = rest4 `quotRem` 60
 292   in
 293       td{ tdYear = diffYears
 294         , tdMonth = diffMonths
 295         , tdDay   = diffDays
 296         , tdHour  = diffHours
 297         , tdMin   = diffMins
 298         , tdSec   = diffSecs
 299         }
 300
 301 -- -----------------------------------------------------------------------------
 302 -- How do we deal with timezones on this architecture?
 303
 304 -- The POSIX way to do it is through the global variable tzname[].
 305 -- But that's crap, so we do it The BSD Way if we can: namely use the
 306 -- tm_zone and tm_gmtoff fields of struct tm, if they're available.
 307
 308 zone   :: Ptr CTm -> IO (Ptr CChar)
 309 gmtoff :: Ptr CTm -> IO CLong
 310 #if HAVE_TM_ZONE
 311 zone x      = (#peek struct tm,tm_zone) x
 312 gmtoff x    = (#peek struct tm,tm_gmtoff) x
 313
 314 #else /* ! HAVE_TM_ZONE */
 315 # if HAVE_TZNAME || defined(_WIN32)
 316 #  if cygwin32_TARGET_OS
 317 #   define tzname _tzname
 318 #  endif
 319 #  ifndef mingw32_TARGET_OS
 320 foreign label tzname :: Ptr (Ptr CChar)
 321 #  else
 322 foreign import "ghcTimezone" unsafe timezone :: Ptr CLong
 323 foreign import "ghcTzname" unsafe tzname :: Ptr (Ptr CChar)
 324 #  endif
 325 zone x = do
 326   dst <- (#peek struct tm,tm_isdst) x
 327   if dst then peekElemOff tzname 1 else peekElemOff tzname 0
 328 # else /* ! HAVE_TZNAME */
 329 -- We're in trouble. If you should end up here, please report this as a bug.
 330 #  error "Don't know how to get at timezone name on your OS."
 331 # endif /* ! HAVE_TZNAME */
 332
 333 -- Get the offset in secs from UTC, if (struct tm) doesn't supply it. */
 334 #if defined(mingw32_TARGET_OS) || defined(cygwin32_TARGET_OS)
 335 #define timezone _timezone
 336 #endif
 337
 338 # if HAVE_ALTZONE
 339 foreign label altzone  :: Ptr CTime
 340 foreign label timezone :: Ptr CTime
 341 gmtoff x = do
 342   dst <- (#peek struct tm,tm_isdst) x
 343   tz <- if dst then peek altzone else peek timezone
 344   return (fromIntegral tz)
 345 #  define GMTOFF(x)      (((struct tm *)x)->tm_isdst ? altzone : timezone )
 346 # else /* ! HAVE_ALTZONE */
 347 -- Assume that DST offset is 1 hour ...
 348 gmtoff x = do
 349   dst <- (#peek struct tm,tm_isdst) x
 350   tz  <- peek timezone
 351   if dst then return (fromIntegral tz - 3600) else return tz
 352 # endif /* ! HAVE_ALTZONE */
 353 #endif  /* ! HAVE_TM_ZONE */
 354
 355 -- -----------------------------------------------------------------------------
 356 -- toCalendarTime t converts t to a local time, modified by
 357 -- the current timezone and daylight savings time settings.  toUTCTime
 358 -- t converts t into UTC time.  toClockTime l converts l into the
 359 -- corresponding internal ClockTime.  The wday, yday, tzname, and isdst fields
 360 -- are ignored.
 361
 362
 363 toCalendarTime :: ClockTime -> IO CalendarTime
 364 #if HAVE_LOCALTIME_R
 365 toCalendarTime =  clockToCalendarTime_reentrant (throwAwayReturnPointer localtime_r) False
 366 #else
 367 toCalendarTime =  clockToCalendarTime_static localtime False
 368 #endif
 369
 370 toUTCTime      :: ClockTime -> CalendarTime
 371 #if HAVE_GMTIME_R
 372 toUTCTime      =  unsafePerformIO . clockToCalendarTime_reentrant (throwAwayReturnPointer gmtime_r) True
 373 #else
 374 toUTCTime      =  unsafePerformIO . clockToCalendarTime_static gmtime True
 375 #endif
 376
 377 throwAwayReturnPointer :: (Ptr CTime -> Ptr CTm -> IO (Ptr CTm))
 378                        -> (Ptr CTime -> Ptr CTm -> IO (       ))
 379 throwAwayReturnPointer fun x y = fun x y >> return ()
 380
 381 clockToCalendarTime_static :: (Ptr CTime -> IO (Ptr CTm)) -> Bool -> ClockTime
 382          -> IO CalendarTime
 383 clockToCalendarTime_static fun is_utc (TOD secs psec) = do
 384   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 385     p_tm <- fun p_timer         -- can't fail, according to POSIX
 386     clockToCalendarTime_aux is_utc p_tm psec
 387
 388 clockToCalendarTime_reentrant :: (Ptr CTime -> Ptr CTm -> IO ()) -> Bool -> ClockTime
 389          -> IO CalendarTime
 390 clockToCalendarTime_reentrant fun is_utc (TOD secs psec) = do
 391   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 392     allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 393       fun p_timer p_tm
 394       clockToCalendarTime_aux is_utc p_tm psec
 395
 396 clockToCalendarTime_aux :: Bool -> Ptr CTm -> Integer -> IO CalendarTime
 397 clockToCalendarTime_aux is_utc p_tm psec = do
 398     sec   <-  (#peek struct tm,tm_sec  ) p_tm :: IO CInt
 399     min   <-  (#peek struct tm,tm_min  ) p_tm :: IO CInt
 400     hour  <-  (#peek struct tm,tm_hour ) p_tm :: IO CInt
 401     mday  <-  (#peek struct tm,tm_mday ) p_tm :: IO CInt
 402     mon   <-  (#peek struct tm,tm_mon  ) p_tm :: IO CInt
 403     year  <-  (#peek struct tm,tm_year ) p_tm :: IO CInt
 404     wday  <-  (#peek struct tm,tm_wday ) p_tm :: IO CInt
 405     yday  <-  (#peek struct tm,tm_yday ) p_tm :: IO CInt
 406     isdst <-  (#peek struct tm,tm_isdst) p_tm :: IO CInt
 407     zone  <-  zone p_tm
 408     tz    <-  gmtoff p_tm
 409
 410     tzname <- peekCString zone
 411
 412     let month  | mon >= 0 && mon <= 11 = toEnum (fromIntegral mon)
 413                | otherwise             = error ("toCalendarTime: illegal month value: " ++ show mon)
 414
 415     return (CalendarTime
 416                 (1900 + fromIntegral year)
 417                 month
 418                 (fromIntegral mday)
 419                 (fromIntegral hour)
 420                 (fromIntegral min)
 421                 (fromIntegral sec)
 422                 psec
 423                 (toEnum (fromIntegral wday))
 424                 (fromIntegral yday)
 425                 (if is_utc then "UTC" else tzname)
 426                 (if is_utc then 0     else fromIntegral tz)
 427                 (if is_utc then False else isdst /= 0))
 428
 429
 430 toClockTime :: CalendarTime -> ClockTime
 431 toClockTime (CalendarTime year mon mday hour min sec psec
 432                           _wday _yday _tzname tz isdst) =
 433
 434      -- `isDst' causes the date to be wrong by one hour...
 435      -- FIXME: check, whether this works on other arch's than Linux, too...
 436      --
 437      -- so we set it to (-1) (means `unknown') and let `mktime' determine
 438      -- the real value...
 439     let isDst = -1 :: CInt in   -- if isdst then (1::Int) else 0
 440
 441     if psec < 0 || psec > 999999999999 then
 442         error "Time.toClockTime: picoseconds out of range"
 443     else if tz < -43200 || tz > 43200 then
 444         error "Time.toClockTime: timezone offset out of range"
 445     else
 446       unsafePerformIO $ do
 447       allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 448         (#poke struct tm,tm_sec  ) p_tm (fromIntegral sec  :: CInt)
 449         (#poke struct tm,tm_min  ) p_tm (fromIntegral min  :: CInt)
 450         (#poke struct tm,tm_hour ) p_tm (fromIntegral hour :: CInt)
 451         (#poke struct tm,tm_mday ) p_tm (fromIntegral mday :: CInt)
 452         (#poke struct tm,tm_mon  ) p_tm (fromIntegral (fromEnum mon) :: CInt)
 453         (#poke struct tm,tm_year ) p_tm (fromIntegral year - 1900 :: CInt)
 454         (#poke struct tm,tm_isdst) p_tm isDst
 455         t <- throwIf (== -1) (\_ -> "Time.toClockTime: invalid input")
 456                 (mktime p_tm)
 457         --
 458         -- mktime expects its argument to be in the local timezone, but
 459         -- toUTCTime makes UTC-encoded CalendarTime's ...
 460         --
 461         -- Since there is no any_tz_struct_tm-to-time_t conversion
 462         -- function, we have to fake one... :-) If not in all, it works in
 463         -- most cases (before, it was the other way round...)
 464         --
 465         -- Luckily, mktime tells us, what it *thinks* the timezone is, so,
 466         -- to compensate, we add the timezone difference to mktime's
 467         -- result.
 468         --
 469         gmtoff <- gmtoff p_tm
 470         let res = fromIntegral t - tz + fromIntegral gmtoff
 471         return (TOD (fromIntegral res) psec)
 472
 473 -- -----------------------------------------------------------------------------
 474 -- Converting time values to strings.
 475
 476 calendarTimeToString  :: CalendarTime -> String
 477 calendarTimeToString  =  formatCalendarTime defaultTimeLocale "%c"
 478
 479 formatCalendarTime :: TimeLocale -> String -> CalendarTime -> String
 480 formatCalendarTime l fmt (CalendarTime year mon day hour min sec _
 481                                        wday yday tzname _ _) =
 482         doFmt fmt
 483   where doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 484         doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 485         doFmt ('%':c:cs)   = decode c ++ doFmt cs
 486         doFmt (c:cs) = c : doFmt cs
 487         doFmt "" = ""
 488
 489         decode 'A' = fst (wDays l  !! fromEnum wday) -- day of the week, full name
 490         decode 'a' = snd (wDays l  !! fromEnum wday) -- day of the week, abbrev.
 491         decode 'B' = fst (months l !! fromEnum mon)  -- month, full name
 492         decode 'b' = snd (months l !! fromEnum mon)  -- month, abbrev
 493         decode 'h' = snd (months l !! fromEnum mon)  -- ditto
 494         decode 'C' = show2 (year `quot` 100)         -- century
 495         decode 'c' = doFmt (dateTimeFmt l)           -- locale's data and time format.
 496         decode 'D' = doFmt "%m/%d/%y"
 497         decode 'd' = show2 day                       -- day of the month
 498         decode 'e' = show2' day                      -- ditto, padded
 499         decode 'H' = show2 hour                      -- hours, 24-hour clock, padded
 500         decode 'I' = show2 (to12 hour)               -- hours, 12-hour clock
 501         decode 'j' = show3 yday                      -- day of the year
 502         decode 'k' = show2' hour                     -- hours, 24-hour clock, no padding
 503         decode 'l' = show2' (to12 hour)              -- hours, 12-hour clock, no padding
 504         decode 'M' = show2 min                       -- minutes
 505         decode 'm' = show2 (fromEnum mon+1)          -- numeric month
 506         decode 'n' = "\n"
 507         decode 'p' = (if hour < 12 then fst else snd) (amPm l) -- am or pm
 508         decode 'R' = doFmt "%H:%M"
 509         decode 'r' = doFmt (time12Fmt l)
 510         decode 'T' = doFmt "%H:%M:%S"
 511         decode 't' = "\t"
 512         decode 'S' = show2 sec                       -- seconds
 513         decode 's' = show2 sec                       -- number of secs since Epoch. (ToDo.)
 514         decode 'U' = show2 ((yday + 7 - fromEnum wday) `div` 7) -- week number, starting on Sunday.
 515         decode 'u' = show (let n = fromEnum wday in  -- numeric day of the week (1=Monday, 7=Sunday)
 516                            if n == 0 then 7 else n)
 517         decode 'V' =                                 -- week number (as per ISO-8601.)
 518             let (week, days) =                       -- [yep, I've always wanted to be able to display that too.]
 519                    (yday + 7 - if fromEnum wday > 0 then
 520                                fromEnum wday - 1 else 6) `divMod` 7
 521             in  show2 (if days >= 4 then
 522                           week+1
 523                        else if week == 0 then 53 else week)
 524
 525         decode 'W' =                                 -- week number, weeks starting on monday
 526             show2 ((yday + 7 - if fromEnum wday > 0 then
 527                                fromEnum wday - 1 else 6) `div` 7)
 528         decode 'w' = show (fromEnum wday)            -- numeric day of the week, weeks starting on Sunday.
 529         decode 'X' = doFmt (timeFmt l)               -- locale's preferred way of printing time.
 530         decode 'x' = doFmt (dateFmt l)               -- locale's preferred way of printing dates.
 531         decode 'Y' = show year                       -- year, including century.
 532         decode 'y' = show2 (year `rem` 100)          -- year, within century.
 533         decode 'Z' = tzname                          -- timezone name
 534         decode '%' = "%"
 535         decode c   = [c]
 536
 537
 538 show2, show2', show3 :: Int -> String
 539 show2 x
 540  | x' < 10   = '0': show x'
 541  | otherwise = show x'
 542  where x' = x `rem` 100
 543
 544 show2' x
 545  | x' < 10   = ' ': show x'
 546  | otherwise = show x'
 547  where x' = x `rem` 100
 548
 549 show3 x = show (x `quot` 100) ++ show2 (x `rem` 100)
 550  where x' = x `rem` 1000
 551
 552 to12 :: Int -> Int
 553 to12 h = let h' = h `mod` 12 in if h' == 0 then 12 else h'
 554
 555 -- Useful extensions for formatting TimeDiffs.
 556
 557 timeDiffToString :: TimeDiff -> String
 558 timeDiffToString = formatTimeDiff defaultTimeLocale "%c"
 559
 560 formatTimeDiff :: TimeLocale -> String -> TimeDiff -> String
 561 formatTimeDiff l fmt td@(TimeDiff year month day hour min sec _)
 562  = doFmt fmt
 563   where
 564    doFmt ""         = ""
 565    doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 566    doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 567    doFmt ('%':c:cs) = decode c ++ doFmt cs
 568    doFmt (c:cs)     = c : doFmt cs
 569
 570    decode spec =
 571     case spec of
 572       'B' -> fst (months l !! fromEnum month)
 573       'b' -> snd (months l !! fromEnum month)
 574       'h' -> snd (months l !! fromEnum month)
 575       'c' -> defaultTimeDiffFmt td
 576       'C' -> show2 (year `quot` 100)
 577       'D' -> doFmt "%m/%d/%y"
 578       'd' -> show2 day
 579       'e' -> show2' day
 580       'H' -> show2 hour
 581       'I' -> show2 (to12 hour)
 582       'k' -> show2' hour
 583       'l' -> show2' (to12 hour)
 584       'M' -> show2 min
 585       'm' -> show2 (fromEnum month + 1)
 586       'n' -> "\n"
 587       'p' -> (if hour < 12 then fst else snd) (amPm l)
 588       'R' -> doFmt "%H:%M"
 589       'r' -> doFmt (time12Fmt l)
 590       'T' -> doFmt "%H:%M:%S"
 591       't' -> "\t"
 592       'S' -> show2 sec
 593       's' -> show2 sec -- Implementation-dependent, sez the lib doc..
 594       'X' -> doFmt (timeFmt l)
 595       'x' -> doFmt (dateFmt l)
 596       'Y' -> show year
 597       'y' -> show2 (year `rem` 100)
 598       '%' -> "%"
 599       c   -> [c]
 600
 601    defaultTimeDiffFmt (TimeDiff year month day hour min sec _) =
 602        foldr (\ (v,s) rest ->
 603                   (if v /= 0
 604                      then show v ++ ' ':(addS v s)
 605                        ++ if null rest then "" else ", "
 606                      else "") ++ rest
 607              )
 608              ""
 609              (zip [year, month, day, hour, min, sec] (intervals l))
 610
 611    addS v s = if abs v == 1 then fst s else snd s
 612
 613
 614 -- -----------------------------------------------------------------------------
 615 -- Foreign time interface (POSIX)
 616
 617 type CTm = () -- struct tm
 618
 619 #if HAVE_LOCALTIME_R
 620 foreign import unsafe localtime_r :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 621 #else
 622 foreign import unsafe localtime   :: Ptr CTime -> IO (Ptr CTm)
 623 #endif
 624 #if HAVE_GMTIME_R
 625 foreign import unsafe gmtime_r    :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 626 #else
 627 foreign import unsafe gmtime      :: Ptr CTime -> IO (Ptr CTm)
 628 #endif
 629 foreign import unsafe mktime      :: Ptr CTm   -> IO CTime
 630 foreign import unsafe time        :: Ptr CTime -> IO CTime
 631
 632 #if HAVE_GETTIMEOFDAY
 633 type CTimeVal = ()
 634 foreign import unsafe gettimeofday :: Ptr CTimeVal -> Ptr () -> IO CInt
 635 #endif
 636
 637 #if HAVE_FTIME
 638 type CTimeB = ()
 639 #ifndef mingw32_TARGET_OS
 640 foreign import unsafe ftime :: Ptr CTimeB -> IO CInt
 641 #else
 642 foreign import unsafe ftime :: Ptr CTimeB -> IO ()
 643 #endif
 644 #endif