ghc/compiler/compMan/CmTypes.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[CmTypes]{Types for the compilation manager}
   5
   6 \begin{code}
   7 module CmTypes (
   8    Unlinked(..),  isObject, nameOfObject, isInterpretable,
   9    Linkable(..),
  10    ModSummary(..), ms_allimps, name_of_summary, pprSummaryTime
  11   ) where
  12
  13 import Interpreter
  14 import HscTypes
  15 import Module
  16 --import CmStaticInfo
  17 import Outputable
  18
  19 import Time             ( ClockTime )
  20
  21
  22 data Unlinked
  23    = DotO FilePath
  24    | DotA FilePath
  25    | DotDLL FilePath
  26    | BCOs [UnlinkedBCO] ItblEnv  -- bunch of interpretable bindings, +
  27                                  -- a mapping from DataCons to their itbls
  28
  29 instance Outputable Unlinked where
  30    ppr (DotO path)   = text "DotO" <+> text path
  31    ppr (DotA path)   = text "DotA" <+> text path
  32    ppr (DotDLL path) = text "DotDLL" <+> text path
  33    ppr (BCOs bcos _) = text "BCOs" <+> vcat (map ppr bcos)
  34
  35 isObject (DotO _) = True
  36 isObject (DotA _) = True
  37 isObject (DotDLL _) = True
  38 isObject _ = False
  39
  40 nameOfObject (DotO fn)   = fn
  41 nameOfObject (DotA fn)   = fn
  42 nameOfObject (DotDLL fn) = fn
  43
  44 isInterpretable (BCOs _ _) = True
  45 isInterpretable _          = False
  46
  47 data Linkable = LM {
  48   linkableTime :: ClockTime,
  49   linkableModName ::  ModuleName,
  50   linkableUnlinked ::  [Unlinked]
  51  }
  52
  53 instance Outputable Linkable where
  54    ppr (LM when_made mod_nm unlinkeds)
  55       = text "LinkableM" <+> parens (text (show when_made)) <+> ppr mod_nm
  56                          <+> ppr unlinkeds
  57
  58 -- The ModuleLocation contains both the original source filename and the
  59 -- filename of the cleaned-up source file after all preprocessing has been
  60 -- done.  The point is that the summariser will have to cpp/unlit/whatever
  61 -- all files anyway, and there's no point in doing this twice -- just
  62 -- park the result in a temp file, put the name of it in the location,
  63 -- and let @compile@ read from that file on the way back up.
  64 data ModSummary
  65    = ModSummary {
  66         ms_mod      :: Module,               -- name, package
  67         ms_location :: ModuleLocation,       -- location
  68         ms_srcimps  :: [ModuleName],         -- source imports
  69         ms_imps     :: [ModuleName],         -- non-source imports
  70         ms_hs_date  :: Maybe ClockTime       -- timestamp of summarised
  71                                              -- file, if home && source
  72      }
  73
  74 instance Outputable ModSummary where
  75    ppr ms
  76       = sep [text "ModSummary {",
  77              nest 3 (sep [text "ms_hs_date = " <> text (show (ms_hs_date ms)),
  78                           text "ms_mod =" <+> ppr (ms_mod ms) <> comma,
  79                           text "ms_imps =" <+> ppr (ms_imps ms),
  80                           text "ms_srcimps =" <+> ppr (ms_srcimps ms)]),
  81              char '}'
  82             ]
  83
  84 pprSummaryTime ms
  85    = text "ms_hs_date = " <> parens (text (show (ms_hs_date ms)))
  86
  87 ms_allimps ms
  88    = ms_srcimps ms ++ ms_imps ms
  89
  90 name_of_summary :: ModSummary -> ModuleName
  91 name_of_summary = moduleName . ms_mod
  92 \end{code}