configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha-dec-osf[[34]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         # We assume you're using mingw32 via the gcc that comes
 206         # with cygwin, and not the native port, so let's augment
 207         # the gcc command-line used here with -mno-cygwin -mwin32
 208         # to arrange for good things to happen.
 209         CFLAGS="-mno-cygwin -mwin32 $CFLAGS"
 210         ;;
 211 m68k-next-nextstep2)
 212         HostPlatform_CPP='m68k_next_nextstep2'
 213         HostArch_CPP='m68k'
 214         HostVendor_CPP='next'
 215         HostOS_CPP='nextstep2'
 216         ;;
 217 m68k-next-nextstep3)
 218         HostPlatform_CPP='m68k_next_nextstep3'
 219         HostArch_CPP='m68k'
 220         HostVendor_CPP='next'
 221         HostOS_CPP='nextstep3'
 222         ;;
 223 i[[3456]]86-next-nextstep3)
 224         HostPlatform=i386-next-nextstep3 # hack again
 225         TargetPlatform=i386-next-nextstep3
 226         BuildPlatform=i386-next-nextstep3
 227         HostPlatform_CPP='i386_next_nextstep3'
 228         HostArch_CPP='i386'
 229         HostVendor_CPP='next'
 230         HostOS_CPP='nextstep3'
 231         ;;
 232 m68k-sun-sunos4*)
 233         HostPlatform=m68k-sun-sunos4
 234         TargetPlatform=m68k-sun-sunos4 #hack
 235         BuildPlatform=m68k-sun-sunos4 #hack
 236         HostPlatform_CPP='m68k_sun_sunos4'
 237         HostArch_CPP='m68k'
 238         HostVendor_CPP='sun'
 239         HostOS_CPP='sunos4'
 240         ;;
 241 mips-dec-ultrix*)
 242         HostPlatform_CPP='mips_dec_ultrix'
 243         HostArch_CPP='mipsel'   # NB a little different
 244         HostVendor_CPP='dec'
 245         HostOS_CPP='ultrix'
 246         ;;
 247 mips-sgi-irix*)
 248         HostPlatform=mips-sgi-irix
 249         TargetPlatform=mips-sgi-irix #hack
 250         BuildPlatform=mips-sgi-irix #hack
 251         HostPlatform_CPP='mips_sgi_irix'
 252         HostArch_CPP='mipseb'   # NB a little different
 253         HostVendor_CPP='sgi'
 254         HostOS_CPP='irix'
 255         ;;
 256 rs6000-ibm-aix*)
 257         HostPlatform=rs6000-ibm-aix
 258         TargetPlatform=rs6000-ibm-aix #hack
 259         BuildPlatform=rs6000-ibm-aix #hack
 260         HostPlatform_CPP='rs6000_ibm_aix'
 261         HostArch_CPP='rs6000'
 262         HostVendor_CPP='ibm'
 263         HostOS_CPP='aix'
 264         ;;
 265 powerpc-ibm-aix*)
 266         HostPlatform=powerpc-ibm-aix
 267         TargetPlatform=powerpc-ibm-aix #hack
 268         BuildPlatform=powerpc-ibm-aix #hack
 269         HostPlatform_CPP='powerpc_ibm_aix'
 270         HostArch_CPP='powerpc'
 271         HostVendor_CPP='ibm'
 272         HostOS_CPP='aix'
 273         ;;
 274 powerpc-apple-macosx*)
 275       HostPlatform=powerpc-apple-macosx
 276       TargetPlatform=powerpc-apple-macosx #hack
 277       BuildPlatform=powerpc-apple-macosx #hack
 278         HostPlatform_CPP='powerpc_apple_macosx'
 279         HostArch_CPP='powerpc'
 280         HostVendor_CPP='apple'
 281         HostOS_CPP='macosx'
 282         ;;
 283 sparc-sun-sunos4*)
 284         HostPlatform=sparc-sun-sunos4
 285         TargetPlatform=sparc-sun-sunos4 #hack
 286         BuildPlatform=sparc-sun-sunos4 #hack
 287         HostPlatform_CPP='sparc_sun_sunos4'
 288         HostArch_CPP='sparc'
 289         HostVendor_CPP='sun'
 290         HostOS_CPP='sunos4'
 291         ;;
 292 sparc-sun-solaris2*)
 293         HostPlatform=sparc-sun-solaris2
 294         TargetPlatform=sparc-sun-solaris2 #hack
 295         BuildPlatform=sparc-sun-solaris2 #hack
 296         HostPlatform_CPP='sparc_sun_solaris2'
 297         HostArch_CPP='sparc'
 298         HostVendor_CPP='sun'
 299         HostOS_CPP='solaris2'
 300         ;;
 301 *)
 302         echo "Unrecognised platform: $HostPlatform"
 303         exit 1
 304         ;;
 305 esac
 306 echo "Canonicalised to: $HostPlatform"
 307 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 308 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 309
 310 BuildPlatform_CPP=$HostPlatform_CPP
 311 TargetPlatform_CPP=$HostPlatform_CPP
 312 BuildArch_CPP=$HostArch_CPP
 313 TargetArch_CPP=$HostArch_CPP
 314 BuildOS_CPP=$HostOS_CPP
 315 HostOS_Full=$host_os
 316 TargetOS_CPP=$HostOS_CPP
 317 BuildVendor_CPP=$HostVendor_CPP
 318 TargetVendor_CPP=$HostVendor_CPP
 319
 320 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 321 dnl AC_SUBST(BuildPlatform)
 322
 323 AC_SUBST(HostPlatform)
 324 AC_SUBST(TargetPlatform)
 325 AC_SUBST(HostPlatform_CPP)
 326 dnl AC_SUBST(BuildPlatform_CPP)
 327 dnl AC_SUBST(TargetPlatform_CPP)
 328
 329 AC_SUBST(HostArch_CPP)
 330 dnl AC_SUBST(BuildArch_CPP)
 331 dnl AC_SUBST(TargetArch_CPP)
 332
 333 AC_SUBST(HostOS_CPP)
 334 AC_SUBST(HostOS_Full)
 335 dnl AC_SUBST(BuildOS_CPP)
 336 dnl AC_SUBST(TargetOS_CPP)
 337
 338 AC_SUBST(HostVendor_CPP)
 339 dnl AC_SUBST(BuildVendor_CPP)
 340 dnl AC_SUBST(TargetVendor_CPP)
 341
 342 AC_SUBST(exeext)
 343
 344 dnl --------------------------------------------------------------
 345 dnl * Project specific configuration options
 346 dnl --------------------------------------------------------------
 347 dnl What follows is a bunch of options that can either be configured
 348 dnl through command line options to the configure script or by
 349 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 350 dnl use either is considered a Feature.
 351
 352 dnl ** What command to use to compile compiler sources ?
 353 dnl --------------------------------------------------------------
 354 if test "$GHC" = ""; then
 355   AC_PATH_PROG(GHC,ghc)
 356 fi
 357
 358 AC_ARG_WITH(ghc,
 359 [  --with-ghc=<haskell compiler>
 360         Use a command different from 'ghc' to compile GHC-specific Haskell code
 361             (including GHC itself).
 362 ],
 363 [WithGhc="$withval"],
 364 [WithGhc=$GHC]
 365 )
 366 AC_SUBST(WithGhc)
 367
 368 AC_ARG_WITH(hc,
 369 [  --with-hc=<haskell compiler>
 370         Use a command different from 'ghc' to compile generic Haskell code.
 371 ],
 372 [WithHc="$withval"],
 373 [WithHc=$WithGhc]
 374 )
 375 AC_SUBST(WithHc)
 376
 377 if test "$WithGhc" != ""; then
 378   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 379   AC_SUBST(GhcVersion)dnl
 380   AC_SUBST(GhcMajVersion)dnl
 381   AC_SUBST(GhcMinVersion)dnl
 382   AC_SUBST(GhcPatchLevel)dnl
 383 fi
 384
 385 AC_PATH_PROGS(NHC,nhc nhc98)
 386 AC_PATH_PROG(HBC,hbc)
 387
 388 dnl ** Which gcc to use?
 389 dnl --------------------------------------------------------------
 390 AC_ARG_WITH(gcc,
 391 [  --with-gcc=<gcc command>
 392         Use a different command instead of 'gcc' for the GNU C compiler.
 393 ],
 394 [WhatGccIsCalled="$withval"],
 395 [WhatGccIsCalled="gcc"]
 396 )
 397 AC_SUBST(WhatGccIsCalled)
 398
 399 dnl ** Booting from .hc files?
 400 dnl --------------------------------------------------------------
 401 AC_ARG_ENABLE(hc-boot,
 402 [  --enable-hc-boot
 403         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 404         (This option is mostly of interest to porters.)
 405 ],
 406 [BootingFromHc=YES],
 407 [BootingFromHc=NO]
 408 )
 409 AC_SUBST(BootingFromHc)
 410
 411
 412 dnl ** Enable the construction of Win32 DLLs?
 413 dnl --------------------------------------------------------------
 414 AC_ARG_ENABLE(win32-dlls,
 415 [  --enable-win32-dlls
 416         If on a Win32 platform running mingw32/cygwin, enable the
 417         construction of DLLs containing ghc-compiled code.
 418 ],
 419 [
 420 case $HostOS_CPP in
 421 cygwin32) ;;
 422 mingw32)  ;;
 423 *)    echo "Unrecognised win32 platform: $HostPlatform"
 424       exit 1
 425       ;;
 426 esac
 427 EnableWin32DLLs=YES
 428 ],
 429 [EnableWin32DLLs=NO]
 430 )
 431 AC_SUBST(EnableWin32DLLs)
 432 if test x"$EnableWin32DLLs" = "xYES" ; then
 433  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 434 fi
 435
 436 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 437 dnl --------------------------------------------------------------
 438 AC_ARG_ENABLE(hopengl,
 439 [  --enable-hopengl
 440         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 441         (This option is only relevant when hslibs are built.)
 442 ],
 443 [GhcLibsWithHOpenGL=YES],
 444 [GhcLibsWithHOpenGL=NO]
 445 )
 446 AC_SUBST(GhcLibsWithHOpenGL)
 447
 448 dnl ** Use a specific version of the GLUT API
 449 dnl --------------------------------------------------------------
 450 AC_ARG_WITH(glut-api,
 451 [  --with-glut-api=<version>
 452         Use a specific version of the GLUT API when building HOpenGL.
 453 ])
 454 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 455
 456
 457 dnl ** Use a specific version of the GLUT API
 458 dnl --------------------------------------------------------------
 459 AC_ARG_WITH(glut-xlib,
 460 [  --with-glut-xlib=<version>
 461         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 462 ])
 463 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 464
 465
 466 dnl --------------------------------------------------------------
 467 dnl End of configure script option section
 468 dnl --------------------------------------------------------------
 469
 470
 471 dnl --------------------------------------------------------------
 472 dnl * General configuration checks
 473 dnl --------------------------------------------------------------
 474
 475 dnl ** does #! work?
 476 AC_SYS_INTERPRETER()
 477
 478 dnl ** look for `perl', but only in /bin on Windows
 479 case $HostOS_CPP in
 480 cygwin32|mingw32)
 481    AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 482    if test -z "$PerlCmd"; then
 483       echo "You must install the version of Perl shipped with GHC"
 484       echo "(or a compatible one) in /bin."
 485       exit 1
 486    fi
 487    ;;
 488 *)
 489    AC_PATH_PROG(PerlCmd,perl)
 490    if test -z "$PerlCmd"; then
 491       echo "You must install perl before you can continue"
 492       echo "Perhaps it is already installed, but not in your PATH?"
 493       exit 1
 494    else
 495    FPTOOLS_CHECK_PERL_VERSION
 496    fi
 497    ;;
 498 esac
 499
 500 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 501 FPTOOLS_SHEBANG_PERL
 502
 503
 504 dnl ** look for GCC and find out which version
 505 dnl     Figure out which C compiler to use.  Gcc is preferred.
 506 dnl     If gcc, make sure it's at least 2.1
 507 dnl
 508 AC_PROG_CC
 509 FPTOOLS_HAVE_GCC
 510
 511 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 512 AC_PROG_CPP
 513 case $HostOS_CPP in
 514 mingw32)
 515    CPP="$CPP -mno-cygwin -mwin32"
 516    ;;
 517 esac
 518
 519 dnl ** figure out how to do context diffs
 520 FPTOOLS_PROG_DIFF
 521
 522 dnl ** Find find command (for Win32's benefit)
 523 AC_PATH_PROG(FindCmd, find)
 524
 525 dnl ** look for a decent parser generator (bison preferred)
 526 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 527 dnl  on the suitability of the 'yacc' returned.)
 528 FPTOOLS_PROG_YACCY
 529
 530 dnl ** Find lex command (lex or flex) and library (-ll or -lfl)
 531 dnl     ( not that we care about the latter, see mk/config.mk.in )
 532 AC_PROG_LEX
 533
 534
 535 dnl ** figure out how to do a BSD-ish install
 536 AC_PROG_INSTALL
 537
 538 dnl If you can run configure, you certainly have /bin/sh
 539 AC_DEFINE(HAVE_BIN_SH)
 540
 541 dnl ** how to invoke `ar' and `ranlib'
 542 FPTOOLS_PROG_AR_AND_RANLIB
 543
 544
 545 dnl ** Check to see whether ln -s works
 546 AC_PROG_LN_S
 547
 548
 549 dnl ** Find the path to sed
 550 AC_PATH_PROG(SedCmd,sed)
 551
 552
 553 dnl ** check for time command
 554 AC_PATH_PROG(TimeCmd,time)
 555
 556
 557 dnl ** check for tar
 558 dnl   if GNU tar is named gtar, look for it first.
 559 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 560
 561 dnl ** check for gzip/compress
 562 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 563
 564 dnl ** check for jade/openjade & determine a working catalog
 565 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 566 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 567                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl $hardtop/glafp-utils/docbook/CATALOG*)
 568 if test -z "$Catalog"; then
 569   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 570 fi
 571 AC_SUBST(Catalog)
 572
 573 compress_nm=`basename $CompressCmd`
 574 if test x"$compress_nm" = xgzip; then
 575   CompressCmd="$CompressCmd -d"
 576   CompressSuffix="gz"
 577 else
 578   CompressSuffix="Z"
 579 fi
 580 AC_SUBST(CompressCmd)
 581 AC_SUBST(CompressSuffix)
 582
 583 dnl ** check for installed happy binary + version
 584 dnl    (don't do it if we're booting from .hc files though.)
 585 if test "$BootingFromHc" = "NO"; then
 586 FPTOOLS_HAPPY
 587 fi;
 588
 589 dnl --------------------------------------------------
 590 dnl ### program checking section ends here ###
 591 dnl --------------------------------------------------
 592
 593 dnl --------------------------------------------------
 594 dnl * Platform header file and syscall feature tests
 595 dnl ### checking the state of the local header files and syscalls ###
 596
 597 dnl ** check for full ANSI header (.h) files
 598 AC_HEADER_STDC
 599
 600 dnl ** check for specific header (.h) files that we are interested in
 601 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 602
 603 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 604 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 605
 606 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 607   HaveReadlineHeaders=YES
 608   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 609 else
 610   HaveReadlineHeaders=NO
 611   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 612 fi
 613 AC_SUBST(HaveReadlineHeaders)
 614
 615 dnl ** check for DOS include files
 616 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 617
 618 dnl ** check for Windows include files
 619 AC_CHECK_HEADERS(windows.h)
 620
 621 dnl ** check for OpenGL include files
 622 AC_CHECK_HEADERS(GL/gl.h)
 623
 624 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 625 AC_HEADER_TIME
 626
 627 dnl dynamic loading include files
 628 AC_CHECK_HEADERS(dlfcn.h dl.h)
 629
 630 dnl ** check for farcalloc (in bcc)
 631 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 632
 633 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 634 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 635
 636 dnl ** how do we get a timezone name, and UTC offset ?
 637 AC_STRUCT_TIMEZONE
 638
 639 dnl ** what's the type of timezone?
 640 FPTOOLS_HAVE_TIMEZONE
 641 FPTOOLS_TYPE_TIMEZONE
 642
 643 dnl ** do we have altzone?
 644 FPTOOLS_ALTZONE
 645
 646 dnl ** does struct stat contain st_blksize?
 647 AC_STRUCT_ST_BLKSIZE
 648
 649 dnl ** do we have long longs?
 650 FPTOOLS_C_LONG_LONG
 651
 652 dnl ** what are the sizes of various types
 653 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 654 AC_CHECK_SIZEOF(char,               1)
 655 AC_CHECK_SIZEOF(double,             8)
 656 AC_CHECK_SIZEOF(float,              4)
 657 AC_CHECK_SIZEOF(int,                4)
 658 AC_CHECK_SIZEOF(long,               4)
 659 if test "$fptools_cv_have_long_long" = yes; then
 660 AC_CHECK_SIZEOF(long long,          8)
 661 fi
 662 AC_CHECK_SIZEOF(short,              2)
 663 AC_CHECK_SIZEOF(unsigned char,      1)
 664 AC_CHECK_SIZEOF(unsigned int,       4)
 665 AC_CHECK_SIZEOF(unsigned long,      4)
 666 if test "$fptools_cv_have_long_long" = yes; then
 667 AC_CHECK_SIZEOF(unsigned long long, 8)
 668 fi
 669 AC_CHECK_SIZEOF(unsigned short,     2)
 670 AC_CHECK_SIZEOF(void *,             4)
 671
 672 dnl ** what are alignment constraints on various types
 673 FPTOOLS_CHECK_ALIGNMENT(char)
 674 FPTOOLS_CHECK_ALIGNMENT(double)
 675 FPTOOLS_CHECK_ALIGNMENT(float)
 676 FPTOOLS_CHECK_ALIGNMENT(int)
 677 FPTOOLS_CHECK_ALIGNMENT(long)
 678 if test "$fptools_cv_have_long_long" = yes; then
 679 FPTOOLS_CHECK_ALIGNMENT(long long)
 680 fi
 681 FPTOOLS_CHECK_ALIGNMENT(short)
 682 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 683 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 684 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 685 if test "$fptools_cv_have_long_long" = yes; then
 686 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 687 fi
 688 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 689 FPTOOLS_CHECK_ALIGNMENT(void *)
 690
 691 dnl ** map standard C types and ISO types to Haskell types
 692 FPTOOLS_CHECK_HTYPE(char)
 693 FPTOOLS_CHECK_HTYPE(signed char)
 694 FPTOOLS_CHECK_HTYPE(unsigned char)
 695 FPTOOLS_CHECK_HTYPE(short)
 696 FPTOOLS_CHECK_HTYPE(unsigned short)
 697 FPTOOLS_CHECK_HTYPE(int)
 698 FPTOOLS_CHECK_HTYPE(unsigned int)
 699 FPTOOLS_CHECK_HTYPE(long)
 700 FPTOOLS_CHECK_HTYPE(unsigned long)
 701 if test "$fptools_cv_have_long_long" = yes; then
 702 FPTOOLS_CHECK_HTYPE(long long)
 703 FPTOOLS_CHECK_HTYPE(unsigned long long)
 704 fi
 705 FPTOOLS_CHECK_HTYPE(float)
 706 FPTOOLS_CHECK_HTYPE(double)
 707 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 708 FPTOOLS_CHECK_HTYPE(size_t)
 709 FPTOOLS_CHECK_HTYPE(wchar_t)
 710 dnl Int32 is a HACK for non-ISO C compilers
 711 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 712 FPTOOLS_CHECK_HTYPE(clock_t)
 713 FPTOOLS_CHECK_HTYPE(time_t)
 714
 715 dnl ** Map OpenGL data types to Haskell types
 716 if test $GhcLibsWithHOpenGL = YES ; then
 717 FPTOOLS_CHECK_HTYPE(GLboolean)
 718 FPTOOLS_CHECK_HTYPE(GLbyte)
 719 FPTOOLS_CHECK_HTYPE(GLubyte)
 720 FPTOOLS_CHECK_HTYPE(GLshort)
 721 FPTOOLS_CHECK_HTYPE(GLushort)
 722 FPTOOLS_CHECK_HTYPE(GLint)
 723 FPTOOLS_CHECK_HTYPE(GLuint)
 724 FPTOOLS_CHECK_HTYPE(GLsizei)
 725 FPTOOLS_CHECK_HTYPE(GLenum)
 726 FPTOOLS_CHECK_HTYPE(GLbitfield)
 727 FPTOOLS_CHECK_HTYPE(GLfloat)
 728 FPTOOLS_CHECK_HTYPE(GLclampf)
 729 FPTOOLS_CHECK_HTYPE(GLdouble)
 730 FPTOOLS_CHECK_HTYPE(GLclampd)
 731 fi
 732
 733 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 734
 735 dnl ** can we open files in binary mode?
 736 FPTOOLS_O_BINARY
 737
 738 dnl ** check for GetModuleFileName and WinExec (windows only)
 739 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 740 dnl Doesn't work because the linker can't see the functions if
 741 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 742
 743 FPTOOLS_TRY_LINK_NOWARN(,[
 744 #if HAVE_WINDOWS_H
 745 #include <windows.h>
 746 #endif
 747 main() {
 748   WinExec("",0);
 749   exit(0);
 750 }
 751 ],
 752 [have_winexec=1],
 753 [have_winexec=0])
 754 if test "$have_winexec" = "1"; then
 755 AC_DEFINE(HAVE_WINEXEC)
 756 fi
 757
 758 FPTOOLS_TRY_LINK_NOWARN(,[
 759 #if HAVE_WINDOWS_H
 760 #include <windows.h>
 761 #endif
 762 main() {
 763   char* dir;
 764   GetModuleFileName((HMODULE)0,dir,0);
 765   exit(0);
 766 }
 767 ],
 768 [have_getmodulefilename=1],
 769 [have_getmodulefilename=0])
 770 if test "$have_getmodulefilename" = "1"; then
 771 AC_DEFINE(HAVE_GETMODULEFILENAME)
 772 fi
 773
 774 dnl ** check return type of signal handlers
 775 dnl Foo: assumes we can use prototypes.
 776 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 777 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 778 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 779 dnl #include <signal.h>
 780 dnl #ifdef signal
 781 dnl #undef signal
 782 dnl #endif
 783 dnl void (*signal (int, void (*)(int)))(int);
 784 dnl ],
 785 dnl [int i;],
 786 dnl ac_cv_type_signal_handler=void_int,
 787 dnl ac_cv_type_signal_handler=int_void)])
 788 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 789 dnl AC_DEFINE(VOID_INT_SIGNALS)
 790 dnl fi
 791
 792 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 793 AC_TYPE_SIGNAL
 794 if test "$ac_cv_type_signal" = void; then
 795 AC_DEFINE(VOID_INT_SIGNALS)
 796 fi
 797
 798 dnl ** check for more functions
 799 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 800 AC_CHECK_FUNCS(strcmp)
 801 AC_CHECK_FUNCS(realpath _fullpath)
 802 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 803 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 804 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 805 AC_CHECK_FUNCS(snprintf  _snprintf )
 806 AC_CHECK_FUNCS(popen     _popen )
 807 AC_CHECK_FUNCS(pclose    _pclose )
 808
 809
 810 dnl ** check for specific library functions that we are interested in
 811 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat symlink sysconf timelocal times vadvise vfork)
 812
 813 dnl ** check whether this machine has gmp3 installed
 814 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 815   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 816     HaveLibGmp=No; LibGmp=not-installed))
 817 AC_SUBST(HaveLibGmp)
 818 AC_SUBST(LibGmp)
 819
 820 dnl ** check whether this machine has GNU regex in libc.
 821 FPTOOLS_REGEX_IN_LIBC
 822
 823 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 824 dnl    the order of these tests matters: bfd needs liberty
 825 AC_CHECK_LIB(iberty, xmalloc)
 826 AC_CHECK_LIB(bfd,    bfd_init)
 827
 828 dnl ** check for readline, for Hugs and hslibs' Readline
 829 dnl ncurses supersedes termcap and curses, but for compatibility,
 830 dnl we have to check for all...
 831 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 832   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 833     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 834       HaveLibTermcap=NO; LibTermcap=not-installed)))
 835
 836 if test $HaveLibTermcap = YES ; then
 837   LIBS="-l$LibTermcap $LIBS"
 838   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 839 fi
 840
 841 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 842   AC_DEFINE(HAVE_READLINE_LIBS,1)
 843   LibsReadline="-lreadline -l$LibTermcap"
 844 else
 845   AC_DEFINE(HAVE_READLINE_LIBS,0)
 846   LibsReadline=
 847 fi
 848 AC_SUBST(LibsReadline)
 849
 850 if test "$HaveLibReadline"; then
 851   AC_CHECK_LIB(readline, rl_erase_empty_line,
 852     [AC_DEFINE(HAVE_READLINE_4, 1)],
 853     [AC_DEFINE(HAVE_READLINE_4, 0)])
 854   AC_CHECK_LIB(readline, rl_free_undo_list,
 855     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
 856     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
 857 else
 858   AC_DEFINE(HAVE_READLINE_4, 0)
 859   AC_DEFINE(HAVE_READLINE_4_2, 0)
 860 fi
 861
 862 dnl ** check for math library
 863 FPTOOLS_CHECK_LIBM()
 864 AC_SUBST(LIBM)
 865
 866 dnl ################################################################
 867 dnl Check for libraries
 868 dnl ################################################################
 869
 870 AC_CHECK_LIB(dl, dlopen,
 871         [HaveLibDL=YES
 872          AC_DEFINE(HAVE_LIBDL)
 873          LIBS="$LIBS -ldl"],
 874         [HaveLibDL=NO])
 875 AC_CHECK_FUNCS(dlopen)
 876 AC_SUBST(HaveLibDL)
 877
 878 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 879
 880 dnl --------------------------------------------------
 881 dnl * test for GTK+
 882 dnl --------------------------------------------------
 883
 884 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 885 if test "$GTK_CONFIG" != ""; then
 886    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 887         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 888     ])
 889     GTK_VERSION=$fptools_cv_gtk_version
 890 else
 891     GTK_VERSION=
 892 fi
 893
 894 case $fptools_cv_gtk_version in
 895   1.[[23]].*) ;;
 896   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 897      GTK_CONFIG=
 898      ;;
 899 esac
 900
 901 AC_SUBST(GTK_CONFIG)
 902 AC_SUBST(GTK_VERSION)
 903
 904 dnl --------------------------------------------------
 905 dnl * Miscellaneous feature tests
 906 dnl --------------------------------------------------
 907
 908 dnl ** can we get alloca?
 909 AC_FUNC_ALLOCA
 910
 911 dnl ** determine whether or not const works
 912 AC_C_CONST
 913
 914 dnl ** determine whether ANSI-function prototypes work?
 915 AC_C_PROTOTYPES
 916
 917 dnl ** are we big endian?
 918 AC_C_BIGENDIAN
 919 # Allay users' general fear of warnings of any kind.
 920 errprint((fptools configure script wizard sez: "don't worry, the above warning is harmless (to us.)")
 921 )
 922
 923 dnl ** check for leading underscores in symbol names
 924 FPTOOLS_UNDERSCORE
 925
 926 dnl ** how is the end of text section signalled?
 927 FPTOOLS_END_TEXT_SECTION
 928
 929 dnl ** how is the end of data section signalled?
 930 FPTOOLS_END_DATA_SECTION
 931
 932 dnl ** code before data?
 933 FPTOOLS_CODE_BEFORE_DATA
 934
 935 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )