System/Time.hsc

   1 -----------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  System.Time
   4 -- Copyright   :  (c) The University of Glasgow 2001
   5 -- License     :  BSD-style (see the file libraries/core/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  provisional
   9 -- Portability :  portable
  10 --
  11 -- The standard Time library.
  12 --
  13 -----------------------------------------------------------------------------
  14
  15 {-
  16 Haskell 98 Time of Day Library
  17 ------------------------------
  18
  19 The Time library provides standard functionality for clock times,
  20 including timezone information (i.e, the functionality of "time.h",
  21 adapted to the Haskell environment), It follows RFC 1129 in its use of
  22 Coordinated Universal Time (UTC).
  23
  24 2000/06/17 <michael.weber@post.rwth-aachen.de>:
  25 RESTRICTIONS:
  26   * min./max. time diff currently is restricted to
  27     [minBound::Int, maxBound::Int]
  28
  29   * surely other restrictions wrt. min/max bounds
  30
  31
  32 NOTES:
  33   * printing times
  34
  35     `showTime' (used in `instance Show ClockTime') always prints time
  36     converted to the local timezone (even if it is taken from
  37     `(toClockTime . toUTCTime)'), whereas `calendarTimeToString'
  38     honors the tzone & tz fields and prints UTC or whatever timezone
  39     is stored inside CalendarTime.
  40
  41     Maybe `showTime' should be changed to use UTC, since it would
  42     better correspond to the actual representation of `ClockTime'
  43     (can be done by replacing localtime(3) by gmtime(3)).
  44
  45
  46 BUGS:
  47   * add proper handling of microsecs, currently, they're mostly
  48     ignored
  49
  50   * `formatFOO' case of `%s' is currently broken...
  51
  52
  53 TODO:
  54   * check for unusual date cases, like 1970/1/1 00:00h, and conversions
  55     between different timezone's etc.
  56
  57   * check, what needs to be in the IO monad, the current situation
  58     seems to be a bit inconsistent to me
  59
  60   * check whether `isDst = -1' works as expected on other arch's
  61     (Solaris anyone?)
  62
  63   * add functions to parse strings to `CalendarTime' (some day...)
  64
  65   * implement padding capabilities ("%_", "%-") in `formatFOO'
  66
  67   * add rfc822 timezone (+0200 is CEST) representation ("%z") in `formatFOO'
  68 -}
  69
  70 module System.Time
  71      (
  72         Month(..)
  73      ,  Day(..)
  74
  75      ,  ClockTime(..) -- non-standard, lib. report gives this as abstract
  76         -- instance Eq, Ord
  77         -- instance Show (non-standard)
  78
  79      ,  getClockTime
  80
  81      ,  TimeDiff(..)
  82      ,  noTimeDiff      -- non-standard (but useful when constructing TimeDiff vals.)
  83      ,  diffClockTimes
  84      ,  addToClockTime
  85
  86      ,  normalizeTimeDiff -- non-standard
  87      ,  timeDiffToString  -- non-standard
  88      ,  formatTimeDiff    -- non-standard
  89
  90      ,  CalendarTime(..)
  91      ,  toCalendarTime
  92      ,  toUTCTime
  93      ,  toClockTime
  94      ,  calendarTimeToString
  95      ,  formatCalendarTime
  96
  97      ) where
  98
  99 #include "HsBase.h"
 100
 101 import Prelude
 102
 103 import Data.Ix
 104 import System.Locale
 105 import System.IO.Unsafe
 106
 107 import Foreign
 108 import Foreign.C
 109
 110 -- One way to partition and give name to chunks of a year and a week:
 111
 112 data Month
 113  = January   | February | March    | April
 114  | May       | June     | July     | August
 115  | September | October  | November | December
 116  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 117
 118 data Day
 119  = Sunday   | Monday | Tuesday | Wednesday
 120  | Thursday | Friday | Saturday
 121  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 122
 123 -- @ClockTime@ is an abstract type, used for the internal clock time.
 124 -- Clock times may be compared, converted to strings, or converted to an
 125 -- external calendar time @CalendarTime@.
 126
 127 data ClockTime = TOD Integer            -- Seconds since 00:00:00 on 1 Jan 1970
 128                      Integer            -- Picoseconds with the specified second
 129                deriving (Eq, Ord)
 130
 131 -- When a ClockTime is shown, it is converted to a CalendarTime in the current
 132 -- timezone and then printed.  FIXME: This is arguably wrong, since we can't
 133 -- get the current timezone without being in the IO monad.
 134
 135 instance Show ClockTime where
 136     showsPrec _ t = showString (calendarTimeToString
 137                                  (unsafePerformIO (toCalendarTime t)))
 138
 139 {-
 140 @CalendarTime@ is a user-readable and manipulable
 141 representation of the internal $ClockTime$ type.  The
 142 numeric fields have the following ranges.
 143
 144 \begin{verbatim}
 145 Value         Range             Comments
 146 -----         -----             --------
 147
 148 year    -maxInt .. maxInt       [Pre-Gregorian dates are inaccurate]
 149 mon           0 .. 11           [Jan = 0, Dec = 11]
 150 day           1 .. 31
 151 hour          0 .. 23
 152 min           0 .. 59
 153 sec           0 .. 61           [Allows for two leap seconds]
 154 picosec       0 .. (10^12)-1    [This could be over-precise?]
 155 wday          0 .. 6            [Sunday = 0, Saturday = 6]
 156 yday          0 .. 365          [364 in non-Leap years]
 157 tz       -43200 .. 43200        [Variation from UTC in seconds]
 158 \end{verbatim}
 159
 160 The {\em tzname} field is the name of the time zone.  The {\em isdst}
 161 field indicates whether Daylight Savings Time would be in effect.
 162 -}
 163
 164 data CalendarTime
 165  = CalendarTime  {
 166      ctYear    :: Int,
 167      ctMonth   :: Month,
 168      ctDay     :: Int,
 169      ctHour    :: Int,
 170      ctMin     :: Int,
 171      ctSec     :: Int,
 172      ctPicosec :: Integer,
 173      ctWDay    :: Day,
 174      ctYDay    :: Int,
 175      ctTZName  :: String,
 176      ctTZ      :: Int,
 177      ctIsDST   :: Bool
 178  }
 179  deriving (Eq,Ord,Read,Show)
 180
 181 -- The @TimeDiff@ type records the difference between two clock times in
 182 -- a user-readable way.
 183
 184 data TimeDiff
 185  = TimeDiff {
 186      tdYear    :: Int,
 187      tdMonth   :: Int,
 188      tdDay     :: Int,
 189      tdHour    :: Int,
 190      tdMin     :: Int,
 191      tdSec     :: Int,
 192      tdPicosec :: Integer -- not standard
 193    }
 194    deriving (Eq,Ord,Read,Show)
 195
 196 noTimeDiff :: TimeDiff
 197 noTimeDiff = TimeDiff 0 0 0 0 0 0 0
 198
 199 -- -----------------------------------------------------------------------------
 200 -- getClockTime returns the current time in its internal representation.
 201
 202 getClockTime :: IO ClockTime
 203 #if HAVE_GETTIMEOFDAY
 204 getClockTime = do
 205   allocaBytes (#const sizeof(struct timeval)) $ \ p_timeval -> do
 206     throwErrnoIfMinus1_ "getClockTime" $ gettimeofday p_timeval nullPtr
 207     sec  <- (#peek struct timeval,tv_sec)  p_timeval :: IO CTime
 208     usec <- (#peek struct timeval,tv_usec) p_timeval :: IO CTime
 209     return (TOD (fromIntegral sec) ((fromIntegral usec) * 1000000))
 210
 211 #elif HAVE_FTIME
 212 getClockTime = do
 213   allocaBytes (#const sizeof(struct timeb)) $ \ p_timeb -> do
 214   ftime p_timeb
 215   sec  <- (#peek struct timeb,time) p_timeb :: IO CTime
 216   msec <- (#peek struct timeb,millitm) p_timeb :: IO CUShort
 217   return (TOD (fromIntegral sec) (fromIntegral msec * 1000000000))
 218
 219 #else /* use POSIX time() */
 220 getClockTime = do
 221     secs <- time nullPtr -- can't fail, according to POSIX
 222     return (TOD (fromIntegral secs) 0)
 223
 224 #endif
 225
 226 -- -----------------------------------------------------------------------------
 227 -- addToClockTime d t adds a time difference d and a
 228 -- clock time t to yield a new clock time.  The difference d
 229 -- may be either positive or negative.  diffClockTimes t1 t2 returns
 230 -- the difference between two clock times t1 and t2 as a TimeDiff.
 231
 232 addToClockTime  :: TimeDiff  -> ClockTime -> ClockTime
 233 addToClockTime (TimeDiff year mon day hour min sec psec)
 234                (TOD c_sec c_psec) =
 235         let
 236           sec_diff = toInteger sec +
 237                      60 * toInteger min +
 238                      3600 * toInteger hour +
 239                      24 * 3600 * toInteger day
 240           cal      = toUTCTime (TOD (c_sec + sec_diff) (c_psec + psec))
 241                                                        -- FIXME! ^^^^
 242           new_mon  = fromEnum (ctMonth cal) + r_mon
 243           (month', yr_diff)
 244             | new_mon < 0  = (toEnum (12 + new_mon), (-1))
 245             | new_mon > 11 = (toEnum (new_mon `mod` 12), 1)
 246             | otherwise    = (toEnum new_mon, 0)
 247
 248           (r_yr, r_mon) = mon `quotRem` 12
 249
 250           year' = ctYear cal + year + r_yr + yr_diff
 251         in
 252         toClockTime cal{ctMonth=month', ctYear=year'}
 253
 254 diffClockTimes  :: ClockTime -> ClockTime -> TimeDiff
 255 -- diffClockTimes is meant to be the dual to `addToClockTime'.
 256 -- If you want to have the TimeDiff properly splitted, use
 257 -- `normalizeTimeDiff' on this function's result
 258 --
 259 -- CAVEAT: see comment of normalizeTimeDiff
 260 diffClockTimes (TOD sa pa) (TOD sb pb) =
 261     noTimeDiff{ tdSec     = fromIntegral (sa - sb)
 262                 -- FIXME: can handle just 68 years...
 263               , tdPicosec = pa - pb
 264               }
 265
 266
 267 normalizeTimeDiff :: TimeDiff -> TimeDiff
 268 -- FIXME: handle psecs properly
 269 -- FIXME: ?should be called by formatTimeDiff automagically?
 270 --
 271 -- when applied to something coming out of `diffClockTimes', you loose
 272 -- the duality to `addToClockTime', since a year does not always have
 273 -- 365 days, etc.
 274 --
 275 -- apply this function as late as possible to prevent those "rounding"
 276 -- errors
 277 normalizeTimeDiff td =
 278   let
 279       rest0 = tdSec td
 280                + 60 * (tdMin td
 281                     + 60 * (tdHour td
 282                          + 24 * (tdDay td
 283                               + 30 * (tdMonth td
 284                                    + 365 * tdYear td))))
 285
 286       (diffYears,  rest1)    = rest0 `quotRem` (365 * 24 * 3600)
 287       (diffMonths, rest2)    = rest1 `quotRem` (30 * 24 * 3600)
 288       (diffDays,   rest3)    = rest2 `quotRem` (24 * 3600)
 289       (diffHours,  rest4)    = rest3 `quotRem` 3600
 290       (diffMins,   diffSecs) = rest4 `quotRem` 60
 291   in
 292       td{ tdYear = diffYears
 293         , tdMonth = diffMonths
 294         , tdDay   = diffDays
 295         , tdHour  = diffHours
 296         , tdMin   = diffMins
 297         , tdSec   = diffSecs
 298         }
 299
 300 -- -----------------------------------------------------------------------------
 301 -- How do we deal with timezones on this architecture?
 302
 303 -- The POSIX way to do it is through the global variable tzname[].
 304 -- But that's crap, so we do it The BSD Way if we can: namely use the
 305 -- tm_zone and tm_gmtoff fields of struct tm, if they're available.
 306
 307 zone   :: Ptr CTm -> IO (Ptr CChar)
 308 gmtoff :: Ptr CTm -> IO CLong
 309 #if HAVE_TM_ZONE
 310 zone x      = (#peek struct tm,tm_zone) x
 311 gmtoff x    = (#peek struct tm,tm_gmtoff) x
 312
 313 #else /* ! HAVE_TM_ZONE */
 314 # if HAVE_TZNAME || defined(_WIN32)
 315 #  if cygwin32_TARGET_OS
 316 #   define tzname _tzname
 317 #  endif
 318 #  ifndef mingw32_TARGET_OS
 319 foreign import ccall unsafe "&tzname" tzname :: Ptr (Ptr CChar)
 320 #  else
 321 foreign import ccall unsafe "__hscore_timezone" timezone :: Ptr CLong
 322 foreign import ccall unsafe "__hscore_tzname"   tzname :: Ptr (Ptr CChar)
 323 #  endif
 324 zone x = do
 325   dst <- (#peek struct tm,tm_isdst) x
 326   if dst then peekElemOff tzname 1 else peekElemOff tzname 0
 327 # else /* ! HAVE_TZNAME */
 328 -- We're in trouble. If you should end up here, please report this as a bug.
 329 #  error "Don't know how to get at timezone name on your OS."
 330 # endif /* ! HAVE_TZNAME */
 331
 332 -- Get the offset in secs from UTC, if (struct tm) doesn't supply it. */
 333 # if HAVE_ALTZONE
 334 foreign import ccall "&altzone"  altzone  :: Ptr CTime
 335 foreign import ccall "&timezone" timezone :: Ptr CTime
 336 gmtoff x = do
 337   dst <- (#peek struct tm,tm_isdst) x
 338   tz <- if dst then peek altzone else peek timezone
 339   return (-fromIntegral tz)
 340 # else /* ! HAVE_ALTZONE */
 341
 342 #if !defined(mingw32_TARGET_OS)
 343 foreign import ccall unsafe "timezone" timezone :: Ptr CLong
 344 #endif
 345
 346 -- Assume that DST offset is 1 hour ...
 347 gmtoff x = do
 348   dst <- (#peek struct tm,tm_isdst) x
 349   tz  <- peek timezone
 350    -- According to the documentation for tzset(),
 351    --   http://www.opengroup.org/onlinepubs/007908799/xsh/tzset.html
 352    -- timezone offsets are > 0 west of the Prime Meridian.
 353    --
 354    -- This module assumes the interpretation of tm_gmtoff, i.e., offsets
 355    -- are > 0 East of the Prime Meridian, so flip the sign.
 356   return (- (if dst then (fromIntegral tz - 3600) else tz))
 357 # endif /* ! HAVE_ALTZONE */
 358 #endif  /* ! HAVE_TM_ZONE */
 359
 360 -- -----------------------------------------------------------------------------
 361 -- toCalendarTime t converts t to a local time, modified by
 362 -- the current timezone and daylight savings time settings.  toUTCTime
 363 -- t converts t into UTC time.  toClockTime l converts l into the
 364 -- corresponding internal ClockTime.  The wday, yday, tzname, and isdst fields
 365 -- are ignored.
 366
 367
 368 toCalendarTime :: ClockTime -> IO CalendarTime
 369 #if HAVE_LOCALTIME_R
 370 toCalendarTime =  clockToCalendarTime_reentrant (throwAwayReturnPointer localtime_r) False
 371 #else
 372 toCalendarTime =  clockToCalendarTime_static localtime False
 373 #endif
 374
 375 toUTCTime      :: ClockTime -> CalendarTime
 376 #if HAVE_GMTIME_R
 377 toUTCTime      =  unsafePerformIO . clockToCalendarTime_reentrant (throwAwayReturnPointer gmtime_r) True
 378 #else
 379 toUTCTime      =  unsafePerformIO . clockToCalendarTime_static gmtime True
 380 #endif
 381
 382 throwAwayReturnPointer :: (Ptr CTime -> Ptr CTm -> IO (Ptr CTm))
 383                        -> (Ptr CTime -> Ptr CTm -> IO (       ))
 384 throwAwayReturnPointer fun x y = fun x y >> return ()
 385
 386 clockToCalendarTime_static :: (Ptr CTime -> IO (Ptr CTm)) -> Bool -> ClockTime
 387          -> IO CalendarTime
 388 clockToCalendarTime_static fun is_utc (TOD secs psec) = do
 389   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 390     p_tm <- fun p_timer         -- can't fail, according to POSIX
 391     clockToCalendarTime_aux is_utc p_tm psec
 392
 393 clockToCalendarTime_reentrant :: (Ptr CTime -> Ptr CTm -> IO ()) -> Bool -> ClockTime
 394          -> IO CalendarTime
 395 clockToCalendarTime_reentrant fun is_utc (TOD secs psec) = do
 396   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 397     allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 398       fun p_timer p_tm
 399       clockToCalendarTime_aux is_utc p_tm psec
 400
 401 clockToCalendarTime_aux :: Bool -> Ptr CTm -> Integer -> IO CalendarTime
 402 clockToCalendarTime_aux is_utc p_tm psec = do
 403     sec   <-  (#peek struct tm,tm_sec  ) p_tm :: IO CInt
 404     min   <-  (#peek struct tm,tm_min  ) p_tm :: IO CInt
 405     hour  <-  (#peek struct tm,tm_hour ) p_tm :: IO CInt
 406     mday  <-  (#peek struct tm,tm_mday ) p_tm :: IO CInt
 407     mon   <-  (#peek struct tm,tm_mon  ) p_tm :: IO CInt
 408     year  <-  (#peek struct tm,tm_year ) p_tm :: IO CInt
 409     wday  <-  (#peek struct tm,tm_wday ) p_tm :: IO CInt
 410     yday  <-  (#peek struct tm,tm_yday ) p_tm :: IO CInt
 411     isdst <-  (#peek struct tm,tm_isdst) p_tm :: IO CInt
 412     zone  <-  zone p_tm
 413     tz    <-  gmtoff p_tm
 414
 415     tzname <- peekCString zone
 416
 417     let month  | mon >= 0 && mon <= 11 = toEnum (fromIntegral mon)
 418                | otherwise             = error ("toCalendarTime: illegal month value: " ++ show mon)
 419
 420     return (CalendarTime
 421                 (1900 + fromIntegral year)
 422                 month
 423                 (fromIntegral mday)
 424                 (fromIntegral hour)
 425                 (fromIntegral min)
 426                 (fromIntegral sec)
 427                 psec
 428                 (toEnum (fromIntegral wday))
 429                 (fromIntegral yday)
 430                 (if is_utc then "UTC" else tzname)
 431                 (if is_utc then 0     else fromIntegral tz)
 432                 (if is_utc then False else isdst /= 0))
 433
 434
 435 toClockTime :: CalendarTime -> ClockTime
 436 toClockTime (CalendarTime year mon mday hour min sec psec
 437                           _wday _yday _tzname tz isdst) =
 438
 439      -- `isDst' causes the date to be wrong by one hour...
 440      -- FIXME: check, whether this works on other arch's than Linux, too...
 441      --
 442      -- so we set it to (-1) (means `unknown') and let `mktime' determine
 443      -- the real value...
 444     let isDst = -1 :: CInt in   -- if isdst then (1::Int) else 0
 445
 446     if psec < 0 || psec > 999999999999 then
 447         error "Time.toClockTime: picoseconds out of range"
 448     else if tz < -43200 || tz > 43200 then
 449         error "Time.toClockTime: timezone offset out of range"
 450     else
 451       unsafePerformIO $ do
 452       allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 453         (#poke struct tm,tm_sec  ) p_tm (fromIntegral sec  :: CInt)
 454         (#poke struct tm,tm_min  ) p_tm (fromIntegral min  :: CInt)
 455         (#poke struct tm,tm_hour ) p_tm (fromIntegral hour :: CInt)
 456         (#poke struct tm,tm_mday ) p_tm (fromIntegral mday :: CInt)
 457         (#poke struct tm,tm_mon  ) p_tm (fromIntegral (fromEnum mon) :: CInt)
 458         (#poke struct tm,tm_year ) p_tm (fromIntegral year - 1900 :: CInt)
 459         (#poke struct tm,tm_isdst) p_tm isDst
 460         t <- throwIf (== -1) (\_ -> "Time.toClockTime: invalid input")
 461                 (mktime p_tm)
 462         --
 463         -- mktime expects its argument to be in the local timezone, but
 464         -- toUTCTime makes UTC-encoded CalendarTime's ...
 465         --
 466         -- Since there is no any_tz_struct_tm-to-time_t conversion
 467         -- function, we have to fake one... :-) If not in all, it works in
 468         -- most cases (before, it was the other way round...)
 469         --
 470         -- Luckily, mktime tells us, what it *thinks* the timezone is, so,
 471         -- to compensate, we add the timezone difference to mktime's
 472         -- result.
 473         --
 474         gmtoff <- gmtoff p_tm
 475         let res = fromIntegral t - tz + fromIntegral gmtoff
 476         return (TOD (fromIntegral res) psec)
 477
 478 -- -----------------------------------------------------------------------------
 479 -- Converting time values to strings.
 480
 481 calendarTimeToString  :: CalendarTime -> String
 482 calendarTimeToString  =  formatCalendarTime defaultTimeLocale "%c"
 483
 484 formatCalendarTime :: TimeLocale -> String -> CalendarTime -> String
 485 formatCalendarTime l fmt (CalendarTime year mon day hour min sec _
 486                                        wday yday tzname _ _) =
 487         doFmt fmt
 488   where doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 489         doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 490         doFmt ('%':c:cs)   = decode c ++ doFmt cs
 491         doFmt (c:cs) = c : doFmt cs
 492         doFmt "" = ""
 493
 494         decode 'A' = fst (wDays l  !! fromEnum wday) -- day of the week, full name
 495         decode 'a' = snd (wDays l  !! fromEnum wday) -- day of the week, abbrev.
 496         decode 'B' = fst (months l !! fromEnum mon)  -- month, full name
 497         decode 'b' = snd (months l !! fromEnum mon)  -- month, abbrev
 498         decode 'h' = snd (months l !! fromEnum mon)  -- ditto
 499         decode 'C' = show2 (year `quot` 100)         -- century
 500         decode 'c' = doFmt (dateTimeFmt l)           -- locale's data and time format.
 501         decode 'D' = doFmt "%m/%d/%y"
 502         decode 'd' = show2 day                       -- day of the month
 503         decode 'e' = show2' day                      -- ditto, padded
 504         decode 'H' = show2 hour                      -- hours, 24-hour clock, padded
 505         decode 'I' = show2 (to12 hour)               -- hours, 12-hour clock
 506         decode 'j' = show3 yday                      -- day of the year
 507         decode 'k' = show2' hour                     -- hours, 24-hour clock, no padding
 508         decode 'l' = show2' (to12 hour)              -- hours, 12-hour clock, no padding
 509         decode 'M' = show2 min                       -- minutes
 510         decode 'm' = show2 (fromEnum mon+1)          -- numeric month
 511         decode 'n' = "\n"
 512         decode 'p' = (if hour < 12 then fst else snd) (amPm l) -- am or pm
 513         decode 'R' = doFmt "%H:%M"
 514         decode 'r' = doFmt (time12Fmt l)
 515         decode 'T' = doFmt "%H:%M:%S"
 516         decode 't' = "\t"
 517         decode 'S' = show2 sec                       -- seconds
 518         decode 's' = show2 sec                       -- number of secs since Epoch. (ToDo.)
 519         decode 'U' = show2 ((yday + 7 - fromEnum wday) `div` 7) -- week number, starting on Sunday.
 520         decode 'u' = show (let n = fromEnum wday in  -- numeric day of the week (1=Monday, 7=Sunday)
 521                            if n == 0 then 7 else n)
 522         decode 'V' =                                 -- week number (as per ISO-8601.)
 523             let (week, days) =                       -- [yep, I've always wanted to be able to display that too.]
 524                    (yday + 7 - if fromEnum wday > 0 then
 525                                fromEnum wday - 1 else 6) `divMod` 7
 526             in  show2 (if days >= 4 then
 527                           week+1
 528                        else if week == 0 then 53 else week)
 529
 530         decode 'W' =                                 -- week number, weeks starting on monday
 531             show2 ((yday + 7 - if fromEnum wday > 0 then
 532                                fromEnum wday - 1 else 6) `div` 7)
 533         decode 'w' = show (fromEnum wday)            -- numeric day of the week, weeks starting on Sunday.
 534         decode 'X' = doFmt (timeFmt l)               -- locale's preferred way of printing time.
 535         decode 'x' = doFmt (dateFmt l)               -- locale's preferred way of printing dates.
 536         decode 'Y' = show year                       -- year, including century.
 537         decode 'y' = show2 (year `rem` 100)          -- year, within century.
 538         decode 'Z' = tzname                          -- timezone name
 539         decode '%' = "%"
 540         decode c   = [c]
 541
 542
 543 show2, show2', show3 :: Int -> String
 544 show2 x
 545  | x' < 10   = '0': show x'
 546  | otherwise = show x'
 547  where x' = x `rem` 100
 548
 549 show2' x
 550  | x' < 10   = ' ': show x'
 551  | otherwise = show x'
 552  where x' = x `rem` 100
 553
 554 show3 x = show (x `quot` 100) ++ show2 (x `rem` 100)
 555  where x' = x `rem` 1000
 556
 557 to12 :: Int -> Int
 558 to12 h = let h' = h `mod` 12 in if h' == 0 then 12 else h'
 559
 560 -- Useful extensions for formatting TimeDiffs.
 561
 562 timeDiffToString :: TimeDiff -> String
 563 timeDiffToString = formatTimeDiff defaultTimeLocale "%c"
 564
 565 formatTimeDiff :: TimeLocale -> String -> TimeDiff -> String
 566 formatTimeDiff l fmt td@(TimeDiff year month day hour min sec _)
 567  = doFmt fmt
 568   where
 569    doFmt ""         = ""
 570    doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 571    doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 572    doFmt ('%':c:cs) = decode c ++ doFmt cs
 573    doFmt (c:cs)     = c : doFmt cs
 574
 575    decode spec =
 576     case spec of
 577       'B' -> fst (months l !! fromEnum month)
 578       'b' -> snd (months l !! fromEnum month)
 579       'h' -> snd (months l !! fromEnum month)
 580       'c' -> defaultTimeDiffFmt td
 581       'C' -> show2 (year `quot` 100)
 582       'D' -> doFmt "%m/%d/%y"
 583       'd' -> show2 day
 584       'e' -> show2' day
 585       'H' -> show2 hour
 586       'I' -> show2 (to12 hour)
 587       'k' -> show2' hour
 588       'l' -> show2' (to12 hour)
 589       'M' -> show2 min
 590       'm' -> show2 (fromEnum month + 1)
 591       'n' -> "\n"
 592       'p' -> (if hour < 12 then fst else snd) (amPm l)
 593       'R' -> doFmt "%H:%M"
 594       'r' -> doFmt (time12Fmt l)
 595       'T' -> doFmt "%H:%M:%S"
 596       't' -> "\t"
 597       'S' -> show2 sec
 598       's' -> show2 sec -- Implementation-dependent, sez the lib doc..
 599       'X' -> doFmt (timeFmt l)
 600       'x' -> doFmt (dateFmt l)
 601       'Y' -> show year
 602       'y' -> show2 (year `rem` 100)
 603       '%' -> "%"
 604       c   -> [c]
 605
 606    defaultTimeDiffFmt (TimeDiff year month day hour min sec _) =
 607        foldr (\ (v,s) rest ->
 608                   (if v /= 0
 609                      then show v ++ ' ':(addS v s)
 610                        ++ if null rest then "" else ", "
 611                      else "") ++ rest
 612              )
 613              ""
 614              (zip [year, month, day, hour, min, sec] (intervals l))
 615
 616    addS v s = if abs v == 1 then fst s else snd s
 617
 618
 619 -- -----------------------------------------------------------------------------
 620 -- Foreign time interface (POSIX)
 621
 622 type CTm = () -- struct tm
 623
 624 #if HAVE_LOCALTIME_R
 625 foreign import ccall unsafe localtime_r :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 626 #else
 627 foreign import ccall unsafe localtime   :: Ptr CTime -> IO (Ptr CTm)
 628 #endif
 629 #if HAVE_GMTIME_R
 630 foreign import ccall unsafe gmtime_r    :: Ptr CTime -> Ptr CTm -> IO (Ptr CTm)
 631 #else
 632 foreign import ccall unsafe gmtime      :: Ptr CTime -> IO (Ptr CTm)
 633 #endif
 634 foreign import ccall unsafe mktime      :: Ptr CTm   -> IO CTime
 635 foreign import ccall unsafe time        :: Ptr CTime -> IO CTime
 636
 637 #if HAVE_GETTIMEOFDAY
 638 type CTimeVal = ()
 639 foreign import ccall unsafe gettimeofday :: Ptr CTimeVal -> Ptr () -> IO CInt
 640 #endif
 641
 642 #if HAVE_FTIME
 643 type CTimeB = ()
 644 #ifndef mingw32_TARGET_OS
 645 foreign import ccall unsafe ftime :: Ptr CTimeB -> IO CInt
 646 #else
 647 foreign import ccall unsafe ftime :: Ptr CTimeB -> IO ()
 648 #endif
 649 #endif