aclocal.m4

   1 # Extra autoconf macros for the Glasgow fptools
   2 #
   3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
   4 # ensure we don't clash with any pre-supplied autoconf ones.
   5
   6
   7 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
   8 # ----------------------------------
   9 # Little endian Arm on Linux with some ABIs has big endian word order
  10 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
  11 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
  12   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
  13     [AC_COMPILE_IFELSE(
  14       [AC_LANG_PROGRAM(
  15         [#include <endian.h>],
  16         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
  17              return 0;
  18          #else
  19              not float word order big endian
  20          #endif]
  21       )],
  22       [fptools_cv_float_word_order_bigendian=yes],
  23       [fptools_cv_float_word_order_bigendian=no])
  24     ])
  25   case $fptools_cv_float_word_order_bigendian in
  26       yes)
  27           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
  28           [Define to 1 if your processor stores words of floats with
  29            the most significant byte first]) ;;
  30   esac
  31 ])
  32
  33
  34 # FP_EVAL_STDERR(COMMAND)
  35 # -----------------------
  36 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
  37 # into the file conftest.err and the exit status in the variable fp_status.
  38 AC_DEFUN([FP_EVAL_STDERR],
  39 [{ (eval $1) 2>conftest.er1
  40   fp_status=$?
  41   grep -v '^ *+' conftest.er1 >conftest.err
  42   rm -f conftest.er1
  43   (exit $fp_status); }[]dnl
  44 ])# FP_EVAL_STDERR
  45
  46
  47 # FP_PROG_CONTEXT_DIFF
  48 # --------------------
  49 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
  50 #
  51 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
  52 #
  53 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
  54 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
  55 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
  56 [echo foo > conftest1
  57 echo foo > conftest2
  58 fp_cv_context_diff=no
  59 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
  60 do
  61   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
  62     fp_cv_context_diff="diff $fp_var"
  63     break
  64   fi
  65 done])
  66 if test x"$fp_cv_context_diff" = xno; then
  67    AC_MSG_ERROR([cannot figure out how to do context diffs])
  68 fi
  69 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
  70 ])# FP_PROG_CONTEXT_DIFF
  71
  72
  73 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
  74 # --------------------------------------------------------
  75 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
  76 # compilation. Execute IF-FAILS when unable to determine the value. Works for
  77 # cross-compilation, too.
  78 #
  79 # Implementation note: We are lazy and use an internal autoconf macro, but it
  80 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
  81 # little risk.
  82 AC_DEFUN([FP_COMPUTE_INT],
  83 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
  84 ])# FP_COMPUTE_INT
  85
  86
  87 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
  88 # ------------------------------------------------------------------
  89 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
  90 # given type. Defines ALIGNMENT_TYPE.
  91 AC_DEFUN([FP_CHECK_ALIGNMENT],
  92 [AS_LITERAL_IF([$1], [],
  93                [AC_FATAL([$0: requires literal arguments])])[]dnl
  94 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
  95 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
  96 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
  97 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
  98   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
  99                  [fp_Cache],
 100                  [AC_INCLUDES_DEFAULT([$3])],
 101                  [AC_MSG_ERROR([cannot compute alignment ($1)
 102 See `config.log' for more details.], [77])])
 103 else
 104   fp_Cache=0
 105 fi])[]dnl
 106 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
 107 m4_popdef([fp_Cache])[]dnl
 108 ])# FP_CHECK_ALIGNMENT
 109
 110
 111 # FP_LEADING_UNDERSCORE
 112 # ---------------------
 113 # Test for determining whether symbol names have a leading underscore. We assume
 114 # that they _haven't_ if anything goes wrong. Sets the output variable
 115 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
 116 #
 117 # Some nlist implementations seem to try to be compatible by ignoring a leading
 118 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
 119 # checking for *no* leading underscore first. Sigh.  --SDM
 120 #
 121 # Similarly on OpenBSD, but this test doesn't help. -- dons
 122 AC_DEFUN([FP_LEADING_UNDERSCORE],
 123 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
 124 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
 125 # Hack!: nlist() under Digital UNIX insist on there being an _,
 126 # but symbol table listings shows none. What is going on here?!?
 127 #
 128 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
 129 # the underscoredness of that "platform"
 130 case $HostPlatform in
 131 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
 132   case $build in
 133     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
 134     *) fptools_cv_leading_underscore=no ;;
 135   esac ;;
 136 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
 137 *cygwin32) fptools_cv_leading_underscore=yes;;
 138 *mingw32) fptools_cv_leading_underscore=yes;;
 139
 140     # HACK: Apple doesn't seem to provide nlist in the 64-bit-libraries
 141 x86_64-apple-darwin*) fptools_cv_leading_underscore=yes;;
 142
 143 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
 144 #include <nlist.h>
 145 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
 146 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
 147 #endif
 148
 149 int main(argc, argv)
 150 int argc;
 151 char **argv;
 152 {
 153 #ifdef HAVE_NLIST_H
 154     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
 155         exit(1);
 156     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
 157         exit(0);
 158 #endif
 159     exit(1);
 160 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
 161 ;;
 162 esac]);
 163 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
 164 if test x"$fptools_cv_leading_underscore" = xyes; then
 165    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
 166 fi])# FP_LEADING_UNDERSCORE
 167
 168
 169 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 170 # ----------------------------------------------------------------------------------
 171 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
 172 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
 173 AC_DEFUN([FP_COMPARE_VERSIONS],
 174 [fp_version1=$1; fp_version2=$3
 175 fp_save_IFS=$IFS; IFS='.'
 176 while test x"$fp_version1" != x || test x"$fp_version2" != x
 177 do
 178
 179   set dummy $fp_version1; shift
 180   fp_num1=""
 181   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
 182   test x"$fp_num1" = x && fp_num1="0"
 183   fp_version1="[$]*"
 184
 185   set dummy $fp_version2; shift
 186   fp_num2=""
 187   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
 188   test x"$fp_num2" = x && fp_num2="0"
 189   fp_version2="[$]*"
 190
 191   test "$fp_num1" = "$fp_num2" || break;
 192 done
 193 IFS=$fp_save_IFS
 194 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
 195 ])# FP_COMPARE_VERSIONS
 196
 197
 198 dnl
 199 dnl Check for GreenCard and version.
 200 dnl
 201 AC_DEFUN([FPTOOLS_GREENCARD],
 202 [
 203 AC_PATH_PROG(GreenCardCmd,greencard)
 204 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
 205 changequote(, )dnl
 206 [if test x"$GreenCardCmd" != x; then
 207    fptools_cv_greencard_version="`$GreenCardCmd --version |
 208                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
 209 else
 210    fptools_cv_greencard_version=""
 211 fi
 212 changequote([, ])dnl
 213 ])
 214 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
 215   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
 216 GreenCardVersion=$fptools_cv_greencard_version
 217 AC_SUBST(GreenCardVersion)
 218 ])
 219
 220 dnl
 221 dnl Check for Happy and version.  If we're building GHC, then we need
 222 dnl at least Happy version 1.14.  If there's no installed Happy, we look
 223 dnl for a happy source tree and point the build system at that instead.
 224 dnl
 225 AC_DEFUN([FPTOOLS_HAPPY],
 226 [AC_PATH_PROG(HappyCmd,happy,)
 227 # Happy is passed to Cabal, so we need a native path
 228 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 229    test "${OSTYPE}"      != "msys"                  && \
 230    test "${HappyCmd}"    != ""
 231 then
 232     # Canonicalise to <drive>:/path/to/gcc
 233     HappyCmd=`cygpath -m ${HappyCmd}`
 234     AC_MSG_NOTICE([normalized happy command to $HappyCmd])
 235 fi
 236
 237 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
 238 changequote(, )dnl
 239 [if test x"$HappyCmd" != x; then
 240    fptools_cv_happy_version="`$HappyCmd -v |
 241                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
 242 else
 243    fptools_cv_happy_version="";
 244 fi;
 245 changequote([, ])dnl
 246 ])
 247 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/main/ParsePkgConf.hs || test ! -f compiler/cmm/CmmParse.hs || test ! -f compiler/parser/ParserCore.hs
 248 then
 249     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
 250       [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
 251 fi
 252 HappyVersion=$fptools_cv_happy_version;
 253 AC_SUBST(HappyVersion)
 254 ])
 255
 256 dnl
 257 dnl Check for Haddock and version.  If there's no installed Haddock, we look
 258 dnl for a haddock source tree and point the build system at that instead.
 259 dnl
 260 AC_DEFUN([FPTOOLS_HADDOCK],
 261 [AC_PATH_PROG(HaddockCmd,haddock,)
 262 dnl Darn, I forgot to make Haddock print out its version number when
 263 dnl invoked with -v.  We could try generating some HTML and grepping
 264 dnl through that to find the version number, but I think we'll make
 265 dnl do without it for now.
 266 # Haddock is passed to Cabal, so we need a native path
 267 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 268    test "${OSTYPE}"      != "msys"                  && \
 269    test "${HaddockCmd}"  != ""
 270 then
 271     # Canonicalise to <drive>:/path/to/gcc
 272     HaddockCmd=`cygpath -m ${HaddockCmd}`
 273     AC_MSG_NOTICE([normalized haddock command to $HaddockCmd])
 274 fi
 275 ])
 276
 277 dnl
 278 dnl Check for Alex and version.  If we're building GHC, then we need
 279 dnl at least Alex version 2.0.1.
 280 dnl
 281 AC_DEFUN([FPTOOLS_ALEX],
 282 [
 283 AC_PATH_PROG(AlexCmd,alex,)
 284 # Alex is passed to Cabal, so we need a native path
 285 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 286    test "${OSTYPE}"      != "msys"                  && \
 287    test "${AlexCmd}"     != ""
 288 then
 289     # Canonicalise to <drive>:/path/to/gcc
 290     AlexCmd=`cygpath -m ${AlexCmd}`
 291 fi
 292
 293 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
 294 changequote(, )dnl
 295 [if test x"$AlexCmd" != x; then
 296    fptools_cv_alex_version="`$AlexCmd -v |
 297                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
 298 else
 299    fptools_cv_alex_version="";
 300 fi;
 301 changequote([, ])dnl
 302 ])
 303 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
 304 then
 305     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0.1],
 306       [AC_MSG_ERROR([Alex version 2.0.1 or later is required to compile GHC.])])[]dnl
 307 fi
 308 AlexVersion=$fptools_cv_alex_version;
 309 AC_SUBST(AlexVersion)
 310 ])
 311
 312
 313 # FP_PROG_LD
 314 # ----------
 315 # Sets the output variable LdCmd to the (non-Cygwin version of the) full path
 316 # of ld. Exits if no ld can be found
 317 AC_DEFUN([FP_PROG_LD],
 318 [
 319 if test -z "$1"
 320 then
 321   AC_PATH_PROG([fp_prog_ld_raw], [ld])
 322   if test -z "$fp_prog_ld_raw"; then
 323     AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
 324   fi
 325   LdCmd=$fp_prog_ld_raw
 326   case $HostPlatform in
 327     *mingw32) if test x${OSTYPE} != xmsys; then
 328               LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
 329                 AC_MSG_NOTICE([normalized ld command to $LdCmd])
 330               fi
 331             # Insist on >= ld-2.15.x, since earlier versions doesn't handle
 332             # the generation of relocatable object files with large amounts
 333             # of relocations correctly. (cf. HSbase.o splittage-hack)
 334             fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
 335             FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
 336                                   [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
 337               ;;
 338   esac
 339 else
 340   LdCmd="$1"
 341 fi
 342 AC_SUBST([LdCmd])
 343 ])# FP_PROG_LD
 344
 345
 346 # FP_PROG_LD_X
 347 # ------------
 348 # Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
 349 # variable's value is empty.
 350 AC_DEFUN([FP_PROG_LD_X],
 351 [AC_REQUIRE([FP_PROG_LD])
 352 AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
 353 [echo 'foo() {}' > conftest.c
 354 ${CC-cc} -c conftest.c
 355 if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
 356    fp_cv_ld_x=yes
 357 else
 358    fp_cv_ld_x=no
 359 fi
 360 rm -rf conftest*])
 361 if test "$fp_cv_ld_x" = yes; then
 362   LdXFlag=-x
 363 else
 364   LdXFlag=
 365 fi
 366 AC_SUBST([LdXFlag])
 367 ])# FP_PROG_LD_X
 368
 369
 370 # FP_PROG_LD_IS_GNU
 371 # -----------------
 372 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
 373 # GNU ld or not.
 374 AC_DEFUN([FP_PROG_LD_IS_GNU],
 375 [AC_REQUIRE([FP_PROG_LD])
 376 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
 377 [if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 378   fp_cv_gnu_ld=yes
 379 else
 380   fp_cv_gnu_ld=no
 381 fi])
 382 AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
 383 ])# FP_PROG_LD_IS_GNU
 384
 385
 386 # FP_PROG_AR
 387 # ----------
 388 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
 389 # version of it. Exits if no ar can be found
 390 AC_DEFUN([FP_PROG_AR],
 391 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
 392 if test -z "$fp_prog_ar_raw"; then
 393   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
 394 fi
 395 fp_prog_ar=$fp_prog_ar_raw
 396 case $HostPlatform in
 397   *mingw32) if test x${OSTYPE} != xmsys; then
 398               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
 399               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
 400             fi
 401             ;;
 402 esac
 403 ])# FP_PROG_AR
 404
 405
 406 # FP_PROG_AR_IS_GNU
 407 # -----------------
 408 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
 409 AC_DEFUN([FP_PROG_AR_IS_GNU],
 410 [AC_REQUIRE([FP_PROG_AR])
 411 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
 412 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
 413   fp_cv_prog_ar_is_gnu=yes
 414 else
 415   fp_cv_prog_ar_is_gnu=no
 416 fi])
 417 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
 418 ])# FP_PROG_AR_IS_GNU
 419
 420
 421 # FP_PROG_AR_ARGS
 422 # ---------------
 423 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
 424 # to a non-Cygwin invocation of ar including these arguments.
 425 AC_DEFUN([FP_PROG_AR_ARGS],
 426 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 427 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
 428 [
 429 # GNU ar needs special treatment: it appears to have problems with
 430 # object files with the same name if you use the 's' modifier, but
 431 # simple 'ar q' works fine, and doesn't need a separate ranlib.
 432 if test $fp_prog_ar_is_gnu = yes; then
 433   fp_cv_prog_ar_args="q"
 434 else
 435   touch conftest.dummy
 436   for fp_var in clqsZ clqs cqs clq cq ; do
 437      rm -f conftest.a
 438      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
 439         fp_cv_prog_ar_args=$fp_var
 440         break
 441      fi
 442   done
 443   rm -f conftest*
 444   if test -z "$fp_cv_prog_ar_args"; then
 445     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
 446   fi
 447 fi])
 448 fp_prog_ar_args=$fp_cv_prog_ar_args
 449 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
 450
 451 ])# FP_PROG_AR_ARGS
 452
 453
 454 # FP_PROG_AR_NEEDS_RANLIB
 455 # -----------------------
 456 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
 457 # to ":" otherwise.
 458 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
 459 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 460 AC_REQUIRE([FP_PROG_AR_ARGS])
 461 AC_REQUIRE([AC_PROG_CC])
 462 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
 463 [if test $fp_prog_ar_is_gnu = yes; then
 464   fp_cv_prog_ar_needs_ranlib=no
 465 elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
 466   # It's quite tedious to check for Apple's crazy timestamps in .a files,
 467   # so we hardcode it.
 468   fp_cv_prog_ar_needs_ranlib=yes
 469 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
 470   fp_cv_prog_ar_needs_ranlib=no
 471 else
 472   fp_cv_prog_ar_needs_ranlib=yes
 473 fi])
 474 if test $fp_cv_prog_ar_needs_ranlib = yes; then
 475    AC_PROG_RANLIB
 476 else
 477   RANLIB=":"
 478   AC_SUBST([RANLIB])
 479 fi
 480 ])# FP_PROG_AR_NEEDS_RANLIB
 481
 482
 483 # FP_PROG_AR_SUPPORTS_INPUT
 484 # -------------------------
 485 # Sets the output variable ArSupportsInput to "-input" or "", depending on
 486 # whether ar supports -input flag is supported or not.
 487 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
 488 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
 489 AC_REQUIRE([FP_PROG_AR_ARGS])
 490 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
 491 [fp_cv_prog_ar_supports_input=no
 492 if test $fp_prog_ar_is_gnu = no; then
 493   rm -f conftest*
 494   touch conftest.lst
 495   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
 496     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
 497   fi
 498   rm -f conftest*
 499 fi])
 500 if test $fp_cv_prog_ar_supports_input = yes; then
 501     ArSupportsInput="-input"
 502 else
 503     ArSupportsInput=""
 504 fi
 505 AC_SUBST([ArSupportsInput])
 506 ])# FP_PROG_AR_SUPPORTS_INPUT
 507
 508
 509 dnl
 510 dnl AC_SHEBANG_PERL - can we she-bang perl?
 511 dnl
 512 AC_DEFUN([FPTOOLS_SHEBANG_PERL],
 513 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
 514 [echo "#!$PerlCmd"'
 515 exit $1;
 516 ' > conftest
 517 chmod u+x conftest
 518 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
 519 if test $? -ne 69; then
 520    fptools_cv_shebang_perl=yes
 521 else
 522    fptools_cv_shebang_perl=no
 523 fi
 524 rm -f conftest
 525 ])])
 526
 527
 528 # FP_HAVE_GCC
 529 # -----------
 530 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
 531 # output variables HaveGcc and GccVersion.
 532 AC_DEFUN([FP_HAVE_GCC],
 533 [AC_REQUIRE([AC_PROG_CC])
 534 if test -z "$GCC"; then
 535    fp_have_gcc=NO
 536 else
 537    fp_have_gcc=YES
 538 fi
 539 if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
 540   AC_MSG_ERROR([gcc is required])
 541 fi
 542 AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
 543 [if test "$fp_have_gcc" = "YES"; then
 544    fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
 545    FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
 546      [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 547  else
 548    fp_gcc_version="not-installed"
 549  fi
 550 ])
 551 AC_SUBST([HaveGcc], [$fp_have_gcc])
 552 AC_SUBST([GccVersion], [$fp_gcc_version])
 553 ])# FP_HAVE_GCC
 554
 555 AC_DEFUN([FP_MINGW_GCC],
 556 [
 557   case $HostOS_CPP in
 558     mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
 559              if $CC -v 2>&1 | grep mingw >/dev/null; then
 560                 AC_MSG_RESULT([yes])
 561              else
 562                 AC_MSG_RESULT([no])
 563                 AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
 564              fi;;
 565     *) ;;
 566   esac
 567 ])
 568
 569 dnl Small feature test for perl version. Assumes PerlCmd
 570 dnl contains path to perl binary.
 571 dnl
 572 dnl (Perl versions prior to v5.6 does not contain the string "v5";
 573 dnl instead they display version strings such as "version 5.005".)
 574 dnl
 575 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
 576 [$PerlCmd -v >conftest.out 2>&1
 577    if grep "v5" conftest.out >/dev/null 2>&1; then
 578       :
 579    else
 580       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
 581    fi
 582 rm -fr conftest*
 583 ])
 584
 585
 586 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
 587 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
 588 # -----------------------------------------------------
 589 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
 590 # of PROG-TO-CHECK-FOR when found.
 591 AC_DEFUN([FP_CHECK_PROG],
 592 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
 593 )# FP_CHECK_PROC
 594
 595
 596 # FP_PROG_FIND
 597 # ------------
 598 # Find a non-WinDoze version of the "find" utility.
 599 AC_DEFUN([FP_PROG_FIND],
 600 [AC_PATH_PROG([fp_prog_find], [find])
 601 echo foo > conftest.txt
 602 $fp_prog_find conftest.txt -print > conftest.out 2>&1
 603 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
 604   # OK, looks like a real "find".
 605   case $HostPlatform in
 606     *mingw32)
 607       if test x${OSTYPE} != xmsys
 608       then
 609             fp_prog_find="`cygpath --mixed ${fp_prog_find}`"
 610         AC_MSG_NOTICE([normalized find command to $fp_prog_find])
 611       fi ;;
 612     *) ;;
 613   esac
 614   FindCmd="$fp_prog_find"
 615 else
 616   # Found a poor WinDoze version of "find", ignore it.
 617   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
 618   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
 619 fi
 620 rm -f conftest.txt conftest.out
 621 AC_SUBST([FindCmd])[]dnl
 622 ])# FP_PROG_FIND
 623
 624
 625 # FP_PROG_SORT
 626 # ------------
 627 # Find a Unix-like sort
 628 AC_DEFUN([FP_PROG_SORT],
 629 [AC_PATH_PROG([fp_prog_sort], [sort])
 630 echo conwip > conftest.txt
 631 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
 632 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
 633   # The goods
 634   SortCmd="$fp_prog_sort"
 635 else
 636   # Summink else..pick next one.
 637   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
 638   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
 639 fi
 640 rm -f conftest.txt conftest.out
 641 AC_SUBST([SortCmd])[]dnl
 642 ])# FP_PROG_SORT
 643
 644 dnl
 645 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
 646 dnl values of the second argument to the result of running
 647 dnl the commands given by the third. It does not cache its
 648 dnl result, so it is suitable for checks which should be
 649 dnl run every time.
 650 dnl
 651 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
 652 [AC_MSG_CHECKING([$1])
 653  $3
 654  AC_MSG_RESULT([$][$2])
 655 ])
 656
 657 dnl
 658 dnl FPTOOLS_GHC_VERSION(version)
 659 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
 660 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
 661 dnl
 662 dnl Test for version of installed ghc.  Uses $GHC.
 663 dnl [original version pinched from c2hs]
 664 dnl
 665 AC_DEFUN([FPTOOLS_GHC_VERSION],
 666 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
 667 ["${WithGhc-ghc}" --version > conftestghc 2>&1
 668   cat conftestghc >&AS_MESSAGE_LOG_FD
 669 #Useless Use Of cat award...
 670   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
 671   rm -fr conftest*
 672   if test "[$]fptools_version_of_ghc" = ""
 673   then
 674     fptools_version_of_ghc='unknown'
 675   fi
 676 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
 677 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
 678 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
 679 #
 680 if test "[$]fptools_version_of_ghc[_pl]" = ""
 681 then
 682   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
 683   fptools_version_of_ghc[_pl]="0"
 684 else
 685   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
 686 fi
 687 #
 688 ifelse($#, [1], [dnl
 689 [$1]="[$]fptools_version_of_ghc[_all]"
 690 ], $#, [2], [dnl
 691 [$1]="[$]fptools_version_of_ghc[_major]"
 692 [$2]="[$]fptools_version_of_ghc[_minor]"
 693 ], $#, [3], [dnl
 694 [$1]="[$]fptools_version_of_ghc[_major]"
 695 [$2]="[$]fptools_version_of_ghc[_minor]"
 696 [$3]="[$]fptools_version_of_ghc[_pl]"
 697 ], $#, [4], [dnl
 698 [$1]="[$]fptools_version_of_ghc[_all]"
 699 [$2]="[$]fptools_version_of_ghc[_major]"
 700 [$3]="[$]fptools_version_of_ghc[_minor]"
 701 [$4]="[$]fptools_version_of_ghc[_pl]"
 702 ])
 703 ])
 704 ])dnl
 705
 706
 707 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 708 # ---------------------------------------------------------------------------------
 709 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
 710 # additional flexibility of specifying the PROLOGUE and BODY.
 711 AC_DEFUN([FP_CHECK_FUNC],
 712 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
 713 AC_CACHE_CHECK([for $1], fp_func,
 714 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
 715                 [AS_VAR_SET(fp_func, yes)],
 716                 [AS_VAR_SET(fp_func, no)])])
 717 AS_IF([test AS_VAR_GET(fp_func) = yes],
 718       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
 719                 [Define to 1 if you have the `]$1[' function.]) $4],
 720       [$5])dnl
 721 AS_VAR_POPDEF([fp_func])dnl
 722 ])# FP_CHECK_FUNC
 723
 724
 725 # FP_GEN_DOCBOOK_XML
 726 # ------------------
 727 # Generates a DocBook XML V4.2 document in conftest.xml.
 728 AC_DEFUN([FP_GEN_DOCBOOK_XML],
 729 [rm -f conftest.xml
 730 cat > conftest.xml << EOF
 731 <?xml version="1.0" encoding="iso-8859-1"?>
 732 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
 733    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
 734 <book id="test">
 735   <title>A DocBook Test Document</title>
 736   <chapter id="id-one">
 737     <title>A Chapter Title</title>
 738     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
 739   </chapter>
 740   <chapter id="id-two">
 741     <title>Another Chapter Title</title>
 742     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
 743   </chapter>
 744 </book>
 745 EOF
 746 ]) # FP_GEN_DOCBOOK_XML
 747
 748
 749 # FP_PROG_XSLTPROC
 750 # ----------------
 751 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
 752 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
 753 AC_DEFUN([FP_PROG_XSLTPROC],
 754 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
 755 if test -z "$XsltprocCmd"; then
 756   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
 757 fi
 758 ])# FP_PROG_XSLTPROC
 759
 760
 761 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
 762 # ----------------------------
 763 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
 764 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
 765 # will be empty if none could be found.
 766 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
 767 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
 768 if test -n "$XsltprocCmd"; then
 769   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
 770   [FP_GEN_DOCBOOK_XML
 771   fp_cv_dir_docbook_xsl=no
 772   for fp_var in $1; do
 773      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
 774         fp_cv_dir_docbook_xsl=$fp_var
 775         break
 776      fi
 777   done
 778   rm -rf conftest*])
 779 fi
 780 if test x"$fp_cv_dir_docbook_xsl" = xno; then
 781   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
 782   DIR_DOCBOOK_XSL=
 783 else
 784   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
 785 fi
 786 AC_SUBST([DIR_DOCBOOK_XSL])
 787 ])# FP_DIR_DOCBOOK_XSL
 788
 789
 790 # FP_PROG_XMLLINT
 791 # ----------------
 792 # Sets the output variable XmllintCmd to the full path of the XSLT processor
 793 # xmllint. XmllintCmd is empty if xmllint could not be found.
 794 AC_DEFUN([FP_PROG_XMLLINT],
 795 [AC_PATH_PROG([XmllintCmd], [xmllint])
 796 if test -z "$XmllintCmd"; then
 797   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
 798 fi
 799 ])# FP_PROG_XMLLINT
 800
 801
 802 # FP_CHECK_DOCBOOK_DTD
 803 # --------------------
 804 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
 805 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
 806 if test -n "$XmllintCmd"; then
 807   AC_MSG_CHECKING([for DocBook DTD])
 808   FP_GEN_DOCBOOK_XML
 809   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
 810     AC_MSG_RESULT([ok])
 811   else
 812     AC_MSG_RESULT([failed])
 813     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
 814     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
 815   fi
 816   rm -rf conftest*
 817 fi
 818 ])# FP_CHECK_DOCBOOK_DTD
 819
 820
 821 # FP_GEN_FO
 822 # ------------------
 823 # Generates a formatting objects document in conftest.fo.
 824 AC_DEFUN([FP_GEN_FO],
 825 [rm -f conftest.fo
 826 cat > conftest.fo << EOF
 827 <?xml version="1.0"?>
 828 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
 829   <fo:layout-master-set>
 830     <fo:simple-page-master master-name="blank">
 831       <fo:region-body/>
 832     </fo:simple-page-master>
 833   </fo:layout-master-set>
 834   <fo:page-sequence master-reference="blank">
 835     <fo:flow flow-name="xsl-region-body">
 836       <fo:block>
 837         Test!
 838       </fo:block>
 839     </fo:flow>
 840   </fo:page-sequence>
 841 </fo:root>
 842 EOF
 843 ]) # FP_GEN_FO
 844
 845
 846 # FP_PROG_FOP
 847 # -----------
 848 # Set the output variable 'FopCmd' to the first working 'fop' in the current
 849 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
 850 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
 851 AC_DEFUN([FP_PROG_FOP],
 852 [AC_PATH_PROGS([FopCmd1], [fop fop.sh])
 853 if test -n "$FopCmd1"; then
 854   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
 855     [FP_GEN_FO
 856     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
 857       fp_cv_fop_usability=yes
 858     else
 859       fp_cv_fop_usability=no
 860     fi
 861     rm -rf conftest*])
 862   if test x"$fp_cv_fop_usability" = xyes; then
 863      FopCmd=$FopCmd1
 864   fi
 865 fi
 866 if test -z "$FopCmd"; then
 867   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
 868   FopCmd=$FopCmd2
 869 fi
 870 AC_SUBST([FopCmd])
 871 ])# FP_PROG_FOP
 872
 873
 874 # FP_PROG_FO_PROCESSOR
 875 # --------------------
 876 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
 877 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
 878 # PdfxmltexCmd.
 879 AC_DEFUN([FP_PROG_FO_PROCESSOR],
 880 [AC_REQUIRE([FP_PROG_FOP])
 881 AC_PATH_PROG([XmltexCmd], [xmltex])
 882 AC_PATH_PROG([DvipsCmd], [dvips])
 883 if test -z "$FopCmd"; then
 884   if test -z "$XmltexCmd"; then
 885     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
 886   else
 887     if test -z "$DvipsCmd"; then
 888       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
 889     fi
 890   fi
 891   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
 892   if test -z "$PdfxmltexCmd"; then
 893     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
 894   fi
 895 elif test -z "$XmltexCmd"; then
 896   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
 897 fi
 898 ])# FP_PROG_FO_PROCESSOR
 899
 900
 901 # FP_PROG_GHC_PKG
 902 # ----------------
 903 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
 904 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
 905 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
 906 AC_DEFUN([FP_PROG_GHC_PKG],
 907 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
 908 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
 909 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
 910   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
 911 else
 912   fp_cv_matching_ghc_pkg=no
 913 fi])
 914 if test x"$fp_cv_matching_ghc_pkg" = xno; then
 915   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
 916 else
 917   GhcPkgCmd=$fp_cv_matching_ghc_pkg
 918 fi])# FP_PROG_GHC_PKG
 919
 920
 921 # FP_GHC_HAS_EDITLINE
 922 # -------------------
 923 AC_DEFUN([FP_GHC_HAS_EDITLINE],
 924 [AC_REQUIRE([FP_PROG_GHC_PKG])
 925 AC_CACHE_CHECK([whether ghc has editline package], [fp_cv_ghc_has_editline],
 926 [if "${GhcPkgCmd-ghc-pkg}" --show-package editline >/dev/null 2>&1; then
 927   fp_cv_ghc_has_editline=yes
 928 else
 929   fp_cv_ghc_has_editline=no
 930  fi])
 931 AC_SUBST([GhcHasEditline], [`echo $fp_cv_ghc_has_editline | sed 'y/yesno/YESNO/'`])
 932 ])# FP_GHC_HAS_EDITLINE
 933
 934
 935 # FP_GCC_EXTRA_FLAGS
 936 # ------------------
 937 # Determine which extra flags we need to pass gcc when we invoke it
 938 # to compile .hc code.
 939 #
 940 # Some OSs (Mandrake Linux, in particular) configure GCC with
 941 # -momit-leaf-frame-pointer on by default. If this is the case, we
 942 # need to turn it off for mangling to work. The test is currently a
 943 # bit crude, using only the version number of gcc.
 944 #
 945 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
 946 # integer wrap around. (Trac #952)
 947 #
 948 # -fno-unit-at-a-time or -fno-toplevel-reoder is necessary to avoid gcc
 949 # reordering things in the module and confusing the manger and/or splitter.
 950 # (eg. Trac #1427)
 951 #
 952 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
 953 [AC_REQUIRE([FP_HAVE_GCC])
 954 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
 955 [fp_cv_gcc_extra_opts=
 956  FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 957   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
 958   [])
 959  case $TargetPlatform in
 960   i386-*|x86_64-*)
 961      FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.2],
 962       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -mno-omit-leaf-frame-pointer"],
 963       [])
 964     FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [3.4],
 965      [FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [4.2],
 966        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 967        [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-unit-at-a-time"]
 968      )],
 969      [])
 970   ;;
 971   sparc-*-solaris2)
 972     FP_COMPARE_VERSIONS([$fp_gcc_version], [-ge], [4.2],
 973       [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-toplevel-reorder"],
 974       [])
 975   ;;
 976  esac
 977 ])
 978 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
 979 ])
 980
 981
 982 # FP_SETUP_PROJECT_VERSION
 983 # ---------------------
 984 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
 985 [
 986 if test "$RELEASE" = "NO"; then
 987     AC_MSG_CHECKING([for GHC version date])
 988     if test -f VERSION_DATE; then
 989         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
 990         AC_MSG_RESULT(given $PACKAGE_VERSION)
 991     elif test -d _darcs; then
 992         changequote(, )dnl
 993         ver_date=`darcs changes --quiet --no-summary --xml | head -500 | grep 'date=' | sed "s/^.*date='\([0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]\).*$/\1/g" | sort -n | tail -1`
 994         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
 995         changequote([, ])dnl
 996                 AC_MSG_ERROR([failed to detect version date: check that darcs is in your path])
 997         fi
 998         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
 999         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1000     elif test -f VERSION; then
1001         PACKAGE_VERSION=`cat VERSION`
1002         AC_MSG_RESULT(given $PACKAGE_VERSION)
1003     else
1004         AC_MSG_WARN([cannot determine snapshot version: no _darcs directory and no VERSION file])
1005     fi
1006 fi
1007
1008 # Some renamings
1009 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1010 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1011
1012 # Split PACKAGE_VERSION into (possibly empty) parts
1013 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1014 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1015 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1016 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1017
1018 # Calculate project version as an integer, using 2 digits for minor version
1019 case $VERSION_MINOR in
1020   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1021   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1022   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1023 esac
1024 AC_SUBST([ProjectVersionInt])
1025
1026 # The project patchlevel is zero unless stated otherwise
1027 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1028
1029 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1030 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1031
1032 AC_SUBST([ProjectPatchLevel])
1033 ])# FP_SETUP_PROJECT_VERSION
1034
1035
1036 # Check for a working timer_create().  We need a pretty detailed check
1037 # here, because there exist partially-working implementations of
1038 # timer_create() in certain versions of Linux (see bug #1933).
1039 #
1040 AC_DEFUN([FP_CHECK_TIMER_CREATE],
1041   [AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1042     [fptools_cv_timer_create_works],
1043     [AC_TRY_RUN([
1044 #include <stdio.h>
1045 #ifdef HAVE_STDLIB_H
1046 #include <stdlib.h>
1047 #endif
1048 #ifdef HAVE_TIME_H
1049 #include <time.h>
1050 #endif
1051 #ifdef HAVE_SIGNAL_H
1052 #include <signal.h>
1053 #endif
1054 #ifdef HAVE_UNISTD_H
1055 #include <unistd.h>
1056 #endif
1057
1058 static volatile int tock = 0;
1059 static void handler(int i)
1060 {
1061    tock = 1;
1062 }
1063
1064 static void timeout(int i)
1065 {
1066   // timer_settime() has been known to hang, so just in case
1067   // we install a 1-second timeout (see #2257)
1068   exit(99);
1069 }
1070
1071 int main(int argc, char *argv[])
1072 {
1073
1074     struct sigevent ev;
1075     timer_t timer;
1076     struct itimerspec it;
1077     struct sigaction action;
1078     int m,n,count = 0;
1079
1080     ev.sigev_notify = SIGEV_SIGNAL;
1081     ev.sigev_signo  = SIGVTALRM;
1082
1083     action.sa_handler = handler;
1084     action.sa_flags = 0;
1085     sigemptyset(&action.sa_mask);
1086     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1087         fprintf(stderr,"SIGVTALRM problem\n");
1088         exit(3);
1089     }
1090
1091     action.sa_handler = timeout;
1092     action.sa_flags = 0;
1093     sigemptyset(&action.sa_mask);
1094     if (sigaction(SIGALRM, &action, NULL) == -1) {
1095       fprintf(stderr,"SIGALRM problem\n");
1096       exit(3);
1097     }
1098     alarm(1);
1099
1100     if (timer_create(CLOCK_PROCESS_CPUTIME_ID, &ev, &timer) != 0) {
1101         fprintf(stderr,"No CLOCK_PROCESS_CPUTIME_ID timer\n");
1102        exit(1);
1103     }
1104
1105     it.it_value.tv_sec = 0;
1106     it.it_value.tv_nsec = 1;
1107     it.it_interval = it.it_value;
1108     if (timer_settime(timer, 0, &it, NULL) != 0) {
1109         fprintf(stderr,"settime problem\n");
1110         exit(4);
1111     }
1112
1113     tock = 0;
1114
1115     for(n = 3; n < 20000; n++){
1116         for(m = 2; m <= n/2; m++){
1117             if (!(n%m)) count++;
1118             if (tock) goto out;
1119         }
1120     }
1121 out:
1122
1123     if (!tock) {
1124         fprintf(stderr,"no CLOCK_PROCESS_CPUTIME_ID signal\n");
1125         exit(5);
1126     }
1127
1128     timer_delete(timer);
1129
1130     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1131         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1132         exit(2);
1133     }
1134
1135     it.it_value.tv_sec = 0;
1136     it.it_value.tv_nsec = 1000000;
1137     it.it_interval = it.it_value;
1138     if (timer_settime(timer, 0, &it, NULL) != 0) {
1139         fprintf(stderr,"settime problem\n");
1140         exit(4);
1141     }
1142
1143     tock = 0;
1144
1145     usleep(3000);
1146
1147     if (!tock) {
1148         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1149         exit(5);
1150     }
1151
1152     timer_delete(timer);
1153
1154     exit(0);
1155 }
1156      ],
1157      [fptools_cv_timer_create_works=yes],
1158      [fptools_cv_timer_create_works=no])
1159   ])
1160 case $fptools_cv_timer_create_works in
1161     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1162                    [Define to 1 if we can use timer_create(CLOCK_PROCESS_CPUTIME_ID,...)]);;
1163 esac
1164 ])
1165
1166 # FP_ARG_GMP
1167 # -------------
1168 AC_DEFUN([FP_ARG_GMP],
1169 [
1170 AC_ARG_WITH([gmp-includes],
1171   [AC_HELP_STRING([--with-gmp-includes],
1172     [directory containing gmp.h])],
1173     [gmp_includes=$withval],
1174     [gmp_includes=NONE])
1175
1176 AC_ARG_WITH([gmp-libraries],
1177   [AC_HELP_STRING([--with-gmp-libraries],
1178     [directory containing gmp library])],
1179     [gmp_libraries=$withval],
1180     [gmp_libraries=NONE])
1181 ])# FP_ARG_GMP
1182
1183 AC_DEFUN([CHECK_GMP],
1184 [AC_REQUIRE([AC_PROG_CPP])
1185 AC_REQUIRE([AC_PROG_CC])
1186 ])
1187
1188 # FP_CHECK_MACOSX_DEPLOYMENT_TARGET
1189 # ---------------------------------
1190 AC_DEFUN([FP_CHECK_MACOSX_DEPLOYMENT_TARGET],
1191 [
1192 if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple"; then
1193   AC_MSG_CHECKING([Mac OS X deployment target])
1194   case $FP_MACOSX_DEPLOYMENT_TARGET in
1195     none)  ;;
1196     10.4)  MACOSX_DEPLOYMENT_VERSION=10.4
1197            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1198            ;;
1199     10.4u) MACOSX_DEPLOYMENT_VERSION=10.4
1200            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX10.4u.sdk
1201            ;;
1202     *)     MACOSX_DEPLOYMENT_VERSION=$FP_MACOSX_DEPLOYMENT_TARGET
1203            MACOSX_DEPLOYMENT_SDK=/Developer/SDKs/MacOSX${FP_MACOSX_DEPLOYMENT_TARGET}.sdk
1204            ;;
1205   esac
1206   if test "x$FP_MACOSX_DEPLOYMENT_TARGET" = "xnone"; then
1207     AC_MSG_RESULT(none)
1208   else
1209     if test ! -d $MACOSX_DEPLOYMENT_SDK; then
1210       AC_MSG_ERROR([Unknown deployment target $FP_MACOSX_DEPLOYMENT_TARGET])
1211     fi
1212     AC_MSG_RESULT([${MACOSX_DEPLOYMENT_VERSION} (${MACOSX_DEPLOYMENT_SDK})])
1213   fi
1214 fi
1215 ])
1216
1217 # --------------------------------------------------------------
1218 # Calculate absolute path to build tree
1219 # --------------------------------------------------------------
1220
1221 AC_DEFUN([FP_FIND_ROOT],[
1222 AC_MSG_CHECKING(for path to top of build tree)
1223
1224 dnl This would be
1225 dnl     make -C utils/pwd clean && make -C utils/pwd
1226 dnl except we don't want to have to know what make is called. Sigh.
1227 if test ! -f utils/pwd/pwd && test ! -f utils/pwd/pwd.exe; then
1228   cd utils/pwd
1229   rm -f *.o
1230   rm -f *.hi
1231   rm -f pwd
1232   rm -f pwd.exe
1233   $WithGhc -v0 --make pwd -o pwd
1234   cd ../..
1235 fi
1236
1237 hardtop=`utils/pwd/pwd forwardslash`
1238
1239 if ! test -d "$hardtop"; then
1240   AC_MSG_ERROR([cannot determine current directory])
1241 fi
1242
1243 dnl Remove common automounter nonsense
1244 dnl
1245 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1246
1247 AC_SUBST(hardtop)
1248
1249 AC_MSG_RESULT(${hardtop})
1250
1251 # We don't support building in directories with spaces.
1252 case "$hardtop" in
1253   *' '*) AC_MSG_ERROR([
1254    The build system does not support building in a directory containing
1255    space characters.  Suggestion: move the build tree somewhere else.])
1256  ;;
1257 esac
1258 ])
1259
1260 # LocalWords:  fi