ghc/compiler/codeGen/CgExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 % $Id: CgExpr.lhs,v 1.45 2001/10/17 14:24:52 simonmar Exp $
   5 %
   6 %********************************************************
   7 %*                                                      *
   8 \section[CgExpr]{Converting @StgExpr@s}
   9 %*                                                      *
  10 %********************************************************
  11
  12 \begin{code}
  13 module CgExpr ( cgExpr ) where
  14
  15 #include "HsVersions.h"
  16
  17 import Constants        ( mAX_SPEC_SELECTEE_SIZE, mAX_SPEC_AP_SIZE )
  18 import StgSyn
  19 import CgMonad
  20 import AbsCSyn
  21 import AbsCUtils        ( mkAbstractCs )
  22 import CLabel           ( mkClosureTblLabel )
  23
  24 import SMRep            ( fixedHdrSize )
  25 import CgBindery        ( getArgAmodes, getArgAmode, CgIdInfo,
  26                           nukeDeadBindings, addBindC, addBindsC )
  27 import CgCase           ( cgCase, saveVolatileVarsAndRegs,
  28                           restoreCurrentCostCentre )
  29 import CgClosure        ( cgRhsClosure, cgStdRhsClosure )
  30 import CgCon            ( buildDynCon, cgReturnDataCon )
  31 import CgLetNoEscape    ( cgLetNoEscapeClosure )
  32 import CgRetConv        ( dataReturnConvPrim )
  33 import CgTailCall       ( cgTailCall, performReturn, performPrimReturn,
  34                           mkDynamicAlgReturnCode, mkPrimReturnCode,
  35                           tailCallPrimOp, returnUnboxedTuple
  36                         )
  37 import ClosureInfo      ( mkClosureLFInfo, mkSelectorLFInfo,
  38                           mkApLFInfo, layOutDynConstr )
  39 import CostCentre       ( sccAbleCostCentre, isSccCountCostCentre )
  40 import Id               ( idPrimRep, idType, Id )
  41 import VarSet
  42 import PrimOp           ( primOpOutOfLine, getPrimOpResultInfo, PrimOp(..), PrimOpResultInfo(..) )
  43 import PrimRep          ( PrimRep(..), isFollowableRep )
  44 import TyCon            ( maybeTyConSingleCon,
  45                           isUnboxedTupleTyCon, isEnumerationTyCon )
  46 import Type             ( Type, typePrimRep, tyConAppArgs, tyConAppTyCon, repType )
  47 import Maybes           ( maybeToBool )
  48 import ListSetOps       ( assocMaybe )
  49 import Unique           ( mkBuiltinUnique )
  50 import BasicTypes       ( TopLevelFlag(..), RecFlag(..) )
  51 import Outputable
  52 \end{code}
  53
  54 This module provides the support code for @StgToAbstractC@ to deal
  55 with STG {\em expressions}.  See also @CgClosure@, which deals
  56 with closures, and @CgCon@, which deals with constructors.
  57
  58 \begin{code}
  59 cgExpr  :: StgExpr              -- input
  60         -> Code                 -- output
  61 \end{code}
  62
  63 %********************************************************
  64 %*                                                      *
  65 %*              Tail calls                              *
  66 %*                                                      *
  67 %********************************************************
  68
  69 ``Applications'' mean {\em tail calls}, a service provided by module
  70 @CgTailCall@.  This includes literals, which show up as
  71 @(STGApp (StgLitArg 42) [])@.
  72
  73 \begin{code}
  74 cgExpr (StgApp fun args) = cgTailCall fun args
  75 \end{code}
  76
  77 %********************************************************
  78 %*                                                      *
  79 %*              STG ConApps  (for inline versions)      *
  80 %*                                                      *
  81 %********************************************************
  82
  83 \begin{code}
  84 cgExpr (StgConApp con args)
  85   = getArgAmodes args `thenFC` \ amodes ->
  86     cgReturnDataCon con amodes
  87 \end{code}
  88
  89 Literals are similar to constructors; they return by putting
  90 themselves in an appropriate register and returning to the address on
  91 top of the stack.
  92
  93 \begin{code}
  94 cgExpr (StgLit lit)
  95   = performPrimReturn (text "literal" <+> ppr lit) (CLit lit)
  96 \end{code}
  97
  98
  99 %********************************************************
 100 %*                                                      *
 101 %*              STG PrimApps  (unboxed primitive ops)   *
 102 %*                                                      *
 103 %********************************************************
 104
 105 Here is where we insert real live machine instructions.
 106
 107 NOTE about _ccall_GC_:
 108
 109 A _ccall_GC_ is treated as an out-of-line primop (returns True
 110 for primOpOutOfLine) so that when we see the call in case context
 111         case (ccall ...) of { ... }
 112 we get a proper stack frame on the stack when we perform it.  When we
 113 get in a tail-call position, however, we need to actually perform the
 114 call, so we treat it as an inline primop.
 115
 116 \begin{code}
 117 cgExpr (StgOpApp op@(StgFCallOp _ _) args res_ty)
 118   = primRetUnboxedTuple op args res_ty
 119
 120 -- tagToEnum# is special: we need to pull the constructor out of the table,
 121 -- and perform an appropriate return.
 122
 123 cgExpr (StgOpApp (StgPrimOp TagToEnumOp) [arg] res_ty)
 124   = ASSERT(isEnumerationTyCon tycon)
 125     getArgAmode arg `thenFC` \amode ->
 126         -- save the tag in a temporary in case amode overlaps
 127         -- with node.
 128     absC (CAssign dyn_tag amode)        `thenC`
 129     performReturn (
 130                 CAssign (CReg node)
 131                         (CVal (CIndex
 132                           (CLbl (mkClosureTblLabel tycon) PtrRep)
 133                           dyn_tag PtrRep) PtrRep))
 134             (\ sequel -> mkDynamicAlgReturnCode tycon dyn_tag sequel)
 135    where
 136         dyn_tag = CTemp (mkBuiltinUnique 0) IntRep
 137           --
 138           -- if you're reading this code in the attempt to figure
 139           -- out why the compiler panic'ed here, it is probably because
 140           -- you used tagToEnum# in a non-monomorphic setting, e.g.,
 141           --         intToTg :: Enum a => Int -> a ; intToTg (I# x#) = tagToEnum# x#
 142           --
 143           -- That won't work.
 144           --
 145         tycon = tyConAppTyCon res_ty
 146
 147
 148 cgExpr x@(StgOpApp op@(StgPrimOp primop) args res_ty)
 149   | primOpOutOfLine primop
 150   = tailCallPrimOp primop args
 151
 152   | otherwise
 153   = ASSERT(primop /= SeqOp) -- can't handle SeqOp
 154
 155     getArgAmodes args   `thenFC` \ arg_amodes ->
 156
 157     case (getPrimOpResultInfo primop) of
 158
 159         ReturnsPrim kind ->
 160             let result_amode = CReg (dataReturnConvPrim kind) in
 161             performReturn
 162               (COpStmt [result_amode] op arg_amodes [{-no vol_regs-}])
 163               (mkPrimReturnCode (text "primapp)" <+> ppr x))
 164
 165         -- otherwise, must be returning an enumerated type (eg. Bool).
 166         -- we've only got the tag in R2, so we have to load the constructor
 167         -- itself into R1.
 168
 169         ReturnsAlg tycon
 170             | isUnboxedTupleTyCon tycon -> primRetUnboxedTuple op args res_ty
 171
 172             | isEnumerationTyCon  tycon ->
 173                 performReturn
 174                      (COpStmt [dyn_tag] op arg_amodes [{-no vol_regs-}])
 175                           (\ sequel ->
 176                           absC (CAssign (CReg node) closure_lbl) `thenC`
 177                           mkDynamicAlgReturnCode tycon dyn_tag sequel)
 178
 179             where
 180                -- Pull a unique out of thin air to put the tag in.
 181                -- It shouldn't matter if this overlaps with anything - we're
 182                -- about to return anyway.
 183                dyn_tag = CTemp (mkBuiltinUnique 0) IntRep
 184
 185                closure_lbl = CVal (CIndex
 186                                (CLbl (mkClosureTblLabel tycon) PtrRep)
 187                                dyn_tag PtrRep) PtrRep
 188
 189 \end{code}
 190
 191 %********************************************************
 192 %*                                                      *
 193 %*              Case expressions                        *
 194 %*                                                      *
 195 %********************************************************
 196 Case-expression conversion is complicated enough to have its own
 197 module, @CgCase@.
 198 \begin{code}
 199
 200 cgExpr (StgCase expr live_vars save_vars bndr srt alts)
 201   = cgCase expr live_vars save_vars bndr srt alts
 202 \end{code}
 203
 204
 205 %********************************************************
 206 %*                                                      *
 207 %*              Let and letrec                          *
 208 %*                                                      *
 209 %********************************************************
 210 \subsection[let-and-letrec-codegen]{Converting @StgLet@ and @StgLetrec@}
 211
 212 \begin{code}
 213 cgExpr (StgLet (StgNonRec srt name rhs) expr)
 214   = cgRhs srt name rhs  `thenFC` \ (name, info) ->
 215     addBindC name info  `thenC`
 216     cgExpr expr
 217
 218 cgExpr (StgLet (StgRec srt pairs) expr)
 219   = fixC (\ new_bindings -> addBindsC new_bindings `thenC`
 220                             listFCs [ cgRhs srt b e | (b,e) <- pairs ]
 221     ) `thenFC` \ new_bindings ->
 222
 223     addBindsC new_bindings `thenC`
 224     cgExpr expr
 225 \end{code}
 226
 227 \begin{code}
 228 cgExpr (StgLetNoEscape live_in_whole_let live_in_rhss bindings body)
 229   =     -- Figure out what volatile variables to save
 230     nukeDeadBindings live_in_whole_let  `thenC`
 231     saveVolatileVarsAndRegs live_in_rhss
 232             `thenFC` \ (save_assts, rhs_eob_info, maybe_cc_slot) ->
 233     -- ToDo: cost centre???
 234     restoreCurrentCostCentre maybe_cc_slot `thenFC` \ restore_cc ->
 235
 236         -- Save those variables right now!
 237     absC save_assts                             `thenC`
 238
 239         -- Produce code for the rhss
 240         -- and add suitable bindings to the environment
 241     cgLetNoEscapeBindings live_in_rhss rhs_eob_info maybe_cc_slot bindings `thenC`
 242
 243         -- Do the body
 244     setEndOfBlockInfo rhs_eob_info (cgExpr body)
 245 \end{code}
 246
 247
 248 %********************************************************
 249 %*                                                      *
 250 %*              SCC Expressions                         *
 251 %*                                                      *
 252 %********************************************************
 253
 254 SCC expressions are treated specially. They set the current cost
 255 centre.
 256 \begin{code}
 257 cgExpr (StgSCC cc expr)
 258   = ASSERT(sccAbleCostCentre cc)
 259     costCentresC
 260         SLIT("SET_CCC")
 261         [mkCCostCentre cc, mkIntCLit (if isSccCountCostCentre cc then 1 else 0)]
 262     `thenC`
 263     cgExpr expr
 264 \end{code}
 265
 266 ToDo: counting of dict sccs ...
 267
 268 %********************************************************
 269 %*                                                      *
 270 %*              Non-top-level bindings                  *
 271 %*                                                      *
 272 %********************************************************
 273 \subsection[non-top-level-bindings]{Converting non-top-level bindings}
 274
 275 We rely on the support code in @CgCon@ (to do constructors) and
 276 in @CgClosure@ (to do closures).
 277
 278 \begin{code}
 279 cgRhs :: SRT -> Id -> StgRhs -> FCode (Id, CgIdInfo)
 280         -- the Id is passed along so a binding can be set up
 281
 282 cgRhs srt name (StgRhsCon maybe_cc con args)
 283   = getArgAmodes args                           `thenFC` \ amodes ->
 284     buildDynCon name maybe_cc con amodes        `thenFC` \ idinfo ->
 285     returnFC (name, idinfo)
 286
 287 cgRhs srt name (StgRhsClosure cc bi fvs upd_flag args body)
 288   = mkRhsClosure name cc bi srt fvs upd_flag args body
 289 \end{code}
 290
 291 mkRhsClosure looks for two special forms of the right-hand side:
 292         a) selector thunks.
 293         b) AP thunks
 294
 295 If neither happens, it just calls mkClosureLFInfo.  You might think
 296 that mkClosureLFInfo should do all this, but it seems wrong for the
 297 latter to look at the structure of an expression
 298
 299 Selectors
 300 ~~~~~~~~~
 301 We look at the body of the closure to see if it's a selector---turgid,
 302 but nothing deep.  We are looking for a closure of {\em exactly} the
 303 form:
 304
 305 ...  = [the_fv] \ u [] ->
 306          case the_fv of
 307            con a_1 ... a_n -> a_i
 308
 309
 310 \begin{code}
 311 mkRhsClosure    bndr cc bi srt
 312                 [the_fv]                -- Just one free var
 313                 upd_flag                -- Updatable thunk
 314                 []                      -- A thunk
 315                 body@(StgCase (StgApp scrutinee [{-no args-}])
 316                       _ _ _ _   -- ignore uniq, etc.
 317                       (StgAlgAlts (Just tycon)
 318                          [(con, params, use_mask,
 319                             (StgApp selectee [{-no args-}]))]
 320                          StgNoDefault))
 321   |  the_fv == scrutinee                -- Scrutinee is the only free variable
 322   && maybeToBool maybe_offset           -- Selectee is a component of the tuple
 323   && offset_into_int <= mAX_SPEC_SELECTEE_SIZE  -- Offset is small enough
 324   = -- NOT TRUE: ASSERT(is_single_constructor)
 325     -- The simplifier may have statically determined that the single alternative
 326     -- is the only possible case and eliminated the others, even if there are
 327     -- other constructors in the datatype.  It's still ok to make a selector
 328     -- thunk in this case, because we *know* which constructor the scrutinee
 329     -- will evaluate to.
 330     cgStdRhsClosure bndr cc bi [the_fv] [] body lf_info [StgVarArg the_fv]
 331   where
 332     lf_info               = mkSelectorLFInfo (idType bndr) offset_into_int
 333                                                 (isUpdatable upd_flag)
 334     (_, params_w_offsets) = layOutDynConstr bogus_name con idPrimRep params
 335                                 -- Just want the layout
 336     maybe_offset          = assocMaybe params_w_offsets selectee
 337     Just the_offset       = maybe_offset
 338     offset_into_int       = the_offset - fixedHdrSize
 339     bogus_name            = panic "mkRhsClosure"
 340 \end{code}
 341
 342 Ap thunks
 343 ~~~~~~~~~
 344
 345 A more generic AP thunk of the form
 346
 347         x = [ x_1...x_n ] \.. [] -> x_1 ... x_n
 348
 349 A set of these is compiled statically into the RTS, so we just use
 350 those.  We could extend the idea to thunks where some of the x_i are
 351 global ids (and hence not free variables), but this would entail
 352 generating a larger thunk.  It might be an option for non-optimising
 353 compilation, though.
 354
 355 We only generate an Ap thunk if all the free variables are pointers,
 356 for semi-obvious reasons.
 357
 358 \begin{code}
 359 mkRhsClosure    bndr cc bi srt
 360                 fvs
 361                 upd_flag
 362                 []                      -- No args; a thunk
 363                 body@(StgApp fun_id args)
 364
 365   | length args + 1 == arity
 366         && all isFollowableRep (map idPrimRep fvs)
 367         && isUpdatable upd_flag
 368         && arity <= mAX_SPEC_AP_SIZE
 369
 370                    -- Ha! an Ap thunk
 371         = cgStdRhsClosure bndr cc bi fvs [] body lf_info payload
 372
 373    where
 374         lf_info = mkApLFInfo (idType bndr) upd_flag arity
 375         -- the payload has to be in the correct order, hence we can't
 376         -- just use the fvs.
 377         payload    = StgVarArg fun_id : args
 378         arity      = length fvs
 379 \end{code}
 380
 381 The default case
 382 ~~~~~~~~~~~~~~~~
 383 \begin{code}
 384 mkRhsClosure bndr cc bi srt fvs upd_flag args body
 385   = cgRhsClosure bndr cc bi srt fvs args body lf_info
 386   where
 387     lf_info = mkClosureLFInfo bndr NotTopLevel fvs upd_flag args
 388 \end{code}
 389
 390
 391 %********************************************************
 392 %*                                                      *
 393 %*              Let-no-escape bindings
 394 %*                                                      *
 395 %********************************************************
 396 \begin{code}
 397 cgLetNoEscapeBindings live_in_rhss rhs_eob_info maybe_cc_slot
 398         (StgNonRec srt binder rhs)
 399   = cgLetNoEscapeRhs live_in_rhss rhs_eob_info maybe_cc_slot
 400                         NonRecursive srt binder rhs
 401                                 `thenFC` \ (binder, info) ->
 402     addBindC binder info
 403
 404 cgLetNoEscapeBindings live_in_rhss rhs_eob_info maybe_cc_slot
 405         (StgRec srt pairs)
 406   = fixC (\ new_bindings ->
 407                 addBindsC new_bindings  `thenC`
 408                 listFCs [ cgLetNoEscapeRhs full_live_in_rhss
 409                                 rhs_eob_info maybe_cc_slot Recursive srt b e
 410                         | (b,e) <- pairs ]
 411     ) `thenFC` \ new_bindings ->
 412
 413     addBindsC new_bindings
 414   where
 415     -- We add the binders to the live-in-rhss set so that we don't
 416     -- delete the bindings for the binder from the environment!
 417     full_live_in_rhss = live_in_rhss `unionVarSet` (mkVarSet [b | (b,r) <- pairs])
 418
 419 cgLetNoEscapeRhs
 420     :: StgLiveVars      -- Live in rhss
 421     -> EndOfBlockInfo
 422     -> Maybe VirtualSpOffset
 423     -> RecFlag
 424     -> SRT
 425     -> Id
 426     -> StgRhs
 427     -> FCode (Id, CgIdInfo)
 428
 429 cgLetNoEscapeRhs full_live_in_rhss rhs_eob_info maybe_cc_slot rec srt binder
 430                  (StgRhsClosure cc bi _ upd_flag args body)
 431   = -- We could check the update flag, but currently we don't switch it off
 432     -- for let-no-escaped things, so we omit the check too!
 433     -- case upd_flag of
 434     --     Updatable -> panic "cgLetNoEscapeRhs"        -- Nothing to update!
 435     --     other     -> cgLetNoEscapeClosure binder cc bi live_in_whole_let live_in_rhss args body
 436     cgLetNoEscapeClosure binder cc bi srt full_live_in_rhss rhs_eob_info
 437         maybe_cc_slot rec args body
 438
 439 -- For a constructor RHS we want to generate a single chunk of code which
 440 -- can be jumped to from many places, which will return the constructor.
 441 -- It's easy; just behave as if it was an StgRhsClosure with a ConApp inside!
 442 cgLetNoEscapeRhs full_live_in_rhss rhs_eob_info maybe_cc_slot rec srt binder
 443                  (StgRhsCon cc con args)
 444   = cgLetNoEscapeClosure binder cc noBinderInfo{-safe-} srt
 445                          full_live_in_rhss rhs_eob_info maybe_cc_slot rec
 446         []      --No args; the binder is data structure, not a function
 447         (StgConApp con args)
 448 \end{code}
 449
 450 Little helper for primitives that return unboxed tuples.
 451
 452
 453 \begin{code}
 454 primRetUnboxedTuple :: StgOp -> [StgArg] -> Type -> Code
 455 primRetUnboxedTuple op args res_ty
 456   = getArgAmodes args       `thenFC` \ arg_amodes ->
 457     {-
 458       put all the arguments in temporaries so they don't get stomped when
 459       we push the return address.
 460     -}
 461     let
 462       n_args              = length args
 463       arg_uniqs           = map mkBuiltinUnique [0 .. n_args-1]
 464       arg_reps            = map getArgPrimRep args
 465       arg_temps           = zipWith CTemp arg_uniqs arg_reps
 466     in
 467     absC (mkAbstractCs (zipWith CAssign arg_temps arg_amodes)) `thenC`
 468     {-
 469       allocate some temporaries for the return values.
 470     -}
 471     let
 472       ty_args     = tyConAppArgs (repType res_ty)
 473       prim_reps   = map typePrimRep ty_args
 474       temp_uniqs  = map mkBuiltinUnique [ n_args .. n_args + length ty_args - 1]
 475       temp_amodes = zipWith CTemp temp_uniqs prim_reps
 476     in
 477     returnUnboxedTuple temp_amodes (absC (COpStmt temp_amodes op arg_temps []))
 478 \end{code}