ghc/compiler/basicTypes/IdInfo.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[IdInfo]{@IdInfos@: Non-essential information about @Ids@}
   5
   6 (And a pretty good illustration of quite a few things wrong with
   7 Haskell. [WDP 94/11])
   8
   9 \begin{code}
  10 module IdInfo (
  11         IdInfo,         -- Abstract
  12
  13         vanillaIdInfo, mkIdInfo, seqIdInfo, megaSeqIdInfo,
  14
  15         -- Flavour
  16         IdFlavour(..), flavourInfo,
  17         setNoDiscardInfo, zapSpecPragInfo, copyIdInfo,
  18         ppFlavourInfo,
  19
  20         -- Arity
  21         ArityInfo(..),
  22         exactArity, atLeastArity, unknownArity, hasArity,
  23         arityInfo, setArityInfo, ppArityInfo, arityLowerBound,
  24
  25         -- Strictness
  26         StrictnessInfo(..),                             -- Non-abstract
  27         mkStrictnessInfo,
  28         noStrictnessInfo, strictnessInfo,
  29         ppStrictnessInfo, setStrictnessInfo,
  30         isBottomingStrictness, appIsBottom,
  31
  32         -- Worker
  33         WorkerInfo, workerExists,
  34         workerInfo, setWorkerInfo, ppWorkerInfo,
  35
  36         -- Unfolding
  37         unfoldingInfo, setUnfoldingInfo,
  38
  39         -- DemandInfo
  40         demandInfo, setDemandInfo,
  41
  42         -- Inline prags
  43         InlinePragInfo(..), OccInfo(..),
  44         inlinePragInfo, setInlinePragInfo, notInsideLambda,
  45
  46         -- Specialisation
  47         specInfo, setSpecInfo,
  48
  49         -- Update
  50         UpdateInfo, UpdateSpec,
  51         mkUpdateInfo, updateInfo, updateInfoMaybe, ppUpdateInfo, setUpdateInfo,
  52
  53         -- CAF info
  54         CafInfo(..), cafInfo, setCafInfo, ppCafInfo,
  55
  56         -- Constructed Product Result Info
  57         CprInfo(..), cprInfo, setCprInfo, ppCprInfo, noCprInfo,
  58
  59         -- Zapping
  60         zapLamIdInfo, zapFragileIdInfo, zapIdInfoForStg,
  61
  62         -- Lambda-bound variable info
  63         LBVarInfo(..), lbvarInfo, setLBVarInfo, noLBVarInfo
  64     ) where
  65
  66 #include "HsVersions.h"
  67
  68
  69 import {-# SOURCE #-} CoreUnfold ( Unfolding, noUnfolding, hasUnfolding, seqUnfolding )
  70 import {-# SOURCE #-} CoreSyn    ( CoreExpr, CoreRules, emptyCoreRules, isEmptyCoreRules, seqRules )
  71 import {-# SOURCE #-} Const      ( Con )
  72
  73 import Var              ( Id )
  74 import FieldLabel       ( FieldLabel )
  75 import Demand           ( Demand, isStrict, isLazy, wwLazy, pprDemands, seqDemand, seqDemands )
  76 import Type             ( UsageAnn )
  77 import Outputable
  78 import Maybe            ( isJust )
  79
  80 infixl  1 `setUpdateInfo`,
  81           `setDemandInfo`,
  82           `setStrictnessInfo`,
  83           `setSpecInfo`,
  84           `setArityInfo`,
  85           `setInlinePragInfo`,
  86           `setUnfoldingInfo`,
  87           `setCprInfo`,
  88           `setWorkerInfo`,
  89           `setCafInfo`
  90         -- infixl so you can say (id `set` a `set` b)
  91 \end{code}
  92
  93 An @IdInfo@ gives {\em optional} information about an @Id@.  If
  94 present it never lies, but it may not be present, in which case there
  95 is always a conservative assumption which can be made.
  96
  97         There is one exception: the 'flavour' is *not* optional.
  98         You must not discard it.
  99         It used to be in Var.lhs, but that seems unclean.
 100
 101 Two @Id@s may have different info even though they have the same
 102 @Unique@ (and are hence the same @Id@); for example, one might lack
 103 the properties attached to the other.
 104
 105 The @IdInfo@ gives information about the value, or definition, of the
 106 @Id@.  It does {\em not} contain information about the @Id@'s usage
 107 (except for @DemandInfo@? ToDo). (@lbvarInfo@ is also a marginal
 108 case.  KSW 1999-04).
 109
 110 \begin{code}
 111 data IdInfo
 112   = IdInfo {
 113         flavourInfo     :: IdFlavour,           -- NOT OPTIONAL
 114         arityInfo       :: ArityInfo,           -- Its arity
 115         demandInfo      :: Demand,              -- Whether or not it is definitely demanded
 116         specInfo        :: CoreRules,           -- Specialisations of this function which exist
 117         strictnessInfo  :: StrictnessInfo,      -- Strictness properties
 118         workerInfo      :: WorkerInfo,          -- Pointer to Worker Function
 119         unfoldingInfo   :: Unfolding,           -- Its unfolding
 120         updateInfo      :: UpdateInfo,          -- Which args should be updated
 121         cafInfo         :: CafInfo,
 122         cprInfo         :: CprInfo,             -- Function always constructs a product result
 123         lbvarInfo       :: LBVarInfo,           -- Info about a lambda-bound variable
 124         inlinePragInfo  :: InlinePragInfo       -- Inline pragmas
 125     }
 126
 127 seqIdInfo :: IdInfo -> ()
 128 seqIdInfo (IdInfo {}) = ()
 129
 130 megaSeqIdInfo :: IdInfo -> ()
 131 megaSeqIdInfo info
 132   = seqFlavour (flavourInfo info)       `seq`
 133     seqArity (arityInfo info)           `seq`
 134     seqDemand (demandInfo info)         `seq`
 135     seqRules (specInfo info)            `seq`
 136     seqStrictness (strictnessInfo info) `seq`
 137     seqWorker (workerInfo info)         `seq`
 138
 139 --    seqUnfolding (unfoldingInfo info) `seq`
 140 -- Omitting this improves runtimes a little, presumably because
 141 -- some unfoldings are not calculated at all
 142
 143     seqCaf (cafInfo info)               `seq`
 144     seqCpr (cprInfo info)               `seq`
 145     seqLBVar (lbvarInfo info)           `seq`
 146     seqInlinePrag (inlinePragInfo info)
 147 \end{code}
 148
 149 Setters
 150
 151 \begin{code}
 152 setWorkerInfo     info wk = wk `seq` info { workerInfo = wk }
 153 setSpecInfo       info sp = PSEQ sp (info { specInfo = sp })
 154 setInlinePragInfo info pr = pr `seq` info { inlinePragInfo = pr }
 155 setStrictnessInfo info st = st `seq` info { strictnessInfo = st }
 156         -- Try to avoid spack leaks by seq'ing
 157
 158 setUnfoldingInfo  info uf = info { unfoldingInfo = uf }
 159         -- We do *not* seq on the unfolding info, For some reason, doing so
 160         -- actually increases residency significantly.
 161
 162 setUpdateInfo     info ud = info { updateInfo = ud }
 163 setDemandInfo     info dd = info { demandInfo = dd }
 164 setArityInfo      info ar = info { arityInfo = ar  }
 165 setCafInfo        info cf = info { cafInfo = cf }
 166 setCprInfo        info cp = info { cprInfo = cp }
 167 setLBVarInfo      info lb = info { lbvarInfo = lb }
 168
 169 setNoDiscardInfo  info = case flavourInfo info of
 170                                 VanillaId -> info { flavourInfo = NoDiscardId }
 171                                 other     -> info
 172 zapSpecPragInfo   info = case flavourInfo info of
 173                                 SpecPragmaId -> info { flavourInfo = VanillaId }
 174                                 other        -> info
 175
 176 copyIdInfo :: IdInfo    -- From
 177            -> IdInfo    -- To
 178            -> IdInfo    -- To, updated with stuff from From; except flavour unchanged
 179 -- copyIdInfo is used when shorting out a top-level binding
 180 --      f_local = BIG
 181 --      f = f_local
 182 -- where f is exported.  We are going to swizzle it around to
 183 --      f = BIG
 184 --      f_local = f
 185 -- but we must be careful to combine their IdInfos right.
 186 -- The fact that things can go wrong here is a bad sign, but I can't see
 187 -- how to make it 'patently right', so copyIdInfo is derived (pretty much) by trial and error
 188 --
 189 -- Here 'from' is f_local, 'to' is f, and the result is attached to f
 190
 191 copyIdInfo from to = from { flavourInfo = flavourInfo to,
 192                             specInfo = specInfo to,
 193                             inlinePragInfo = inlinePragInfo to
 194                           }
 195         -- It's important to preserve the inline pragma on 'f'; e.g. consider
 196         --      {-# NOINLINE f #-}
 197         --      f = local
 198         --
 199         -- similarly, transformation rules may be attached to f
 200         -- and we want to preserve them.
 201         --
 202         -- On the other hand, we want the strictness info from f_local.
 203 \end{code}
 204
 205
 206 \begin{code}
 207 vanillaIdInfo :: IdInfo
 208 vanillaIdInfo = mkIdInfo VanillaId
 209
 210 mkIdInfo :: IdFlavour -> IdInfo
 211 mkIdInfo flv = IdInfo {
 212                     flavourInfo         = flv,
 213                     arityInfo           = UnknownArity,
 214                     demandInfo          = wwLazy,
 215                     specInfo            = emptyCoreRules,
 216                     workerInfo          = Nothing,
 217                     strictnessInfo      = NoStrictnessInfo,
 218                     unfoldingInfo       = noUnfolding,
 219                     updateInfo          = NoUpdateInfo,
 220                     cafInfo             = MayHaveCafRefs,
 221                     cprInfo             = NoCPRInfo,
 222                     lbvarInfo           = NoLBVarInfo,
 223                     inlinePragInfo      = NoInlinePragInfo
 224            }
 225 \end{code}
 226
 227
 228 %************************************************************************
 229 %*                                                                      *
 230 \subsection{Flavour}
 231 %*                                                                      *
 232 %************************************************************************
 233
 234 \begin{code}
 235 data IdFlavour
 236   = VanillaId                           -- Most Ids are like this
 237   | ConstantId Con                      -- The Id for a constant (data constructor or primop)
 238   | RecordSelId FieldLabel              -- The Id for a record selector
 239   | SpecPragmaId                        -- Don't discard these
 240   | NoDiscardId                         -- Don't discard these either
 241
 242 ppFlavourInfo :: IdFlavour -> SDoc
 243 ppFlavourInfo VanillaId       = empty
 244 ppFlavourInfo (ConstantId _)  = ptext SLIT("[Constr]")
 245 ppFlavourInfo (RecordSelId _) = ptext SLIT("[RecSel]")
 246 ppFlavourInfo SpecPragmaId    = ptext SLIT("[SpecPrag]")
 247 ppFlavourInfo NoDiscardId     = ptext SLIT("[NoDiscard]")
 248
 249 seqFlavour :: IdFlavour -> ()
 250 seqFlavour f = f `seq` ()
 251 \end{code}
 252
 253 The @SpecPragmaId@ exists only to make Ids that are
 254 on the *LHS* of bindings created by SPECIALISE pragmas;
 255 eg:             s = f Int d
 256 The SpecPragmaId is never itself mentioned; it
 257 exists solely so that the specialiser will find
 258 the call to f, and make specialised version of it.
 259 The SpecPragmaId binding is discarded by the specialiser
 260 when it gathers up overloaded calls.
 261 Meanwhile, it is not discarded as dead code.
 262
 263
 264 %************************************************************************
 265 %*                                                                      *
 266 \subsection[arity-IdInfo]{Arity info about an @Id@}
 267 %*                                                                      *
 268 %************************************************************************
 269
 270 For locally-defined Ids, the code generator maintains its own notion
 271 of their arities; so it should not be asking...  (but other things
 272 besides the code-generator need arity info!)
 273
 274 \begin{code}
 275 data ArityInfo
 276   = UnknownArity        -- No idea
 277
 278   | ArityExactly Int    -- Arity is exactly this.  We use this when importing a
 279                         -- function; it's already been compiled and we know its
 280                         -- arity for sure.
 281
 282   | ArityAtLeast Int    -- Arity is this or greater.  We attach this arity to
 283                         -- functions in the module being compiled.  Their arity
 284                         -- might increase later in the compilation process, if
 285                         -- an extra lambda floats up to the binding site.
 286
 287 seqArity :: ArityInfo -> ()
 288 seqArity a = arityLowerBound a `seq` ()
 289
 290 exactArity   = ArityExactly
 291 atLeastArity = ArityAtLeast
 292 unknownArity = UnknownArity
 293
 294 arityLowerBound :: ArityInfo -> Int
 295 arityLowerBound UnknownArity     = 0
 296 arityLowerBound (ArityAtLeast n) = n
 297 arityLowerBound (ArityExactly n) = n
 298
 299 hasArity :: ArityInfo -> Bool
 300 hasArity UnknownArity = False
 301 hasArity other        = True
 302
 303 ppArityInfo UnknownArity         = empty
 304 ppArityInfo (ArityExactly arity) = hsep [ptext SLIT("__A"), int arity]
 305 ppArityInfo (ArityAtLeast arity) = hsep [ptext SLIT("__AL"), int arity]
 306 \end{code}
 307
 308 %************************************************************************
 309 %*                                                                      *
 310 \subsection{Inline-pragma information}
 311 %*                                                                      *
 312 %************************************************************************
 313
 314 \begin{code}
 315 data InlinePragInfo
 316   = NoInlinePragInfo
 317
 318   | IMustNotBeINLINEd   -- User NOINLINE pragma
 319
 320   | IAmALoopBreaker     -- Used by the occurrence analyser to mark loop-breakers
 321                         -- in a group of recursive definitions
 322
 323   | ICanSafelyBeINLINEd -- Used by the occurrence analyser to mark things
 324                         -- that manifesly occur once, not inside SCCs,
 325                         -- not in constructor arguments
 326
 327         OccInfo         -- Says whether the occurrence is inside a lambda
 328                         --      If so, must only substitute WHNFs
 329
 330         Bool            -- False <=> occurs in more than one case branch
 331                         --      If so, there's a code-duplication issue
 332
 333   | IAmDead             -- Marks unused variables.  Sometimes useful for
 334                         -- lambda and case-bound variables.
 335
 336   | IMustBeINLINEd      -- Absolutely must inline; used for PrimOps and
 337                         -- constructors only.
 338
 339 seqInlinePrag :: InlinePragInfo -> ()
 340 seqInlinePrag (ICanSafelyBeINLINEd occ alts)
 341   = occ `seq` alts `seq` ()
 342 seqInlinePrag other
 343   = ()
 344
 345 instance Outputable InlinePragInfo where
 346   -- only used for debugging; never parsed.  KSW 1999-07
 347   ppr NoInlinePragInfo          = empty
 348   ppr IMustBeINLINEd            = ptext SLIT("__UU")
 349   ppr IMustNotBeINLINEd         = ptext SLIT("__Unot")
 350   ppr IAmALoopBreaker           = ptext SLIT("__Ux")
 351   ppr IAmDead                   = ptext SLIT("__Ud")
 352   ppr (ICanSafelyBeINLINEd InsideLam _) = ptext SLIT("__Ul")
 353   ppr (ICanSafelyBeINLINEd _ _) = ptext SLIT("__Us")
 354
 355 instance Show InlinePragInfo where
 356   showsPrec p prag = showsPrecSDoc p (ppr prag)
 357 \end{code}
 358
 359 \begin{code}
 360 data OccInfo
 361   = NotInsideLam
 362
 363   | InsideLam           -- Inside a non-linear lambda (that is, a lambda which
 364                         -- is sure to be instantiated only once).
 365                         -- Substituting a redex for this occurrence is
 366                         -- dangerous because it might duplicate work.
 367
 368 instance Outputable OccInfo where
 369   ppr NotInsideLam = empty
 370   ppr InsideLam    = text "l"
 371
 372
 373 notInsideLambda :: OccInfo -> Bool
 374 notInsideLambda NotInsideLam = True
 375 notInsideLambda InsideLam    = False
 376 \end{code}
 377
 378 %************************************************************************
 379 %*                                                                      *
 380 \subsection[strictness-IdInfo]{Strictness info about an @Id@}
 381 %*                                                                      *
 382 %************************************************************************
 383
 384 We specify the strictness of a function by giving information about
 385 each of the ``wrapper's'' arguments (see the description about
 386 worker/wrapper-style transformations in the PJ/Launchbury paper on
 387 unboxed types).
 388
 389 The list of @Demands@ specifies: (a)~the strictness properties of a
 390 function's arguments; and (b)~the type signature of that worker (if it
 391 exists); i.e. its calling convention.
 392
 393 Note that the existence of a worker function is now denoted by the Id's
 394 workerInfo field.
 395
 396 \begin{code}
 397 data StrictnessInfo
 398   = NoStrictnessInfo
 399
 400   | StrictnessInfo [Demand]
 401                    Bool         -- True <=> the function diverges regardless of its arguments
 402                                 -- Useful for "error" and other disguised variants thereof.
 403                                 -- BUT NB: f = \x y. error "urk"
 404                                 --         will have info  SI [SS] True
 405                                 -- but still (f) and (f 2) are not bot; only (f 3 2) is bot
 406
 407 seqStrictness :: StrictnessInfo -> ()
 408 seqStrictness (StrictnessInfo ds b) = b `seq` seqDemands ds
 409 seqStrictness other                 = ()
 410 \end{code}
 411
 412 \begin{code}
 413 mkStrictnessInfo :: ([Demand], Bool) -> StrictnessInfo
 414
 415 mkStrictnessInfo (xs, is_bot)
 416   | all isLazy xs && not is_bot = NoStrictnessInfo              -- Uninteresting
 417   | otherwise                   = StrictnessInfo xs is_bot
 418
 419 noStrictnessInfo       = NoStrictnessInfo
 420
 421 isBottomingStrictness (StrictnessInfo _ bot) = bot
 422 isBottomingStrictness NoStrictnessInfo       = False
 423
 424 -- appIsBottom returns true if an application to n args would diverge
 425 appIsBottom (StrictnessInfo ds bot)   n = bot && (n >= length ds)
 426 appIsBottom  NoStrictnessInfo         n = False
 427
 428 ppStrictnessInfo NoStrictnessInfo = empty
 429 ppStrictnessInfo (StrictnessInfo wrapper_args bot)
 430   = hsep [ptext SLIT("__S"), pprDemands wrapper_args bot]
 431 \end{code}
 432
 433 %************************************************************************
 434 %*                                                                      *
 435 \subsection[worker-IdInfo]{Worker info about an @Id@}
 436 %*                                                                      *
 437 %************************************************************************
 438
 439 If this Id has a worker then we store a reference to it. Worker
 440 functions are generated by the worker/wrapper pass.  This uses
 441 information from the strictness and CPR analyses.
 442
 443 There might not be a worker, even for a strict function, because:
 444 (a) the function might be small enough to inline, so no need
 445     for w/w split
 446 (b) the strictness info might be "SSS" or something, so no w/w split.
 447
 448 \begin{code}
 449
 450 type WorkerInfo = Maybe Id
 451
 452 {- UNUSED:
 453 mkWorkerInfo :: Id -> WorkerInfo
 454 mkWorkerInfo wk_id = Just wk_id
 455 -}
 456
 457 seqWorker :: WorkerInfo -> ()
 458 seqWorker (Just id) = id `seq` ()
 459 seqWorker Nothing   = ()
 460
 461 ppWorkerInfo Nothing      = empty
 462 ppWorkerInfo (Just wk_id) = ptext SLIT("__P") <+> ppr wk_id
 463
 464 noWorkerInfo = Nothing
 465
 466 workerExists :: Maybe Id -> Bool
 467 workerExists = isJust
 468 \end{code}
 469
 470
 471 %************************************************************************
 472 %*                                                                      *
 473 \subsection[update-IdInfo]{Update-analysis info about an @Id@}
 474 %*                                                                      *
 475 %************************************************************************
 476
 477 \begin{code}
 478 data UpdateInfo
 479   = NoUpdateInfo
 480   | SomeUpdateInfo UpdateSpec
 481   deriving (Eq, Ord)
 482       -- we need Eq/Ord to cross-chk update infos in interfaces
 483
 484 -- the form in which we pass update-analysis info between modules:
 485 type UpdateSpec = [Int]
 486 \end{code}
 487
 488 \begin{code}
 489 mkUpdateInfo = SomeUpdateInfo
 490
 491 updateInfoMaybe NoUpdateInfo        = Nothing
 492 updateInfoMaybe (SomeUpdateInfo []) = Nothing
 493 updateInfoMaybe (SomeUpdateInfo  u) = Just u
 494 \end{code}
 495
 496 Text instance so that the update annotations can be read in.
 497
 498 \begin{code}
 499 ppUpdateInfo NoUpdateInfo          = empty
 500 ppUpdateInfo (SomeUpdateInfo [])   = empty
 501 ppUpdateInfo (SomeUpdateInfo spec) = (<>) (ptext SLIT("__UA ")) (hcat (map int spec))
 502   -- was "__U "; changed to avoid conflict with unfoldings.  KSW 1999-07.
 503 \end{code}
 504
 505 %************************************************************************
 506 %*                                                                      *
 507 \subsection[CAF-IdInfo]{CAF-related information}
 508 %*                                                                      *
 509 %************************************************************************
 510
 511 This information is used to build Static Reference Tables (see
 512 simplStg/ComputeSRT.lhs).
 513
 514 \begin{code}
 515 data CafInfo
 516         = MayHaveCafRefs                -- either:
 517                                         -- (1) A function or static constructor
 518                                         --     that refers to one or more CAFs,
 519                                         -- (2) A real live CAF
 520
 521         | NoCafRefs                     -- A function or static constructor
 522                                         -- that refers to no CAFs.
 523
 524 -- LATER: not sure how easy this is...
 525 --      | OneCafRef Id
 526
 527
 528 seqCaf c = c `seq` ()
 529
 530 ppCafInfo NoCafRefs = ptext SLIT("__C")
 531 ppCafInfo MayHaveCafRefs = empty
 532 \end{code}
 533
 534
 535 %************************************************************************
 536 %*                                                                      *
 537 \subsection[CAF-IdInfo]{CAF-related information}
 538 %*                                                                      *
 539 %************************************************************************
 540
 541 zapFragileIdInfo is used when cloning binders, mainly in the
 542 simplifier.  We must forget about used-once information because that
 543 isn't necessarily correct in the transformed program.
 544 Also forget specialisations and unfoldings because they would need
 545 substitution to be correct.  (They get pinned back on separately.)
 546
 547 \begin{code}
 548 zapFragileIdInfo :: IdInfo -> Maybe IdInfo
 549 zapFragileIdInfo info@(IdInfo {inlinePragInfo   = inline_prag,
 550                                workerInfo       = wrkr,
 551                                specInfo         = rules,
 552                                unfoldingInfo    = unfolding})
 553   |  not is_fragile_inline_prag
 554         -- We must forget about whether it was marked safe-to-inline,
 555         -- because that isn't necessarily true in the simplified expression.
 556         -- This is important because expressions may  be re-simplified
 557
 558   && isEmptyCoreRules rules
 559         -- Specialisations would need substituting.  They get pinned
 560         -- back on separately.
 561
 562   && not (workerExists wrkr)
 563
 564   && not (hasUnfolding unfolding)
 565         -- This is very important; occasionally a let-bound binder is used
 566         -- as a binder in some lambda, in which case its unfolding is utterly
 567         -- bogus.  Also the unfolding uses old binders so if we left it we'd
 568         -- have to substitute it. Much better simply to give the Id a new
 569         -- unfolding each time, which is what the simplifier does.
 570   = Nothing
 571
 572   | otherwise
 573   = Just (info {inlinePragInfo  = safe_inline_prag,
 574                 workerInfo      = noWorkerInfo,
 575                 specInfo        = emptyCoreRules,
 576                 unfoldingInfo   = noUnfolding})
 577
 578   where
 579     is_fragile_inline_prag = case inline_prag of
 580                                 ICanSafelyBeINLINEd _ _ -> True
 581
 582 -- We used to say the dead-ness was fragile, but I don't
 583 -- see why it is.  Furthermore, deadness is a pain to lose;
 584 -- see Simplify.mkDupableCont (Select ...)
 585 --                              IAmDead                 -> True
 586
 587                                 other                   -> False
 588
 589         -- Be careful not to destroy real 'pragma' info
 590     safe_inline_prag | is_fragile_inline_prag = NoInlinePragInfo
 591                      | otherwise              = inline_prag
 592 \end{code}
 593
 594
 595 @zapLamIdInfo@ is used for lambda binders that turn out to to be
 596 part of an unsaturated lambda
 597
 598 \begin{code}
 599 zapLamIdInfo :: IdInfo -> Maybe IdInfo
 600 zapLamIdInfo info@(IdInfo {inlinePragInfo = inline_prag, demandInfo = demand})
 601   | is_safe_inline_prag && not (isStrict demand)
 602   = Nothing
 603   | otherwise
 604   = Just (info {inlinePragInfo = safe_inline_prag,
 605                 demandInfo = wwLazy})
 606   where
 607         -- The "unsafe" prags are the ones that say I'm not in a lambda
 608         -- because that might not be true for an unsaturated lambda
 609     is_safe_inline_prag = case inline_prag of
 610                                 ICanSafelyBeINLINEd NotInsideLam nalts -> False
 611                                 other                                  -> True
 612
 613     safe_inline_prag    = case inline_prag of
 614                                 ICanSafelyBeINLINEd _ nalts
 615                                       -> ICanSafelyBeINLINEd InsideLam nalts
 616                                 other -> inline_prag
 617 \end{code}
 618
 619 \begin{code}
 620 zapIdInfoForStg :: IdInfo -> IdInfo
 621         -- Return only the info needed for STG stuff
 622         -- Namely, nothing, I think
 623 zapIdInfoForStg info = vanillaIdInfo
 624 \end{code}
 625
 626
 627 %************************************************************************
 628 %*                                                                      *
 629 \subsection[cpr-IdInfo]{Constructed Product Result info about an @Id@}
 630 %*                                                                      *
 631 %************************************************************************
 632
 633 If the @Id@ is a function then it may have CPR info. A CPR analysis
 634 phase detects whether:
 635
 636 \begin{enumerate}
 637 \item
 638 The function's return value has a product type, i.e. an algebraic  type
 639 with a single constructor. Examples of such types are tuples and boxed
 640 primitive values.
 641 \item
 642 The function always 'constructs' the value that it is returning.  It
 643 must do this on every path through,  and it's OK if it calls another
 644 function which constructs the result.
 645 \end{enumerate}
 646
 647 If this is the case then we store a template which tells us the
 648 function has the CPR property and which components of the result are
 649 also CPRs.
 650
 651 \begin{code}
 652 data CprInfo
 653   = NoCPRInfo
 654
 655   | CPRInfo [CprInfo]
 656
 657 -- e.g. const 5 == CPRInfo [NoCPRInfo]
 658 --              == __M(-)
 659 --      \x -> (5,
 660 --              (x,
 661 --               5,
 662 --               x)
 663 --            )
 664 --            CPRInfo [CPRInfo [NoCPRInfo],
 665 --                     CPRInfo [NoCprInfo,
 666 --                              CPRInfo [NoCPRInfo],
 667 --                              NoCPRInfo]
 668 --                    ]
 669 --            __M((-)(-(-)-)-)
 670 \end{code}
 671
 672 \begin{code}
 673 seqCpr :: CprInfo -> ()
 674 seqCpr (CPRInfo cs) = seqCprs cs
 675 seqCpr NoCPRInfo    = ()
 676
 677 seqCprs [] = ()
 678 seqCprs (c:cs) = seqCpr c `seq` seqCprs cs
 679
 680
 681 noCprInfo       = NoCPRInfo
 682
 683 ppCprInfo NoCPRInfo = empty
 684 ppCprInfo c@(CPRInfo _)
 685   = hsep [ptext SLIT("__M"), ppCprInfo' c]
 686     where
 687     ppCprInfo' NoCPRInfo      = char '-'
 688     ppCprInfo' (CPRInfo args) = parens (hcat (map ppCprInfo' args))
 689
 690 instance Outputable CprInfo where
 691     ppr = ppCprInfo
 692
 693 instance Show CprInfo where
 694     showsPrec p c = showsPrecSDoc p (ppr c)
 695 \end{code}
 696
 697
 698 %************************************************************************
 699 %*                                                                      *
 700 \subsection[lbvar-IdInfo]{Lambda-bound var info about an @Id@}
 701 %*                                                                      *
 702 %************************************************************************
 703
 704 If the @Id@ is a lambda-bound variable then it may have lambda-bound
 705 var info.  The usage analysis (UsageSP) detects whether the lambda
 706 binding this var is a ``one-shot'' lambda; that is, whether it is
 707 applied at most once.
 708
 709 This information may be useful in optimisation, as computations may
 710 safely be floated inside such a lambda without risk of duplicating
 711 work.
 712
 713 \begin{code}
 714 data LBVarInfo
 715   = NoLBVarInfo
 716
 717   | IsOneShotLambda             -- The lambda that binds this Id is applied
 718                                 --   at most once
 719                                 -- HACK ALERT! placing this info here is a short-term hack,
 720                                 --   but it minimises changes to the rest of the compiler.
 721                                 --   Hack agreed by SLPJ/KSW 1999-04.
 722
 723 seqLBVar l = l `seq` ()
 724 \end{code}
 725
 726 \begin{code}
 727 noLBVarInfo = NoLBVarInfo
 728
 729 -- not safe to print or parse LBVarInfo because it is not really a
 730 -- property of the definition, but a property of the context.
 731 pprLBVarInfo NoLBVarInfo     = empty
 732 pprLBVarInfo IsOneShotLambda = getPprStyle $ \ sty ->
 733                                if ifaceStyle sty then empty
 734                                                  else ptext SLIT("OneShot")
 735
 736 instance Outputable LBVarInfo where
 737     ppr = pprLBVarInfo
 738
 739 instance Show LBVarInfo where
 740     showsPrec p c = showsPrecSDoc p (ppr c)
 741 \end{code}