System/Timeout.hs

   1 -------------------------------------------------------------------------------
   2 -- |
   3 -- Module      :  System.Timeout
   4 -- Copyright   :  (c) The University of Glasgow 2007
   5 -- License     :  BSD-style (see the file libraries/base/LICENSE)
   6 --
   7 -- Maintainer  :  libraries@haskell.org
   8 -- Stability   :  experimental
   9 -- Portability :  non-portable
  10 --
  11 -- Attach a timeout event to arbitrary 'IO' computations.
  12 --
  13 -------------------------------------------------------------------------------
  14
  15 module System.Timeout ( timeout ) where
  16
  17 #if __NHC__
  18 timeout :: Int -> IO a -> IO (Maybe a)
  19 timeout n f = fmap Just f
  20 #else
  21
  22 import Prelude             (Show(show), IO, Ord((<)), Eq((==)), Int,
  23                             (.), otherwise, fmap)
  24 import Data.Maybe          (Maybe(..))
  25 import Control.Monad       (Monad(..), guard)
  26 import Control.Concurrent  (forkIO, threadDelay, myThreadId, killThread)
  27 import Control.Exception   (Exception, handleJust, throwTo, bracket)
  28 import Data.Dynamic        (Typeable, fromDynamic)
  29 import Data.Unique         (Unique, newUnique)
  30
  31 -- An internal type that is thrown as a dynamic exception to
  32 -- interrupt the running IO computation when the timeout has
  33 -- expired.
  34
  35 data Timeout = Timeout Unique deriving (Eq, Typeable)
  36
  37 instance Show Timeout where
  38     show _ = "<<timeout>>"
  39
  40 instance Exception Timeout
  41
  42 -- |Wrap an 'IO' computation to time out and return @Nothing@ in case no result
  43 -- is available within @n@ microseconds (@1\/10^6@ seconds). In case a result
  44 -- is available before the timeout expires, @Just a@ is returned. A negative
  45 -- timeout interval means \"wait indefinitely\". When specifying long timeouts,
  46 -- be careful not to exceed @maxBound :: Int@.
  47 --
  48 -- The design of this combinator was guided by the objective that @timeout n f@
  49 -- should behave exactly the same as @f@ as long as @f@ doesn't time out. This
  50 -- means that @f@ has the same 'myThreadId' it would have without the timeout
  51 -- wrapper. Any exceptions @f@ might throw cancel the timeout and propagate
  52 -- further up. It also possible for @f@ to receive exceptions thrown to it by
  53 -- another thread.
  54 --
  55 -- A tricky implementation detail is the question of how to abort an @IO@
  56 -- computation. This combinator relies on asynchronous exceptions internally.
  57 -- The technique works very well for computations executing inside of the
  58 -- Haskell runtime system, but it doesn't work at all for non-Haskell code.
  59 -- Foreign function calls, for example, cannot be timed out with this
  60 -- combinator simply because an arbitrary C function cannot receive
  61 -- asynchronous exceptions. When @timeout@ is used to wrap an FFI call that
  62 -- blocks, no timeout event can be delivered until the FFI call returns, which
  63 -- pretty much negates the purpose of the combinator. In practice, however,
  64 -- this limitation is less severe than it may sound. Standard I\/O functions
  65 -- like 'System.IO.hGetBuf', 'System.IO.hPutBuf', Network.Socket.accept, or
  66 -- 'System.IO.hWaitForInput' appear to be blocking, but they really don't
  67 -- because the runtime system uses scheduling mechanisms like @select(2)@ to
  68 -- perform asynchronous I\/O, so it is possible to interrupt standard socket
  69 -- I\/O or file I\/O using this combinator.
  70
  71 timeout :: Int -> IO a -> IO (Maybe a)
  72 timeout n f
  73     | n <  0    = fmap Just f
  74     | n == 0    = return Nothing
  75     | otherwise = do
  76         pid <- myThreadId
  77         ex  <- fmap Timeout newUnique
  78         handleJust (\e -> if e == ex then Just () else Nothing)
  79                    (\_ -> return Nothing)
  80                    (bracket (forkIO (threadDelay n >> throwTo pid ex))
  81                             (killThread)
  82                             (\_ -> fmap Just f))
  83 #endif