ghc/compiler/basicTypes/Module.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[Module]{The @Module@ module.}
   5
   6 Representing modules and their flavours.
   7
   8
   9 Notes on DLLs
  10 ~~~~~~~~~~~~~
  11 When compiling module A, which imports module B, we need to
  12 know whether B will be in the same DLL as A.
  13         If it's in the same DLL, we refer to B_f_closure
  14         If it isn't, we refer to _imp__B_f_closure
  15 When compiling A, we record in B's Module value whether it's
  16 in a different DLL, by setting the DLL flag.
  17
  18
  19
  20
  21 \begin{code}
  22 module Module
  23     (
  24       Module,                   -- Abstract, instance of Eq, Ord, Outputable
  25
  26     , PackageName               -- = FastString; instance of Outputable, Uniquable
  27     , modulePackage             -- :: Module -> PackageName
  28     , preludePackage            -- :: PackageName       name of Standard Prelude package
  29
  30     , ModuleName
  31     , pprModuleName             -- :: ModuleName -> SDoc
  32     , printModulePrefix
  33
  34     , moduleName                -- :: Module -> ModuleName
  35     , moduleNameString          -- :: ModuleName -> EncodedString
  36     , moduleNameUserString      -- :: ModuleName -> UserString
  37     , moduleNameFS              -- :: ModuleName -> EncodedFS
  38
  39     , moduleString              -- :: Module -> EncodedString
  40     , moduleUserString          -- :: Module -> UserString
  41
  42     , mkVanillaModule           -- :: ModuleName -> Module
  43     , isVanillaModule           -- :: Module -> Bool
  44     , mkPrelModule              -- :: UserString -> Module
  45     , isPrelModule              -- :: Module -> Bool
  46     , mkModule                  -- :: ModuleName -> PackageName -> Module
  47     , mkHomeModule              -- :: ModuleName -> Module
  48     , isHomeModule              -- :: Module -> Bool
  49
  50     , mkModuleName              -- :: UserString -> ModuleName
  51     , mkModuleNameFS            -- :: UserFS    -> ModuleName
  52     , mkSysModuleNameFS         -- :: EncodedFS -> ModuleName
  53
  54     , pprModule,
  55
  56         -- Where to find a .hi file
  57     , WhereFrom(..)
  58
  59     , ModuleEnv,
  60     , elemModuleEnv, extendModuleEnv, extendModuleEnvList, plusModuleEnv_C
  61     , delModuleEnvList, delModuleEnv, plusModuleEnv, lookupModuleEnv
  62     , lookupWithDefaultModuleEnv, mapModuleEnv, mkModuleEnv, emptyModuleEnv
  63     , moduleEnvElts, unitModuleEnv, isEmptyModuleEnv, foldModuleEnv
  64     , lookupModuleEnvByName, extendModuleEnv_C
  65
  66     , ModuleSet, emptyModuleSet, mkModuleSet, moduleSetElts, extendModuleSet, elemModuleSet
  67
  68     ) where
  69
  70 #include "HsVersions.h"
  71 import OccName
  72 import Outputable
  73 import CmdLineOpts      ( opt_InPackage )
  74 import FastString       ( FastString )
  75 import Unique           ( Uniquable(..) )
  76 import UniqFM
  77 import UniqSet
  78 \end{code}
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83 \subsection{Interface file flavour}
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 A further twist to the tale is the support for dynamically linked
  88 libraries under Win32. Here, dealing with the use of global variables
  89 that's residing in a DLL requires special handling at the point of use
  90 (there's an extra level of indirection, i.e., (**v) to get at v's
  91 value, rather than just (*v) .) When slurping in an interface file we
  92 then record whether it's coming from a .hi corresponding to a module
  93 that's packaged up in a DLL or not, so that we later can emit the
  94 appropriate code.
  95
  96 The logic for how an interface file is marked as corresponding to a
  97 module that's hiding in a DLL is explained elsewhere (ToDo: give
  98 renamer href here.)
  99
 100 \begin{code}
 101 data Module = Module ModuleName PackageInfo
 102
 103 data PackageInfo
 104   = ThisPackage                         -- A module from the same package
 105                                         -- as the one being compiled
 106   | AnotherPackage PackageName          -- A module from a different package
 107
 108   | DunnoYet    -- This is used when we don't yet know
 109                 -- Main case: we've come across Foo.x in an interface file
 110                 -- but we havn't yet opened Foo.hi.  We need a Name for Foo.x
 111                 -- Later on (in RnEnv.newTopBinder) we'll update the cache
 112                 -- to have the right PackageName
 113
 114 type PackageName = FastString           -- No encoding at all
 115
 116 preludePackage :: PackageName
 117 preludePackage = SLIT("std")
 118
 119 packageInfoPackage :: PackageInfo -> PackageName
 120 packageInfoPackage ThisPackage        = SLIT("<THIS>")
 121 packageInfoPackage DunnoYet           = SLIT("<?>")
 122 packageInfoPackage (AnotherPackage p) = p
 123
 124 instance Outputable PackageInfo where
 125         -- Just used in debug prints of lex tokens and in debug modde
 126    ppr pkg_info = ppr (packageInfoPackage pkg_info)
 127 \end{code}
 128
 129
 130 %************************************************************************
 131 %*                                                                      *
 132 \subsection{Where from}
 133 %*                                                                      *
 134 %************************************************************************
 135
 136 The @WhereFrom@ type controls where the renamer looks for an interface file
 137
 138 \begin{code}
 139 data WhereFrom = ImportByUser           -- Ordinary user import: look for M.hi
 140                | ImportByUserSource     -- User {- SOURCE -}: look for M.hi-boot
 141                | ImportBySystem         -- Non user import.  Look for M.hi if M is in
 142                                         -- the module this module depends on, or is a system-ish module;
 143                                         -- M.hi-boot otherwise
 144
 145 instance Outputable WhereFrom where
 146   ppr ImportByUser       = empty
 147   ppr ImportByUserSource = ptext SLIT("{- SOURCE -}")
 148   ppr ImportBySystem     = ptext SLIT("{- SYSTEM IMPORT -}")
 149 \end{code}
 150
 151
 152 %************************************************************************
 153 %*                                                                      *
 154 \subsection{The name of a module}
 155 %*                                                                      *
 156 %************************************************************************
 157
 158 \begin{code}
 159 newtype ModuleName = ModuleName EncodedFS
 160         -- Haskell module names can include the quote character ',
 161         -- so the module names have the z-encoding applied to them
 162
 163 instance Uniquable ModuleName where
 164   getUnique (ModuleName nm) = getUnique nm
 165
 166 instance Eq ModuleName where
 167   nm1 == nm2 = getUnique nm1 == getUnique nm2
 168
 169 -- Warning: gives an ordering relation based on the uniques of the
 170 -- FastStrings which are the (encoded) module names.  This is _not_
 171 -- a lexicographical ordering.
 172 instance Ord ModuleName where
 173   nm1 `compare` nm2 = getUnique nm1 `compare` getUnique nm2
 174
 175 instance Outputable ModuleName where
 176   ppr = pprModuleName
 177
 178
 179 pprModuleName :: ModuleName -> SDoc
 180 pprModuleName (ModuleName nm) = pprEncodedFS nm
 181
 182 moduleNameFS :: ModuleName -> EncodedFS
 183 moduleNameFS (ModuleName mod) = mod
 184
 185 moduleNameString :: ModuleName -> EncodedString
 186 moduleNameString (ModuleName mod) = _UNPK_ mod
 187
 188 moduleNameUserString :: ModuleName -> UserString
 189 moduleNameUserString (ModuleName mod) = decode (_UNPK_ mod)
 190
 191 -- used to be called mkSrcModule
 192 mkModuleName :: UserString -> ModuleName
 193 mkModuleName s = ModuleName (_PK_ (encode s))
 194
 195 -- used to be called mkSrcModuleFS
 196 mkModuleNameFS :: UserFS -> ModuleName
 197 mkModuleNameFS s = ModuleName (encodeFS s)
 198
 199 -- used to be called mkSysModuleFS
 200 mkSysModuleNameFS :: EncodedFS -> ModuleName
 201 mkSysModuleNameFS s = ModuleName s
 202 \end{code}
 203
 204 \begin{code}
 205 instance Outputable Module where
 206   ppr = pprModule
 207
 208 instance Uniquable Module where
 209   getUnique (Module nm _) = getUnique nm
 210
 211 -- Same if they have the same name.
 212 instance Eq Module where
 213   m1 == m2 = getUnique m1 == getUnique m2
 214
 215 -- Warning: gives an ordering relation based on the uniques of the
 216 -- FastStrings which are the (encoded) module names.  This is _not_
 217 -- a lexicographical ordering.
 218 instance Ord Module where
 219   m1 `compare` m2 = getUnique m1 `compare` getUnique m2
 220 \end{code}
 221
 222
 223 \begin{code}
 224 pprModule :: Module -> SDoc
 225 pprModule (Module mod p) = getPprStyle $ \ sty ->
 226                            if debugStyle sty then
 227                                 -- Print the package too
 228                                 ppr p <> dot <> pprModuleName mod
 229                            else
 230                                 pprModuleName mod
 231 \end{code}
 232
 233
 234 \begin{code}
 235 mkModule :: ModuleName  -- Name of the module
 236          -> PackageName
 237          -> Module
 238 mkModule mod_nm pack_name
 239   = Module mod_nm pack_info
 240   where
 241     pack_info | pack_name == opt_InPackage = ThisPackage
 242               | otherwise                  = AnotherPackage pack_name
 243
 244 mkHomeModule :: ModuleName -> Module
 245 mkHomeModule mod_nm = Module mod_nm ThisPackage
 246
 247 isHomeModule :: Module -> Bool
 248 isHomeModule (Module nm ThisPackage) = True
 249 isHomeModule _                       = False
 250
 251 -- Used temporarily when we first come across Foo.x in an interface
 252 -- file, but before we've opened Foo.hi.
 253 -- (Until we've opened Foo.hi we don't know what the Package is.)
 254 mkVanillaModule :: ModuleName -> Module
 255 mkVanillaModule name = Module name DunnoYet
 256
 257 isVanillaModule :: Module -> Bool
 258 isVanillaModule (Module nm DunnoYet) = True
 259 isVanillaModule _                       = False
 260
 261 mkPrelModule :: ModuleName -> Module
 262 mkPrelModule name = mkModule name preludePackage
 263
 264 isPrelModule :: Module -> Bool
 265 isPrelModule (Module nm (AnotherPackage p)) | p == preludePackage = True
 266 isPrelModule _                       = False
 267
 268 moduleString :: Module -> EncodedString
 269 moduleString (Module (ModuleName fs) _) = _UNPK_ fs
 270
 271 moduleName :: Module -> ModuleName
 272 moduleName (Module mod pkg_info) = mod
 273
 274 modulePackage :: Module -> PackageName
 275 modulePackage (Module mod pkg_info) = packageInfoPackage pkg_info
 276
 277 moduleUserString :: Module -> UserString
 278 moduleUserString (Module mod _) = moduleNameUserString mod
 279
 280 printModulePrefix :: Module -> Bool
 281   -- When printing, say M.x
 282 printModulePrefix (Module nm ThisPackage) = False
 283 printModulePrefix _                       = True
 284 \end{code}
 285
 286
 287 %************************************************************************
 288 %*                                                                      *
 289 \subsection{@ModuleEnv@s}
 290 %*                                                                      *
 291 %************************************************************************
 292
 293 \begin{code}
 294 type ModuleEnv elt = UniqFM elt
 295
 296 emptyModuleEnv       :: ModuleEnv a
 297 mkModuleEnv          :: [(Module, a)] -> ModuleEnv a
 298 unitModuleEnv        :: Module -> a -> ModuleEnv a
 299 extendModuleEnv      :: ModuleEnv a -> Module -> a -> ModuleEnv a
 300 extendModuleEnv_C    :: (a->a->a) -> ModuleEnv a -> Module -> a -> ModuleEnv a
 301 plusModuleEnv        :: ModuleEnv a -> ModuleEnv a -> ModuleEnv a
 302 extendModuleEnvList  :: ModuleEnv a -> [(Module, a)] -> ModuleEnv a
 303
 304 delModuleEnvList     :: ModuleEnv a -> [Module] -> ModuleEnv a
 305 delModuleEnv         :: ModuleEnv a -> Module -> ModuleEnv a
 306 plusModuleEnv_C      :: (a -> a -> a) -> ModuleEnv a -> ModuleEnv a -> ModuleEnv a
 307 mapModuleEnv         :: (a -> b) -> ModuleEnv a -> ModuleEnv b
 308 moduleEnvElts        :: ModuleEnv a -> [a]
 309
 310 isEmptyModuleEnv     :: ModuleEnv a -> Bool
 311 lookupModuleEnv      :: ModuleEnv a -> Module     -> Maybe a
 312 lookupModuleEnvByName:: ModuleEnv a -> ModuleName -> Maybe a
 313 lookupWithDefaultModuleEnv :: ModuleEnv a -> a -> Module -> a
 314 elemModuleEnv        :: Module -> ModuleEnv a -> Bool
 315 foldModuleEnv        :: (a -> b -> b) -> b -> ModuleEnv a -> b
 316
 317 elemModuleEnv       = elemUFM
 318 extendModuleEnv     = addToUFM
 319 extendModuleEnv_C   = addToUFM_C
 320 extendModuleEnvList = addListToUFM
 321 plusModuleEnv_C     = plusUFM_C
 322 delModuleEnvList    = delListFromUFM
 323 delModuleEnv        = delFromUFM
 324 plusModuleEnv       = plusUFM
 325 lookupModuleEnv     = lookupUFM
 326 lookupModuleEnvByName = lookupUFM
 327 lookupWithDefaultModuleEnv = lookupWithDefaultUFM
 328 mapModuleEnv        = mapUFM
 329 mkModuleEnv         = listToUFM
 330 emptyModuleEnv      = emptyUFM
 331 moduleEnvElts       = eltsUFM
 332 unitModuleEnv       = unitUFM
 333 isEmptyModuleEnv    = isNullUFM
 334 foldModuleEnv       = foldUFM
 335 \end{code}
 336
 337 \begin{code}
 338
 339 type ModuleSet = UniqSet Module
 340 mkModuleSet     :: [Module] -> ModuleSet
 341 extendModuleSet :: ModuleSet -> Module -> ModuleSet
 342 emptyModuleSet  :: ModuleSet
 343 moduleSetElts   :: ModuleSet -> [Module]
 344 elemModuleSet   :: Module -> ModuleSet -> Bool
 345
 346 emptyModuleSet  = emptyUniqSet
 347 mkModuleSet     = mkUniqSet
 348 extendModuleSet = addOneToUniqSet
 349 moduleSetElts   = uniqSetToList
 350 elemModuleSet   = elementOfUniqSet
 351 \end{code}