ghc/compiler/codeGen/CgInfoTbls.hs

   1 -----------------------------------------------------------------------------
   2 --
   3 -- Building info tables.
   4 --
   5 -- (c) The University of Glasgow 2004
   6 --
   7 -----------------------------------------------------------------------------
   8
   9 module CgInfoTbls (
  10         emitClosureCodeAndInfoTable,
  11         emitInfoTableAndCode,
  12         dataConTagZ,
  13         getSRTInfo,
  14         emitDirectReturnTarget, emitAlgReturnTarget,
  15         emitDirectReturnInstr, emitVectoredReturnInstr,
  16         mkRetInfoTable,
  17         mkStdInfoTable,
  18         stdInfoTableSizeB,
  19         mkFunGenInfoExtraBits,
  20         entryCode, closureInfoPtr,
  21         getConstrTag,
  22         infoTable, infoTableClosureType,
  23         infoTablePtrs, infoTableNonPtrs,
  24         funInfoTable,
  25         retVec
  26   ) where
  27
  28
  29 #include "HsVersions.h"
  30
  31 import ClosureInfo      ( ClosureInfo, closureTypeDescr, closureName,
  32                           infoTableLabelFromCI, Liveness,
  33                           closureValDescr, closureSRT, closureSMRep,
  34                           closurePtrsSize, closureNonHdrSize, closureFunInfo,
  35                           C_SRT(..), needsSRT, isConstrClosure_maybe,
  36                           ArgDescr(..) )
  37 import SMRep            ( StgHalfWord, hALF_WORD_SIZE_IN_BITS, hALF_WORD_SIZE,
  38                           WordOff, ByteOff,
  39                           smRepClosureTypeInt, tablesNextToCode,
  40                           rET_BIG, rET_SMALL, rET_VEC_BIG, rET_VEC_SMALL )
  41 import CgBindery        ( getLiveStackSlots )
  42 import CgCallConv       ( isBigLiveness, mkLivenessCLit, buildContLiveness,
  43                           argDescrType, getSequelAmode,
  44                           CtrlReturnConvention(..) )
  45 import CgUtils          ( mkStringCLit, packHalfWordsCLit, mkWordCLit,
  46                           cmmOffsetB, cmmOffsetExprW, cmmLabelOffW, cmmOffsetW,
  47                           emitDataLits, emitRODataLits, emitSwitch, cmmNegate,
  48                           newTemp )
  49 import CgMonad
  50
  51 import CmmUtils         ( mkIntCLit, zeroCLit )
  52 import Cmm              ( CmmStmt(..), CmmExpr(..), CmmLit(..), LocalReg,
  53                           CmmBasicBlock, nodeReg )
  54 import MachOp           ( MachOp(..), wordRep, halfWordRep )
  55 import CLabel
  56 import StgSyn           ( SRT(..) )
  57 import Name             ( Name )
  58 import DataCon          ( DataCon, dataConTag, fIRST_TAG )
  59 import Unique           ( Uniquable(..) )
  60 import CmdLineOpts      ( opt_SccProfilingOn, DynFlags(..), HscTarget(..) )
  61 import ListSetOps       ( assocDefault )
  62 import Maybes           ( isJust )
  63 import Constants        ( wORD_SIZE, sIZEOF_StgFunInfoExtraRev )
  64 import Outputable
  65
  66
  67 -------------------------------------------------------------------------
  68 --
  69 --      Generating the info table and code for a closure
  70 --
  71 -------------------------------------------------------------------------
  72
  73 -- Here we make a concrete info table, represented as a list of CmmAddr
  74 -- (it can't be simply a list of Word, because the SRT field is
  75 -- represented by a label+offset expression).
  76
  77 -- With tablesNextToCode, the layout is
  78 --      <reversed variable part>
  79 --      <normal forward StgInfoTable, but without
  80 --              an entry point at the front>
  81 --      <code>
  82 --
  83 -- Without tablesNextToCode, the layout of an info table is
  84 --      <entry label>
  85 --      <normal forward rest of StgInfoTable>
  86 --      <forward variable part>
  87 --
  88 --      See includes/InfoTables.h
  89
  90 emitClosureCodeAndInfoTable :: ClosureInfo -> [LocalReg] -> CgStmts -> Code
  91 emitClosureCodeAndInfoTable cl_info args body
  92  = do   { ty_descr_lit <-
  93                 if opt_SccProfilingOn
  94                    then mkStringCLit (closureTypeDescr cl_info)
  95                    else return (mkIntCLit 0)
  96         ; cl_descr_lit <-
  97                 if opt_SccProfilingOn
  98                    then mkStringCLit cl_descr_string
  99                    else return (mkIntCLit 0)
 100         ; let std_info = mkStdInfoTable ty_descr_lit cl_descr_lit
 101                                         cl_type srt_len layout_lit
 102
 103         ; blks <- cgStmtsToBlocks body
 104         ; emitInfoTableAndCode info_lbl std_info extra_bits args blks }
 105   where
 106     info_lbl  = infoTableLabelFromCI cl_info
 107
 108     cl_descr_string = closureValDescr cl_info
 109     cl_type = smRepClosureTypeInt (closureSMRep cl_info)
 110
 111     srt = closureSRT cl_info
 112     needs_srt = needsSRT srt
 113
 114     mb_con = isConstrClosure_maybe  cl_info
 115     is_con = isJust mb_con
 116
 117     (srt_label,srt_len)
 118         = case mb_con of
 119             Just con -> -- Constructors don't have an SRT
 120                         -- We keep the *zero-indexed* tag in the srt_len
 121                         -- field of the info table.
 122                         (mkIntCLit 0, fromIntegral (dataConTagZ con))
 123
 124             Nothing  -> -- Not a constructor
 125                         srtLabelAndLength srt info_lbl
 126
 127     ptrs       = closurePtrsSize cl_info
 128     nptrs      = size - ptrs
 129     size       = closureNonHdrSize cl_info
 130     layout_lit = packHalfWordsCLit ptrs nptrs
 131
 132     extra_bits
 133         | is_fun    = fun_extra_bits
 134         | is_con    = []
 135         | needs_srt = [srt_label]
 136         | otherwise = []
 137
 138     maybe_fun_stuff = closureFunInfo cl_info
 139     is_fun = isJust maybe_fun_stuff
 140     (Just (arity, arg_descr)) = maybe_fun_stuff
 141
 142     fun_extra_bits
 143         | ArgGen liveness <- arg_descr
 144         = [ fun_amode,
 145             srt_label,
 146             makeRelativeRefTo info_lbl $ mkLivenessCLit liveness,
 147             slow_entry ]
 148         | needs_srt = [fun_amode, srt_label]
 149         | otherwise = [fun_amode]
 150
 151     slow_entry = makeRelativeRefTo info_lbl (CmmLabel slow_entry_label)
 152     slow_entry_label = mkSlowEntryLabel (closureName cl_info)
 153
 154     fun_amode = packHalfWordsCLit fun_type arity
 155     fun_type  = argDescrType arg_descr
 156
 157 -- We keep the *zero-indexed* tag in the srt_len field of the info
 158 -- table of a data constructor.
 159 dataConTagZ :: DataCon -> ConTagZ
 160 dataConTagZ con = dataConTag con - fIRST_TAG
 161
 162 -- A low-level way to generate the variable part of a fun-style info table.
 163 -- (must match fun_extra_bits above).  Used by the C-- parser.
 164 mkFunGenInfoExtraBits :: Int -> Int -> CmmLit -> CmmLit -> CmmLit -> [CmmLit]
 165 mkFunGenInfoExtraBits fun_type arity srt_label liveness slow_entry
 166   = [ packHalfWordsCLit fun_type arity,
 167       srt_label,
 168       liveness,
 169       slow_entry ]
 170
 171 -------------------------------------------------------------------------
 172 --
 173 --      Generating the info table and code for a return point
 174 --
 175 -------------------------------------------------------------------------
 176
 177 --      Here's the layout of a return-point info table
 178 --
 179 -- Tables next to code:
 180 --
 181 --                      <reversed vector table>
 182 --                      <srt slot>
 183 --                      <standard info table>
 184 --      ret-addr -->    <entry code (if any)>
 185 --
 186 -- Not tables-next-to-code:
 187 --
 188 --      ret-addr -->    <ptr to entry code>
 189 --                      <standard info table>
 190 --                      <srt slot>
 191 --                      <forward vector table>
 192 --
 193 -- * The vector table is only present for vectored returns
 194 --
 195 -- * The SRT slot is only there if either
 196 --      (a) there is SRT info to record, OR
 197 --      (b) if the return is vectored
 198 --   The latter (b) is necessary so that the vector is in a
 199 --   predictable place
 200
 201 vectorSlot :: CmmExpr -> CmmExpr -> CmmExpr
 202 -- Get the vector slot from the info pointer
 203 vectorSlot info_amode zero_indexed_tag
 204   | tablesNextToCode
 205   = cmmOffsetExprW (cmmOffsetW info_amode (- (stdInfoTableSizeW + 2)))
 206                    (cmmNegate zero_indexed_tag)
 207         -- The "2" is one for the SRT slot, and one more
 208         -- to get to the first word of the vector
 209
 210   | otherwise
 211   = cmmOffsetExprW (cmmOffsetW info_amode (stdInfoTableSizeW + 2))
 212                    zero_indexed_tag
 213         -- The "2" is one for the entry-code slot and one for the SRT slot
 214
 215 retVec :: CmmExpr -> CmmExpr -> CmmExpr
 216 -- Get a return vector from the info pointer
 217 retVec info_amode zero_indexed_tag
 218   = let slot = vectorSlot info_amode zero_indexed_tag
 219         tableEntry = CmmLoad slot wordRep
 220     in if tablesNextToCode
 221            then CmmMachOp (MO_Add wordRep) [tableEntry, info_amode]
 222            else tableEntry
 223
 224 emitReturnTarget
 225    :: Name
 226    -> CgStmts                   -- The direct-return code (if any)
 227                                 --      (empty for vectored returns)
 228    -> [CmmLit]                  -- Vector of return points
 229                                 --      (empty for non-vectored returns)
 230    -> SRT
 231    -> FCode CLabel
 232 emitReturnTarget name stmts vector srt
 233   = do  { live_slots <- getLiveStackSlots
 234         ; liveness   <- buildContLiveness name live_slots
 235         ; srt_info   <- getSRTInfo name srt
 236
 237         ; let
 238               cl_type = case (null vector, isBigLiveness liveness) of
 239                          (True,  True)  -> rET_BIG
 240                          (True,  False) -> rET_SMALL
 241                          (False, True)  -> rET_VEC_BIG
 242                          (False, False) -> rET_VEC_SMALL
 243
 244               (std_info, extra_bits) =
 245                    mkRetInfoTable info_lbl liveness srt_info cl_type vector
 246
 247         ; blks <- cgStmtsToBlocks stmts
 248         ; emitInfoTableAndCode info_lbl std_info extra_bits args blks
 249         ; return info_lbl }
 250   where
 251     args = trace "emitReturnTarget: missing args" []
 252     uniq      = getUnique name
 253     info_lbl  = mkReturnInfoLabel uniq
 254
 255
 256 mkRetInfoTable
 257   :: CLabel             -- info label
 258   -> Liveness           -- liveness
 259   -> C_SRT              -- SRT Info
 260   -> Int                -- type (eg. rET_SMALL)
 261   -> [CmmLit]           -- vector
 262   -> ([CmmLit],[CmmLit])
 263 mkRetInfoTable info_lbl liveness srt_info cl_type vector
 264   =  (std_info, extra_bits)
 265   where
 266         (srt_label, srt_len) = srtLabelAndLength srt_info info_lbl
 267
 268         srt_slot | need_srt  = [srt_label]
 269                  | otherwise = []
 270
 271         need_srt = needsSRT srt_info || not (null vector)
 272                 -- If there's a vector table then we must allocate
 273                 -- an SRT slot, so that the vector table is at a
 274                 -- known offset from the info pointer
 275
 276         liveness_lit = makeRelativeRefTo info_lbl $ mkLivenessCLit liveness
 277         std_info = mkStdInfoTable zeroCLit zeroCLit cl_type srt_len liveness_lit
 278         extra_bits = srt_slot ++ map (makeRelativeRefTo info_lbl) vector
 279
 280
 281 emitDirectReturnTarget
 282    :: Name
 283    -> CgStmts           -- The direct-return code
 284    -> SRT
 285    -> FCode CLabel
 286 emitDirectReturnTarget name code srt
 287   = emitReturnTarget name code [] srt
 288
 289 emitAlgReturnTarget
 290         :: Name                         -- Just for its unique
 291         -> [(ConTagZ, CgStmts)]         -- Tagged branches
 292         -> Maybe CgStmts                -- Default branch (if any)
 293         -> SRT                          -- Continuation's SRT
 294         -> CtrlReturnConvention
 295         -> FCode (CLabel, SemiTaggingStuff)
 296
 297 emitAlgReturnTarget name branches mb_deflt srt ret_conv
 298   = case ret_conv of
 299       UnvectoredReturn fam_sz -> do
 300         { blks <- getCgStmts $
 301                     emitSwitch tag_expr branches mb_deflt 0 (fam_sz - 1)
 302                 -- NB: tag_expr is zero-based
 303         ; lbl <- emitDirectReturnTarget name blks srt
 304         ; return (lbl, Nothing) }
 305                 -- Nothing: the internal branches in the switch don't have
 306                 -- global labels, so we can't use them at the 'call site'
 307
 308       VectoredReturn fam_sz -> do
 309         { let tagged_lbls = zip (map fst branches) $
 310                             map (CmmLabel . mkAltLabel uniq . fst) branches
 311               deflt_lbl | isJust mb_deflt = CmmLabel $ mkDefaultLabel uniq
 312                         | otherwise       = mkIntCLit 0
 313         ; let vector = [ assocDefault deflt_lbl tagged_lbls i
 314                        | i <- [0..fam_sz-1]]
 315         ; lbl <- emitReturnTarget name noCgStmts vector srt
 316         ; mapFCs emit_alt branches
 317         ; emit_deflt mb_deflt
 318         ; return (lbl, Just (tagged_lbls, deflt_lbl)) }
 319   where
 320     uniq = getUnique name
 321     tag_expr = getConstrTag (CmmReg nodeReg)
 322
 323     emit_alt :: (Int, CgStmts) -> FCode (Int, CmmLit)
 324         -- Emit the code for the alternative as a top-level
 325         -- code block returning a label for it
 326     emit_alt (tag, stmts) = do   { let lbl = mkAltLabel uniq tag
 327                                  ; blks <- cgStmtsToBlocks stmts
 328                                  ; emitProc [] lbl [] blks
 329                                  ; return (tag, CmmLabel lbl) }
 330
 331     emit_deflt (Just stmts) = do { let lbl = mkDefaultLabel uniq
 332                                  ; blks <- cgStmtsToBlocks stmts
 333                                  ; emitProc [] lbl [] blks
 334                                  ; return (CmmLabel lbl) }
 335     emit_deflt Nothing = return (mkIntCLit 0)
 336                 -- Nothing case: the simplifier might have eliminated a case
 337                 --               so we may have e.g. case xs of
 338                 --                                       [] -> e
 339                 -- In that situation the default should never be taken,
 340                 -- so we just use a NULL pointer
 341
 342 --------------------------------
 343 emitDirectReturnInstr :: Code
 344 emitDirectReturnInstr
 345   = do  { info_amode <- getSequelAmode
 346         ; stmtC (CmmJump (entryCode info_amode) []) }
 347
 348 emitVectoredReturnInstr :: CmmExpr      -- *Zero-indexed* constructor tag
 349                         -> Code
 350 emitVectoredReturnInstr zero_indexed_tag
 351   = do  { info_amode <- getSequelAmode
 352                 -- HACK! assign info_amode to a temp, because retVec
 353                 -- uses it twice and the NCG doesn't have any CSE yet.
 354                 -- Only do this for the NCG, because gcc is too stupid
 355                 -- to optimise away the extra tmp (grrr).
 356         ; dflags <- getDynFlags
 357         ; x <- if hscTarget dflags == HscAsm
 358                    then do z <- newTemp wordRep
 359                            stmtC (CmmAssign z info_amode)
 360                            return (CmmReg z)
 361                    else
 362
 363                         return info_amode
 364         ; let target = retVec x zero_indexed_tag
 365         ; stmtC (CmmJump target []) }
 366
 367
 368 -------------------------------------------------------------------------
 369 --
 370 --      Generating a standard info table
 371 --
 372 -------------------------------------------------------------------------
 373
 374 -- The standard bits of an info table.  This part of the info table
 375 -- corresponds to the StgInfoTable type defined in InfoTables.h.
 376 --
 377 -- Its shape varies with ticky/profiling/tables next to code etc
 378 -- so we can't use constant offsets from Constants
 379
 380 mkStdInfoTable
 381    :: CmmLit            -- closure type descr (profiling)
 382    -> CmmLit            -- closure descr (profiling)
 383    -> Int               -- closure type
 384    -> StgHalfWord       -- SRT length
 385    -> CmmLit            -- layout field
 386    -> [CmmLit]
 387
 388 mkStdInfoTable type_descr closure_descr cl_type srt_len layout_lit
 389  =      -- Parallel revertible-black hole field
 390     prof_info
 391         -- Ticky info (none at present)
 392         -- Debug info (none at present)
 393  ++ [layout_lit, type_lit]
 394
 395  where
 396     prof_info
 397         | opt_SccProfilingOn = [closure_descr, type_descr]
 398         | otherwise          = []
 399
 400     type_lit = packHalfWordsCLit cl_type srt_len
 401
 402 stdInfoTableSizeW :: WordOff
 403 -- The size of a standard info table varies with profiling/ticky etc,
 404 -- so we can't get it from Constants
 405 -- It must vary in sync with mkStdInfoTable
 406 stdInfoTableSizeW
 407   = size_fixed + size_prof
 408   where
 409     size_fixed = 2      -- layout, type
 410     size_prof | opt_SccProfilingOn = 2
 411               | otherwise          = 0
 412
 413 stdInfoTableSizeB = stdInfoTableSizeW * wORD_SIZE :: ByteOff
 414
 415 stdSrtBitmapOffset :: ByteOff
 416 -- Byte offset of the SRT bitmap half-word which is
 417 -- in the *higher-addressed* part of the type_lit
 418 stdSrtBitmapOffset = stdInfoTableSizeB - hALF_WORD_SIZE
 419
 420 stdClosureTypeOffset :: ByteOff
 421 -- Byte offset of the closure type half-word
 422 stdClosureTypeOffset = stdInfoTableSizeB - wORD_SIZE
 423
 424 stdPtrsOffset, stdNonPtrsOffset :: ByteOff
 425 stdPtrsOffset    = stdInfoTableSizeB - 2*wORD_SIZE
 426 stdNonPtrsOffset = stdInfoTableSizeB - 2*wORD_SIZE + hALF_WORD_SIZE
 427
 428 -------------------------------------------------------------------------
 429 --
 430 --      Accessing fields of an info table
 431 --
 432 -------------------------------------------------------------------------
 433
 434 closureInfoPtr :: CmmExpr -> CmmExpr
 435 -- Takes a closure pointer and returns the info table pointer
 436 closureInfoPtr e = CmmLoad e wordRep
 437
 438 entryCode :: CmmExpr -> CmmExpr
 439 -- Takes an info pointer (the first word of a closure)
 440 -- and returns its entry code
 441 entryCode e | tablesNextToCode = e
 442             | otherwise        = CmmLoad e wordRep
 443
 444 getConstrTag :: CmmExpr -> CmmExpr
 445 -- Takes a closure pointer, and return the *zero-indexed*
 446 -- constructor tag obtained from the info table
 447 -- This lives in the SRT field of the info table
 448 -- (constructors don't need SRTs).
 449 getConstrTag closure_ptr
 450   = CmmMachOp (MO_U_Conv halfWordRep wordRep) [infoTableConstrTag info_table]
 451   where
 452     info_table = infoTable (closureInfoPtr closure_ptr)
 453
 454 infoTable :: CmmExpr -> CmmExpr
 455 -- Takes an info pointer (the first word of a closure)
 456 -- and returns a pointer to the first word of the standard-form
 457 -- info table, excluding the entry-code word (if present)
 458 infoTable info_ptr
 459   | tablesNextToCode = cmmOffsetB info_ptr (- stdInfoTableSizeB)
 460   | otherwise        = cmmOffsetW info_ptr 1    -- Past the entry code pointer
 461
 462 infoTableConstrTag :: CmmExpr -> CmmExpr
 463 -- Takes an info table pointer (from infoTable) and returns the constr tag
 464 -- field of the info table (same as the srt_bitmap field)
 465 infoTableConstrTag = infoTableSrtBitmap
 466
 467 infoTableSrtBitmap :: CmmExpr -> CmmExpr
 468 -- Takes an info table pointer (from infoTable) and returns the srt_bitmap
 469 -- field of the info table
 470 infoTableSrtBitmap info_tbl
 471   = CmmLoad (cmmOffsetB info_tbl stdSrtBitmapOffset) halfWordRep
 472
 473 infoTableClosureType :: CmmExpr -> CmmExpr
 474 -- Takes an info table pointer (from infoTable) and returns the closure type
 475 -- field of the info table.
 476 infoTableClosureType info_tbl
 477   = CmmLoad (cmmOffsetB info_tbl stdClosureTypeOffset) halfWordRep
 478
 479 infoTablePtrs :: CmmExpr -> CmmExpr
 480 infoTablePtrs info_tbl
 481   = CmmLoad (cmmOffsetB info_tbl stdPtrsOffset) halfWordRep
 482
 483 infoTableNonPtrs :: CmmExpr -> CmmExpr
 484 infoTableNonPtrs info_tbl
 485   = CmmLoad (cmmOffsetB info_tbl stdNonPtrsOffset) halfWordRep
 486
 487 funInfoTable :: CmmExpr -> CmmExpr
 488 -- Takes the info pointer of a function,
 489 -- and returns a pointer to the first word of the StgFunInfoExtra struct
 490 -- in the info table.
 491 funInfoTable info_ptr
 492   | tablesNextToCode
 493   = cmmOffsetB info_ptr (- stdInfoTableSizeB - sIZEOF_StgFunInfoExtraRev)
 494   | otherwise
 495   = cmmOffsetW info_ptr (1 + stdInfoTableSizeW)
 496                                 -- Past the entry code pointer
 497
 498 -------------------------------------------------------------------------
 499 --
 500 --      Emit the code for a closure (or return address)
 501 --      and its associated info table
 502 --
 503 -------------------------------------------------------------------------
 504
 505 -- The complication here concerns whether or not we can
 506 -- put the info table next to the code
 507
 508 emitInfoTableAndCode
 509         :: CLabel               -- Label of info table
 510         -> [CmmLit]             -- ...its invariant part
 511         -> [CmmLit]             -- ...and its variant part
 512         -> [LocalReg]           -- ...args
 513         -> [CmmBasicBlock]      -- ...and body
 514         -> Code
 515
 516 emitInfoTableAndCode info_lbl std_info extra_bits args blocks
 517   | tablesNextToCode    -- Reverse the extra_bits; and emit the top-level proc
 518   = emitProc (reverse extra_bits ++ std_info)
 519              entry_lbl args blocks
 520         -- NB: the info_lbl is discarded
 521
 522   | null blocks -- No actual code; only the info table is significant
 523   =             -- Use a zero place-holder in place of the
 524                 -- entry-label in the info table
 525     emitRODataLits info_lbl (zeroCLit : std_info ++ extra_bits)
 526
 527   | otherwise   -- Separately emit info table (with the function entry
 528   =             -- point as first entry) and the entry code
 529     do  { emitDataLits info_lbl (CmmLabel entry_lbl : std_info ++ extra_bits)
 530         ; emitProc [] entry_lbl args blocks }
 531
 532   where
 533         entry_lbl = infoLblToEntryLbl info_lbl
 534
 535 -------------------------------------------------------------------------
 536 --
 537 --      Static reference tables
 538 --
 539 -------------------------------------------------------------------------
 540
 541 -- There is just one SRT for each top level binding; all the nested
 542 -- bindings use sub-sections of this SRT.  The label is passed down to
 543 -- the nested bindings via the monad.
 544
 545 getSRTInfo :: Name -> SRT -> FCode C_SRT
 546 getSRTInfo id NoSRT = return NoC_SRT
 547 getSRTInfo id (SRT off len bmp)
 548   | len > hALF_WORD_SIZE_IN_BITS || bmp == [fromIntegral srt_escape]
 549   = do  { srt_lbl <- getSRTLabel
 550         ; let srt_desc_lbl = mkSRTDescLabel id
 551         ; emitRODataLits srt_desc_lbl
 552                    ( cmmLabelOffW srt_lbl off
 553                    : mkWordCLit (fromIntegral len)
 554                    : map mkWordCLit bmp)
 555         ; return (C_SRT srt_desc_lbl 0 srt_escape) }
 556
 557   | otherwise
 558   = do  { srt_lbl <- getSRTLabel
 559         ; return (C_SRT srt_lbl off (fromIntegral (head bmp))) }
 560                 -- The fromIntegral converts to StgHalfWord
 561
 562 srt_escape = (-1) :: StgHalfWord
 563
 564 srtLabelAndLength :: C_SRT -> CLabel -> (CmmLit, StgHalfWord)
 565 srtLabelAndLength NoC_SRT _
 566   = (zeroCLit, 0)
 567 srtLabelAndLength (C_SRT lbl off bitmap) info_lbl
 568   = (makeRelativeRefTo info_lbl $ cmmLabelOffW lbl off, bitmap)
 569
 570 -------------------------------------------------------------------------
 571 --
 572 --      Position independent code
 573 --
 574 -------------------------------------------------------------------------
 575 -- In order to support position independent code, we mustn't put absolute
 576 -- references into read-only space. Info tables in the tablesNextToCode
 577 -- case must be in .text, which is read-only, so we doctor the CmmLits
 578 -- to use relative offsets instead.
 579
 580 -- Note that this is done even when the -fPIC flag is not specified,
 581 -- as we want to keep binary compatibility between PIC and non-PIC.
 582
 583 makeRelativeRefTo :: CLabel -> CmmLit -> CmmLit
 584
 585 makeRelativeRefTo info_lbl (CmmLabel lbl)
 586   | tablesNextToCode
 587   = CmmLabelDiffOff lbl info_lbl 0
 588 makeRelativeRefTo info_lbl (CmmLabelOff lbl off)
 589   | tablesNextToCode
 590   = CmmLabelDiffOff lbl info_lbl off
 591 makeRelativeRefTo _ lit = lit