compiler/utils/Encoding.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 1997-2006
   4 --
   5 -- Character encodings
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module Encoding (
  10         -- * UTF-8
  11         utf8DecodeChar#,
  12         utf8PrevChar,
  13         utf8CharStart,
  14         utf8DecodeChar,
  15         utf8DecodeString,
  16         utf8EncodeChar,
  17         utf8EncodeString,
  18         utf8EncodedLength,
  19         countUTF8Chars,
  20
  21         -- * Z-encoding
  22         zEncodeString,
  23         zDecodeString
  24   ) where
  25
  26 #include "HsVersions.h"
  27 import Foreign
  28 import Data.Char        ( ord, chr, isDigit, digitToInt, intToDigit,
  29                           isHexDigit )
  30 import Numeric          ( showIntAtBase )
  31 import Data.Bits
  32 import GHC.Ptr          ( Ptr(..) )
  33 import GHC.Base
  34
  35 -- -----------------------------------------------------------------------------
  36 -- UTF-8
  37
  38 -- We can't write the decoder as efficiently as we'd like without
  39 -- resorting to unboxed extensions, unfortunately.  I tried to write
  40 -- an IO version of this function, but GHC can't eliminate boxed
  41 -- results from an IO-returning function.
  42 --
  43 -- We assume we can ignore overflow when parsing a multibyte character here.
  44 -- To make this safe, we add extra sentinel bytes to unparsed UTF-8 sequences
  45 -- before decoding them (see StringBuffer.hs).
  46
  47 {-# INLINE utf8DecodeChar# #-}
  48 utf8DecodeChar# :: Addr# -> (# Char#, Addr# #)
  49 utf8DecodeChar# a# =
  50   let ch0 = word2Int# (indexWord8OffAddr# a# 0#) in
  51   case () of
  52     _ | ch0 <=# 0x7F# -> (# chr# ch0, a# `plusAddr#` 1# #)
  53
  54       | ch0 >=# 0xC0# && ch0 <=# 0xDF# ->
  55         let ch1 = word2Int# (indexWord8OffAddr# a# 1#) in
  56         if ch1 <# 0x80# || ch1 >=# 0xC0# then fail 1# else
  57         (# chr# (((ch0 -# 0xC0#) `uncheckedIShiftL#` 6#) +#
  58                   (ch1 -# 0x80#)),
  59            a# `plusAddr#` 2# #)
  60
  61       | ch0 >=# 0xE0# && ch0 <=# 0xEF# ->
  62         let ch1 = word2Int# (indexWord8OffAddr# a# 1#) in
  63         if ch1 <# 0x80# || ch1 >=# 0xC0# then fail 1# else
  64         let ch2 = word2Int# (indexWord8OffAddr# a# 2#) in
  65         if ch2 <# 0x80# || ch2 >=# 0xC0# then fail 2# else
  66         (# chr# (((ch0 -# 0xE0#) `uncheckedIShiftL#` 12#) +#
  67                  ((ch1 -# 0x80#) `uncheckedIShiftL#` 6#)  +#
  68                   (ch2 -# 0x80#)),
  69            a# `plusAddr#` 3# #)
  70
  71      | ch0 >=# 0xF0# && ch0 <=# 0xF8# ->
  72         let ch1 = word2Int# (indexWord8OffAddr# a# 1#) in
  73         if ch1 <# 0x80# || ch1 >=# 0xC0# then fail 1# else
  74         let ch2 = word2Int# (indexWord8OffAddr# a# 2#) in
  75         if ch2 <# 0x80# || ch2 >=# 0xC0# then fail 2# else
  76         let ch3 = word2Int# (indexWord8OffAddr# a# 3#) in
  77         if ch3 <# 0x80# || ch3 >=# 0xC0# then fail 3# else
  78         (# chr# (((ch0 -# 0xF0#) `uncheckedIShiftL#` 18#) +#
  79                  ((ch1 -# 0x80#) `uncheckedIShiftL#` 12#) +#
  80                  ((ch2 -# 0x80#) `uncheckedIShiftL#` 6#)  +#
  81                   (ch3 -# 0x80#)),
  82            a# `plusAddr#` 4# #)
  83
  84       | otherwise -> fail 1#
  85   where
  86         -- all invalid sequences end up here:
  87         fail n = (# '\0'#, a# `plusAddr#` n #)
  88         -- '\xFFFD' would be the usual replacement character, but
  89         -- that's a valid symbol in Haskell, so will result in a
  90         -- confusing parse error later on.  Instead we use '\0' which
  91         -- will signal a lexer error immediately.
  92
  93 utf8DecodeChar :: Ptr Word8 -> (Char, Ptr Word8)
  94 utf8DecodeChar (Ptr a#) =
  95   case utf8DecodeChar# a# of (# c#, b# #) -> ( C# c#, Ptr b# )
  96
  97 -- UTF-8 is cleverly designed so that we can always figure out where
  98 -- the start of the current character is, given any position in a
  99 -- stream.  This function finds the start of the previous character,
 100 -- assuming there *is* a previous character.
 101 utf8PrevChar :: Ptr Word8 -> IO (Ptr Word8)
 102 utf8PrevChar p = utf8CharStart (p `plusPtr` (-1))
 103
 104 utf8CharStart :: Ptr Word8 -> IO (Ptr Word8)
 105 utf8CharStart p = go p
 106  where go p = do w <- peek p
 107                  if w >= 0x80 && w < 0xC0
 108                         then go (p `plusPtr` (-1))
 109                         else return p
 110
 111 utf8DecodeString :: Ptr Word8 -> Int -> IO [Char]
 112 STRICT2(utf8DecodeString)
 113 utf8DecodeString (Ptr a#) (I# len#)
 114   = unpack a#
 115   where
 116     end# = addr2Int# (a# `plusAddr#` len#)
 117
 118     unpack p#
 119         | addr2Int# p# >=# end# = return []
 120         | otherwise  =
 121         case utf8DecodeChar# p# of
 122            (# c#, q# #) -> do
 123                 chs <- unpack q#
 124                 return (C# c# : chs)
 125
 126 countUTF8Chars :: Ptr Word8 -> Int -> IO Int
 127 countUTF8Chars ptr bytes = go ptr 0
 128   where
 129         end = ptr `plusPtr` bytes
 130
 131         STRICT2(go)
 132         go ptr n
 133            | ptr >= end = return n
 134            | otherwise  = do
 135                 case utf8DecodeChar# (unPtr ptr) of
 136                   (# _, a #) -> go (Ptr a) (n+1)
 137
 138 unPtr :: Ptr a -> Addr#
 139 unPtr (Ptr a) = a
 140
 141 utf8EncodeChar :: Char -> Ptr Word8 -> IO (Ptr Word8)
 142 utf8EncodeChar c ptr =
 143   let x = ord c in
 144   case () of
 145     _ | x > 0 && x <= 0x007f -> do
 146           poke ptr (fromIntegral x)
 147           return (ptr `plusPtr` 1)
 148         -- NB. '\0' is encoded as '\xC0\x80', not '\0'.  This is so that we
 149         -- can have 0-terminated UTF-8 strings (see GHC.Base.unpackCStringUtf8).
 150       | x <= 0x07ff -> do
 151           poke ptr (fromIntegral (0xC0 .|. ((x `shiftR` 6) .&. 0x1F)))
 152           pokeElemOff ptr 1 (fromIntegral (0x80 .|. (x .&. 0x3F)))
 153           return (ptr `plusPtr` 2)
 154       | x <= 0xffff -> do
 155           poke ptr (fromIntegral (0xE0 .|. (x `shiftR` 12) .&. 0x0F))
 156           pokeElemOff ptr 1 (fromIntegral (0x80 .|. (x `shiftR` 6) .&. 0x3F))
 157           pokeElemOff ptr 2 (fromIntegral (0x80 .|. (x .&. 0x3F)))
 158           return (ptr `plusPtr` 3)
 159       | otherwise -> do
 160           poke ptr (fromIntegral (0xF0 .|. (x `shiftR` 18)))
 161           pokeElemOff ptr 1 (fromIntegral (0x80 .|. ((x `shiftR` 12) .&. 0x3F)))
 162           pokeElemOff ptr 2 (fromIntegral (0x80 .|. ((x `shiftR` 6) .&. 0x3F)))
 163           pokeElemOff ptr 3 (fromIntegral (0x80 .|. (x .&. 0x3F)))
 164           return (ptr `plusPtr` 4)
 165
 166 utf8EncodeString :: Ptr Word8 -> String -> IO ()
 167 utf8EncodeString ptr str = go ptr str
 168   where STRICT2(go)
 169         go _   []     = return ()
 170         go ptr (c:cs) = do
 171           ptr' <- utf8EncodeChar c ptr
 172           go ptr' cs
 173
 174 utf8EncodedLength :: String -> Int
 175 utf8EncodedLength str = go 0 str
 176   where STRICT2(go)
 177         go n [] = n
 178         go n (c:cs)
 179           | ord c > 0 && ord c <= 0x007f = go (n+1) cs
 180           | ord c <= 0x07ff = go (n+2) cs
 181           | ord c <= 0xffff = go (n+3) cs
 182           | otherwise       = go (n+4) cs
 183
 184 -- -----------------------------------------------------------------------------
 185 -- The Z-encoding
 186
 187 {-
 188 This is the main name-encoding and decoding function.  It encodes any
 189 string into a string that is acceptable as a C name.  This is done
 190 right before we emit a symbol name into the compiled C or asm code.
 191 Z-encoding of strings is cached in the FastString interface, so we
 192 never encode the same string more than once.
 193
 194 The basic encoding scheme is this.
 195
 196 * Tuples (,,,) are coded as Z3T
 197
 198 * Alphabetic characters (upper and lower) and digits
 199         all translate to themselves;
 200         except 'Z', which translates to 'ZZ'
 201         and    'z', which translates to 'zz'
 202   We need both so that we can preserve the variable/tycon distinction
 203
 204 * Most other printable characters translate to 'zx' or 'Zx' for some
 205         alphabetic character x
 206
 207 * The others translate as 'znnnU' where 'nnn' is the decimal number
 208         of the character
 209
 210         Before          After
 211         --------------------------
 212         Trak            Trak
 213         foo_wib         foozuwib
 214         >               zg
 215         >1              zg1
 216         foo#            foozh
 217         foo##           foozhzh
 218         foo##1          foozhzh1
 219         fooZ            fooZZ
 220         :+              ZCzp
 221         ()              Z0T     0-tuple
 222         (,,,,)          Z5T     5-tuple
 223         (# #)           Z1H     unboxed 1-tuple (note the space)
 224         (#,,,,#)        Z5H     unboxed 5-tuple
 225                 (NB: There is no Z1T nor Z0H.)
 226 -}
 227
 228 type UserString = String        -- As the user typed it
 229 type EncodedString = String     -- Encoded form
 230
 231
 232 zEncodeString :: UserString -> EncodedString
 233 zEncodeString cs = case maybe_tuple cs of
 234                 Just n  -> n            -- Tuples go to Z2T etc
 235                 Nothing -> go cs
 236           where
 237                 go []     = []
 238                 go (c:cs) = encode_ch c ++ go cs
 239
 240 unencodedChar :: Char -> Bool   -- True for chars that don't need encoding
 241 unencodedChar 'Z' = False
 242 unencodedChar 'z' = False
 243 unencodedChar c   =  c >= 'a' && c <= 'z'
 244                   || c >= 'A' && c <= 'Z'
 245                   || c >= '0' && c <= '9'
 246
 247 encode_ch :: Char -> EncodedString
 248 encode_ch c | unencodedChar c = [c]     -- Common case first
 249
 250 -- Constructors
 251 encode_ch '('  = "ZL"   -- Needed for things like (,), and (->)
 252 encode_ch ')'  = "ZR"   -- For symmetry with (
 253 encode_ch '['  = "ZM"
 254 encode_ch ']'  = "ZN"
 255 encode_ch ':'  = "ZC"
 256 encode_ch 'Z'  = "ZZ"
 257
 258 -- Variables
 259 encode_ch 'z'  = "zz"
 260 encode_ch '&'  = "za"
 261 encode_ch '|'  = "zb"
 262 encode_ch '^'  = "zc"
 263 encode_ch '$'  = "zd"
 264 encode_ch '='  = "ze"
 265 encode_ch '>'  = "zg"
 266 encode_ch '#'  = "zh"
 267 encode_ch '.'  = "zi"
 268 encode_ch '<'  = "zl"
 269 encode_ch '-'  = "zm"
 270 encode_ch '!'  = "zn"
 271 encode_ch '+'  = "zp"
 272 encode_ch '\'' = "zq"
 273 encode_ch '\\' = "zr"
 274 encode_ch '/'  = "zs"
 275 encode_ch '*'  = "zt"
 276 encode_ch '_'  = "zu"
 277 encode_ch '%'  = "zv"
 278 encode_ch c    = 'z' : if isDigit (head hex_str) then hex_str
 279                                                  else '0':hex_str
 280   where hex_str = showHex (ord c) "U"
 281   -- ToDo: we could improve the encoding here in various ways.
 282   -- eg. strings of unicode characters come out as 'z1234Uz5678U', we
 283   -- could remove the 'U' in the middle (the 'z' works as a separator).
 284
 285         showHex = showIntAtBase 16 intToDigit
 286         -- needed because prior to GHC 6.2, Numeric.showHex added a "0x" prefix
 287
 288 zDecodeString :: EncodedString -> UserString
 289 zDecodeString [] = []
 290 zDecodeString ('Z' : d : rest)
 291   | isDigit d = decode_tuple   d rest
 292   | otherwise = decode_upper   d : zDecodeString rest
 293 zDecodeString ('z' : d : rest)
 294   | isDigit d = decode_num_esc d rest
 295   | otherwise = decode_lower   d : zDecodeString rest
 296 zDecodeString (c   : rest) = c : zDecodeString rest
 297
 298 decode_upper, decode_lower :: Char -> Char
 299
 300 decode_upper 'L' = '('
 301 decode_upper 'R' = ')'
 302 decode_upper 'M' = '['
 303 decode_upper 'N' = ']'
 304 decode_upper 'C' = ':'
 305 decode_upper 'Z' = 'Z'
 306 decode_upper ch  = {-pprTrace "decode_upper" (char ch)-} ch
 307
 308 decode_lower 'z' = 'z'
 309 decode_lower 'a' = '&'
 310 decode_lower 'b' = '|'
 311 decode_lower 'c' = '^'
 312 decode_lower 'd' = '$'
 313 decode_lower 'e' = '='
 314 decode_lower 'g' = '>'
 315 decode_lower 'h' = '#'
 316 decode_lower 'i' = '.'
 317 decode_lower 'l' = '<'
 318 decode_lower 'm' = '-'
 319 decode_lower 'n' = '!'
 320 decode_lower 'p' = '+'
 321 decode_lower 'q' = '\''
 322 decode_lower 'r' = '\\'
 323 decode_lower 's' = '/'
 324 decode_lower 't' = '*'
 325 decode_lower 'u' = '_'
 326 decode_lower 'v' = '%'
 327 decode_lower ch  = {-pprTrace "decode_lower" (char ch)-} ch
 328
 329 -- Characters not having a specific code are coded as z224U (in hex)
 330 decode_num_esc :: Char -> EncodedString -> UserString
 331 decode_num_esc d rest
 332   = go (digitToInt d) rest
 333   where
 334     go n (c : rest) | isHexDigit c = go (16*n + digitToInt c) rest
 335     go n ('U' : rest)           = chr n : zDecodeString rest
 336     go n other = error ("decode_num_esc: " ++ show n ++  ' ':other)
 337
 338 decode_tuple :: Char -> EncodedString -> UserString
 339 decode_tuple d rest
 340   = go (digitToInt d) rest
 341   where
 342         -- NB. recurse back to zDecodeString after decoding the tuple, because
 343         -- the tuple might be embedded in a longer name.
 344     go n (c : rest) | isDigit c = go (10*n + digitToInt c) rest
 345     go 0 ('T':rest)     = "()" ++ zDecodeString rest
 346     go n ('T':rest)     = '(' : replicate (n-1) ',' ++ ")" ++ zDecodeString rest
 347     go 1 ('H':rest)     = "(# #)" ++ zDecodeString rest
 348     go n ('H':rest)     = '(' : '#' : replicate (n-1) ',' ++ "#)" ++ zDecodeString rest
 349     go n other = error ("decode_tuple: " ++ show n ++ ' ':other)
 350
 351 {-
 352 Tuples are encoded as
 353         Z3T or Z3H
 354 for 3-tuples or unboxed 3-tuples respectively.  No other encoding starts
 355         Z<digit>
 356
 357 * "(# #)" is the tycon for an unboxed 1-tuple (not 0-tuple)
 358   There are no unboxed 0-tuples.
 359
 360 * "()" is the tycon for a boxed 0-tuple.
 361   There are no boxed 1-tuples.
 362 -}
 363
 364 maybe_tuple :: UserString -> Maybe EncodedString
 365
 366 maybe_tuple "(# #)" = Just("Z1H")
 367 maybe_tuple ('(' : '#' : cs) = case count_commas (0::Int) cs of
 368                                  (n, '#' : ')' : _) -> Just ('Z' : shows (n+1) "H")
 369                                  _                  -> Nothing
 370 maybe_tuple "()" = Just("Z0T")
 371 maybe_tuple ('(' : cs)       = case count_commas (0::Int) cs of
 372                                  (n, ')' : _) -> Just ('Z' : shows (n+1) "T")
 373                                  _            -> Nothing
 374 maybe_tuple _                = Nothing
 375
 376 count_commas :: Int -> String -> (Int, String)
 377 count_commas n (',' : cs) = count_commas (n+1) cs
 378 count_commas n cs         = (n,cs)