System/Time.hsc

   1 {-# OPTIONS -optc-DNON_POSIX_SOURCE #-}
   2 -- JRS 010117: we had to say NON_POSIX_SOURCE to get the resulting .hc
   3 -- to compile on sparc-solaris.  Blargh.
   4 -----------------------------------------------------------------------------
   5 --
   6 -- Module      :  System.Time
   7 -- Copyright   :  (c) The University of Glasgow 2001
   8 -- License     :  BSD-style (see the file libraries/core/LICENSE)
   9 --
  10 -- Maintainer  :  libraries@haskell.org
  11 -- Stability   :  provisional
  12 -- Portability :  portable
  13 --
  14 -- $Id: Time.hsc,v 1.1 2001/06/28 14:15:04 simonmar Exp $
  15 --
  16 -- The standard Time library.
  17 --
  18 -----------------------------------------------------------------------------
  19
  20 {-
  21 Haskell 98 Time of Day Library
  22 ------------------------------
  23
  24 The Time library provides standard functionality for clock times,
  25 including timezone information (i.e, the functionality of "time.h",
  26 adapted to the Haskell environment), It follows RFC 1129 in its use of
  27 Coordinated Universal Time (UTC).
  28
  29 2000/06/17 <michael.weber@post.rwth-aachen.de>:
  30 RESTRICTIONS:
  31   * min./max. time diff currently is restricted to
  32     [minBound::Int, maxBound::Int]
  33
  34   * surely other restrictions wrt. min/max bounds
  35
  36
  37 NOTES:
  38   * printing times
  39
  40     `showTime' (used in `instance Show ClockTime') always prints time
  41     converted to the local timezone (even if it is taken from
  42     `(toClockTime . toUTCTime)'), whereas `calendarTimeToString'
  43     honors the tzone & tz fields and prints UTC or whatever timezone
  44     is stored inside CalendarTime.
  45
  46     Maybe `showTime' should be changed to use UTC, since it would
  47     better correspond to the actual representation of `ClockTime'
  48     (can be done by replacing localtime(3) by gmtime(3)).
  49
  50
  51 BUGS:
  52   * add proper handling of microsecs, currently, they're mostly
  53     ignored
  54
  55   * `formatFOO' case of `%s' is currently broken...
  56
  57
  58 TODO:
  59   * check for unusual date cases, like 1970/1/1 00:00h, and conversions
  60     between different timezone's etc.
  61
  62   * check, what needs to be in the IO monad, the current situation
  63     seems to be a bit inconsistent to me
  64
  65   * check whether `isDst = -1' works as expected on other arch's
  66     (Solaris anyone?)
  67
  68   * add functions to parse strings to `CalendarTime' (some day...)
  69
  70   * implement padding capabilities ("%_", "%-") in `formatFOO'
  71
  72   * add rfc822 timezone (+0200 is CEST) representation ("%z") in `formatFOO'
  73 -}
  74
  75 module System.Time
  76      (
  77         Month(..)
  78      ,  Day(..)
  79
  80      ,  ClockTime(..) -- non-standard, lib. report gives this as abstract
  81         -- instance Eq, Ord
  82         -- instance Show (non-standard)
  83
  84      ,  getClockTime
  85
  86      ,  TimeDiff(..)
  87      ,  noTimeDiff      -- non-standard (but useful when constructing TimeDiff vals.)
  88      ,  diffClockTimes
  89      ,  addToClockTime
  90
  91      ,  normalizeTimeDiff -- non-standard
  92      ,  timeDiffToString  -- non-standard
  93      ,  formatTimeDiff    -- non-standard
  94
  95      ,  CalendarTime(..)
  96      ,  toCalendarTime
  97      ,  toUTCTime
  98      ,  toClockTime
  99      ,  calendarTimeToString
 100      ,  formatCalendarTime
 101
 102      ) where
 103
 104 #include "HsCore.h"
 105
 106 import Prelude
 107
 108 import Data.Ix
 109 import System.Locale
 110 import System.IO.Unsafe
 111
 112 import Foreign
 113 import Foreign.C
 114
 115 -- One way to partition and give name to chunks of a year and a week:
 116
 117 data Month
 118  = January   | February | March    | April
 119  | May       | June     | July     | August
 120  | September | October  | November | December
 121  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 122
 123 data Day
 124  = Sunday   | Monday | Tuesday | Wednesday
 125  | Thursday | Friday | Saturday
 126  deriving (Eq, Ord, Enum, Bounded, Ix, Read, Show)
 127
 128 -- @ClockTime@ is an abstract type, used for the internal clock time.
 129 -- Clock times may be compared, converted to strings, or converted to an
 130 -- external calendar time @CalendarTime@.
 131
 132 data ClockTime = TOD Integer            -- Seconds since 00:00:00 on 1 Jan 1970
 133                      Integer            -- Picoseconds with the specified second
 134                deriving (Eq, Ord)
 135
 136 -- When a ClockTime is shown, it is converted to a CalendarTime in the current
 137 -- timezone and then printed.  FIXME: This is arguably wrong, since we can't
 138 -- get the current timezone without being in the IO monad.
 139
 140 instance Show ClockTime where
 141     showsPrec _ t = showString (calendarTimeToString
 142                                  (unsafePerformIO (toCalendarTime t)))
 143
 144 {-
 145 @CalendarTime@ is a user-readable and manipulable
 146 representation of the internal $ClockTime$ type.  The
 147 numeric fields have the following ranges.
 148
 149 \begin{verbatim}
 150 Value         Range             Comments
 151 -----         -----             --------
 152
 153 year    -maxInt .. maxInt       [Pre-Gregorian dates are inaccurate]
 154 mon           0 .. 11           [Jan = 0, Dec = 11]
 155 day           1 .. 31
 156 hour          0 .. 23
 157 min           0 .. 59
 158 sec           0 .. 61           [Allows for two leap seconds]
 159 picosec       0 .. (10^12)-1    [This could be over-precise?]
 160 wday          0 .. 6            [Sunday = 0, Saturday = 6]
 161 yday          0 .. 365          [364 in non-Leap years]
 162 tz       -43200 .. 43200        [Variation from UTC in seconds]
 163 \end{verbatim}
 164
 165 The {\em tzname} field is the name of the time zone.  The {\em isdst}
 166 field indicates whether Daylight Savings Time would be in effect.
 167 -}
 168
 169 data CalendarTime
 170  = CalendarTime  {
 171      ctYear    :: Int,
 172      ctMonth   :: Month,
 173      ctDay     :: Int,
 174      ctHour    :: Int,
 175      ctMin     :: Int,
 176      ctSec     :: Int,
 177      ctPicosec :: Integer,
 178      ctWDay    :: Day,
 179      ctYDay    :: Int,
 180      ctTZName  :: String,
 181      ctTZ      :: Int,
 182      ctIsDST   :: Bool
 183  }
 184  deriving (Eq,Ord,Read,Show)
 185
 186 -- The @TimeDiff@ type records the difference between two clock times in
 187 -- a user-readable way.
 188
 189 data TimeDiff
 190  = TimeDiff {
 191      tdYear    :: Int,
 192      tdMonth   :: Int,
 193      tdDay     :: Int,
 194      tdHour    :: Int,
 195      tdMin     :: Int,
 196      tdSec     :: Int,
 197      tdPicosec :: Integer -- not standard
 198    }
 199    deriving (Eq,Ord,Read,Show)
 200
 201 noTimeDiff :: TimeDiff
 202 noTimeDiff = TimeDiff 0 0 0 0 0 0 0
 203
 204 -- -----------------------------------------------------------------------------
 205 -- getClockTime returns the current time in its internal representation.
 206
 207 #if HAVE_GETTIMEOFDAY
 208 getClockTime = do
 209   allocaBytes (#const sizeof(struct timeval)) $ \ p_timeval -> do
 210     throwErrnoIfMinus1_ "getClockTime" $ gettimeofday p_timeval nullPtr
 211     sec  <- (#peek struct timeval,tv_sec)  p_timeval :: IO CLong
 212     usec <- (#peek struct timeval,tv_usec) p_timeval :: IO CLong
 213     return (TOD (fromIntegral sec) ((fromIntegral usec) * 1000))
 214
 215 #elif HAVE_FTIME
 216 getClockTime = do
 217   allocaBytes (#const sizeof(struct timeb)) $ \ p_timeb -> do
 218   ftime p_timeb
 219   sec  <- (#peek struct timeb,time) p_timeb :: IO CTime
 220   msec <- (#peek struct timeb,millitm) p_timeb :: IO CUShort
 221   return (TOD (fromIntegral sec) (fromIntegral msec * 1000{-ToDo: correct???-}))
 222
 223 #else /* use POSIX time() */
 224 getClockTime = do
 225     secs <- time nullPtr -- can't fail, according to POSIX
 226     return (TOD (fromIntegral secs) 0)
 227
 228 #endif
 229
 230 -- -----------------------------------------------------------------------------
 231 -- addToClockTime d t adds a time difference d and a
 232 -- clock time t to yield a new clock time.  The difference d
 233 -- may be either positive or negative.  diffClockTimes t1 t2 returns
 234 -- the difference between two clock times t1 and t2 as a TimeDiff.
 235
 236 addToClockTime  :: TimeDiff  -> ClockTime -> ClockTime
 237 addToClockTime (TimeDiff year mon day hour min sec psec)
 238                (TOD c_sec c_psec) =
 239         let
 240           sec_diff = toInteger sec +
 241                      60 * toInteger min +
 242                      3600 * toInteger hour +
 243                      24 * 3600 * toInteger day
 244           cal      = toUTCTime (TOD (c_sec + sec_diff) (c_psec + psec))
 245                                                        -- FIXME! ^^^^
 246           new_mon  = fromEnum (ctMonth cal) + r_mon
 247           (month', yr_diff)
 248             | new_mon < 0  = (toEnum (12 + new_mon), (-1))
 249             | new_mon > 11 = (toEnum (new_mon `mod` 12), 1)
 250             | otherwise    = (toEnum new_mon, 0)
 251
 252           (r_yr, r_mon) = mon `quotRem` 12
 253
 254           year' = ctYear cal + year + r_yr + yr_diff
 255         in
 256         toClockTime cal{ctMonth=month', ctYear=year'}
 257
 258 diffClockTimes  :: ClockTime -> ClockTime -> TimeDiff
 259 -- diffClockTimes is meant to be the dual to `addToClockTime'.
 260 -- If you want to have the TimeDiff properly splitted, use
 261 -- `normalizeTimeDiff' on this function's result
 262 --
 263 -- CAVEAT: see comment of normalizeTimeDiff
 264 diffClockTimes (TOD sa pa) (TOD sb pb) =
 265     noTimeDiff{ tdSec     = fromIntegral (sa - sb)
 266                 -- FIXME: can handle just 68 years...
 267               , tdPicosec = pa - pb
 268               }
 269
 270
 271 normalizeTimeDiff :: TimeDiff -> TimeDiff
 272 -- FIXME: handle psecs properly
 273 -- FIXME: ?should be called by formatTimeDiff automagically?
 274 --
 275 -- when applied to something coming out of `diffClockTimes', you loose
 276 -- the duality to `addToClockTime', since a year does not always have
 277 -- 365 days, etc.
 278 --
 279 -- apply this function as late as possible to prevent those "rounding"
 280 -- errors
 281 normalizeTimeDiff td =
 282   let
 283       rest0 = tdSec td
 284                + 60 * (tdMin td
 285                     + 60 * (tdHour td
 286                          + 24 * (tdDay td
 287                               + 30 * (tdMonth td
 288                                    + 365 * tdYear td))))
 289
 290       (diffYears,  rest1)    = rest0 `quotRem` (365 * 24 * 3600)
 291       (diffMonths, rest2)    = rest1 `quotRem` (30 * 24 * 3600)
 292       (diffDays,   rest3)    = rest2 `quotRem` (24 * 3600)
 293       (diffHours,  rest4)    = rest3 `quotRem` 3600
 294       (diffMins,   diffSecs) = rest4 `quotRem` 60
 295   in
 296       td{ tdYear = diffYears
 297         , tdMonth = diffMonths
 298         , tdDay   = diffDays
 299         , tdHour  = diffHours
 300         , tdMin   = diffMins
 301         , tdSec   = diffSecs
 302         }
 303
 304 -- -----------------------------------------------------------------------------
 305 -- How do we deal with timezones on this architecture?
 306
 307 -- The POSIX way to do it is through the global variable tzname[].
 308 -- But that's crap, so we do it The BSD Way if we can: namely use the
 309 -- tm_zone and tm_gmtoff fields of struct tm, if they're available.
 310
 311 zone   :: Ptr CTm -> IO (Ptr CChar)
 312 gmtoff :: Ptr CTm -> IO CLong
 313 #if HAVE_TM_ZONE
 314 zone x      = (#peek struct tm,tm_zone) x
 315 gmtoff x    = (#peek struct tm,tm_gmtoff) x
 316
 317 #else /* ! HAVE_TM_ZONE */
 318 # if HAVE_TZNAME || defined(_WIN32)
 319 #  if cygwin32_TARGET_OS
 320 #   define tzname _tzname
 321 #  endif
 322 #  ifndef mingw32_TARGET_OS
 323 foreign label tzname :: Ptr (Ptr CChar)
 324 #  else
 325 foreign import "ghcTimezone" unsafe timezone :: Ptr CLong
 326 foreign import "ghcTzname" unsafe tzname :: Ptr (Ptr CChar)
 327 #   def inline long  *ghcTimezone(void) { return &_timezone; }
 328 #   def inline char **ghcTzname(void) { return _tzname; }
 329 #  endif
 330 zone x = do
 331   dst <- (#peek struct tm,tm_isdst) x
 332   if dst then peekElemOff tzname 1 else peekElemOff tzname 0
 333 # else /* ! HAVE_TZNAME */
 334 -- We're in trouble. If you should end up here, please report this as a bug.
 335 #  error "Don't know how to get at timezone name on your OS."
 336 # endif /* ! HAVE_TZNAME */
 337
 338 -- Get the offset in secs from UTC, if (struct tm) doesn't supply it. */
 339 #if defined(mingw32_TARGET_OS) || defined(cygwin32_TARGET_OS)
 340 #define timezone _timezone
 341 #endif
 342
 343 # if HAVE_ALTZONE
 344 foreign label altzone  :: Ptr CTime
 345 foreign label timezone :: Ptr CTime
 346 gmtoff x = do
 347   dst <- (#peek struct tm,tm_isdst) x
 348   tz <- if dst then peek altzone else peek timezone
 349   return (fromIntegral tz)
 350 #  define GMTOFF(x)      (((struct tm *)x)->tm_isdst ? altzone : timezone )
 351 # else /* ! HAVE_ALTZONE */
 352 -- Assume that DST offset is 1 hour ...
 353 gmtoff x = do
 354   dst <- (#peek struct tm,tm_isdst) x
 355   tz  <- peek timezone
 356   if dst then return (fromIntegral tz - 3600) else return tz
 357 # endif /* ! HAVE_ALTZONE */
 358 #endif  /* ! HAVE_TM_ZONE */
 359
 360 -- -----------------------------------------------------------------------------
 361 -- toCalendarTime t converts t to a local time, modified by
 362 -- the current timezone and daylight savings time settings.  toUTCTime
 363 -- t converts t into UTC time.  toClockTime l converts l into the
 364 -- corresponding internal ClockTime.  The wday, yday, tzname, and isdst fields
 365 -- are ignored.
 366
 367
 368 toCalendarTime :: ClockTime -> IO CalendarTime
 369 toCalendarTime =  clockToCalendarTime localtime False
 370
 371 toUTCTime      :: ClockTime -> CalendarTime
 372 toUTCTime      =  unsafePerformIO . clockToCalendarTime gmtime True
 373
 374 -- ToDo: should be made thread safe, because localtime uses static storage,
 375 -- or use the localtime_r version.
 376 clockToCalendarTime :: (Ptr CTime -> IO (Ptr CTm)) -> Bool -> ClockTime
 377          -> IO CalendarTime
 378 clockToCalendarTime fun is_utc (TOD secs psec) = do
 379   withObject (fromIntegral secs :: CTime)  $ \ p_timer -> do
 380     p_tm <- fun p_timer         -- can't fail, according to POSIX
 381     sec   <-  (#peek struct tm,tm_sec  ) p_tm :: IO CInt
 382     min   <-  (#peek struct tm,tm_min  ) p_tm :: IO CInt
 383     hour  <-  (#peek struct tm,tm_hour ) p_tm :: IO CInt
 384     mday  <-  (#peek struct tm,tm_mday ) p_tm :: IO CInt
 385     mon   <-  (#peek struct tm,tm_mon  ) p_tm :: IO CInt
 386     year  <-  (#peek struct tm,tm_year ) p_tm :: IO CInt
 387     wday  <-  (#peek struct tm,tm_wday ) p_tm :: IO CInt
 388     yday  <-  (#peek struct tm,tm_yday ) p_tm :: IO CInt
 389     isdst <-  (#peek struct tm,tm_isdst) p_tm :: IO CInt
 390     zone  <-  zone p_tm
 391     tz    <-  gmtoff p_tm
 392
 393     tzname <- peekCString zone
 394
 395     let month  | mon >= 0 && mon <= 11 = toEnum (fromIntegral mon)
 396                | otherwise             = error ("toCalendarTime: illegal month value: " ++ show mon)
 397
 398     return (CalendarTime
 399                 (1900 + fromIntegral year)
 400                 month
 401                 (fromIntegral mday)
 402                 (fromIntegral hour)
 403                 (fromIntegral min)
 404                 (fromIntegral sec)
 405                 psec
 406                 (toEnum (fromIntegral wday))
 407                 (fromIntegral yday)
 408                 (if is_utc then "UTC" else tzname)
 409                 (if is_utc then 0     else fromIntegral tz)
 410                 (if is_utc then False else isdst /= 0))
 411
 412
 413 toClockTime :: CalendarTime -> ClockTime
 414 toClockTime (CalendarTime year mon mday hour min sec psec
 415                           _wday _yday _tzname tz isdst) =
 416
 417      -- `isDst' causes the date to be wrong by one hour...
 418      -- FIXME: check, whether this works on other arch's than Linux, too...
 419      --
 420      -- so we set it to (-1) (means `unknown') and let `mktime' determine
 421      -- the real value...
 422     let isDst = -1 :: CInt in   -- if isdst then (1::Int) else 0
 423
 424     if psec < 0 || psec > 999999999999 then
 425         error "Time.toClockTime: picoseconds out of range"
 426     else if tz < -43200 || tz > 43200 then
 427         error "Time.toClockTime: timezone offset out of range"
 428     else
 429       unsafePerformIO $ do
 430       allocaBytes (#const sizeof(struct tm)) $ \ p_tm -> do
 431         (#poke struct tm,tm_sec  ) p_tm (fromIntegral sec  :: CInt)
 432         (#poke struct tm,tm_min  ) p_tm (fromIntegral min  :: CInt)
 433         (#poke struct tm,tm_hour ) p_tm (fromIntegral hour :: CInt)
 434         (#poke struct tm,tm_mday ) p_tm (fromIntegral mday :: CInt)
 435         (#poke struct tm,tm_mon  ) p_tm (fromIntegral (fromEnum mon) :: CInt)
 436         (#poke struct tm,tm_year ) p_tm (fromIntegral year - 1900 :: CInt)
 437         (#poke struct tm,tm_isdst) p_tm isDst
 438         t <- throwIf (== -1) (\_ -> "Time.toClockTime: invalid input")
 439                 (mktime p_tm)
 440         --
 441         -- mktime expects its argument to be in the local timezone, but
 442         -- toUTCTime makes UTC-encoded CalendarTime's ...
 443         --
 444         -- Since there is no any_tz_struct_tm-to-time_t conversion
 445         -- function, we have to fake one... :-) If not in all, it works in
 446         -- most cases (before, it was the other way round...)
 447         --
 448         -- Luckily, mktime tells us, what it *thinks* the timezone is, so,
 449         -- to compensate, we add the timezone difference to mktime's
 450         -- result.
 451         --
 452         gmtoff <- gmtoff p_tm
 453         let res = fromIntegral t - tz + fromIntegral gmtoff
 454         return (TOD (fromIntegral res) 0)
 455
 456 -- -----------------------------------------------------------------------------
 457 -- Converting time values to strings.
 458
 459 calendarTimeToString  :: CalendarTime -> String
 460 calendarTimeToString  =  formatCalendarTime defaultTimeLocale "%c"
 461
 462 formatCalendarTime :: TimeLocale -> String -> CalendarTime -> String
 463 formatCalendarTime l fmt (CalendarTime year mon day hour min sec _
 464                                        wday yday tzname _ _) =
 465         doFmt fmt
 466   where doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 467         doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 468         doFmt ('%':c:cs)   = decode c ++ doFmt cs
 469         doFmt (c:cs) = c : doFmt cs
 470         doFmt "" = ""
 471
 472         decode 'A' = fst (wDays l  !! fromEnum wday) -- day of the week, full name
 473         decode 'a' = snd (wDays l  !! fromEnum wday) -- day of the week, abbrev.
 474         decode 'B' = fst (months l !! fromEnum mon)  -- month, full name
 475         decode 'b' = snd (months l !! fromEnum mon)  -- month, abbrev
 476         decode 'h' = snd (months l !! fromEnum mon)  -- ditto
 477         decode 'C' = show2 (year `quot` 100)         -- century
 478         decode 'c' = doFmt (dateTimeFmt l)           -- locale's data and time format.
 479         decode 'D' = doFmt "%m/%d/%y"
 480         decode 'd' = show2 day                       -- day of the month
 481         decode 'e' = show2' day                      -- ditto, padded
 482         decode 'H' = show2 hour                      -- hours, 24-hour clock, padded
 483         decode 'I' = show2 (to12 hour)               -- hours, 12-hour clock
 484         decode 'j' = show3 yday                      -- day of the year
 485         decode 'k' = show2' hour                     -- hours, 24-hour clock, no padding
 486         decode 'l' = show2' (to12 hour)              -- hours, 12-hour clock, no padding
 487         decode 'M' = show2 min                       -- minutes
 488         decode 'm' = show2 (fromEnum mon+1)          -- numeric month
 489         decode 'n' = "\n"
 490         decode 'p' = (if hour < 12 then fst else snd) (amPm l) -- am or pm
 491         decode 'R' = doFmt "%H:%M"
 492         decode 'r' = doFmt (time12Fmt l)
 493         decode 'T' = doFmt "%H:%M:%S"
 494         decode 't' = "\t"
 495         decode 'S' = show2 sec                       -- seconds
 496         decode 's' = show2 sec                       -- number of secs since Epoch. (ToDo.)
 497         decode 'U' = show2 ((yday + 7 - fromEnum wday) `div` 7) -- week number, starting on Sunday.
 498         decode 'u' = show (let n = fromEnum wday in  -- numeric day of the week (1=Monday, 7=Sunday)
 499                            if n == 0 then 7 else n)
 500         decode 'V' =                                 -- week number (as per ISO-8601.)
 501             let (week, days) =                       -- [yep, I've always wanted to be able to display that too.]
 502                    (yday + 7 - if fromEnum wday > 0 then
 503                                fromEnum wday - 1 else 6) `divMod` 7
 504             in  show2 (if days >= 4 then
 505                           week+1
 506                        else if week == 0 then 53 else week)
 507
 508         decode 'W' =                                 -- week number, weeks starting on monday
 509             show2 ((yday + 7 - if fromEnum wday > 0 then
 510                                fromEnum wday - 1 else 6) `div` 7)
 511         decode 'w' = show (fromEnum wday)            -- numeric day of the week, weeks starting on Sunday.
 512         decode 'X' = doFmt (timeFmt l)               -- locale's preferred way of printing time.
 513         decode 'x' = doFmt (dateFmt l)               -- locale's preferred way of printing dates.
 514         decode 'Y' = show year                       -- year, including century.
 515         decode 'y' = show2 (year `rem` 100)          -- year, within century.
 516         decode 'Z' = tzname                          -- timezone name
 517         decode '%' = "%"
 518         decode c   = [c]
 519
 520
 521 show2, show2', show3 :: Int -> String
 522 show2 x
 523  | x' < 10   = '0': show x'
 524  | otherwise = show x'
 525  where x' = x `rem` 100
 526
 527 show2' x
 528  | x' < 10   = ' ': show x'
 529  | otherwise = show x'
 530  where x' = x `rem` 100
 531
 532 show3 x = show (x `quot` 100) ++ show2 (x `rem` 100)
 533  where x' = x `rem` 1000
 534
 535 to12 :: Int -> Int
 536 to12 h = let h' = h `mod` 12 in if h' == 0 then 12 else h'
 537
 538 -- Useful extensions for formatting TimeDiffs.
 539
 540 timeDiffToString :: TimeDiff -> String
 541 timeDiffToString = formatTimeDiff defaultTimeLocale "%c"
 542
 543 formatTimeDiff :: TimeLocale -> String -> TimeDiff -> String
 544 formatTimeDiff l fmt td@(TimeDiff year month day hour min sec _)
 545  = doFmt fmt
 546   where
 547    doFmt ""         = ""
 548    doFmt ('%':'-':cs) = doFmt ('%':cs) -- padding not implemented
 549    doFmt ('%':'_':cs) = doFmt ('%':cs) -- padding not implemented
 550    doFmt ('%':c:cs) = decode c ++ doFmt cs
 551    doFmt (c:cs)     = c : doFmt cs
 552
 553    decode spec =
 554     case spec of
 555       'B' -> fst (months l !! fromEnum month)
 556       'b' -> snd (months l !! fromEnum month)
 557       'h' -> snd (months l !! fromEnum month)
 558       'c' -> defaultTimeDiffFmt td
 559       'C' -> show2 (year `quot` 100)
 560       'D' -> doFmt "%m/%d/%y"
 561       'd' -> show2 day
 562       'e' -> show2' day
 563       'H' -> show2 hour
 564       'I' -> show2 (to12 hour)
 565       'k' -> show2' hour
 566       'l' -> show2' (to12 hour)
 567       'M' -> show2 min
 568       'm' -> show2 (fromEnum month + 1)
 569       'n' -> "\n"
 570       'p' -> (if hour < 12 then fst else snd) (amPm l)
 571       'R' -> doFmt "%H:%M"
 572       'r' -> doFmt (time12Fmt l)
 573       'T' -> doFmt "%H:%M:%S"
 574       't' -> "\t"
 575       'S' -> show2 sec
 576       's' -> show2 sec -- Implementation-dependent, sez the lib doc..
 577       'X' -> doFmt (timeFmt l)
 578       'x' -> doFmt (dateFmt l)
 579       'Y' -> show year
 580       'y' -> show2 (year `rem` 100)
 581       '%' -> "%"
 582       c   -> [c]
 583
 584    defaultTimeDiffFmt (TimeDiff year month day hour min sec _) =
 585        foldr (\ (v,s) rest ->
 586                   (if v /= 0
 587                      then show v ++ ' ':(addS v s)
 588                        ++ if null rest then "" else ", "
 589                      else "") ++ rest
 590              )
 591              ""
 592              (zip [year, month, day, hour, min, sec] (intervals l))
 593
 594    addS v s = if abs v == 1 then fst s else snd s
 595
 596
 597 -- -----------------------------------------------------------------------------
 598 -- Foreign time interface (POSIX)
 599
 600 type CTm = () -- struct tm
 601
 602 foreign import unsafe localtime :: Ptr CTime -> IO (Ptr CTm)
 603 foreign import unsafe gmtime    :: Ptr CTime -> IO (Ptr CTm)
 604 foreign import unsafe mktime    :: Ptr CTm   -> IO CTime
 605 foreign import unsafe time      :: Ptr CTime -> IO CTime
 606
 607 #if HAVE_GETTIMEOFDAY
 608 type CTimeVal = ()
 609 foreign import unsafe gettimeofday :: Ptr CTimeVal -> Ptr () -> IO CInt
 610 #endif
 611
 612 #if HAVE_FTIME
 613 type CTimeB = ()
 614 #ifndef mingw32_TARGET_OS
 615 foreign import unsafe ftime :: Ptr CTimeB -> IO CInt
 616 #else
 617 foreign import unsafe ftime :: Ptr CTimeB -> IO ()
 618 #endif
 619 #endif