ghc/compiler/cmm/CmmParse.y

   1 -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2004
   4 --
   5 -- Parser for concrete Cmm.
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 {
  10 module CmmParse ( parseCmmFile ) where
  11
  12 import CgMonad
  13 import CgHeapery
  14 import CgUtils
  15 import CgProf
  16 import CgTicky
  17 import CgInfoTbls
  18 import CgForeignCall
  19 import CgTailCall       ( pushUnboxedTuple )
  20 import CgStackery       ( emitPushUpdateFrame )
  21 import ClosureInfo      ( C_SRT(..) )
  22 import CgCallConv       ( smallLiveness )
  23 import CgClosure        ( emitBlackHoleCode )
  24 import CostCentre       ( dontCareCCS )
  25
  26 import Cmm
  27 import PprCmm
  28 import CmmUtils         ( mkIntCLit )
  29 import CmmLex
  30 import CLabel
  31 import MachOp
  32 import SMRep            ( fixedHdrSize, CgRep(..) )
  33 import Lexer
  34
  35 import ForeignCall      ( CCallConv(..) )
  36 import Literal          ( mkMachInt )
  37 import Unique
  38 import UniqFM
  39 import SrcLoc
  40 import DynFlags         ( DynFlags, DynFlag(..) )
  41 import Packages         ( HomeModules )
  42 import StaticFlags      ( opt_SccProfilingOn )
  43 import ErrUtils         ( printError, dumpIfSet_dyn, showPass )
  44 import StringBuffer     ( hGetStringBuffer )
  45 import FastString
  46 import Panic            ( panic )
  47 import Constants        ( wORD_SIZE )
  48 import Outputable
  49
  50 import Monad            ( when )
  51
  52 #include "HsVersions.h"
  53 }
  54
  55 %token
  56         ':'     { L _ (CmmT_SpecChar ':') }
  57         ';'     { L _ (CmmT_SpecChar ';') }
  58         '{'     { L _ (CmmT_SpecChar '{') }
  59         '}'     { L _ (CmmT_SpecChar '}') }
  60         '['     { L _ (CmmT_SpecChar '[') }
  61         ']'     { L _ (CmmT_SpecChar ']') }
  62         '('     { L _ (CmmT_SpecChar '(') }
  63         ')'     { L _ (CmmT_SpecChar ')') }
  64         '='     { L _ (CmmT_SpecChar '=') }
  65         '`'     { L _ (CmmT_SpecChar '`') }
  66         '~'     { L _ (CmmT_SpecChar '~') }
  67         '/'     { L _ (CmmT_SpecChar '/') }
  68         '*'     { L _ (CmmT_SpecChar '*') }
  69         '%'     { L _ (CmmT_SpecChar '%') }
  70         '-'     { L _ (CmmT_SpecChar '-') }
  71         '+'     { L _ (CmmT_SpecChar '+') }
  72         '&'     { L _ (CmmT_SpecChar '&') }
  73         '^'     { L _ (CmmT_SpecChar '^') }
  74         '|'     { L _ (CmmT_SpecChar '|') }
  75         '>'     { L _ (CmmT_SpecChar '>') }
  76         '<'     { L _ (CmmT_SpecChar '<') }
  77         ','     { L _ (CmmT_SpecChar ',') }
  78         '!'     { L _ (CmmT_SpecChar '!') }
  79
  80         '..'    { L _ (CmmT_DotDot) }
  81         '::'    { L _ (CmmT_DoubleColon) }
  82         '>>'    { L _ (CmmT_Shr) }
  83         '<<'    { L _ (CmmT_Shl) }
  84         '>='    { L _ (CmmT_Ge) }
  85         '<='    { L _ (CmmT_Le) }
  86         '=='    { L _ (CmmT_Eq) }
  87         '!='    { L _ (CmmT_Ne) }
  88         '&&'    { L _ (CmmT_BoolAnd) }
  89         '||'    { L _ (CmmT_BoolOr) }
  90
  91         'CLOSURE'       { L _ (CmmT_CLOSURE) }
  92         'INFO_TABLE'    { L _ (CmmT_INFO_TABLE) }
  93         'INFO_TABLE_RET'{ L _ (CmmT_INFO_TABLE_RET) }
  94         'INFO_TABLE_FUN'{ L _ (CmmT_INFO_TABLE_FUN) }
  95         'INFO_TABLE_CONSTR'{ L _ (CmmT_INFO_TABLE_CONSTR) }
  96         'INFO_TABLE_SELECTOR'{ L _ (CmmT_INFO_TABLE_SELECTOR) }
  97         'else'          { L _ (CmmT_else) }
  98         'export'        { L _ (CmmT_export) }
  99         'section'       { L _ (CmmT_section) }
 100         'align'         { L _ (CmmT_align) }
 101         'goto'          { L _ (CmmT_goto) }
 102         'if'            { L _ (CmmT_if) }
 103         'jump'          { L _ (CmmT_jump) }
 104         'foreign'       { L _ (CmmT_foreign) }
 105         'import'        { L _ (CmmT_import) }
 106         'switch'        { L _ (CmmT_switch) }
 107         'case'          { L _ (CmmT_case) }
 108         'default'       { L _ (CmmT_default) }
 109         'bits8'         { L _ (CmmT_bits8) }
 110         'bits16'        { L _ (CmmT_bits16) }
 111         'bits32'        { L _ (CmmT_bits32) }
 112         'bits64'        { L _ (CmmT_bits64) }
 113         'float32'       { L _ (CmmT_float32) }
 114         'float64'       { L _ (CmmT_float64) }
 115
 116         GLOBALREG       { L _ (CmmT_GlobalReg   $$) }
 117         NAME            { L _ (CmmT_Name        $$) }
 118         STRING          { L _ (CmmT_String      $$) }
 119         INT             { L _ (CmmT_Int         $$) }
 120         FLOAT           { L _ (CmmT_Float       $$) }
 121
 122 %monad { P } { >>= } { return }
 123 %lexer { cmmlex } { L _ CmmT_EOF }
 124 %name cmmParse cmm
 125 %tokentype { Located CmmToken }
 126
 127 -- C-- operator precedences, taken from the C-- spec
 128 %right '||'     -- non-std extension, called %disjoin in C--
 129 %right '&&'     -- non-std extension, called %conjoin in C--
 130 %right '!'
 131 %nonassoc '>=' '>' '<=' '<' '!=' '=='
 132 %left '|'
 133 %left '^'
 134 %left '&'
 135 %left '>>' '<<'
 136 %left '-' '+'
 137 %left '/' '*' '%'
 138 %right '~'
 139
 140 %%
 141
 142 cmm     :: { ExtCode }
 143         : {- empty -}                   { return () }
 144         | cmmtop cmm                    { do $1; $2 }
 145
 146 cmmtop  :: { ExtCode }
 147         : cmmproc                       { $1 }
 148         | cmmdata                       { $1 }
 149         | decl                          { $1 }
 150         | 'CLOSURE' '(' NAME ',' NAME lits ')' ';'
 151                 { do lits <- sequence $6;
 152                      staticClosure $3 $5 (map getLit lits) }
 153
 154 -- The only static closures in the RTS are dummy closures like
 155 -- stg_END_TSO_QUEUE_closure and stg_dummy_ret.  We don't need
 156 -- to provide the full generality of static closures here.
 157 -- In particular:
 158 --      * CCS can always be CCS_DONT_CARE
 159 --      * closure is always extern
 160 --      * payload is always empty
 161 --      * we can derive closure and info table labels from a single NAME
 162
 163 cmmdata :: { ExtCode }
 164         : 'section' STRING '{' statics '}'
 165                 { do ss <- sequence $4;
 166                      code (emitData (section $2) (concat ss)) }
 167
 168 statics :: { [ExtFCode [CmmStatic]] }
 169         : {- empty -}                   { [] }
 170         | static statics                { $1 : $2 }
 171
 172 -- Strings aren't used much in the RTS HC code, so it doesn't seem
 173 -- worth allowing inline strings.  C-- doesn't allow them anyway.
 174 static  :: { ExtFCode [CmmStatic] }
 175         : NAME ':'      { return [CmmDataLabel (mkRtsDataLabelFS $1)] }
 176         | type expr ';' { do e <- $2;
 177                              return [CmmStaticLit (getLit e)] }
 178         | type ';'                      { return [CmmUninitialised
 179                                                         (machRepByteWidth $1)] }
 180         | 'bits8' '[' ']' STRING ';'    { return [CmmString $4] }
 181         | 'bits8' '[' INT ']' ';'       { return [CmmUninitialised
 182                                                         (fromIntegral $3)] }
 183         | typenot8 '[' INT ']' ';'      { return [CmmUninitialised
 184                                                 (machRepByteWidth $1 *
 185                                                         fromIntegral $3)] }
 186         | 'align' INT ';'               { return [CmmAlign (fromIntegral $2)] }
 187         | 'CLOSURE' '(' NAME lits ')'
 188                 { do lits <- sequence $4;
 189                      return $ map CmmStaticLit $
 190                        mkStaticClosure (mkRtsInfoLabelFS $3)
 191                          dontCareCCS (map getLit lits) [] [] [] }
 192         -- arrays of closures required for the CHARLIKE & INTLIKE arrays
 193
 194 lits    :: { [ExtFCode CmmExpr] }
 195         : {- empty -}           { [] }
 196         | ',' expr lits         { $2 : $3 }
 197
 198 cmmproc :: { ExtCode }
 199         : info '{' body '}'
 200                 { do  (info_lbl, info1, info2) <- $1;
 201                       stmts <- getCgStmtsEC (loopDecls $3)
 202                       blks <- code (cgStmtsToBlocks stmts)
 203                       code (emitInfoTableAndCode info_lbl info1 info2 [] blks) }
 204
 205         | info ';'
 206                 { do (info_lbl, info1, info2) <- $1;
 207                      code (emitInfoTableAndCode info_lbl info1 info2 [] []) }
 208
 209         | NAME '{' body '}'
 210                 { do stmts <- getCgStmtsEC (loopDecls $3);
 211                      blks <- code (cgStmtsToBlocks stmts)
 212                      code (emitProc [] (mkRtsCodeLabelFS $1) [] blks) }
 213
 214 info    :: { ExtFCode (CLabel, [CmmLit],[CmmLit]) }
 215         : 'INFO_TABLE' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 216                 -- ptrs, nptrs, closure type, description, type
 217                 { stdInfo $3 $5 $7 0 $9 $11 $13 }
 218
 219         | 'INFO_TABLE_FUN' '(' NAME ',' INT ',' INT ',' INT ',' STRING ',' STRING ',' INT ')'
 220                 -- ptrs, nptrs, closure type, description, type, fun type
 221                 { funInfo $3 $5 $7 $9 $11 $13 $15 }
 222
 223         | 'INFO_TABLE_CONSTR' '(' NAME ',' INT ',' INT ',' INT ',' INT ',' STRING ',' STRING ')'
 224                 -- ptrs, nptrs, tag, closure type, description, type
 225                 { stdInfo $3 $5 $7 $9 $11 $13 $15 }
 226
 227         | 'INFO_TABLE_SELECTOR' '(' NAME ',' INT ',' INT ',' STRING ',' STRING ')'
 228                 -- selector, closure type, description, type
 229                 { basicInfo $3 (mkIntCLit (fromIntegral $5)) 0 $7 $9 $11 }
 230
 231         | 'INFO_TABLE_RET' '(' NAME ',' INT ',' INT ',' INT maybe_vec ')'
 232                 { retInfo $3 $5 $7 $9 $10 }
 233
 234 maybe_vec :: { [CmmLit] }
 235         : {- empty -}                   { [] }
 236         | ',' NAME maybe_vec            { CmmLabel (mkRtsCodeLabelFS $2) : $3 }
 237
 238 body    :: { ExtCode }
 239         : {- empty -}                   { return () }
 240         | decl body                     { do $1; $2 }
 241         | stmt body                     { do $1; $2 }
 242
 243 decl    :: { ExtCode }
 244         : type names ';'                { mapM_ (newLocal $1) $2 }
 245         | 'import' names ';'            { return () }  -- ignore imports
 246         | 'export' names ';'            { return () }  -- ignore exports
 247
 248 names   :: { [FastString] }
 249         : NAME                  { [$1] }
 250         | NAME ',' names        { $1 : $3 }
 251
 252 stmt    :: { ExtCode }
 253         : ';'                                   { nopEC }
 254
 255         | block_id ':'                          { code (labelC $1) }
 256
 257         | lreg '=' expr ';'
 258                 { do reg <- $1; e <- $3; stmtEC (CmmAssign reg e) }
 259         | type '[' expr ']' '=' expr ';'
 260                 { doStore $1 $3 $6 }
 261         | 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 262                 {% foreignCall $2 [] $3 $5 $7 }
 263         | lreg '=' 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 264                 {% let result = do r <- $1; return (r,NoHint) in
 265                    foreignCall $4 [result] $5 $7 $9 }
 266         | STRING lreg '=' 'foreign' STRING expr '(' hint_exprs0 ')' vols ';'
 267                 {% do h <- parseHint $1;
 268                       let result = do r <- $2; return (r,h) in
 269                       foreignCall $5 [result] $6 $8 $10 }
 270         -- stmt-level macros, stealing syntax from ordinary C-- function calls.
 271         -- Perhaps we ought to use the %%-form?
 272         | NAME '(' exprs0 ')' ';'
 273                 {% stmtMacro $1 $3  }
 274         | 'switch' maybe_range expr '{' arms default '}'
 275                 { doSwitch $2 $3 $5 $6 }
 276         | 'goto' block_id ';'
 277                 { stmtEC (CmmBranch $2) }
 278         | 'jump' expr {-maybe_actuals-} ';'
 279                 { do e <- $2; stmtEC (CmmJump e []) }
 280         | 'if' bool_expr '{' body '}' else
 281                 { ifThenElse $2 $4 $6 }
 282
 283 bool_expr :: { ExtFCode BoolExpr }
 284         : bool_op                       { $1 }
 285         | expr                          { do e <- $1; return (BoolTest e) }
 286
 287 bool_op :: { ExtFCode BoolExpr }
 288         : bool_expr '&&' bool_expr      { do e1 <- $1; e2 <- $3;
 289                                           return (BoolAnd e1 e2) }
 290         | bool_expr '||' bool_expr      { do e1 <- $1; e2 <- $3;
 291                                           return (BoolOr e1 e2)  }
 292         | '!' bool_expr                 { do e <- $2; return (BoolNot e) }
 293         | '(' bool_op ')'               { $2 }
 294
 295 -- This is not C-- syntax.  What to do?
 296 vols    :: { Maybe [GlobalReg] }
 297         : {- empty -}                   { Nothing }
 298         | '[' globals ']'               { Just $2 }
 299
 300 globals :: { [GlobalReg] }
 301         : GLOBALREG                     { [$1] }
 302         | GLOBALREG ',' globals         { $1 : $3 }
 303
 304 maybe_range :: { Maybe (Int,Int) }
 305         : '[' INT '..' INT ']'  { Just (fromIntegral $2, fromIntegral $4) }
 306         | {- empty -}           { Nothing }
 307
 308 arms    :: { [([Int],ExtCode)] }
 309         : {- empty -}                   { [] }
 310         | arm arms                      { $1 : $2 }
 311
 312 arm     :: { ([Int],ExtCode) }
 313         : 'case' ints ':' '{' body '}'  { ($2, $5) }
 314
 315 ints    :: { [Int] }
 316         : INT                           { [ fromIntegral $1 ] }
 317         | INT ',' ints                  { fromIntegral $1 : $3 }
 318
 319 default :: { Maybe ExtCode }
 320         : 'default' ':' '{' body '}'    { Just $4 }
 321         -- taking a few liberties with the C-- syntax here; C-- doesn't have
 322         -- 'default' branches
 323         | {- empty -}                   { Nothing }
 324
 325 else    :: { ExtCode }
 326         : {- empty -}                   { nopEC }
 327         | 'else' '{' body '}'           { $3 }
 328
 329 -- we have to write this out longhand so that Happy's precedence rules
 330 -- can kick in.
 331 expr    :: { ExtFCode CmmExpr }
 332         : expr '/' expr                 { mkMachOp MO_U_Quot [$1,$3] }
 333         | expr '*' expr                 { mkMachOp MO_Mul [$1,$3] }
 334         | expr '%' expr                 { mkMachOp MO_U_Rem [$1,$3] }
 335         | expr '-' expr                 { mkMachOp MO_Sub [$1,$3] }
 336         | expr '+' expr                 { mkMachOp MO_Add [$1,$3] }
 337         | expr '>>' expr                { mkMachOp MO_U_Shr [$1,$3] }
 338         | expr '<<' expr                { mkMachOp MO_Shl [$1,$3] }
 339         | expr '&' expr                 { mkMachOp MO_And [$1,$3] }
 340         | expr '^' expr                 { mkMachOp MO_Xor [$1,$3] }
 341         | expr '|' expr                 { mkMachOp MO_Or [$1,$3] }
 342         | expr '>=' expr                { mkMachOp MO_U_Ge [$1,$3] }
 343         | expr '>' expr                 { mkMachOp MO_U_Gt [$1,$3] }
 344         | expr '<=' expr                { mkMachOp MO_U_Le [$1,$3] }
 345         | expr '<' expr                 { mkMachOp MO_U_Lt [$1,$3] }
 346         | expr '!=' expr                { mkMachOp MO_Ne [$1,$3] }
 347         | expr '==' expr                { mkMachOp MO_Eq [$1,$3] }
 348         | '~' expr                      { mkMachOp MO_Not [$2] }
 349         | '-' expr                      { mkMachOp MO_S_Neg [$2] }
 350         | expr0 '`' NAME '`' expr0      {% do { mo <- nameToMachOp $3 ;
 351                                                 return (mkMachOp mo [$1,$5]) } }
 352         | expr0                         { $1 }
 353
 354 expr0   :: { ExtFCode CmmExpr }
 355         : INT   maybe_ty         { return (CmmLit (CmmInt $1 $2)) }
 356         | FLOAT maybe_ty         { return (CmmLit (CmmFloat $1 $2)) }
 357         | STRING                 { do s <- code (mkStringCLit $1);
 358                                       return (CmmLit s) }
 359         | reg                    { $1 }
 360         | type '[' expr ']'      { do e <- $3; return (CmmLoad e $1) }
 361         | '%' NAME '(' exprs0 ')' {% exprOp $2 $4 }
 362         | '(' expr ')'           { $2 }
 363
 364
 365 -- leaving out the type of a literal gives you the native word size in C--
 366 maybe_ty :: { MachRep }
 367         : {- empty -}                   { wordRep }
 368         | '::' type                     { $2 }
 369
 370 hint_exprs0 :: { [ExtFCode (CmmExpr, MachHint)] }
 371         : {- empty -}                   { [] }
 372         | hint_exprs                    { $1 }
 373
 374 hint_exprs :: { [ExtFCode (CmmExpr, MachHint)] }
 375         : hint_expr                     { [$1] }
 376         | hint_expr ',' hint_exprs      { $1 : $3 }
 377
 378 hint_expr :: { ExtFCode (CmmExpr, MachHint) }
 379         : expr                          { do e <- $1; return (e, inferHint e) }
 380         | expr STRING                   {% do h <- parseHint $2;
 381                                               return $ do
 382                                                 e <- $1; return (e,h) }
 383
 384 exprs0  :: { [ExtFCode CmmExpr] }
 385         : {- empty -}                   { [] }
 386         | exprs                         { $1 }
 387
 388 exprs   :: { [ExtFCode CmmExpr] }
 389         : expr                          { [ $1 ] }
 390         | expr ',' exprs                { $1 : $3 }
 391
 392 reg     :: { ExtFCode CmmExpr }
 393         : NAME                  { lookupName $1 }
 394         | GLOBALREG             { return (CmmReg (CmmGlobal $1)) }
 395
 396 lreg    :: { ExtFCode CmmReg }
 397         : NAME                  { do e <- lookupName $1;
 398                                      return $
 399                                        case e of
 400                                         CmmReg r -> r
 401                                         other -> pprPanic "CmmParse:" (ftext $1 <> text " not a register") }
 402         | GLOBALREG             { return (CmmGlobal $1) }
 403
 404 block_id :: { BlockId }
 405         : NAME                  { BlockId (newTagUnique (getUnique $1) 'L') }
 406                         -- TODO: ugh.  The unique of a FastString has a null
 407                         -- tag, so we have to put our own tag on.  We should
 408                         -- really make a new unique for every label, and keep
 409                         -- them in an environment.
 410
 411 type    :: { MachRep }
 412         : 'bits8'               { I8 }
 413         | typenot8              { $1 }
 414
 415 typenot8 :: { MachRep }
 416         : 'bits16'              { I16 }
 417         | 'bits32'              { I32 }
 418         | 'bits64'              { I64 }
 419         | 'float32'             { F32 }
 420         | 'float64'             { F64 }
 421 {
 422 section :: String -> Section
 423 section "text"   = Text
 424 section "data"   = Data
 425 section "rodata" = ReadOnlyData
 426 section "bss"    = UninitialisedData
 427 section s        = OtherSection s
 428
 429 -- mkMachOp infers the type of the MachOp from the type of its first
 430 -- argument.  We assume that this is correct: for MachOps that don't have
 431 -- symmetrical args (e.g. shift ops), the first arg determines the type of
 432 -- the op.
 433 mkMachOp :: (MachRep -> MachOp) -> [ExtFCode CmmExpr] -> ExtFCode CmmExpr
 434 mkMachOp fn args = do
 435   arg_exprs <- sequence args
 436   return (CmmMachOp (fn (cmmExprRep (head arg_exprs))) arg_exprs)
 437
 438 getLit :: CmmExpr -> CmmLit
 439 getLit (CmmLit l) = l
 440 getLit (CmmMachOp (MO_S_Neg _) [CmmLit (CmmInt i r)])  = CmmInt (negate i) r
 441 getLit _ = panic "invalid literal" -- TODO messy failure
 442
 443 nameToMachOp :: FastString -> P (MachRep -> MachOp)
 444 nameToMachOp name =
 445   case lookupUFM machOps name of
 446         Nothing -> fail ("unknown primitive " ++ unpackFS name)
 447         Just m  -> return m
 448
 449 exprOp :: FastString -> [ExtFCode CmmExpr] -> P (ExtFCode CmmExpr)
 450 exprOp name args_code =
 451   case lookupUFM exprMacros name of
 452      Just f  -> return $ do
 453         args <- sequence args_code
 454         return (f args)
 455      Nothing -> do
 456         mo <- nameToMachOp name
 457         return $ mkMachOp mo args_code
 458
 459 exprMacros :: UniqFM ([CmmExpr] -> CmmExpr)
 460 exprMacros = listToUFM [
 461   ( FSLIT("ENTRY_CODE"),   \ [x] -> entryCode x ),
 462   ( FSLIT("GET_ENTRY"),    \ [x] -> entryCode (closureInfoPtr x) ),
 463   ( FSLIT("STD_INFO"),     \ [x] -> infoTable x ),
 464   ( FSLIT("GET_STD_INFO"), \ [x] -> infoTable (closureInfoPtr x) ),
 465   ( FSLIT("GET_FUN_INFO"), \ [x] -> funInfoTable (closureInfoPtr x) ),
 466   ( FSLIT("INFO_TYPE"),    \ [x] -> infoTableClosureType x ),
 467   ( FSLIT("INFO_PTRS"),    \ [x] -> infoTablePtrs x ),
 468   ( FSLIT("INFO_NPTRS"),   \ [x] -> infoTableNonPtrs x ),
 469   ( FSLIT("RET_VEC"),      \ [info, conZ] -> retVec info conZ )
 470   ]
 471
 472 -- we understand a subset of C-- primitives:
 473 machOps = listToUFM $
 474         map (\(x, y) -> (mkFastString x, y)) [
 475         ( "add",        MO_Add ),
 476         ( "sub",        MO_Sub ),
 477         ( "eq",         MO_Eq ),
 478         ( "ne",         MO_Ne ),
 479         ( "mul",        MO_Mul ),
 480         ( "neg",        MO_S_Neg ),
 481         ( "quot",       MO_S_Quot ),
 482         ( "rem",        MO_S_Rem ),
 483         ( "divu",       MO_U_Quot ),
 484         ( "modu",       MO_U_Rem ),
 485
 486         ( "ge",         MO_S_Ge ),
 487         ( "le",         MO_S_Le ),
 488         ( "gt",         MO_S_Gt ),
 489         ( "lt",         MO_S_Lt ),
 490
 491         ( "geu",        MO_U_Ge ),
 492         ( "leu",        MO_U_Le ),
 493         ( "gtu",        MO_U_Gt ),
 494         ( "ltu",        MO_U_Lt ),
 495
 496         ( "flt",        MO_S_Lt ),
 497         ( "fle",        MO_S_Le ),
 498         ( "feq",        MO_Eq ),
 499         ( "fne",        MO_Ne ),
 500         ( "fgt",        MO_S_Gt ),
 501         ( "fge",        MO_S_Ge ),
 502         ( "fneg",       MO_S_Neg ),
 503
 504         ( "and",        MO_And ),
 505         ( "or",         MO_Or ),
 506         ( "xor",        MO_Xor ),
 507         ( "com",        MO_Not ),
 508         ( "shl",        MO_Shl ),
 509         ( "shrl",       MO_U_Shr ),
 510         ( "shra",       MO_S_Shr ),
 511
 512         ( "lobits8",  flip MO_U_Conv I8  ),
 513         ( "lobits16", flip MO_U_Conv I16 ),
 514         ( "lobits32", flip MO_U_Conv I32 ),
 515         ( "lobits64", flip MO_U_Conv I64 ),
 516         ( "sx16",     flip MO_S_Conv I16 ),
 517         ( "sx32",     flip MO_S_Conv I32 ),
 518         ( "sx64",     flip MO_S_Conv I64 ),
 519         ( "zx16",     flip MO_U_Conv I16 ),
 520         ( "zx32",     flip MO_U_Conv I32 ),
 521         ( "zx64",     flip MO_U_Conv I64 ),
 522         ( "f2f32",    flip MO_S_Conv F32 ),  -- TODO; rounding mode
 523         ( "f2f64",    flip MO_S_Conv F64 ),  -- TODO; rounding mode
 524         ( "f2i8",     flip MO_S_Conv I8 ),
 525         ( "f2i16",    flip MO_S_Conv I8 ),
 526         ( "f2i32",    flip MO_S_Conv I8 ),
 527         ( "f2i64",    flip MO_S_Conv I8 ),
 528         ( "i2f32",    flip MO_S_Conv F32 ),
 529         ( "i2f64",    flip MO_S_Conv F64 )
 530         ]
 531
 532 parseHint :: String -> P MachHint
 533 parseHint "ptr"    = return PtrHint
 534 parseHint "signed" = return SignedHint
 535 parseHint "float"  = return FloatHint
 536 parseHint str      = fail ("unrecognised hint: " ++ str)
 537
 538 -- labels are always pointers, so we might as well infer the hint
 539 inferHint :: CmmExpr -> MachHint
 540 inferHint (CmmLit (CmmLabel _)) = PtrHint
 541 inferHint (CmmReg (CmmGlobal g)) | isPtrGlobalReg g = PtrHint
 542 inferHint _ = NoHint
 543
 544 isPtrGlobalReg Sp               = True
 545 isPtrGlobalReg SpLim            = True
 546 isPtrGlobalReg Hp               = True
 547 isPtrGlobalReg HpLim            = True
 548 isPtrGlobalReg CurrentTSO       = True
 549 isPtrGlobalReg CurrentNursery   = True
 550 isPtrGlobalReg _                = False
 551
 552 happyError :: P a
 553 happyError = srcParseFail
 554
 555 -- -----------------------------------------------------------------------------
 556 -- Statement-level macros
 557
 558 stmtMacro :: FastString -> [ExtFCode CmmExpr] -> P ExtCode
 559 stmtMacro fun args_code = do
 560   case lookupUFM stmtMacros fun of
 561     Nothing -> fail ("unknown macro: " ++ unpackFS fun)
 562     Just fcode -> return $ do
 563         args <- sequence args_code
 564         code (fcode args)
 565
 566 stmtMacros :: UniqFM ([CmmExpr] -> Code)
 567 stmtMacros = listToUFM [
 568   ( FSLIT("CCS_ALLOC"),            \[words,ccs]  -> profAlloc words ccs ),
 569   ( FSLIT("CLOSE_NURSERY"),        \[]  -> emitCloseNursery ),
 570   ( FSLIT("ENTER_CCS_PAP_CL"),     \[e] -> enterCostCentrePAP e ),
 571   ( FSLIT("ENTER_CCS_THUNK"),      \[e] -> enterCostCentreThunk e ),
 572   ( FSLIT("HP_CHK_GEN"),           \[words,liveness,reentry] ->
 573                                       hpChkGen words liveness reentry ),
 574   ( FSLIT("HP_CHK_NP_ASSIGN_SP0"), \[e,f] -> hpChkNodePointsAssignSp0 e f ),
 575   ( FSLIT("LOAD_THREAD_STATE"),    \[] -> emitLoadThreadState ),
 576   ( FSLIT("LDV_ENTER"),            \[e] -> ldvEnter e ),
 577   ( FSLIT("LDV_RECORD_CREATE"),    \[e] -> ldvRecordCreate e ),
 578   ( FSLIT("OPEN_NURSERY"),         \[]  -> emitOpenNursery ),
 579   ( FSLIT("PUSH_UPD_FRAME"),       \[sp,e] -> emitPushUpdateFrame sp e ),
 580   ( FSLIT("SAVE_THREAD_STATE"),    \[] -> emitSaveThreadState ),
 581   ( FSLIT("SET_HDR"),              \[ptr,info,ccs] ->
 582                                         emitSetDynHdr ptr info ccs ),
 583   ( FSLIT("STK_CHK_GEN"),          \[words,liveness,reentry] ->
 584                                       stkChkGen words liveness reentry ),
 585   ( FSLIT("STK_CHK_NP"),           \[e] -> stkChkNodePoints e ),
 586   ( FSLIT("TICK_ALLOC_PRIM"),      \[hdr,goods,slop] ->
 587                                         tickyAllocPrim hdr goods slop ),
 588   ( FSLIT("TICK_ALLOC_PAP"),       \[goods,slop] ->
 589                                         tickyAllocPAP goods slop ),
 590   ( FSLIT("TICK_ALLOC_UP_THK"),    \[goods,slop] ->
 591                                         tickyAllocThunk goods slop ),
 592   ( FSLIT("UPD_BH_UPDATABLE"),       \[] -> emitBlackHoleCode False ),
 593   ( FSLIT("UPD_BH_SINGLE_ENTRY"),    \[] -> emitBlackHoleCode True ),
 594
 595   ( FSLIT("RET_P"),     \[a] ->       emitRetUT [(PtrArg,a)]),
 596   ( FSLIT("RET_N"),     \[a] ->       emitRetUT [(NonPtrArg,a)]),
 597   ( FSLIT("RET_PP"),    \[a,b] ->     emitRetUT [(PtrArg,a),(PtrArg,b)]),
 598   ( FSLIT("RET_NN"),    \[a,b] ->     emitRetUT [(NonPtrArg,a),(NonPtrArg,b)]),
 599   ( FSLIT("RET_NP"),    \[a,b] ->     emitRetUT [(NonPtrArg,a),(PtrArg,b)]),
 600   ( FSLIT("RET_PPP"),   \[a,b,c] ->   emitRetUT [(PtrArg,a),(PtrArg,b),(PtrArg,c)]),
 601   ( FSLIT("RET_NNP"),   \[a,b,c] ->   emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(PtrArg,c)]),
 602   ( FSLIT("RET_NNNP"),  \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(NonPtrArg,b),(NonPtrArg,c),(PtrArg,d)]),
 603   ( FSLIT("RET_NPNP"),  \[a,b,c,d] -> emitRetUT [(NonPtrArg,a),(PtrArg,b),(NonPtrArg,c),(PtrArg,d)])
 604
 605  ]
 606
 607 -- -----------------------------------------------------------------------------
 608 -- Our extended FCode monad.
 609
 610 -- We add a mapping from names to CmmExpr, to support local variable names in
 611 -- the concrete C-- code.  The unique supply of the underlying FCode monad
 612 -- is used to grab a new unique for each local variable.
 613
 614 -- In C--, a local variable can be declared anywhere within a proc,
 615 -- and it scopes from the beginning of the proc to the end.  Hence, we have
 616 -- to collect declarations as we parse the proc, and feed the environment
 617 -- back in circularly (to avoid a two-pass algorithm).
 618
 619 type Decls = [(FastString,CmmExpr)]
 620 type Env   = UniqFM CmmExpr
 621
 622 newtype ExtFCode a = EC { unEC :: Env -> Decls -> FCode (Decls, a) }
 623
 624 type ExtCode = ExtFCode ()
 625
 626 returnExtFC a = EC $ \e s -> return (s, a)
 627 thenExtFC (EC m) k = EC $ \e s -> do (s',r) <- m e s; unEC (k r) e s'
 628
 629 instance Monad ExtFCode where
 630   (>>=) = thenExtFC
 631   return = returnExtFC
 632
 633 -- This function takes the variable decarations and imports and makes
 634 -- an environment, which is looped back into the computation.  In this
 635 -- way, we can have embedded declarations that scope over the whole
 636 -- procedure, and imports that scope over the entire module.
 637 loopDecls :: ExtFCode a -> ExtFCode a
 638 loopDecls (EC fcode) =
 639    EC $ \e s -> fixC (\ ~(decls,a) -> fcode (addListToUFM e decls) [])
 640
 641 getEnv :: ExtFCode Env
 642 getEnv = EC $ \e s -> return (s, e)
 643
 644 addVarDecl :: FastString -> CmmExpr -> ExtCode
 645 addVarDecl var expr = EC $ \e s -> return ((var,expr):s, ())
 646
 647 newLocal :: MachRep -> FastString -> ExtCode
 648 newLocal ty name  = do
 649    u <- code newUnique
 650    addVarDecl name (CmmReg (CmmLocal (LocalReg u ty)))
 651
 652 -- Unknown names are treated as if they had been 'import'ed.
 653 -- This saves us a lot of bother in the RTS sources, at the expense of
 654 -- deferring some errors to link time.
 655 lookupName :: FastString -> ExtFCode CmmExpr
 656 lookupName name = do
 657   env <- getEnv
 658   return $
 659      case lookupUFM env name of
 660         Nothing -> CmmLit (CmmLabel (mkRtsCodeLabelFS name))
 661         Just e  -> e
 662
 663 -- Lifting FCode computations into the ExtFCode monad:
 664 code :: FCode a -> ExtFCode a
 665 code fc = EC $ \e s -> do r <- fc; return (s, r)
 666
 667 code2 :: (FCode (Decls,b) -> FCode ((Decls,b),c))
 668          -> ExtFCode b -> ExtFCode c
 669 code2 f (EC ec) = EC $ \e s -> do ((s',b),c) <- f (ec e s); return (s',c)
 670
 671 nopEC = code nopC
 672 stmtEC stmt = code (stmtC stmt)
 673 stmtsEC stmts = code (stmtsC stmts)
 674 getCgStmtsEC = code2 getCgStmts'
 675
 676 forkLabelledCodeEC ec = do
 677   stmts <- getCgStmtsEC ec
 678   code (forkCgStmts stmts)
 679
 680 retInfo name size live_bits cl_type vector = do
 681   let liveness = smallLiveness (fromIntegral size) (fromIntegral live_bits)
 682       info_lbl = mkRtsRetInfoLabelFS name
 683       (info1,info2) = mkRetInfoTable info_lbl liveness NoC_SRT
 684                                 (fromIntegral cl_type) vector
 685   return (info_lbl, info1, info2)
 686
 687 stdInfo name ptrs nptrs srt_bitmap cl_type desc_str ty_str =
 688   basicInfo name (packHalfWordsCLit ptrs nptrs)
 689         srt_bitmap cl_type desc_str ty_str
 690
 691 basicInfo name layout srt_bitmap cl_type desc_str ty_str = do
 692   lit1 <- if opt_SccProfilingOn
 693                    then code $ mkStringCLit desc_str
 694                    else return (mkIntCLit 0)
 695   lit2 <- if opt_SccProfilingOn
 696                    then code $ mkStringCLit ty_str
 697                    else return (mkIntCLit 0)
 698   let info1 = mkStdInfoTable lit1 lit2 (fromIntegral cl_type)
 699                         (fromIntegral srt_bitmap)
 700                         layout
 701   return (mkRtsInfoLabelFS name, info1, [])
 702
 703 funInfo name ptrs nptrs cl_type desc_str ty_str fun_type = do
 704   (label,info1,_) <- stdInfo name ptrs nptrs 0{-srt_bitmap-}
 705                          cl_type desc_str ty_str
 706   let info2 = mkFunGenInfoExtraBits (fromIntegral fun_type) 0 zero zero zero
 707                 -- we leave most of the fields zero here.  This is only used
 708                 -- to generate the BCO info table in the RTS at the moment.
 709   return (label,info1,info2)
 710  where
 711    zero = mkIntCLit 0
 712
 713
 714 staticClosure :: FastString -> FastString -> [CmmLit] -> ExtCode
 715 staticClosure cl_label info payload
 716   = code $ emitDataLits (mkRtsDataLabelFS cl_label) lits
 717   where  lits = mkStaticClosure (mkRtsInfoLabelFS info) dontCareCCS payload [] [] []
 718
 719 foreignCall
 720         :: String
 721         -> [ExtFCode (CmmReg,MachHint)]
 722         -> ExtFCode CmmExpr
 723         -> [ExtFCode (CmmExpr,MachHint)]
 724         -> Maybe [GlobalReg] -> P ExtCode
 725 foreignCall "C" results_code expr_code args_code vols
 726   = return $ do
 727         results <- sequence results_code
 728         expr <- expr_code
 729         args <- sequence args_code
 730         stmtEC (CmmCall (CmmForeignCall expr CCallConv) results args vols)
 731 foreignCall conv _ _ _ _
 732   = fail ("unknown calling convention: " ++ conv)
 733
 734 doStore :: MachRep -> ExtFCode CmmExpr  -> ExtFCode CmmExpr -> ExtCode
 735 doStore rep addr_code val_code
 736   = do addr <- addr_code
 737        val <- val_code
 738         -- if the specified store type does not match the type of the expr
 739         -- on the rhs, then we insert a coercion that will cause the type
 740         -- mismatch to be flagged by cmm-lint.  If we don't do this, then
 741         -- the store will happen at the wrong type, and the error will not
 742         -- be noticed.
 743        let coerce_val
 744                 | cmmExprRep val /= rep = CmmMachOp (MO_U_Conv rep rep) [val]
 745                 | otherwise             = val
 746        stmtEC (CmmStore addr coerce_val)
 747
 748 -- Return an unboxed tuple.
 749 emitRetUT :: [(CgRep,CmmExpr)] -> Code
 750 emitRetUT args = do
 751   tickyUnboxedTupleReturn (length args)  -- TICK
 752   (sp, stmts) <- pushUnboxedTuple 0 args
 753   emitStmts stmts
 754   when (sp /= 0) $ stmtC (CmmAssign spReg (cmmRegOffW spReg (-sp)))
 755   stmtC (CmmJump (entryCode (CmmLoad (cmmRegOffW spReg sp) wordRep)) [])
 756
 757 -- -----------------------------------------------------------------------------
 758 -- If-then-else and boolean expressions
 759
 760 data BoolExpr
 761   = BoolExpr `BoolAnd` BoolExpr
 762   | BoolExpr `BoolOr`  BoolExpr
 763   | BoolNot BoolExpr
 764   | BoolTest CmmExpr
 765
 766 -- ToDo: smart constructors which simplify the boolean expression.
 767
 768 ifThenElse cond then_part else_part = do
 769      then_id <- code newLabelC
 770      join_id <- code newLabelC
 771      c <- cond
 772      emitCond c then_id
 773      else_part
 774      stmtEC (CmmBranch join_id)
 775      code (labelC then_id)
 776      then_part
 777      -- fall through to join
 778      code (labelC join_id)
 779
 780 -- 'emitCond cond true_id'  emits code to test whether the cond is true,
 781 -- branching to true_id if so, and falling through otherwise.
 782 emitCond (BoolTest e) then_id = do
 783   stmtEC (CmmCondBranch e then_id)
 784 emitCond (BoolNot (BoolTest (CmmMachOp op args))) then_id
 785   | Just op' <- maybeInvertComparison op
 786   = emitCond (BoolTest (CmmMachOp op' args)) then_id
 787 emitCond (BoolNot e) then_id = do
 788   else_id <- code newLabelC
 789   emitCond e else_id
 790   stmtEC (CmmBranch then_id)
 791   code (labelC else_id)
 792 emitCond (e1 `BoolOr` e2) then_id = do
 793   emitCond e1 then_id
 794   emitCond e2 then_id
 795 emitCond (e1 `BoolAnd` e2) then_id = do
 796         -- we'd like to invert one of the conditionals here to avoid an
 797         -- extra branch instruction, but we can't use maybeInvertComparison
 798         -- here because we can't look too closely at the expression since
 799         -- we're in a loop.
 800   and_id <- code newLabelC
 801   else_id <- code newLabelC
 802   emitCond e1 and_id
 803   stmtEC (CmmBranch else_id)
 804   code (labelC and_id)
 805   emitCond e2 then_id
 806   code (labelC else_id)
 807
 808
 809 -- -----------------------------------------------------------------------------
 810 -- Table jumps
 811
 812 -- We use a simplified form of C-- switch statements for now.  A
 813 -- switch statement always compiles to a table jump.  Each arm can
 814 -- specify a list of values (not ranges), and there can be a single
 815 -- default branch.  The range of the table is given either by the
 816 -- optional range on the switch (eg. switch [0..7] {...}), or by
 817 -- the minimum/maximum values from the branches.
 818
 819 doSwitch :: Maybe (Int,Int) -> ExtFCode CmmExpr -> [([Int],ExtCode)]
 820          -> Maybe ExtCode -> ExtCode
 821 doSwitch mb_range scrut arms deflt
 822    = do
 823         -- Compile code for the default branch
 824         dflt_entry <-
 825                 case deflt of
 826                   Nothing -> return Nothing
 827                   Just e  -> do b <- forkLabelledCodeEC e; return (Just b)
 828
 829         -- Compile each case branch
 830         table_entries <- mapM emitArm arms
 831
 832         -- Construct the table
 833         let
 834             all_entries = concat table_entries
 835             ixs = map fst all_entries
 836             (min,max)
 837                 | Just (l,u) <- mb_range = (l,u)
 838                 | otherwise              = (minimum ixs, maximum ixs)
 839
 840             entries = elems (accumArray (\_ a -> Just a) dflt_entry (min,max)
 841                                 all_entries)
 842         expr <- scrut
 843         -- ToDo: check for out of range and jump to default if necessary
 844         stmtEC (CmmSwitch expr entries)
 845    where
 846         emitArm :: ([Int],ExtCode) -> ExtFCode [(Int,BlockId)]
 847         emitArm (ints,code) = do
 848            blockid <- forkLabelledCodeEC code
 849            return [ (i,blockid) | i <- ints ]
 850
 851
 852 -- -----------------------------------------------------------------------------
 853 -- Putting it all together
 854
 855 -- The initial environment: we define some constants that the compiler
 856 -- knows about here.
 857 initEnv :: Env
 858 initEnv = listToUFM [
 859   ( FSLIT("SIZEOF_StgHeader"),
 860         CmmLit (CmmInt (fromIntegral (fixedHdrSize * wORD_SIZE)) wordRep) ),
 861   ( FSLIT("SIZEOF_StgInfoTable"),
 862         CmmLit (CmmInt (fromIntegral stdInfoTableSizeB) wordRep) )
 863   ]
 864
 865 parseCmmFile :: DynFlags -> HomeModules -> FilePath -> IO (Maybe Cmm)
 866 parseCmmFile dflags hmods filename = do
 867   showPass dflags "ParseCmm"
 868   buf <- hGetStringBuffer filename
 869   let
 870         init_loc = mkSrcLoc (mkFastString filename) 1 0
 871         init_state = (mkPState buf init_loc dflags) { lex_state = [0] }
 872                 -- reset the lex_state: the Lexer monad leaves some stuff
 873                 -- in there we don't want.
 874   case unP cmmParse init_state of
 875     PFailed span err -> do printError span err; return Nothing
 876     POk _ code -> do
 877         cmm <- initC dflags hmods no_module (getCmm (unEC code initEnv [] >> return ()))
 878         dumpIfSet_dyn dflags Opt_D_dump_cmm "Cmm" (pprCmms [cmm])
 879         return (Just cmm)
 880   where
 881         no_module = panic "parseCmmFile: no module"
 882 }