ghc/compiler/absCSyn/PprAbsC.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 %************************************************************************
   5 %*                                                                      *
   6 \section[PprAbsC]{Pretty-printing Abstract~C}
   7 %*                                                                      *
   8 %************************************************************************
   9
  10 \begin{code}
  11 module PprAbsC (
  12         writeRealC,
  13         dumpRealC,
  14         pprAmode,
  15         pprMagicId
  16     ) where
  17
  18 #include "HsVersions.h"
  19
  20 import IO       ( Handle )
  21
  22 import AbsCSyn
  23 import ClosureInfo
  24 import AbsCUtils        ( getAmodeRep, nonemptyAbsC,
  25                           mixedPtrLocn, mixedTypeLocn
  26                         )
  27
  28 import Constants        ( mIN_UPD_SIZE )
  29 import CallConv         ( CallConv, callConvAttribute )
  30 import CLabel           ( externallyVisibleCLabel, mkErrorStdEntryLabel,
  31                           needsCDecl, pprCLabel,
  32                           mkReturnInfoLabel, mkReturnPtLabel, mkClosureTblLabel,
  33                           mkClosureLabel,
  34                           CLabel, CLabelType(..), labelType, labelDynamic
  35                         )
  36
  37 import CmdLineOpts      ( opt_SccProfilingOn, opt_EmitCExternDecls, opt_GranMacros )
  38 import CostCentre       ( pprCostCentreDecl, pprCostCentreStackDecl )
  39
  40 import Costs            ( costs, addrModeCosts, CostRes(..), Side(..) )
  41 import CStrings         ( stringToC, pprCLabelString )
  42 import FiniteMap        ( addToFM, emptyFM, lookupFM, FiniteMap )
  43 import Literal          ( Literal(..) )
  44 import TyCon            ( tyConDataCons )
  45 import Name             ( NamedThing(..) )
  46 import DataCon          ( DataCon{-instance NamedThing-}, dataConWrapId )
  47 import Maybes           ( maybeToBool, catMaybes )
  48 import PrimOp           ( primOpNeedsWrapper, pprPrimOp, pprCCallOp,
  49                           PrimOp(..), CCall(..), CCallTarget(..) )
  50 import PrimRep          ( isFloatingRep, PrimRep(..), getPrimRepSize, showPrimRep )
  51 import SMRep            ( pprSMRep )
  52 import Unique           ( pprUnique, Unique{-instance NamedThing-} )
  53 import UniqSet          ( emptyUniqSet, elementOfUniqSet,
  54                           addOneToUniqSet, UniqSet
  55                         )
  56 import StgSyn           ( SRT(..) )
  57 import BitSet           ( intBS )
  58 import Outputable
  59 import Util             ( nOfThem )
  60 import Addr             ( Addr )
  61
  62 import ST
  63 import MutableArray
  64
  65 infixr 9 `thenTE`
  66 \end{code}
  67
  68 For spitting out the costs of an abstract~C expression, @writeRealC@
  69 now not only prints the C~code of the @absC@ arg but also adds a macro
  70 call to a cost evaluation function @GRAN_EXEC@. For that,
  71 @pprAbsC@ has a new ``costs'' argument.  %% HWL
  72
  73 \begin{code}
  74 {-
  75 writeRealC :: Handle -> AbstractC -> IO ()
  76 writeRealC handle absC
  77      -- avoid holding on to the whole of absC in the !Gransim case.
  78      if opt_GranMacros
  79         then printForCFast fp (pprAbsC absC (costs absC))
  80         else printForCFast fp (pprAbsC absC (panic "costs"))
  81              --printForC handle (pprAbsC absC (panic "costs"))
  82 dumpRealC :: AbstractC -> SDoc
  83 dumpRealC absC = pprAbsC absC (costs absC)
  84 -}
  85
  86 writeRealC :: Handle -> AbstractC -> IO ()
  87 --writeRealC handle absC =
  88 -- _scc_ "writeRealC"
  89 -- printDoc LeftMode handle (pprAbsC absC (costs absC))
  90
  91 writeRealC handle absC
  92  | opt_GranMacros = _scc_ "writeRealC" printForC handle $
  93                                        pprCode CStyle (pprAbsC absC (costs absC))
  94  | otherwise      = _scc_ "writeRealC" printForC handle $
  95                                        pprCode CStyle (pprAbsC absC (panic "costs"))
  96
  97 dumpRealC :: AbstractC -> SDoc
  98 dumpRealC absC
  99  | opt_GranMacros = pprCode CStyle (pprAbsC absC (costs absC))
 100  | otherwise      = pprCode CStyle (pprAbsC absC (panic "costs"))
 101
 102 \end{code}
 103
 104 This emits the macro,  which is used in GrAnSim  to compute the total costs
 105 from a cost 5 tuple. %%  HWL
 106
 107 \begin{code}
 108 emitMacro :: CostRes -> SDoc
 109
 110 emitMacro _ | not opt_GranMacros = empty
 111
 112 emitMacro (Cost (i,b,l,s,f))
 113   = hcat [ ptext SLIT("GRAN_EXEC"), char '(',
 114                           int i, comma, int b, comma, int l, comma,
 115                           int s, comma, int f, pp_paren_semi ]
 116
 117 pp_paren_semi = text ");"
 118 \end{code}
 119
 120 New type: Now pprAbsC also takes the costs for evaluating the Abstract C
 121 code as an argument (that's needed when spitting out the GRAN_EXEC macro
 122 which must be done before the return i.e. inside absC code)   HWL
 123
 124 \begin{code}
 125 pprAbsC :: AbstractC -> CostRes -> SDoc
 126 pprAbsC AbsCNop _ = empty
 127 pprAbsC (AbsCStmts s1 s2) c = ($$) (pprAbsC s1 c) (pprAbsC s2 c)
 128
 129 pprAbsC (CAssign dest src) _ = pprAssign (getAmodeRep dest) dest src
 130
 131 pprAbsC (CJump target) c
 132   = ($$) (hcat [emitMacro c {-WDP:, text "/* <--++  CJump */"-} ])
 133              (hcat [ text jmp_lit, pprAmode target, pp_paren_semi ])
 134
 135 pprAbsC (CFallThrough target) c
 136   = ($$) (hcat [emitMacro c {-WDP:, text "/* <--++  CFallThrough */"-} ])
 137              (hcat [ text jmp_lit, pprAmode target, pp_paren_semi ])
 138
 139 -- --------------------------------------------------------------------------
 140 -- Spit out GRAN_EXEC macro immediately before the return                 HWL
 141
 142 pprAbsC (CReturn am return_info)  c
 143   = ($$) (hcat [emitMacro c {-WDP:, text "/* <----  CReturn */"-} ])
 144              (hcat [text jmp_lit, target, pp_paren_semi ])
 145   where
 146    target = case return_info of
 147         DirectReturn -> hcat [ptext SLIT("ENTRY_CODE"), lparen,
 148                               pprAmode am, rparen]
 149         DynamicVectoredReturn am' -> mk_vector (pprAmode am')
 150         StaticVectoredReturn n -> mk_vector (int n)     -- Always positive
 151    mk_vector x = hcat [ptext SLIT("RET_VEC"), char '(', pprAmode am, comma,
 152                        x, rparen ]
 153
 154 pprAbsC (CSplitMarker) _ = ptext SLIT("/* SPLIT */")
 155
 156 -- we optimise various degenerate cases of CSwitches.
 157
 158 -- --------------------------------------------------------------------------
 159 -- Assume: CSwitch is also end of basic block
 160 --         costs function yields nullCosts for whole switch
 161 --         ==> inherited costs c are those of basic block up to switch
 162 --         ==> inherit c + costs for the corresponding branch
 163 --                                                                       HWL
 164 -- --------------------------------------------------------------------------
 165
 166 pprAbsC (CSwitch discrim [] deflt) c
 167   = pprAbsC deflt (c + costs deflt)
 168     -- Empty alternative list => no costs for discrim as nothing cond. here HWL
 169
 170 pprAbsC (CSwitch discrim [(tag,alt_code)] deflt) c -- only one alt
 171   = case (nonemptyAbsC deflt) of
 172       Nothing ->                -- one alt and no default
 173                  pprAbsC alt_code (c + costs alt_code)
 174                  -- Nothing conditional in here either  HWL
 175
 176       Just dc ->                -- make it an "if"
 177                  do_if_stmt discrim tag alt_code dc c
 178
 179 -- What problem is the re-ordering trying to solve ?
 180 pprAbsC (CSwitch discrim [(tag1@(MachInt i1), alt_code1),
 181                           (tag2@(MachInt i2), alt_code2)] deflt) c
 182   | empty_deflt && ((i1 == 0 && i2 == 1) || (i1 == 1 && i2 == 0))
 183   = if (i1 == 0) then
 184         do_if_stmt discrim tag1 alt_code1 alt_code2 c
 185     else
 186         do_if_stmt discrim tag2 alt_code2 alt_code1 c
 187   where
 188     empty_deflt = not (maybeToBool (nonemptyAbsC deflt))
 189
 190 pprAbsC (CSwitch discrim alts deflt) c -- general case
 191   | isFloatingRep (getAmodeRep discrim)
 192     = pprAbsC (foldr ( \ a -> CSwitch discrim [a]) deflt alts) c
 193   | otherwise
 194     = vcat [
 195         hcat [text "switch (", pp_discrim, text ") {"],
 196         nest 2 (vcat (map ppr_alt alts)),
 197         (case (nonemptyAbsC deflt) of
 198            Nothing -> empty
 199            Just dc ->
 200             nest 2 (vcat [ptext SLIT("default:"),
 201                                   pprAbsC dc (c + switch_head_cost
 202                                                     + costs dc),
 203                                   ptext SLIT("break;")])),
 204         char '}' ]
 205   where
 206     pp_discrim
 207       = pprAmode discrim
 208
 209     ppr_alt (lit, absC)
 210       = vcat [ hcat [ptext SLIT("case "), pprBasicLit lit, char ':'],
 211                    nest 2 (($$) (pprAbsC absC (c + switch_head_cost + costs absC))
 212                                        (ptext SLIT("break;"))) ]
 213
 214     -- Costs for addressing header of switch and cond. branching        -- HWL
 215     switch_head_cost = addrModeCosts discrim Rhs + (Cost (0, 1, 0, 0, 0))
 216
 217 pprAbsC stmt@(COpStmt results (CCallOp ccall) args vol_regs) _
 218   = pprCCall ccall args results vol_regs
 219
 220 pprAbsC stmt@(COpStmt results op args vol_regs) _
 221   = let
 222         non_void_args = grab_non_void_amodes args
 223         non_void_results = grab_non_void_amodes results
 224         -- if just one result, we print in the obvious "assignment" style;
 225         -- if 0 or many results, we emit a macro call, w/ the results
 226         -- followed by the arguments.  The macro presumably knows which
 227         -- are which :-)
 228
 229         the_op = ppr_op_call non_void_results non_void_args
 230                 -- liveness mask is *in* the non_void_args
 231     in
 232     if primOpNeedsWrapper op then
 233         case (ppr_vol_regs vol_regs) of { (pp_saves, pp_restores) ->
 234         vcat [  pp_saves,
 235                 the_op,
 236                 pp_restores
 237              ]
 238         }
 239     else
 240         the_op
 241   where
 242     ppr_op_call results args
 243       = hcat [ pprPrimOp op, lparen,
 244         hcat (punctuate comma (map ppr_op_result results)),
 245         if null results || null args then empty else comma,
 246         hcat (punctuate comma (map pprAmode args)),
 247         pp_paren_semi ]
 248
 249     ppr_op_result r = ppr_amode r
 250       -- primop macros do their own casting of result;
 251       -- hence we can toss the provided cast...
 252
 253 pprAbsC stmt@(CSRT lbl closures) c
 254   = case (pprTempAndExternDecls stmt) of { (_, pp_exts) ->
 255          pp_exts
 256       $$ ptext SLIT("SRT") <> lparen <> pprCLabel lbl <> rparen
 257       $$ nest 2 (hcat (punctuate comma (map pp_closure_lbl closures)))
 258          <> ptext SLIT("};")
 259   }
 260
 261 pprAbsC stmt@(CBitmap lbl mask) c
 262   = vcat [
 263         hcat [ ptext SLIT("BITMAP"), lparen,
 264                         pprCLabel lbl, comma,
 265                         int (length mask),
 266                rparen ],
 267         hcat (punctuate comma (map (int.intBS) mask)),
 268         ptext SLIT("}};")
 269     ]
 270
 271 pprAbsC (CSimultaneous abs_c) c
 272   = hcat [ptext SLIT("{{"), pprAbsC abs_c c, ptext SLIT("}}")]
 273
 274 pprAbsC (CCheck macro as code) c
 275   = hcat [ptext (cCheckMacroText macro), lparen,
 276        hcat (punctuate comma (map ppr_amode as)), comma,
 277        pprAbsC code c, pp_paren_semi
 278     ]
 279 pprAbsC (CMacroStmt macro as) _
 280   = hcat [ptext (cStmtMacroText macro), lparen,
 281         hcat (punctuate comma (map ppr_amode as)),pp_paren_semi] -- no casting
 282 pprAbsC (CCallProfCtrMacro op as) _
 283   = hcat [ptext op, lparen,
 284         hcat (punctuate comma (map ppr_amode as)),pp_paren_semi]
 285 pprAbsC (CCallProfCCMacro op as) _
 286   = hcat [ptext op, lparen,
 287         hcat (punctuate comma (map ppr_amode as)),pp_paren_semi]
 288 pprAbsC stmt@(CCallTypedef is_tdef (CCall op_str is_asm may_gc cconv) results args) _
 289   =  hsep [ ptext (if is_tdef then SLIT("typedef") else SLIT("extern"))
 290           , ccall_res_ty
 291           , fun_nm
 292           , parens (hsep (punctuate comma ccall_decl_ty_args))
 293           ] <> semi
 294     where
 295     {-
 296       In the non-casm case, to ensure that we're entering the given external
 297       entry point using the correct calling convention, we have to do the following:
 298
 299         - When entering via a function pointer (the `dynamic' case) using the specified
 300           calling convention, we emit a typedefn declaration attributed with the
 301           calling convention to use together with the result and parameter types we're
 302           assuming. Coerce the function pointer to this type and go.
 303
 304         - to enter the function at a given code label, we emit an extern declaration
 305           for the label here, stating the calling convention together with result and
 306           argument types we're assuming.
 307
 308           The C compiler will hopefully use this extern declaration to good effect,
 309           reporting any discrepancies between our extern decl and any other that
 310           may be in scope.
 311
 312           Re: calling convention, notice that gcc (2.8.1 and egcs-1.0.2) will for
 313           the external function `foo' use the calling convention of the first `foo'
 314           prototype it encounters (nor does it complain about conflicting attribute
 315           declarations). The consequence of this is that you cannot override the
 316           calling convention of `foo' using an extern declaration (you'd have to use
 317           a typedef), but why you would want to do such a thing in the first place
 318           is totally beyond me.
 319
 320           ToDo: petition the gcc folks to add code to warn about conflicting attribute
 321           declarations.
 322
 323     -}
 324
 325      fun_nm
 326        | is_tdef   = parens (text (callConvAttribute cconv) <+> char '*' <> ccall_fun_ty)
 327        | otherwise = text (callConvAttribute cconv) <+> ccall_fun_ty
 328
 329      ccall_fun_ty =
 330         case op_str of
 331           DynamicTarget u -> ptext SLIT("_ccall_fun_ty") <> ppr u
 332           StaticTarget x  -> pprCLabelString x
 333
 334      ccall_res_ty =
 335        case non_void_results of
 336           []       -> ptext SLIT("void")
 337           [amode]  -> text (showPrimRep (getAmodeRep amode))
 338           _        -> panic "pprAbsC{CCallTypedef}: ccall_res_ty"
 339
 340      ccall_decl_ty_args
 341        | is_tdef   = tail ccall_arg_tys
 342        | otherwise = ccall_arg_tys
 343
 344      ccall_arg_tys      = map (text.showPrimRep.getAmodeRep) non_void_args
 345
 346       -- the first argument will be the "I/O world" token (a VoidRep)
 347       -- all others should be non-void
 348      non_void_args =
 349         let nvas = init args
 350         in ASSERT (all non_void nvas) nvas
 351
 352       -- there will usually be two results: a (void) state which we
 353       -- should ignore and a (possibly void) result.
 354      non_void_results =
 355         let nvrs = grab_non_void_amodes results
 356         in ASSERT (length nvrs <= 1) nvrs
 357
 358 pprAbsC (CCodeBlock lbl abs_C) _
 359   = if not (maybeToBool(nonemptyAbsC abs_C)) then
 360         pprTrace "pprAbsC: curious empty code block for" (pprCLabel lbl) empty
 361     else
 362     case (pprTempAndExternDecls abs_C) of { (pp_temps, pp_exts) ->
 363     vcat [
 364         char ' ',
 365         hcat [text (if (externallyVisibleCLabel lbl)
 366                           then "FN_("   -- abbreviations to save on output
 367                           else "IFN_("),
 368                    pprCLabel lbl, text ") {"],
 369
 370         pp_exts, pp_temps,
 371
 372         nest 8 (ptext SLIT("FB_")),
 373         nest 8 (pprAbsC abs_C (costs abs_C)),
 374         nest 8 (ptext SLIT("FE_")),
 375         char '}',
 376         char ' ' ]
 377     }
 378
 379
 380 pprAbsC (CInitHdr cl_info amode cost_centre) _
 381   = hcat [ ptext SLIT("SET_HDR_"), char '(',
 382                 ppr_amode amode, comma,
 383                 pprCLabelAddr info_lbl, comma,
 384                 if_profiling (pprAmode cost_centre),
 385                 pp_paren_semi ]
 386   where
 387     info_lbl    = infoTableLabelFromCI cl_info
 388
 389 pprAbsC stmt@(CStaticClosure closure_lbl cl_info cost_centre amodes) _
 390   = case (pprTempAndExternDecls stmt) of { (_, pp_exts) ->
 391     vcat [
 392         pp_exts,
 393         hcat [
 394                 ptext SLIT("SET_STATIC_HDR"), char '(',
 395                 pprCLabel closure_lbl,                          comma,
 396                 pprCLabel info_lbl,                             comma,
 397                 if_profiling (pprAmode cost_centre),            comma,
 398                 ppLocalness closure_lbl,                        comma,
 399                 ppLocalnessMacro True{-include dyn-} info_lbl,
 400                 char ')'
 401                 ],
 402         nest 2 (ppr_payload (amodes ++ padding_wds ++ static_link_field)),
 403         ptext SLIT("};") ]
 404     }
 405   where
 406     info_lbl = infoTableLabelFromCI cl_info
 407
 408     ppr_payload [] = empty
 409     ppr_payload ls = comma <+>
 410                      braces (hsep (punctuate comma (map ((text "(L_)" <>).ppr_item) ls)))
 411
 412     ppr_item item
 413       | rep == VoidRep   = text "0" -- might not even need this...
 414       | rep == FloatRep  = ppr_amode (floatToWord item)
 415       | rep == DoubleRep = hcat (punctuate (text ", (L_)")
 416                                  (map ppr_amode (doubleToWords item)))
 417       | otherwise        = ppr_amode item
 418       where
 419         rep = getAmodeRep item
 420
 421     padding_wds =
 422         if not (closureUpdReqd cl_info) then
 423             []
 424         else
 425             case max 0 (mIN_UPD_SIZE - length amodes) of { still_needed ->
 426             nOfThem still_needed (mkIntCLit 0) } -- a bunch of 0s
 427
 428     static_link_field
 429         | staticClosureNeedsLink cl_info = [mkIntCLit 0]
 430         | otherwise                      = []
 431
 432 pprAbsC stmt@(CClosureInfoAndCode cl_info slow maybe_fast cl_descr) _
 433   = vcat [
 434         hcat [
 435              ptext SLIT("INFO_TABLE"),
 436              ( if is_selector then
 437                  ptext SLIT("_SELECTOR")
 438                else if is_constr then
 439                  ptext SLIT("_CONSTR")
 440                else if needs_srt then
 441                  ptext SLIT("_SRT")
 442                else empty ), char '(',
 443
 444             pprCLabel info_lbl,                         comma,
 445             pprCLabel slow_lbl,                         comma,
 446             pp_rest, {- ptrs,nptrs,[srt,]type,-}        comma,
 447
 448             ppLocalness info_lbl,                          comma,
 449             ppLocalnessMacro True{-include dyn-} slow_lbl, comma,
 450
 451             if_profiling pp_descr, comma,
 452             if_profiling pp_type,
 453             text ");"
 454              ],
 455         pp_slow,
 456         case maybe_fast of
 457             Nothing -> empty
 458             Just fast -> let stuff = CCodeBlock fast_lbl fast in
 459                          pprAbsC stuff (costs stuff)
 460     ]
 461   where
 462     info_lbl    = infoTableLabelFromCI cl_info
 463     fast_lbl    = fastLabelFromCI cl_info
 464
 465     (slow_lbl, pp_slow)
 466       = case (nonemptyAbsC slow) of
 467           Nothing -> (mkErrorStdEntryLabel, empty)
 468           Just xx -> (entryLabelFromCI cl_info,
 469                        let stuff = CCodeBlock slow_lbl xx in
 470                        pprAbsC stuff (costs stuff))
 471
 472     maybe_selector = maybeSelectorInfo cl_info
 473     is_selector = maybeToBool maybe_selector
 474     (Just select_word_i) = maybe_selector
 475
 476     maybe_tag = closureSemiTag cl_info
 477     is_constr = maybeToBool maybe_tag
 478     (Just tag) = maybe_tag
 479
 480     needs_srt = infoTblNeedsSRT cl_info
 481     srt = getSRTInfo cl_info
 482
 483     size = closureNonHdrSize cl_info
 484
 485     ptrs        = closurePtrsSize cl_info
 486     nptrs       = size - ptrs
 487
 488     pp_rest | is_selector      = int select_word_i
 489             | otherwise        = hcat [
 490                   int ptrs,             comma,
 491                   int nptrs,            comma,
 492                   if is_constr then
 493                         hcat [ int tag, comma ]
 494                   else if needs_srt then
 495                         pp_srt_info srt
 496                   else empty,
 497                   type_str ]
 498
 499     type_str = pprSMRep (closureSMRep cl_info)
 500
 501     pp_descr = hcat [char '"', text (stringToC cl_descr), char '"']
 502     pp_type  = hcat [char '"', text (stringToC (closureTypeDescr cl_info)), char '"']
 503
 504 pprAbsC stmt@(CClosureTbl tycon) _
 505   = vcat (
 506         ptext SLIT("CLOSURE_TBL") <>
 507            lparen <> pprCLabel (mkClosureTblLabel tycon) <> rparen :
 508         punctuate comma (
 509            map (pp_closure_lbl . mkClosureLabel . getName . dataConWrapId) (tyConDataCons tycon)
 510         )
 511    ) $$ ptext SLIT("};")
 512
 513 pprAbsC stmt@(CRetDirect uniq code srt liveness) _
 514   = vcat [
 515       hcat [
 516           ptext SLIT("INFO_TABLE_SRT_BITMAP"), lparen,
 517           pprCLabel info_lbl,           comma,
 518           pprCLabel entry_lbl,          comma,
 519           pp_liveness liveness,         comma,    -- bitmap
 520           pp_srt_info srt,                        -- SRT
 521           ptext type_str,               comma,    -- closure type
 522           ppLocalness info_lbl,         comma,    -- info table storage class
 523           ppLocalnessMacro True{-include dyn-} entry_lbl,       comma,    -- entry pt storage class
 524           int 0, comma,
 525           int 0, text ");"
 526       ],
 527       pp_code
 528     ]
 529   where
 530      info_lbl  = mkReturnInfoLabel uniq
 531      entry_lbl = mkReturnPtLabel uniq
 532
 533      pp_code   = let stuff = CCodeBlock entry_lbl code in
 534                  pprAbsC stuff (costs stuff)
 535
 536      type_str = case liveness of
 537                    LvSmall _ -> SLIT("RET_SMALL")
 538                    LvLarge _ -> SLIT("RET_BIG")
 539
 540 pprAbsC stmt@(CRetVector lbl amodes srt liveness) _
 541   = case (pprTempAndExternDecls stmt) of { (_, pp_exts) ->
 542     vcat [
 543         pp_exts,
 544         hcat [
 545           ptext SLIT("VEC_INFO_") <> int size,
 546           lparen,
 547           pprCLabel lbl, comma,
 548           pp_liveness liveness, comma,  -- bitmap liveness mask
 549           pp_srt_info srt,              -- SRT
 550           ptext type_str, comma,
 551           ppLocalness lbl, comma
 552         ],
 553         nest 2 (sep (punctuate comma (map ppr_item amodes))),
 554         text ");"
 555     ]
 556     }
 557
 558   where
 559     ppr_item item = (<>) (text "(F_) ") (ppr_amode item)
 560     size = length amodes
 561
 562     type_str = case liveness of
 563                    LvSmall _ -> SLIT("RET_VEC_SMALL")
 564                    LvLarge _ -> SLIT("RET_VEC_BIG")
 565
 566
 567 pprAbsC stmt@(CModuleInitBlock lbl code) _
 568   = vcat [
 569         ptext SLIT("START_MOD_INIT") <> parens (pprCLabel lbl),
 570         case (pprTempAndExternDecls stmt) of { (_, pp_exts) -> pp_exts },
 571         pprAbsC code (costs code),
 572         hcat [ptext SLIT("END_MOD_INIT"), lparen, rparen]
 573     ]
 574
 575 pprAbsC (CCostCentreDecl is_local cc) _ = pprCostCentreDecl is_local cc
 576 pprAbsC (CCostCentreStackDecl ccs)    _ = pprCostCentreStackDecl ccs
 577 \end{code}
 578
 579 \begin{code}
 580 ppLocalness lbl
 581   = if (externallyVisibleCLabel lbl)
 582                 then empty
 583                 else ptext SLIT("static ")
 584
 585 -- Horrible macros for declaring the types and locality of labels (see
 586 -- StgMacros.h).
 587
 588 ppLocalnessMacro include_dyn_prefix clabel =
 589      hcat [
 590         visiblity_prefix,
 591         dyn_prefix,
 592         case label_type of
 593           ClosureType    -> ptext SLIT("C_")
 594           CodeType       -> ptext SLIT("F_")
 595           InfoTblType    -> ptext SLIT("I_")
 596           ClosureTblType -> ptext SLIT("CP_")
 597           DataType       -> ptext SLIT("D_")
 598      ]
 599   where
 600    is_visible = externallyVisibleCLabel clabel
 601    label_type = labelType clabel
 602
 603    visiblity_prefix
 604      | is_visible = char 'E'
 605      | otherwise  = char 'I'
 606
 607    dyn_prefix
 608      | include_dyn_prefix && labelDynamic clabel = char 'D'
 609      | otherwise                                 = empty
 610
 611 \end{code}
 612
 613 \begin{code}
 614 jmp_lit = "JMP_("
 615
 616 grab_non_void_amodes amodes
 617   = filter non_void amodes
 618
 619 non_void amode
 620   = case (getAmodeRep amode) of
 621       VoidRep -> False
 622       k -> True
 623 \end{code}
 624
 625 \begin{code}
 626 ppr_vol_regs :: [MagicId] -> (SDoc, SDoc)
 627
 628 ppr_vol_regs [] = (empty, empty)
 629 ppr_vol_regs (VoidReg:rs) = ppr_vol_regs rs
 630 ppr_vol_regs (r:rs)
 631   = let pp_reg = case r of
 632                     VanillaReg pk n -> pprVanillaReg n
 633                     _ -> pprMagicId r
 634         (more_saves, more_restores) = ppr_vol_regs rs
 635     in
 636     (($$) ((<>) (ptext SLIT("CALLER_SAVE_"))    pp_reg) more_saves,
 637      ($$) ((<>) (ptext SLIT("CALLER_RESTORE_")) pp_reg) more_restores)
 638
 639 -- pp_basic_{saves,restores}: The BaseReg, Sp, Su, Hp and
 640 -- HpLim (see StgRegs.lh) may need to be saved/restored around CCalls,
 641 -- depending on the platform.  (The "volatile regs" stuff handles all
 642 -- other registers.)  Just be *sure* BaseReg is OK before trying to do
 643 -- anything else. The correct sequence of saves&restores are
 644 -- encoded by the CALLER_*_SYSTEM macros.
 645 pp_basic_saves    = ptext SLIT("CALLER_SAVE_SYSTEM")
 646 pp_basic_restores = ptext SLIT("CALLER_RESTORE_SYSTEM")
 647 \end{code}
 648
 649 \begin{code}
 650 has_srt (_, NoSRT) = False
 651 has_srt _ = True
 652
 653 pp_srt_info srt =
 654     case srt of
 655         (lbl, NoSRT) ->
 656                 hcat [  int 0, comma,
 657                         int 0, comma,
 658                         int 0, comma ]
 659         (lbl, SRT off len) ->
 660                 hcat [  pprCLabel lbl, comma,
 661                         int off, comma,
 662                         int len, comma ]
 663 \end{code}
 664
 665 \begin{code}
 666 pp_closure_lbl lbl
 667       | labelDynamic lbl = text "DLL_SRT_ENTRY" <> parens (pprCLabel lbl)
 668       | otherwise        = char '&' <> pprCLabel lbl
 669 \end{code}
 670
 671 \begin{code}
 672 if_profiling pretty
 673   = if  opt_SccProfilingOn
 674     then pretty
 675     else char '0' -- leave it out!
 676 -- ---------------------------------------------------------------------------
 677 -- Changes for GrAnSim:
 678 --  draw costs for computation in head of if into both branches;
 679 --  as no abstractC data structure is given for the head, one is constructed
 680 --  guessing unknown values and fed into the costs function
 681 -- ---------------------------------------------------------------------------
 682
 683 do_if_stmt discrim tag alt_code deflt c
 684   = case tag of
 685       -- This special case happens when testing the result of a comparison.
 686       -- We can just avoid some redundant clutter in the output.
 687       MachInt n | n==0 -> ppr_if_stmt (pprAmode discrim)
 688                                       deflt alt_code
 689                                       (addrModeCosts discrim Rhs) c
 690       other            -> let
 691                                cond = hcat [ pprAmode discrim
 692                                            , ptext SLIT(" == ")
 693                                            , tcast
 694                                            , pprAmode (CLit tag)
 695                                            ]
 696                                 -- to be absolutely sure that none of the
 697                                 -- conversion rules hit, e.g.,
 698                                 --
 699                                 --     minInt is different to (int)minInt
 700                                 --
 701                                 -- in C (when minInt is a number not a constant
 702                                 --  expression which evaluates to it.)
 703                                 --
 704                                tcast = case other of
 705                                            MachInt _  -> ptext SLIT("(I_)")
 706                                            _          -> empty
 707                             in
 708                             ppr_if_stmt cond
 709                                          alt_code deflt
 710                                          (addrModeCosts discrim Rhs) c
 711
 712 ppr_if_stmt pp_pred then_part else_part discrim_costs c
 713   = vcat [
 714       hcat [text "if (", pp_pred, text ") {"],
 715       nest 8 (pprAbsC then_part         (c + discrim_costs +
 716                                         (Cost (0, 2, 0, 0, 0)) +
 717                                         costs then_part)),
 718       (case nonemptyAbsC else_part of Nothing -> empty; Just _ -> text "} else {"),
 719       nest 8 (pprAbsC else_part  (c + discrim_costs +
 720                                         (Cost (0, 1, 0, 0, 0)) +
 721                                         costs else_part)),
 722       char '}' ]
 723     {- Total costs = inherited costs (before if) + costs for accessing discrim
 724                      + costs for cond branch ( = (0, 1, 0, 0, 0) )
 725                      + costs for that alternative
 726     -}
 727 \end{code}
 728
 729 Historical note: this used to be two separate cases -- one for `ccall'
 730 and one for `casm'.  To get round a potential limitation to only 10
 731 arguments, the numbering of arguments in @process_casm@ was beefed up a
 732 bit. ADR
 733
 734 Some rough notes on generating code for @CCallOp@:
 735
 736 1) Evaluate all arguments and stuff them into registers. (done elsewhere)
 737 2) Save any essential registers (heap, stack, etc).
 738
 739    ToDo: If stable pointers are in use, these must be saved in a place
 740    where the runtime system can get at them so that the Stg world can
 741    be restarted during the call.
 742
 743 3) Save any temporary registers that are currently in use.
 744 4) Do the call, putting result into a local variable
 745 5) Restore essential registers
 746 6) Restore temporaries
 747
 748    (This happens after restoration of essential registers because we
 749    might need the @Base@ register to access all the others correctly.)
 750
 751    Otherwise, copy local variable into result register.
 752
 753 8) If ccall (not casm), declare the function being called as extern so
 754    that C knows if it returns anything other than an int.
 755
 756 \begin{pseudocode}
 757 { ResultType _ccall_result;
 758   basic_saves;
 759   saves;
 760   _ccall_result = f( args );
 761   basic_restores;
 762   restores;
 763
 764   return_reg = _ccall_result;
 765 }
 766 \end{pseudocode}
 767
 768 Amendment to the above: if we can GC, we have to:
 769
 770 * make sure we save all our registers away where the garbage collector
 771   can get at them.
 772 * be sure that there are no live registers or we're in trouble.
 773   (This can cause problems if you try something foolish like passing
 774    an array or a foreign obj to a _ccall_GC_ thing.)
 775 * increment/decrement the @inCCallGC@ counter before/after the call so
 776   that the runtime check that PerformGC is being used sensibly will work.
 777
 778 \begin{code}
 779 pprCCall call@(CCall op_str is_asm may_gc cconv) args results vol_regs
 780   = vcat [
 781       char '{',
 782       declare_local_vars,   -- local var for *result*
 783       vcat local_arg_decls,
 784       pp_save_context,
 785         process_casm local_vars pp_non_void_args casm_str,
 786       pp_restore_context,
 787       assign_results,
 788       char '}'
 789     ]
 790   where
 791     (pp_saves, pp_restores) = ppr_vol_regs vol_regs
 792     (pp_save_context, pp_restore_context)
 793         | may_gc  = ( text "{ I_ id; SUSPEND_THREAD(id);"
 794                     , text "RESUME_THREAD(id);}"
 795                     )
 796         | otherwise = ( pp_basic_saves $$ pp_saves,
 797                         pp_basic_restores $$ pp_restores)
 798
 799     non_void_args =
 800         let nvas = init args
 801         in ASSERT2 ( all non_void nvas, pprCCallOp call <+> hsep (map pprAmode args) )
 802         nvas
 803     -- the last argument will be the "I/O world" token (a VoidRep)
 804     -- all others should be non-void
 805
 806     non_void_results =
 807         let nvrs = grab_non_void_amodes results
 808         in ASSERT (length nvrs <= 1) nvrs
 809     -- there will usually be two results: a (void) state which we
 810     -- should ignore and a (possibly void) result.
 811
 812     (local_arg_decls, pp_non_void_args)
 813       = unzip [ ppr_casm_arg a i | (a,i) <- non_void_args `zip` [1..] ]
 814
 815     ccall_arg_tys = map (text.showPrimRep.getAmodeRep) non_void_args
 816
 817     ccall_res_ty =
 818        case non_void_results of
 819           []       -> ptext SLIT("void")
 820           [amode]  -> text (showPrimRep (getAmodeRep amode))
 821           _        -> panic "pprCCall: ccall_res_ty"
 822
 823     ccall_fun_ty =
 824        ptext SLIT("_ccall_fun_ty") <>
 825        case op_str of
 826          DynamicTarget u -> ppr u
 827          _               -> empty
 828
 829     (declare_local_vars, local_vars, assign_results)
 830       = ppr_casm_results non_void_results
 831
 832     (StaticTarget asm_str) = op_str
 833     is_dynamic =
 834        case op_str of
 835          StaticTarget _  -> False
 836          DynamicTarget _ -> True
 837
 838     casm_str = if is_asm then _UNPK_ asm_str else ccall_str
 839
 840     -- Remainder only used for ccall
 841
 842     fun_name
 843       | is_dynamic = parens (parens (ccall_fun_ty) <> text "%0")
 844       | otherwise  = ptext asm_str
 845
 846     ccall_str = showSDoc
 847         (hcat [
 848                 if null non_void_results
 849                   then empty
 850                   else text "%r = ",
 851                 lparen, fun_name, lparen,
 852                   hcat (punctuate comma ccall_fun_args),
 853                 text "));"
 854         ])
 855
 856     ccall_fun_args
 857      | is_dynamic = tail ccall_args
 858      | otherwise  = ccall_args
 859
 860     ccall_args    = zipWith (\ _ i -> char '%' <> int i) non_void_args [0..]
 861
 862 \end{code}
 863
 864 If the argument is a heap object, we need to reach inside and pull out
 865 the bit the C world wants to see.  The only heap objects which can be
 866 passed are @Array@s and @ByteArray@s.
 867
 868 \begin{code}
 869 ppr_casm_arg :: CAddrMode -> Int -> (SDoc, SDoc)
 870     -- (a) decl and assignment, (b) local var to be used later
 871
 872 ppr_casm_arg amode a_num
 873   = let
 874         a_kind   = getAmodeRep amode
 875         pp_amode = pprAmode amode
 876         pp_kind  = pprPrimKind a_kind
 877
 878         local_var  = (<>) (ptext SLIT("_ccall_arg")) (int a_num)
 879
 880         (arg_type, pp_amode2)
 881           = case a_kind of
 882
 883               -- for array arguments, pass a pointer to the body of the array
 884               -- (PTRS_ARR_CTS skips over all the header nonsense)
 885               ArrayRep      -> (pp_kind,
 886                                 hcat [ptext SLIT("PTRS_ARR_CTS"),char '(', pp_amode, rparen])
 887               ByteArrayRep -> (pp_kind,
 888                                 hcat [ptext SLIT("BYTE_ARR_CTS"),char '(', pp_amode, rparen])
 889
 890               -- for ForeignObj, use FOREIGN_OBJ_DATA to fish out the contents.
 891               ForeignObjRep -> (pp_kind,
 892                                 hcat [ptext SLIT("ForeignObj_CLOSURE_DATA"),
 893                                       char '(', pp_amode, char ')'])
 894
 895               other         -> (pp_kind, pp_amode)
 896
 897         declare_local_var
 898           = hcat [ arg_type, space, local_var, equals, pp_amode2, semi ]
 899     in
 900     (declare_local_var, local_var)
 901 \end{code}
 902
 903 For l-values, the critical questions are:
 904
 905 1) Are there any results at all?
 906
 907    We only allow zero or one results.
 908
 909 \begin{code}
 910 ppr_casm_results
 911         :: [CAddrMode]  -- list of results (length <= 1)
 912         ->
 913         ( SDoc,         -- declaration of any local vars
 914           [SDoc],       -- list of result vars (same length as results)
 915           SDoc )        -- assignment (if any) of results in local var to registers
 916
 917 ppr_casm_results []
 918   = (empty, [], empty)  -- no results
 919
 920 ppr_casm_results [r]
 921   = let
 922         result_reg = ppr_amode r
 923         r_kind     = getAmodeRep r
 924
 925         local_var  = ptext SLIT("_ccall_result")
 926
 927         (result_type, assign_result)
 928           = (pprPrimKind r_kind,
 929              hcat [ result_reg, equals, local_var, semi ])
 930
 931         declare_local_var = hcat [ result_type, space, local_var, semi ]
 932     in
 933     (declare_local_var, [local_var], assign_result)
 934
 935 ppr_casm_results rs
 936   = panic "ppr_casm_results: ccall/casm with many results"
 937 \end{code}
 938
 939
 940 Note the sneaky way _the_ result is represented by a list so that we
 941 can complain if it's used twice.
 942
 943 ToDo: Any chance of giving line numbers when process-casm fails?
 944       Or maybe we should do a check _much earlier_ in compiler. ADR
 945
 946 \begin{code}
 947 process_casm :: [SDoc]          -- results (length <= 1)
 948              -> [SDoc]          -- arguments
 949              -> String          -- format string (with embedded %'s)
 950              -> SDoc            -- code being generated
 951
 952 process_casm results args string = process results args string
 953  where
 954   process []    _ "" = empty
 955   process (_:_) _ "" = error ("process_casm: non-void result not assigned while processing _casm_ \"" ++
 956                               string ++
 957                               "\"\n(Try changing result type to IO ()\n")
 958
 959   process ress args ('%':cs)
 960     = case cs of
 961         [] ->
 962             error ("process_casm: lonely % while processing _casm_ \"" ++ string ++ "\".\n")
 963
 964         ('%':css) ->
 965             char '%' <> process ress args css
 966
 967         ('r':css)  ->
 968           case ress of
 969             []  -> error ("process_casm: no result to match %r while processing _casm_ \"" ++ string ++ "\".\nTry deleting %r or changing result type from PrimIO ()\n")
 970             [r] -> r <> (process [] args css)
 971             _   -> panic ("process_casm: casm with many results while processing _casm_ \"" ++ string ++ "\".\n")
 972
 973         other ->
 974           let
 975                 read_int :: ReadS Int
 976                 read_int = reads
 977           in
 978           case (read_int other) of
 979             [(num,css)] ->
 980                   if 0 <= num && num < length args
 981                   then parens (args !! num) <> process ress args css
 982                   else error ("process_casm: no such arg #:"++(show num)++" while processing \"" ++ string ++ "\".\n")
 983             _ -> error ("process_casm: not %<num> while processing _casm_ \"" ++ string ++ "\".\n")
 984
 985   process ress args (other_c:cs)
 986     = char other_c <> process ress args cs
 987 \end{code}
 988
 989 %************************************************************************
 990 %*                                                                      *
 991 \subsection[a2r-assignments]{Assignments}
 992 %*                                                                      *
 993 %************************************************************************
 994
 995 Printing assignments is a little tricky because of type coercion.
 996
 997 First of all, the kind of the thing being assigned can be gotten from
 998 the destination addressing mode.  (It should be the same as the kind
 999 of the source addressing mode.)  If the kind of the assignment is of
1000 @VoidRep@, then don't generate any code at all.
1001
1002 \begin{code}
1003 pprAssign :: PrimRep -> CAddrMode -> CAddrMode -> SDoc
1004
1005 pprAssign VoidRep dest src = empty
1006 \end{code}
1007
1008 Special treatment for floats and doubles, to avoid unwanted conversions.
1009
1010 \begin{code}
1011 pprAssign FloatRep dest@(CVal reg_rel _) src
1012   = hcat [ ptext SLIT("ASSIGN_FLT"),char '(', ppr_amode (CAddr reg_rel), comma, pprAmode src, pp_paren_semi ]
1013
1014 pprAssign DoubleRep dest@(CVal reg_rel _) src
1015   = hcat [ ptext SLIT("ASSIGN_DBL"),char '(', ppr_amode (CAddr reg_rel), comma, pprAmode src, pp_paren_semi ]
1016
1017 pprAssign Int64Rep dest@(CVal reg_rel _) src
1018   = hcat [ ptext SLIT("ASSIGN_Int64"),char '(', ppr_amode (CAddr reg_rel), comma, pprAmode src, pp_paren_semi ]
1019 pprAssign Word64Rep dest@(CVal reg_rel _) src
1020   = hcat [ ptext SLIT("ASSIGN_Word64"),char '(', ppr_amode (CAddr reg_rel), comma, pprAmode src, pp_paren_semi ]
1021 \end{code}
1022
1023 Lastly, the question is: will the C compiler think the types of the
1024 two sides of the assignment match?
1025
1026         We assume that the types will match if neither side is a
1027         @CVal@ addressing mode for any register which can point into
1028         the heap or stack.
1029
1030 Why?  Because the heap and stack are used to store miscellaneous
1031 things, whereas the temporaries, registers, etc., are only used for
1032 things of fixed type.
1033
1034 \begin{code}
1035 pprAssign kind (CReg (VanillaReg _ dest)) (CReg (VanillaReg _ src))
1036   = hcat [ pprVanillaReg dest, equals,
1037                 pprVanillaReg src, semi ]
1038
1039 pprAssign kind dest src
1040   | mixedTypeLocn dest
1041     -- Add in a cast to StgWord (a.k.a. W_) iff the destination is mixed
1042   = hcat [ ppr_amode dest, equals,
1043                 text "(W_)(",   -- Here is the cast
1044                 ppr_amode src, pp_paren_semi ]
1045
1046 pprAssign kind dest src
1047   | mixedPtrLocn dest && getAmodeRep src /= PtrRep
1048     -- Add in a cast to StgPtr (a.k.a. P_) iff the destination is mixed
1049   = hcat [ ppr_amode dest, equals,
1050                 text "(P_)(",   -- Here is the cast
1051                 ppr_amode src, pp_paren_semi ]
1052
1053 pprAssign ByteArrayRep dest src
1054   | mixedPtrLocn src
1055     -- Add in a cast iff the source is mixed
1056   = hcat [ ppr_amode dest, equals,
1057                 text "(StgByteArray)(", -- Here is the cast
1058                 ppr_amode src, pp_paren_semi ]
1059
1060 pprAssign kind other_dest src
1061   = hcat [ ppr_amode other_dest, equals,
1062                 pprAmode  src, semi ]
1063 \end{code}
1064
1065
1066 %************************************************************************
1067 %*                                                                      *
1068 \subsection[a2r-CAddrModes]{Addressing modes}
1069 %*                                                                      *
1070 %************************************************************************
1071
1072 @pprAmode@ is used to print r-values (which may need casts), whereas
1073 @ppr_amode@ is used for l-values {\em and} as a help function for
1074 @pprAmode@.
1075
1076 \begin{code}
1077 pprAmode, ppr_amode :: CAddrMode -> SDoc
1078 \end{code}
1079
1080 For reasons discussed above under assignments, @CVal@ modes need
1081 to be treated carefully.  First come special cases for floats and doubles,
1082 similar to those in @pprAssign@:
1083
1084 (NB: @PK_FLT@ and @PK_DBL@ require the {\em address} of the value in
1085 question.)
1086
1087 \begin{code}
1088 pprAmode (CVal reg_rel FloatRep)
1089   = hcat [ text "PK_FLT(", ppr_amode (CAddr reg_rel), rparen ]
1090 pprAmode (CVal reg_rel DoubleRep)
1091   = hcat [ text "PK_DBL(", ppr_amode (CAddr reg_rel), rparen ]
1092 pprAmode (CVal reg_rel Int64Rep)
1093   = hcat [ text "PK_Int64(", ppr_amode (CAddr reg_rel), rparen ]
1094 pprAmode (CVal reg_rel Word64Rep)
1095   = hcat [ text "PK_Word64(", ppr_amode (CAddr reg_rel), rparen ]
1096 \end{code}
1097
1098 Next comes the case where there is some other cast need, and the
1099 no-cast case:
1100
1101 \begin{code}
1102 pprAmode amode
1103   | mixedTypeLocn amode
1104   = parens (hcat [ pprPrimKind (getAmodeRep amode), ptext SLIT(")("),
1105                 ppr_amode amode ])
1106   | otherwise   -- No cast needed
1107   = ppr_amode amode
1108 \end{code}
1109
1110 Now the rest of the cases for ``workhorse'' @ppr_amode@:
1111
1112 \begin{code}
1113 ppr_amode (CVal reg_rel _)
1114   = case (pprRegRelative False{-no sign wanted-} reg_rel) of
1115         (pp_reg, Nothing)     -> (<>)  (char '*') pp_reg
1116         (pp_reg, Just offset) -> hcat [ pp_reg, brackets offset ]
1117
1118 ppr_amode (CAddr reg_rel)
1119   = case (pprRegRelative True{-sign wanted-} reg_rel) of
1120         (pp_reg, Nothing)     -> pp_reg
1121         (pp_reg, Just offset) -> (<>) pp_reg offset
1122
1123 ppr_amode (CReg magic_id) = pprMagicId magic_id
1124
1125 ppr_amode (CTemp uniq kind) = char '_' <> pprUnique uniq <> char '_'
1126
1127 ppr_amode (CLbl lbl kind) = pprCLabelAddr lbl
1128
1129 ppr_amode (CCharLike ch)
1130   = hcat [ptext SLIT("CHARLIKE_CLOSURE"), char '(', pprAmode ch, rparen ]
1131 ppr_amode (CIntLike int)
1132   = hcat [ptext SLIT("INTLIKE_CLOSURE"), char '(', pprAmode int, rparen ]
1133
1134 ppr_amode (CLit lit) = pprBasicLit lit
1135
1136 ppr_amode (CLitLit str _) = ptext str
1137
1138 ppr_amode (CJoinPoint _)
1139   = panic "ppr_amode: CJoinPoint"
1140
1141 ppr_amode (CMacroExpr pk macro as)
1142   = parens (pprPrimKind pk) <>
1143     parens (ptext (cExprMacroText macro) <>
1144             parens (hcat (punctuate comma (map pprAmode as))))
1145 \end{code}
1146
1147 \begin{code}
1148 cExprMacroText ENTRY_CODE               = SLIT("ENTRY_CODE")
1149 cExprMacroText ARG_TAG                  = SLIT("ARG_TAG")
1150 cExprMacroText GET_TAG                  = SLIT("GET_TAG")
1151 cExprMacroText UPD_FRAME_UPDATEE        = SLIT("UPD_FRAME_UPDATEE")
1152
1153 cStmtMacroText ARGS_CHK                 = SLIT("ARGS_CHK")
1154 cStmtMacroText ARGS_CHK_LOAD_NODE       = SLIT("ARGS_CHK_LOAD_NODE")
1155 cStmtMacroText UPD_CAF                  = SLIT("UPD_CAF")
1156 cStmtMacroText UPD_BH_UPDATABLE         = SLIT("UPD_BH_UPDATABLE")
1157 cStmtMacroText UPD_BH_SINGLE_ENTRY      = SLIT("UPD_BH_SINGLE_ENTRY")
1158 cStmtMacroText PUSH_UPD_FRAME           = SLIT("PUSH_UPD_FRAME")
1159 cStmtMacroText PUSH_SEQ_FRAME           = SLIT("PUSH_SEQ_FRAME")
1160 cStmtMacroText UPDATE_SU_FROM_UPD_FRAME = SLIT("UPDATE_SU_FROM_UPD_FRAME")
1161 cStmtMacroText SET_TAG                  = SLIT("SET_TAG")
1162 cStmtMacroText REGISTER_FOREIGN_EXPORT  = SLIT("REGISTER_FOREIGN_EXPORT")
1163 cStmtMacroText REGISTER_IMPORT          = SLIT("REGISTER_IMPORT")
1164 cStmtMacroText GRAN_FETCH               = SLIT("GRAN_FETCH")
1165 cStmtMacroText GRAN_RESCHEDULE          = SLIT("GRAN_RESCHEDULE")
1166 cStmtMacroText GRAN_FETCH_AND_RESCHEDULE= SLIT("GRAN_FETCH_AND_RESCHEDULE")
1167 cStmtMacroText THREAD_CONTEXT_SWITCH    = SLIT("THREAD_CONTEXT_SWITCH")
1168 cStmtMacroText GRAN_YIELD               = SLIT("GRAN_YIELD")
1169
1170 cCheckMacroText HP_CHK_NP               = SLIT("HP_CHK_NP")
1171 cCheckMacroText STK_CHK_NP              = SLIT("STK_CHK_NP")
1172 cCheckMacroText HP_STK_CHK_NP           = SLIT("HP_STK_CHK_NP")
1173 cCheckMacroText HP_CHK_SEQ_NP           = SLIT("HP_CHK_SEQ_NP")
1174 cCheckMacroText HP_CHK                  = SLIT("HP_CHK")
1175 cCheckMacroText STK_CHK                 = SLIT("STK_CHK")
1176 cCheckMacroText HP_STK_CHK              = SLIT("HP_STK_CHK")
1177 cCheckMacroText HP_CHK_NOREGS           = SLIT("HP_CHK_NOREGS")
1178 cCheckMacroText HP_CHK_UNPT_R1          = SLIT("HP_CHK_UNPT_R1")
1179 cCheckMacroText HP_CHK_UNBX_R1          = SLIT("HP_CHK_UNBX_R1")
1180 cCheckMacroText HP_CHK_F1               = SLIT("HP_CHK_F1")
1181 cCheckMacroText HP_CHK_D1               = SLIT("HP_CHK_D1")
1182 cCheckMacroText HP_CHK_L1               = SLIT("HP_CHK_L1")
1183 cCheckMacroText HP_CHK_UT_ALT           = SLIT("HP_CHK_UT_ALT")
1184 cCheckMacroText HP_CHK_GEN              = SLIT("HP_CHK_GEN")
1185 \end{code}
1186
1187 %************************************************************************
1188 %*                                                                      *
1189 \subsection[ppr-liveness-masks]{Liveness Masks}
1190 %*                                                                      *
1191 %************************************************************************
1192
1193 \begin{code}
1194 pp_liveness :: Liveness -> SDoc
1195 pp_liveness lv =
1196    case lv of
1197         LvLarge lbl  -> char '&' <> pprCLabel lbl
1198         LvSmall mask    -- Avoid gcc bug when printing minInt
1199            | bitmap_int == minInt -> int (bitmap_int+1) <> text "-1"
1200            | otherwise            -> int bitmap_int
1201          where
1202            bitmap_int = intBS mask
1203 \end{code}
1204
1205 %************************************************************************
1206 %*                                                                      *
1207 \subsection[a2r-MagicIds]{Magic ids}
1208 %*                                                                      *
1209 %************************************************************************
1210
1211 @pprRegRelative@ returns a pair of the @Doc@ for the register
1212 (some casting may be required), and a @Maybe Doc@ for the offset
1213 (zero offset gives a @Nothing@).
1214
1215 \begin{code}
1216 addPlusSign :: Bool -> SDoc -> SDoc
1217 addPlusSign False p = p
1218 addPlusSign True  p = (<>) (char '+') p
1219
1220 pprSignedInt :: Bool -> Int -> Maybe SDoc       -- Nothing => 0
1221 pprSignedInt sign_wanted n
1222  = if n == 0 then Nothing else
1223    if n > 0  then Just (addPlusSign sign_wanted (int n))
1224    else           Just (int n)
1225
1226 pprRegRelative :: Bool          -- True <=> Print leading plus sign (if +ve)
1227                -> RegRelative
1228                -> (SDoc, Maybe SDoc)
1229
1230 pprRegRelative sign_wanted (SpRel off)
1231   = (pprMagicId Sp, pprSignedInt sign_wanted (I# off))
1232
1233 pprRegRelative sign_wanted r@(HpRel o)
1234   = let pp_Hp    = pprMagicId Hp; off = I# o
1235     in
1236     if off == 0 then
1237         (pp_Hp, Nothing)
1238     else
1239         (pp_Hp, Just ((<>) (char '-') (int off)))
1240
1241 pprRegRelative sign_wanted (NodeRel o)
1242   = let pp_Node = pprMagicId node; off = I# o
1243     in
1244     if off == 0 then
1245         (pp_Node, Nothing)
1246     else
1247         (pp_Node, Just (addPlusSign sign_wanted (int off)))
1248
1249 pprRegRelative sign_wanted (CIndex base offset kind)
1250   = ( hcat [text "((", pprPrimKind kind, text " *)(", ppr_amode base, text "))"]
1251     , Just (hcat [if sign_wanted then char '+' else empty,
1252             text "(I_)(", ppr_amode offset, ptext SLIT(")")])
1253     )
1254 \end{code}
1255
1256 @pprMagicId@ just prints the register name.  @VanillaReg@ registers are
1257 represented by a discriminated union (@StgUnion@), so we use the @PrimRep@
1258 to select the union tag.
1259
1260 \begin{code}
1261 pprMagicId :: MagicId -> SDoc
1262
1263 pprMagicId BaseReg                  = ptext SLIT("BaseReg")
1264 pprMagicId (VanillaReg pk n)
1265                                     = hcat [ pprVanillaReg n, char '.',
1266                                                   pprUnionTag pk ]
1267 pprMagicId (FloatReg  n)            = (<>) (ptext SLIT("F")) (int IBOX(n))
1268 pprMagicId (DoubleReg n)            = (<>) (ptext SLIT("D")) (int IBOX(n))
1269 pprMagicId (LongReg _ n)            = (<>) (ptext SLIT("L")) (int IBOX(n))
1270 pprMagicId Sp                       = ptext SLIT("Sp")
1271 pprMagicId Su                       = ptext SLIT("Su")
1272 pprMagicId SpLim                    = ptext SLIT("SpLim")
1273 pprMagicId Hp                       = ptext SLIT("Hp")
1274 pprMagicId HpLim                    = ptext SLIT("HpLim")
1275 pprMagicId CurCostCentre            = ptext SLIT("CCCS")
1276 pprMagicId VoidReg                  = panic "pprMagicId:VoidReg!"
1277
1278 pprVanillaReg :: FAST_INT -> SDoc
1279 pprVanillaReg n = (<>) (char 'R') (int IBOX(n))
1280
1281 pprUnionTag :: PrimRep -> SDoc
1282
1283 pprUnionTag PtrRep              = char 'p'
1284 pprUnionTag CodePtrRep          = ptext SLIT("fp")
1285 pprUnionTag DataPtrRep          = char 'd'
1286 pprUnionTag RetRep              = char 'p'
1287 pprUnionTag CostCentreRep       = panic "pprUnionTag:CostCentre?"
1288
1289 pprUnionTag CharRep             = char 'c'
1290 pprUnionTag IntRep              = char 'i'
1291 pprUnionTag WordRep             = char 'w'
1292 pprUnionTag AddrRep             = char 'a'
1293 pprUnionTag FloatRep            = char 'f'
1294 pprUnionTag DoubleRep           = panic "pprUnionTag:Double?"
1295
1296 pprUnionTag StablePtrRep        = char 'i'
1297 pprUnionTag StableNameRep       = char 'p'
1298 pprUnionTag WeakPtrRep          = char 'p'
1299 pprUnionTag ForeignObjRep       = char 'p'
1300
1301 pprUnionTag ThreadIdRep         = char 't'
1302
1303 pprUnionTag ArrayRep            = char 'p'
1304 pprUnionTag ByteArrayRep        = char 'b'
1305
1306 pprUnionTag _                   = panic "pprUnionTag:Odd kind"
1307 \end{code}
1308
1309
1310 Find and print local and external declarations for a list of
1311 Abstract~C statements.
1312 \begin{code}
1313 pprTempAndExternDecls :: AbstractC -> (SDoc{-temps-}, SDoc{-externs-})
1314 pprTempAndExternDecls AbsCNop = (empty, empty)
1315
1316 pprTempAndExternDecls (AbsCStmts stmt1 stmt2)
1317   = initTE (ppr_decls_AbsC stmt1        `thenTE` \ (t_p1, e_p1) ->
1318             ppr_decls_AbsC stmt2        `thenTE` \ (t_p2, e_p2) ->
1319             case (catMaybes [t_p1, t_p2])        of { real_temps ->
1320             case (catMaybes [e_p1, e_p2])        of { real_exts ->
1321             returnTE (vcat real_temps, vcat real_exts) }}
1322            )
1323
1324 pprTempAndExternDecls other_stmt
1325   = initTE (ppr_decls_AbsC other_stmt `thenTE` \ (maybe_t, maybe_e) ->
1326             returnTE (
1327                 case maybe_t of
1328                   Nothing -> empty
1329                   Just pp -> pp,
1330
1331                 case maybe_e of
1332                   Nothing -> empty
1333                   Just pp -> pp )
1334            )
1335
1336 pprBasicLit :: Literal -> SDoc
1337 pprPrimKind :: PrimRep -> SDoc
1338
1339 pprBasicLit  lit = ppr lit
1340 pprPrimKind  k   = ppr k
1341 \end{code}
1342
1343
1344 %************************************************************************
1345 %*                                                                      *
1346 \subsection[a2r-monad]{Monadery}
1347 %*                                                                      *
1348 %************************************************************************
1349
1350 We need some monadery to keep track of temps and externs we have already
1351 printed.  This info must be threaded right through the Abstract~C, so
1352 it's most convenient to hide it in this monad.
1353
1354 WDP 95/02: Switched from \tr{([Unique], [CLabel])} to
1355 \tr{(UniqSet, CLabelSet)}.  Allegedly for efficiency.
1356
1357 \begin{code}
1358 type CLabelSet = FiniteMap CLabel (){-any type will do-}
1359 emptyCLabelSet = emptyFM
1360 x `elementOfCLabelSet` labs
1361   = case (lookupFM labs x) of { Just _ -> True; Nothing -> False }
1362
1363 addToCLabelSet set x = addToFM set x ()
1364
1365 type TEenv = (UniqSet Unique, CLabelSet)
1366
1367 type TeM result =  TEenv -> (TEenv, result)
1368
1369 initTE :: TeM a -> a
1370 initTE sa
1371   = case sa (emptyUniqSet, emptyCLabelSet) of { (_, result) ->
1372     result }
1373
1374 {-# INLINE thenTE #-}
1375 {-# INLINE returnTE #-}
1376
1377 thenTE :: TeM a -> (a -> TeM b) -> TeM b
1378 thenTE a b u
1379   = case a u        of { (u_1, result_of_a) ->
1380     b result_of_a u_1 }
1381
1382 mapTE :: (a -> TeM b) -> [a] -> TeM [b]
1383 mapTE f []     = returnTE []
1384 mapTE f (x:xs)
1385   = f x         `thenTE` \ r  ->
1386     mapTE f xs  `thenTE` \ rs ->
1387     returnTE (r : rs)
1388
1389 returnTE :: a -> TeM a
1390 returnTE result env = (env, result)
1391
1392 -- these next two check whether the thing is already
1393 -- recorded, and THEN THEY RECORD IT
1394 -- (subsequent calls will return False for the same uniq/label)
1395
1396 tempSeenTE :: Unique -> TeM Bool
1397 tempSeenTE uniq env@(seen_uniqs, seen_labels)
1398   = if (uniq `elementOfUniqSet` seen_uniqs)
1399     then (env, True)
1400     else ((addOneToUniqSet seen_uniqs uniq,
1401           seen_labels),
1402           False)
1403
1404 labelSeenTE :: CLabel -> TeM Bool
1405 labelSeenTE lbl env@(seen_uniqs, seen_labels)
1406   = if (lbl `elementOfCLabelSet` seen_labels)
1407     then (env, True)
1408     else ((seen_uniqs,
1409           addToCLabelSet seen_labels lbl),
1410           False)
1411 \end{code}
1412
1413 \begin{code}
1414 pprTempDecl :: Unique -> PrimRep -> SDoc
1415 pprTempDecl uniq kind
1416   = hcat [ pprPrimKind kind, space, char '_', pprUnique uniq, ptext SLIT("_;") ]
1417
1418 pprExternDecl :: Bool -> CLabel -> SDoc
1419 pprExternDecl in_srt clabel
1420   | not (needsCDecl clabel) = empty -- do not print anything for "known external" things
1421   | otherwise               =
1422         hcat [ ppLocalnessMacro (not in_srt) clabel,
1423                lparen, dyn_wrapper (pprCLabel clabel), pp_paren_semi ]
1424  where
1425   dyn_wrapper d
1426     | in_srt && labelDynamic clabel = text "DLL_IMPORT_DATA_VAR" <> parens d
1427     | otherwise                     = d
1428
1429 \end{code}
1430
1431 \begin{code}
1432 ppr_decls_AbsC :: AbstractC -> TeM (Maybe SDoc{-temps-}, Maybe SDoc{-externs-})
1433
1434 ppr_decls_AbsC AbsCNop          = returnTE (Nothing, Nothing)
1435
1436 ppr_decls_AbsC (AbsCStmts stmts_1 stmts_2)
1437   = ppr_decls_AbsC stmts_1  `thenTE` \ p1 ->
1438     ppr_decls_AbsC stmts_2  `thenTE` \ p2 ->
1439     returnTE (maybe_vcat [p1, p2])
1440
1441 ppr_decls_AbsC (CSplitMarker) = returnTE (Nothing, Nothing)
1442
1443 ppr_decls_AbsC (CAssign dest source)
1444   = ppr_decls_Amode dest    `thenTE` \ p1 ->
1445     ppr_decls_Amode source  `thenTE` \ p2 ->
1446     returnTE (maybe_vcat [p1, p2])
1447
1448 ppr_decls_AbsC (CJump target) = ppr_decls_Amode target
1449
1450 ppr_decls_AbsC (CFallThrough target) = ppr_decls_Amode target
1451
1452 ppr_decls_AbsC (CReturn target _) = ppr_decls_Amode target
1453
1454 ppr_decls_AbsC (CSwitch discrim alts deflt)
1455   = ppr_decls_Amode discrim     `thenTE` \ pdisc ->
1456     mapTE ppr_alt_stuff alts    `thenTE` \ palts  ->
1457     ppr_decls_AbsC deflt        `thenTE` \ pdeflt ->
1458     returnTE (maybe_vcat (pdisc:pdeflt:palts))
1459   where
1460     ppr_alt_stuff (_, absC) = ppr_decls_AbsC absC
1461
1462 ppr_decls_AbsC (CCodeBlock lbl absC)
1463   = ppr_decls_AbsC absC
1464
1465 ppr_decls_AbsC (CInitHdr cl_info reg_rel cost_centre)
1466         -- ToDo: strictly speaking, should chk "cost_centre" amode
1467   = labelSeenTE info_lbl     `thenTE` \  label_seen ->
1468     returnTE (Nothing,
1469               if label_seen then
1470                   Nothing
1471               else
1472                   Just (pprExternDecl False{-not in an SRT decl-} info_lbl))
1473   where
1474     info_lbl = infoTableLabelFromCI cl_info
1475
1476 ppr_decls_AbsC (COpStmt results _ args _) = ppr_decls_Amodes (results ++ args)
1477 ppr_decls_AbsC (CSimultaneous abc)          = ppr_decls_AbsC abc
1478
1479 ppr_decls_AbsC (CCheck              _ amodes code) =
1480      ppr_decls_Amodes amodes `thenTE` \p1 ->
1481      ppr_decls_AbsC code     `thenTE` \p2 ->
1482      returnTE (maybe_vcat [p1,p2])
1483
1484 ppr_decls_AbsC (CMacroStmt          _ amodes)   = ppr_decls_Amodes amodes
1485
1486 ppr_decls_AbsC (CCallProfCtrMacro   _ amodes)   = ppr_decls_Amodes [] -- *****!!!
1487   -- you get some nasty re-decls of stdio.h if you compile
1488   -- the prelude while looking inside those amodes;
1489   -- no real reason to, anyway.
1490 ppr_decls_AbsC (CCallProfCCMacro    _ amodes)   = ppr_decls_Amodes amodes
1491
1492 ppr_decls_AbsC (CStaticClosure closure_lbl closure_info cost_centre amodes)
1493         -- ToDo: strictly speaking, should chk "cost_centre" amode
1494   = ppr_decls_Amodes amodes
1495
1496 ppr_decls_AbsC (CClosureInfoAndCode cl_info slow maybe_fast _)
1497   = ppr_decls_Amodes [entry_lbl]                `thenTE` \ p1 ->
1498     ppr_decls_AbsC slow                         `thenTE` \ p2 ->
1499     (case maybe_fast of
1500         Nothing   -> returnTE (Nothing, Nothing)
1501         Just fast -> ppr_decls_AbsC fast)       `thenTE` \ p3 ->
1502     returnTE (maybe_vcat [p1, p2, p3])
1503   where
1504     entry_lbl = CLbl slow_lbl CodePtrRep
1505     slow_lbl    = case (nonemptyAbsC slow) of
1506                     Nothing -> mkErrorStdEntryLabel
1507                     Just _  -> entryLabelFromCI cl_info
1508
1509 ppr_decls_AbsC (CSRT lbl closure_lbls)
1510   = mapTE labelSeenTE closure_lbls              `thenTE` \ seen ->
1511     returnTE (Nothing,
1512               if and seen then Nothing
1513                 else Just (vcat [ pprExternDecl True{-in SRT decl-} l
1514                                 | (l,False) <- zip closure_lbls seen ]))
1515
1516 ppr_decls_AbsC (CRetDirect     _ code _ _)   = ppr_decls_AbsC code
1517 ppr_decls_AbsC (CRetVector _ amodes _ _)     = ppr_decls_Amodes amodes
1518 ppr_decls_AbsC (CModuleInitBlock _ code)     = ppr_decls_AbsC code
1519
1520 ppr_decls_AbsC (_) = returnTE (Nothing, Nothing)
1521 \end{code}
1522
1523 \begin{code}
1524 ppr_decls_Amode :: CAddrMode -> TeM (Maybe SDoc, Maybe SDoc)
1525 ppr_decls_Amode (CVal  (CIndex base offset _) _) = ppr_decls_Amodes [base,offset]
1526 ppr_decls_Amode (CAddr (CIndex base offset _))   = ppr_decls_Amodes [base,offset]
1527 ppr_decls_Amode (CVal _ _)      = returnTE (Nothing, Nothing)
1528 ppr_decls_Amode (CAddr _)       = returnTE (Nothing, Nothing)
1529 ppr_decls_Amode (CReg _)        = returnTE (Nothing, Nothing)
1530 ppr_decls_Amode (CLit _)        = returnTE (Nothing, Nothing)
1531 ppr_decls_Amode (CLitLit _ _)   = returnTE (Nothing, Nothing)
1532
1533 -- CIntLike must be a literal -- no decls
1534 ppr_decls_Amode (CIntLike int)  = returnTE (Nothing, Nothing)
1535
1536 -- CCharLike may have be arbitrary value -- may have decls
1537 ppr_decls_Amode (CCharLike char)
1538   = ppr_decls_Amode char
1539
1540 -- now, the only place where we actually print temps/externs...
1541 ppr_decls_Amode (CTemp uniq kind)
1542   = case kind of
1543       VoidRep -> returnTE (Nothing, Nothing)
1544       other ->
1545         tempSeenTE uniq `thenTE` \ temp_seen ->
1546         returnTE
1547           (if temp_seen then Nothing else Just (pprTempDecl uniq kind), Nothing)
1548
1549 ppr_decls_Amode (CLbl lbl VoidRep)
1550   = returnTE (Nothing, Nothing)
1551
1552 ppr_decls_Amode (CLbl lbl kind)
1553   = labelSeenTE lbl `thenTE` \ label_seen ->
1554     returnTE (Nothing,
1555               if label_seen then Nothing else Just (pprExternDecl False{-not in an SRT decl-} lbl))
1556
1557 ppr_decls_Amode (CMacroExpr _ _ amodes)
1558   = ppr_decls_Amodes amodes
1559
1560 ppr_decls_Amode other = returnTE (Nothing, Nothing)
1561
1562
1563 maybe_vcat :: [(Maybe SDoc, Maybe SDoc)] -> (Maybe SDoc, Maybe SDoc)
1564 maybe_vcat ps
1565   = case (unzip ps)     of { (ts, es) ->
1566     case (catMaybes ts) of { real_ts  ->
1567     case (catMaybes es) of { real_es  ->
1568     (if (null real_ts) then Nothing else Just (vcat real_ts),
1569      if (null real_es) then Nothing else Just (vcat real_es))
1570     } } }
1571 \end{code}
1572
1573 \begin{code}
1574 ppr_decls_Amodes :: [CAddrMode] -> TeM (Maybe SDoc, Maybe SDoc)
1575 ppr_decls_Amodes amodes
1576   = mapTE ppr_decls_Amode amodes `thenTE` \ ps ->
1577     returnTE ( maybe_vcat ps )
1578 \end{code}
1579
1580 Print out a C Label where you want the *address* of the label, not the
1581 object it refers to.  The distinction is important when the label may
1582 refer to a C structure (info tables and closures, for instance).
1583
1584 When just generating a declaration for the label, use pprCLabel.
1585
1586 \begin{code}
1587 pprCLabelAddr :: CLabel -> SDoc
1588 pprCLabelAddr clabel =
1589   case labelType clabel of
1590      InfoTblType -> addr_of_label
1591      ClosureType -> addr_of_label
1592      VecTblType  -> addr_of_label
1593      _           -> pp_label
1594   where
1595     addr_of_label = ptext SLIT("(P_)&") <> pp_label
1596     pp_label = pprCLabel clabel
1597
1598 \end{code}
1599
1600 -----------------------------------------------------------------------------
1601 Initialising static objects with floating-point numbers.  We can't
1602 just emit the floating point number, because C will cast it to an int
1603 by rounding it.  We want the actual bit-representation of the float.
1604
1605 This is a hack to turn the floating point numbers into ints that we
1606 can safely initialise to static locations.
1607
1608 \begin{code}
1609 big_doubles = (getPrimRepSize DoubleRep) /= 1
1610
1611 -- floatss are always 1 word
1612 floatToWord :: CAddrMode -> CAddrMode
1613 floatToWord (CLit (MachFloat r))
1614   = runST (do
1615         arr <- newFloatArray ((0::Int),0)
1616         writeFloatArray arr 0 (fromRational r)
1617         i <- readIntArray arr 0
1618         return (CLit (MachInt (toInteger i)))
1619     )
1620
1621 doubleToWords :: CAddrMode -> [CAddrMode]
1622 doubleToWords (CLit (MachDouble r))
1623   | big_doubles                         -- doubles are 2 words
1624   = runST (do
1625         arr <- newDoubleArray ((0::Int),1)
1626         writeDoubleArray arr 0 (fromRational r)
1627         i1 <- readIntArray arr 0
1628         i2 <- readIntArray arr 1
1629         return [ CLit (MachInt (toInteger i1))
1630                , CLit (MachInt (toInteger i2))
1631                ]
1632     )
1633   | otherwise                           -- doubles are 1 word
1634   = runST (do
1635         arr <- newDoubleArray ((0::Int),0)
1636         writeDoubleArray arr 0 (fromRational r)
1637         i <- readIntArray arr 0
1638         return [ CLit (MachInt (toInteger i)) ]
1639     )
1640 \end{code}