ghc/compiler/compMan/CompManager.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section[CompManager]{The Compilation Manager}
   5
   6 \begin{code}
   7 module CompManager (
   8     cmInit,       -- :: GhciMode -> IO CmState
   9
  10     cmLoadModule, -- :: CmState -> FilePath -> IO (CmState, [String])
  11
  12     cmUnload,     -- :: CmState -> IO CmState
  13
  14     cmSetContext, -- :: CmState -> String -> IO CmState
  15
  16     cmGetContext, -- :: CmState -> IO String
  17
  18 #ifdef GHCI
  19     cmRunStmt,    --  :: CmState -> DynFlags -> String -> IO (CmState, [Name])
  20
  21     cmTypeOfExpr, --  :: CmState -> DynFlags -> String
  22                   --  -> IO (CmState, Maybe String)
  23
  24     cmTypeOfName, -- :: CmState -> Name -> IO (Maybe String)
  25
  26     cmCompileExpr,-- :: CmState -> DynFlags -> String
  27                   -- -> IO (CmState, Maybe HValue)#endif
  28 #endif
  29     CmState, emptyCmState  -- abstract
  30   )
  31 where
  32
  33 #include "HsVersions.h"
  34
  35 import CmLink
  36 import CmTypes
  37 import CmStaticInfo     ( GhciMode(..) )
  38 import DriverPipeline
  39 import DriverFlags      ( getDynFlags )
  40 import DriverPhases
  41 import DriverUtil
  42 import Finder
  43 import HscMain          ( initPersistentCompilerState )
  44 import HscTypes
  45 import RnEnv            ( unQualInScope )
  46 import Id               ( idType, idName )
  47 import Name             ( Name, NamedThing(..), nameRdrName )
  48 import NameEnv
  49 import RdrName          ( lookupRdrEnv, emptyRdrEnv )
  50 import Module
  51 import GetImports
  52 import Type             ( tidyType )
  53 import VarEnv           ( emptyTidyEnv )
  54 import UniqFM
  55 import Unique           ( Uniquable )
  56 import Digraph          ( SCC(..), stronglyConnComp, flattenSCC )
  57 import ErrUtils         ( showPass )
  58 import Util
  59 import TmpFiles
  60 import Outputable
  61 import Panic
  62 import CmdLineOpts      ( DynFlags(..) )
  63 import IOExts
  64
  65 #ifdef GHCI
  66 import Interpreter      ( HValue )
  67 import HscMain          ( hscStmt )
  68 import PrelGHC          ( unsafeCoerce# )
  69 #endif
  70
  71 -- lang
  72 import Exception        ( throwDyn )
  73
  74 -- std
  75 import Directory        ( getModificationTime, doesFileExist )
  76 import IO
  77 import Monad
  78 import List             ( nub )
  79 import Maybe
  80 \end{code}
  81
  82
  83 \begin{code}
  84 -- Persistent state for the entire system
  85 data CmState
  86    = CmState {
  87         hst   :: HomeSymbolTable,    -- home symbol table
  88         hit   :: HomeIfaceTable,     -- home interface table
  89         ui    :: UnlinkedImage,      -- the unlinked images
  90         mg    :: ModuleGraph,        -- the module graph
  91         gmode :: GhciMode,           -- NEVER CHANGES
  92         ic    :: InteractiveContext, -- command-line binding info
  93
  94         pcs    :: PersistentCompilerState, -- compile's persistent state
  95         pls    :: PersistentLinkerState    -- link's persistent state
  96      }
  97
  98 emptyCmState :: GhciMode -> Module -> IO CmState
  99 emptyCmState gmode mod
 100     = do pcs     <- initPersistentCompilerState
 101          pls     <- emptyPLS
 102          return (CmState { hst    = emptySymbolTable,
 103                            hit    = emptyIfaceTable,
 104                            ui     = emptyUI,
 105                            mg     = emptyMG,
 106                            gmode  = gmode,
 107                            ic     = emptyInteractiveContext mod,
 108                            pcs    = pcs,
 109                            pls    = pls })
 110
 111 emptyInteractiveContext mod
 112   = InteractiveContext { ic_module = mod,
 113                          ic_rn_env = emptyRdrEnv,
 114                          ic_type_env = emptyTypeEnv }
 115
 116 defaultCurrentModuleName = mkModuleName "Prelude"
 117 GLOBAL_VAR(defaultCurrentModule, error "no defaultCurrentModule", Module)
 118
 119 -- CM internal types
 120 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
 121 emptyUI :: UnlinkedImage
 122 emptyUI = []
 123
 124 type ModuleGraph = [ModSummary]  -- the module graph, topologically sorted
 125 emptyMG :: ModuleGraph
 126 emptyMG = []
 127
 128 -----------------------------------------------------------------------------
 129 -- Produce an initial CmState.
 130
 131 cmInit :: GhciMode -> IO CmState
 132 cmInit mode = do
 133    prel <- moduleNameToModule defaultCurrentModuleName
 134    writeIORef defaultCurrentModule prel
 135    emptyCmState mode prel
 136
 137 -----------------------------------------------------------------------------
 138 -- Setting the context doesn't throw away any bindings; the bindings
 139 -- we've built up in the InteractiveContext simply move to the new
 140 -- module.  They always shadow anything in scope in the current context.
 141
 142 cmSetContext :: CmState -> String -> IO CmState
 143 cmSetContext cmstate str
 144    = do let mn = mkModuleName str
 145             modules_loaded = [ (name_of_summary s, ms_mod s)  | s <- mg cmstate ]
 146
 147         m <- case lookup mn modules_loaded of
 148                 Just m  -> return m
 149                 Nothing -> do
 150                    mod <- moduleNameToModule mn
 151                    if isHomeModule mod
 152                         then throwDyn (CmdLineError (showSDoc
 153                                 (quotes (ppr (moduleName mod))
 154                                   <+> text "is not currently loaded")))
 155                         else return mod
 156
 157         return cmstate{ ic = (ic cmstate){ic_module=m} }
 158
 159 cmGetContext :: CmState -> IO String
 160 cmGetContext cmstate = return (moduleUserString (ic_module (ic cmstate)))
 161
 162 moduleNameToModule :: ModuleName -> IO Module
 163 moduleNameToModule mn
 164  = do maybe_stuff <- findModule mn
 165       case maybe_stuff of
 166         Nothing -> throwDyn (CmdLineError ("can't find module `"
 167                                     ++ moduleNameUserString mn ++ "'"))
 168         Just (m,_) -> return m
 169
 170 -----------------------------------------------------------------------------
 171 -- cmRunStmt:  Run a statement/expr.
 172
 173 #ifdef GHCI
 174 cmRunStmt :: CmState -> DynFlags -> String
 175         -> IO (CmState,                 -- new state
 176                [Name])                  -- names bound by this evaluation
 177 cmRunStmt cmstate dflags expr
 178    = do
 179         let InteractiveContext {
 180                 ic_rn_env = rn_env,
 181                 ic_type_env = type_env,
 182                 ic_module   = this_mod } = icontext
 183
 184         (new_pcs, maybe_stuff)
 185             <- hscStmt dflags hst hit pcs icontext expr False{-stmt-}
 186
 187         case maybe_stuff of
 188            Nothing -> return (cmstate{ pcs=new_pcs }, [])
 189            Just (ids, _, bcos) -> do
 190
 191                 -- update the interactive context
 192                 let
 193                     names = map idName ids
 194
 195                     -- these names have just been shadowed
 196                     shadowed = [ n | r <- map nameRdrName names,
 197                                      Just n <- [lookupRdrEnv rn_env r] ]
 198
 199                     new_rn_env   = extendLocalRdrEnv rn_env names
 200
 201                     -- remove any shadowed bindings from the type_env
 202                     filtered_type_env = delListFromNameEnv type_env shadowed
 203
 204                     new_type_env = extendNameEnvList filtered_type_env
 205                                         [ (getName id, AnId id) | id <- ids]
 206
 207                     new_ic = icontext { ic_rn_env   = new_rn_env,
 208                                         ic_type_env = new_type_env }
 209
 210                 -- link it
 211                 hval <- linkExpr pls bcos
 212
 213                 -- run it!
 214                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 215                 hvals <- thing_to_run
 216
 217                 -- Get the newly bound things, and bind them.  Don't forget
 218                 -- to delete any shadowed bindings from the closure_env, lest
 219                 -- we end up with a space leak.
 220                 pls <- delListFromClosureEnv pls shadowed
 221                 new_pls <- addListToClosureEnv pls (zip names hvals)
 222
 223                 return (cmstate{ pcs=new_pcs, pls=new_pls, ic=new_ic }, names)
 224    where
 225        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 226 #endif
 227
 228 -----------------------------------------------------------------------------
 229 -- cmTypeOfExpr: returns a string representing the type of an expression
 230
 231 #ifdef GHCI
 232 cmTypeOfExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe String)
 233 cmTypeOfExpr cmstate dflags expr
 234    = do (new_pcs, maybe_stuff)
 235           <- hscStmt dflags hst hit pcs ic expr True{-just an expr-}
 236
 237         let new_cmstate = cmstate{pcs = new_pcs}
 238
 239         case maybe_stuff of
 240            Nothing -> return (new_cmstate, Nothing)
 241            Just (_, ty, _) ->
 242              let pit = pcs_PIT pcs
 243                  modname = moduleName (ic_module ic)
 244                  tidy_ty = tidyType emptyTidyEnv ty
 245                  str = case lookupIfaceByModName hit pit modname of
 246                           Nothing    -> showSDoc (ppr tidy_ty)
 247                           Just iface -> showSDocForUser unqual (ppr tidy_ty)
 248                              where unqual = unQualInScope (mi_globals iface)
 249              in return (new_cmstate, Just str)
 250    where
 251        CmState{ hst=hst, hit=hit, pcs=pcs, ic=ic } = cmstate
 252 #endif
 253
 254 -----------------------------------------------------------------------------
 255 -- cmTypeOfName: returns a string representing the type of a name.
 256
 257 #ifdef GHCI
 258 cmTypeOfName :: CmState -> Name -> IO (Maybe String)
 259 cmTypeOfName CmState{ hit=hit, pcs=pcs, ic=ic } name
 260  = case lookupNameEnv (ic_type_env ic) name of
 261         Nothing -> return Nothing
 262         Just (AnId id) ->
 263            let pit = pcs_PIT pcs
 264                modname = moduleName (ic_module ic)
 265                ty = tidyType emptyTidyEnv (idType id)
 266                str = case lookupIfaceByModName hit pit modname of
 267                         Nothing    -> showSDoc (ppr ty)
 268                         Just iface -> showSDocForUser unqual (ppr ty)
 269                            where unqual = unQualInScope (mi_globals iface)
 270            in return (Just str)
 271
 272         _ -> panic "cmTypeOfName"
 273 #endif
 274
 275 -----------------------------------------------------------------------------
 276 -- cmCompileExpr: compile an expression and deliver an HValue
 277
 278 #ifdef GHCI
 279 cmCompileExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe HValue)
 280 cmCompileExpr cmstate dflags expr
 281    = do
 282         let InteractiveContext {
 283                 ic_rn_env = rn_env,
 284                 ic_type_env = type_env,
 285                 ic_module   = this_mod } = icontext
 286
 287         (new_pcs, maybe_stuff)
 288             <- hscStmt dflags hst hit pcs icontext
 289                   ("let __cmCompileExpr = "++expr) False{-stmt-}
 290
 291         case maybe_stuff of
 292            Nothing -> return (cmstate{ pcs=new_pcs }, Nothing)
 293            Just (ids, _, bcos) -> do
 294
 295                 -- link it
 296                 hval <- linkExpr pls bcos
 297
 298                 -- run it!
 299                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 300                 hvals <- thing_to_run
 301
 302                 case (ids,hvals) of
 303                   ([id],[hv]) -> return (cmstate{ pcs=new_pcs }, Just hv)
 304                   _ -> panic "cmCompileExpr"
 305
 306    where
 307        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 308 #endif
 309
 310 -----------------------------------------------------------------------------
 311 -- cmInfo: return "info" about an expression.  The info might be:
 312 --
 313 --      * its type, for an expression,
 314 --      * the class definition, for a class
 315 --      * the datatype definition, for a tycon (or synonym)
 316 --      * the export list, for a module
 317 --
 318 -- Can be used to find the type of the last expression compiled, by looking
 319 -- for "it".
 320
 321 cmInfo :: CmState -> String -> IO (Maybe String)
 322 cmInfo cmstate str
 323  = do error "cmInfo not implemented yet"
 324
 325 -----------------------------------------------------------------------------
 326 -- Unload the compilation manager's state: everything it knows about the
 327 -- current collection of modules in the Home package.
 328
 329 cmUnload :: CmState -> IO CmState
 330 cmUnload state
 331  = do -- Throw away the old home dir cache
 332       emptyHomeDirCache
 333       -- Throw away the HIT and the HST
 334       return state{ hst=new_hst, hit=new_hit, ui=emptyUI }
 335    where
 336      CmState{ hst=hst, hit=hit } = state
 337      (new_hst, new_hit) = retainInTopLevelEnvs [] (hst,hit)
 338
 339 -----------------------------------------------------------------------------
 340 -- The real business of the compilation manager: given a system state and
 341 -- a module name, try and bring the module up to date, probably changing
 342 -- the system state at the same time.
 343
 344 cmLoadModule :: CmState
 345              -> FilePath
 346              -> IO (CmState,            -- new state
 347                     Bool,               -- was successful
 348                     [String])           -- list of modules loaded
 349
 350 cmLoadModule cmstate1 rootname
 351    = do -- version 1's are the original, before downsweep
 352         let pls1      = pls    cmstate1
 353         let pcs1      = pcs    cmstate1
 354         let hst1      = hst    cmstate1
 355         let hit1      = hit    cmstate1
 356         -- similarly, ui1 is the (complete) set of linkables from
 357         -- the previous pass, if any.
 358         let ui1       = ui     cmstate1
 359         let mg1       = mg     cmstate1
 360         let ic1       = ic     cmstate1
 361
 362         let ghci_mode = gmode cmstate1 -- this never changes
 363
 364         -- Do the downsweep to reestablish the module graph
 365         dflags <- getDynFlags
 366         let verb = verbosity dflags
 367
 368         showPass dflags "Chasing dependencies"
 369         when (verb >= 1 && ghci_mode == Batch) $
 370            hPutStrLn stderr (progName ++ ": chasing modules from: " ++ rootname)
 371
 372         (mg2unsorted, a_root_is_Main) <- downsweep [rootname] mg1
 373         let mg2unsorted_names = map name_of_summary mg2unsorted
 374
 375         -- reachable_from follows source as well as normal imports
 376         let reachable_from :: ModuleName -> [ModuleName]
 377             reachable_from = downwards_closure_of_module mg2unsorted
 378
 379         -- should be cycle free; ignores 'import source's
 380         let mg2 = topological_sort False mg2unsorted
 381         -- ... whereas this takes them into account.  Used for
 382         -- backing out partially complete cycles following a failed
 383         -- upsweep, and for removing from hst/hit all the modules
 384         -- not in strict downwards closure, during calls to compile.
 385         let mg2_with_srcimps = topological_sort True mg2unsorted
 386
 387         -- Sort out which linkables we wish to keep in the unlinked image.
 388         -- See getValidLinkables below for details.
 389         valid_linkables <- getValidLinkables ui1 mg2unsorted_names
 390                                 mg2_with_srcimps
 391
 392         -- Figure out a stable set of modules which can be retained
 393         -- the top level envs, to avoid upsweeping them.  Goes to a
 394         -- bit of trouble to avoid upsweeping module cycles.
 395         --
 396         -- Construct a set S of stable modules like this:
 397         -- Travel upwards, over the sccified graph.  For each scc
 398         -- of modules ms, add ms to S only if:
 399         -- 1.  All home imports of ms are either in ms or S
 400         -- 2.  A valid linkable exists for each module in ms
 401
 402         stable_mods <- preUpsweep valid_linkables hit1
 403                                   mg2unsorted_names [] mg2_with_srcimps
 404
 405         let stable_summaries
 406                = concatMap (findInSummaries mg2unsorted) stable_mods
 407
 408             stable_linkables
 409                = filter (\m -> linkableModName m `elem` stable_mods)
 410                     valid_linkables
 411
 412         when (verb >= 2) $
 413            putStrLn (showSDoc (text "Stable modules:"
 414                                <+> sep (map (text.moduleNameUserString) stable_mods)))
 415
 416         -- unload any modules which aren't going to be re-linked this
 417         -- time around.
 418         pls2 <- unload ghci_mode dflags stable_linkables pls1
 419
 420         -- We could at this point detect cycles which aren't broken by
 421         -- a source-import, and complain immediately, but it seems better
 422         -- to let upsweep_mods do this, so at least some useful work gets
 423         -- done before the upsweep is abandoned.
 424         let upsweep_these
 425                = filter (\scc -> any (`notElem` stable_mods)
 426                                      (map name_of_summary (flattenSCC scc)))
 427                         mg2
 428
 429         --hPutStrLn stderr "after tsort:\n"
 430         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 431
 432         -- Because we don't take into account source imports when doing
 433         -- the topological sort, there shouldn't be any cycles in mg2.
 434         -- If there is, we complain and give up -- the user needs to
 435         -- break the cycle using a boot file.
 436
 437         -- Now do the upsweep, calling compile for each module in
 438         -- turn.  Final result is version 3 of everything.
 439
 440         let threaded2 = CmThreaded pcs1 hst1 hit1
 441
 442         (upsweep_complete_success, threaded3, modsUpswept, newLis)
 443            <- upsweep_mods ghci_mode dflags valid_linkables reachable_from
 444                            threaded2 upsweep_these
 445
 446         let ui3 = add_to_ui valid_linkables newLis
 447         let (CmThreaded pcs3 hst3 hit3) = threaded3
 448
 449         -- At this point, modsUpswept and newLis should have the same
 450         -- length, so there is one new (or old) linkable for each
 451         -- mod which was processed (passed to compile).
 452
 453         -- Make modsDone be the summaries for each home module now
 454         -- available; this should equal the domains of hst3 and hit3.
 455         -- (NOT STRICTLY TRUE if an interactive session was started
 456         --  with some object on disk ???)
 457         -- Get in in a roughly top .. bottom order (hence reverse).
 458
 459         let modsDone = reverse modsUpswept ++ stable_summaries
 460
 461         -- Try and do linking in some form, depending on whether the
 462         -- upsweep was completely or only partially successful.
 463
 464         if upsweep_complete_success
 465
 466          then
 467            -- Easy; just relink it all.
 468            do when (verb >= 2) $
 469                  hPutStrLn stderr "Upsweep completely successful."
 470
 471               -- clean up after ourselves
 472               cleanTempFilesExcept verb (ppFilesFromSummaries modsDone)
 473
 474               -- link everything together
 475               linkresult <- link ghci_mode dflags a_root_is_Main ui3 pls2
 476
 477               cmLoadFinish True linkresult
 478                         hst3 hit3 ui3 modsDone ghci_mode pcs3
 479
 480          else
 481            -- Tricky.  We need to back out the effects of compiling any
 482            -- half-done cycles, both so as to clean up the top level envs
 483            -- and to avoid telling the interactive linker to link them.
 484            do when (verb >= 2) $
 485                 hPutStrLn stderr "Upsweep partially successful."
 486
 487               let modsDone_names
 488                      = map name_of_summary modsDone
 489               let mods_to_zap_names
 490                      = findPartiallyCompletedCycles modsDone_names
 491                           mg2_with_srcimps
 492               let (hst4, hit4, ui4)
 493                      = removeFromTopLevelEnvs mods_to_zap_names (hst3,hit3,ui3)
 494
 495               let mods_to_keep
 496                      = filter ((`notElem` mods_to_zap_names).name_of_summary)
 497                           modsDone
 498
 499               -- clean up after ourselves
 500               cleanTempFilesExcept verb (ppFilesFromSummaries mods_to_keep)
 501
 502               -- link everything together
 503               linkresult <- link ghci_mode dflags False ui4 pls2
 504
 505               cmLoadFinish False linkresult
 506                     hst4 hit4 ui4 mods_to_keep ghci_mode pcs3
 507
 508
 509 -- Finish up after a cmLoad.
 510 --
 511 -- Empty the interactive context and set the module context to the topmost
 512 -- newly loaded module, or the Prelude if none were loaded.
 513 cmLoadFinish ok linkresult hst hit ui mods ghci_mode pcs
 514   = do case linkresult of {
 515           LinkErrs _ _ -> panic "cmLoadModule: link failed (2)";
 516           LinkOK pls   -> do
 517
 518        def_mod <- readIORef defaultCurrentModule
 519        let current_mod = case mods of
 520                                 []    -> def_mod
 521                                 (x:_) -> ms_mod x
 522
 523            new_ic = emptyInteractiveContext current_mod
 524
 525            new_cmstate = CmState{ hst=hst, hit=hit,
 526                                   ui=ui, mg=mods,
 527                                   gmode=ghci_mode, pcs=pcs,
 528                                   pls=pls,
 529                                   ic = new_ic }
 530            mods_loaded = map (moduleNameUserString.name_of_summary) mods
 531
 532        return (new_cmstate, ok, mods_loaded)
 533     }
 534
 535 ppFilesFromSummaries summaries
 536   = [ fn | Just fn <- map (ml_hspp_file . ms_location) summaries ]
 537
 538 -----------------------------------------------------------------------------
 539 -- getValidLinkables
 540
 541 -- For each module (or SCC of modules), we take:
 542 --
 543 --      - an on-disk linkable, if this is the first time around and one
 544 --        is available.
 545 --
 546 --      - the old linkable, otherwise (and if one is available).
 547 --
 548 -- and we throw away the linkable if it is older than the source
 549 -- file.  We ignore the on-disk linkables unless all of the dependents
 550 -- of this SCC also have on-disk linkables.
 551 --
 552 -- If a module has a valid linkable, then it may be STABLE (see below),
 553 -- and it is classified as SOURCE UNCHANGED for the purposes of calling
 554 -- compile.
 555 --
 556 -- ToDo: this pass could be merged with the preUpsweep.
 557
 558 getValidLinkables
 559         :: [Linkable]           -- old linkables
 560         -> [ModuleName]         -- all home modules
 561         -> [SCC ModSummary]     -- all modules in the program, dependency order
 562         -> IO [Linkable]        -- still-valid linkables
 563
 564 getValidLinkables old_linkables all_home_mods module_graph
 565   = foldM (getValidLinkablesSCC old_linkables all_home_mods) [] module_graph
 566
 567 getValidLinkablesSCC old_linkables all_home_mods new_linkables scc0
 568    = let
 569           scc             = flattenSCC scc0
 570           scc_names       = map name_of_summary scc
 571           home_module m   = m `elem` all_home_mods && m `notElem` scc_names
 572           scc_allhomeimps = nub (filter home_module (concatMap ms_allimps scc))
 573
 574           has_object m = case findModuleLinkable_maybe new_linkables m of
 575                             Nothing -> False
 576                             Just l  -> isObjectLinkable l
 577
 578           objects_allowed = all has_object scc_allhomeimps
 579      in do
 580
 581      these_linkables
 582         <- foldM (getValidLinkable old_linkables objects_allowed) [] scc
 583
 584         -- since an scc can contain only all objects or no objects at all,
 585         -- we have to check whether we got all objects or not, and re-do
 586         -- the linkable check if not.
 587      adjusted_linkables
 588         <- if objects_allowed && not (all isObjectLinkable these_linkables)
 589               then foldM (getValidLinkable old_linkables False) [] scc
 590               else return these_linkables
 591
 592      return (adjusted_linkables ++ new_linkables)
 593
 594
 595 getValidLinkable :: [Linkable] -> Bool -> [Linkable] -> ModSummary
 596         -> IO [Linkable]
 597 getValidLinkable old_linkables objects_allowed new_linkables summary
 598   = do let mod_name = name_of_summary summary
 599
 600        maybe_disk_linkable
 601           <- if (not objects_allowed)
 602                 then return Nothing
 603                 else case ml_obj_file (ms_location summary) of
 604                         Just obj_fn -> maybe_getFileLinkable mod_name obj_fn
 605                         Nothing -> return Nothing
 606
 607        let old_linkable = findModuleLinkable_maybe old_linkables mod_name
 608            maybe_old_linkable =
 609                 case old_linkable of
 610                     Just l | not (isObjectLinkable l) || stillThere l
 611                                 -> old_linkable
 612                                 -- ToDo: emit a warning if not (stillThere l)
 613                            | otherwise
 614                                 -> Nothing
 615
 616            -- make sure that if we had an old disk linkable around, that it's
 617            -- still there on the disk (in case we need to re-link it).
 618            stillThere l =
 619                 case maybe_disk_linkable of
 620                    Nothing    -> False
 621                    Just l_disk -> linkableTime l == linkableTime l_disk
 622
 623            -- we only look for objects on disk the first time around;
 624            -- if the user compiles a module on the side during a GHCi session,
 625            -- it won't be picked up until the next ":load".  This is what the
 626            -- "null old_linkables" test below is.
 627            linkable | null old_linkables = maybeToList maybe_disk_linkable
 628                     | otherwise          = maybeToList maybe_old_linkable
 629
 630            -- only linkables newer than the source code are valid
 631            src_date = ms_hs_date summary
 632
 633            valid_linkable
 634               =  filter (\l -> linkableTime l > src_date) linkable
 635
 636        return (valid_linkable ++ new_linkables)
 637
 638
 639
 640 maybe_getFileLinkable :: ModuleName -> FilePath -> IO (Maybe Linkable)
 641 maybe_getFileLinkable mod_name obj_fn
 642    = do obj_exist <- doesFileExist obj_fn
 643         if not obj_exist
 644          then return Nothing
 645          else
 646          do let stub_fn = case splitFilename3 obj_fn of
 647                              (dir, base, ext) -> dir ++ "/" ++ base ++ ".stub_o"
 648             stub_exist <- doesFileExist stub_fn
 649             obj_time <- getModificationTime obj_fn
 650             if stub_exist
 651              then return (Just (LM obj_time mod_name [DotO obj_fn, DotO stub_fn]))
 652              else return (Just (LM obj_time mod_name [DotO obj_fn]))
 653
 654
 655 -----------------------------------------------------------------------------
 656 -- Do a pre-upsweep without use of "compile", to establish a
 657 -- (downward-closed) set of stable modules for which we won't call compile.
 658
 659 -- a stable module:
 660 --      * has a valid linkable (see getValidLinkables above)
 661 --      * depends only on stable modules
 662 --      * has an interface in the HIT (interactive mode only)
 663
 664 preUpsweep :: [Linkable]        -- new valid linkables
 665            -> HomeIfaceTable
 666            -> [ModuleName]      -- names of all mods encountered in downsweep
 667            -> [ModuleName]      -- accumulating stable modules
 668            -> [SCC ModSummary]  -- scc-ified mod graph, including src imps
 669            -> IO [ModuleName]   -- stable modules
 670
 671 preUpsweep valid_lis hit all_home_mods stable []  = return stable
 672 preUpsweep valid_lis hit all_home_mods stable (scc0:sccs)
 673    = do let scc = flattenSCC scc0
 674             scc_allhomeimps :: [ModuleName]
 675             scc_allhomeimps
 676                = nub (filter (`elem` all_home_mods) (concatMap ms_allimps scc))
 677             all_imports_in_scc_or_stable
 678                = all in_stable_or_scc scc_allhomeimps
 679             scc_names
 680                = map name_of_summary scc
 681             in_stable_or_scc m
 682                = m `elem` scc_names || m `elem` stable
 683
 684             -- now we check for valid linkables: each module in the SCC must
 685             -- have a valid linkable (see getValidLinkables above).
 686             has_valid_linkable new_summary
 687               = isJust (findModuleLinkable_maybe valid_lis modname)
 688                where modname = name_of_summary new_summary
 689
 690             has_interface summary = ms_mod summary `elemUFM` hit
 691
 692             scc_is_stable = all_imports_in_scc_or_stable
 693                           && all has_valid_linkable scc
 694                           && all has_interface scc
 695
 696         if scc_is_stable
 697          then preUpsweep valid_lis hit all_home_mods (scc_names++stable) sccs
 698          else preUpsweep valid_lis hit all_home_mods stable sccs
 699
 700
 701 -- Helper for preUpsweep.  Assuming that new_summary's imports are all
 702 -- stable (in the sense of preUpsweep), determine if new_summary is itself
 703 -- stable, and, if so, in batch mode, return its linkable.
 704 findInSummaries :: [ModSummary] -> ModuleName -> [ModSummary]
 705 findInSummaries old_summaries mod_name
 706    = [s | s <- old_summaries, name_of_summary s == mod_name]
 707
 708 findModInSummaries :: [ModSummary] -> Module -> Maybe ModSummary
 709 findModInSummaries old_summaries mod
 710    = case [s | s <- old_summaries, ms_mod s == mod] of
 711          [] -> Nothing
 712          (s:_) -> Just s
 713
 714 -- Return (names of) all those in modsDone who are part of a cycle
 715 -- as defined by theGraph.
 716 findPartiallyCompletedCycles :: [ModuleName] -> [SCC ModSummary] -> [ModuleName]
 717 findPartiallyCompletedCycles modsDone theGraph
 718    = chew theGraph
 719      where
 720         chew [] = []
 721         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 722         chew ((CyclicSCC vs):rest)
 723            = let names_in_this_cycle = nub (map name_of_summary vs)
 724                  mods_in_this_cycle
 725                     = nub ([done | done <- modsDone,
 726                                    done `elem` names_in_this_cycle])
 727                  chewed_rest = chew rest
 728              in
 729              if   not (null mods_in_this_cycle)
 730                   && length mods_in_this_cycle < length names_in_this_cycle
 731              then mods_in_this_cycle ++ chewed_rest
 732              else chewed_rest
 733
 734
 735 -- Add the given (LM-form) Linkables to the UI, overwriting previous
 736 -- versions if they exist.
 737 add_to_ui :: UnlinkedImage -> [Linkable] -> UnlinkedImage
 738 add_to_ui ui lis
 739    = filter (not_in lis) ui ++ lis
 740      where
 741         not_in :: [Linkable] -> Linkable -> Bool
 742         not_in lis li
 743            = all (\l -> linkableModName l /= mod) lis
 744            where mod = linkableModName li
 745
 746
 747 data CmThreaded  -- stuff threaded through individual module compilations
 748    = CmThreaded PersistentCompilerState HomeSymbolTable HomeIfaceTable
 749
 750
 751 -- Compile multiple modules, stopping as soon as an error appears.
 752 -- There better had not be any cyclic groups here -- we check for them.
 753 upsweep_mods :: GhciMode
 754              -> DynFlags
 755              -> UnlinkedImage         -- valid linkables
 756              -> (ModuleName -> [ModuleName])  -- to construct downward closures
 757              -> CmThreaded            -- PCS & HST & HIT
 758              -> [SCC ModSummary]      -- mods to do (the worklist)
 759                                       -- ...... RETURNING ......
 760              -> IO (Bool{-complete success?-},
 761                     CmThreaded,
 762                     [ModSummary],     -- mods which succeeded
 763                     [Linkable])       -- new linkables
 764
 765 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 766      []
 767    = return (True, threaded, [], [])
 768
 769 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 770      ((CyclicSCC ms):_)
 771    = do hPutStrLn stderr ("Module imports form a cycle for modules:\n\t" ++
 772                           unwords (map (moduleNameUserString.name_of_summary) ms))
 773         return (False, threaded, [], [])
 774
 775 upsweep_mods ghci_mode dflags oldUI reachable_from threaded
 776      ((AcyclicSCC mod):mods)
 777    = do --case threaded of
 778         --   CmThreaded pcsz hstz hitz
 779         --      -> putStrLn ("UPSWEEP_MOD: hit = " ++ show (map (moduleNameUserString.moduleName.mi_module) (eltsUFM hitz)))
 780
 781         (threaded1, maybe_linkable)
 782            <- upsweep_mod ghci_mode dflags oldUI threaded mod
 783                           (reachable_from (name_of_summary mod))
 784         case maybe_linkable of
 785            Just linkable
 786               -> -- No errors; do the rest
 787                  do (restOK, threaded2, modOKs, linkables)
 788                        <- upsweep_mods ghci_mode dflags oldUI reachable_from
 789                                        threaded1 mods
 790                     return (restOK, threaded2, mod:modOKs, linkable:linkables)
 791            Nothing -- we got a compilation error; give up now
 792               -> return (False, threaded1, [], [])
 793
 794
 795 -- Compile a single module.  Always produce a Linkable for it if
 796 -- successful.  If no compilation happened, return the old Linkable.
 797 upsweep_mod :: GhciMode
 798             -> DynFlags
 799             -> UnlinkedImage
 800             -> CmThreaded
 801             -> ModSummary
 802             -> [ModuleName]
 803             -> IO (CmThreaded, Maybe Linkable)
 804
 805 upsweep_mod ghci_mode dflags oldUI threaded1 summary1 reachable_inc_me
 806    = do
 807         let mod_name = name_of_summary summary1
 808         let verb = verbosity dflags
 809
 810         let (CmThreaded pcs1 hst1 hit1) = threaded1
 811         let old_iface = lookupUFM hit1 mod_name
 812
 813         let maybe_old_linkable = findModuleLinkable_maybe oldUI mod_name
 814
 815             source_unchanged = isJust maybe_old_linkable
 816
 817             reachable_only = filter (/= (name_of_summary summary1))
 818                                 reachable_inc_me
 819
 820            -- in interactive mode, all home modules below us *must* have an
 821            -- interface in the HIT.  We never demand-load home interfaces in
 822            -- interactive mode.
 823             (hst1_strictDC, hit1_strictDC)
 824                = ASSERT(ghci_mode == Batch ||
 825                         all (`elemUFM` hit1) reachable_only)
 826                  retainInTopLevelEnvs reachable_only (hst1,hit1)
 827
 828             old_linkable
 829                = unJust "upsweep_mod:old_linkable" maybe_old_linkable
 830
 831             have_object
 832                | Just l <- maybe_old_linkable, isObjectLinkable l = True
 833                | otherwise = False
 834
 835         compresult <- compile ghci_mode summary1 source_unchanged
 836                          have_object old_iface hst1_strictDC hit1_strictDC pcs1
 837
 838         case compresult of
 839
 840            -- Compilation "succeeded", and may or may not have returned a new
 841            -- linkable (depending on whether compilation was actually performed
 842            -- or not).
 843            CompOK pcs2 new_details new_iface maybe_new_linkable
 844               -> do let hst2      = addToUFM hst1 mod_name new_details
 845                         hit2      = addToUFM hit1 mod_name new_iface
 846                         threaded2 = CmThreaded pcs2 hst2 hit2
 847
 848                     return (threaded2, if isJust maybe_new_linkable
 849                                           then maybe_new_linkable
 850                                           else Just old_linkable)
 851
 852            -- Compilation failed.  compile may still have updated
 853            -- the PCS, tho.
 854            CompErrs pcs2
 855               -> do let threaded2 = CmThreaded pcs2 hst1 hit1
 856                     return (threaded2, Nothing)
 857
 858 -- Remove unwanted modules from the top level envs (HST, HIT, UI).
 859 removeFromTopLevelEnvs :: [ModuleName]
 860                        -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 861                        -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
 862 removeFromTopLevelEnvs zap_these (hst, hit, ui)
 863    = (delListFromUFM hst zap_these,
 864       delListFromUFM hit zap_these,
 865       filterModuleLinkables (`notElem` zap_these) ui
 866      )
 867
 868 retainInTopLevelEnvs :: [ModuleName]
 869                         -> (HomeSymbolTable, HomeIfaceTable)
 870                         -> (HomeSymbolTable, HomeIfaceTable)
 871 retainInTopLevelEnvs keep_these (hst, hit)
 872    = (retainInUFM hst keep_these,
 873       retainInUFM hit keep_these
 874      )
 875      where
 876         retainInUFM :: Uniquable key => UniqFM elt -> [key] -> UniqFM elt
 877         retainInUFM ufm keys_to_keep
 878            = listToUFM (concatMap (maybeLookupUFM ufm) keys_to_keep)
 879         maybeLookupUFM ufm u
 880            = case lookupUFM ufm u of Nothing -> []; Just val -> [(u, val)]
 881
 882 -- Needed to clean up HIT and HST so that we don't get duplicates in inst env
 883 downwards_closure_of_module :: [ModSummary] -> ModuleName -> [ModuleName]
 884 downwards_closure_of_module summaries root
 885    = let toEdge :: ModSummary -> (ModuleName,[ModuleName])
 886          toEdge summ = (name_of_summary summ,
 887                         filter (`elem` all_mods) (ms_allimps summ))
 888
 889          all_mods = map name_of_summary summaries
 890
 891          res = simple_transitive_closure (map toEdge summaries) [root]
 892      in
 893          --trace (showSDoc (text "DC of mod" <+> ppr root
 894          --                 <+> text "=" <+> ppr res)) (
 895          res
 896          --)
 897
 898 -- Calculate transitive closures from a set of roots given an adjacency list
 899 simple_transitive_closure :: Eq a => [(a,[a])] -> [a] -> [a]
 900 simple_transitive_closure graph set
 901    = let set2      = nub (concatMap dsts set ++ set)
 902          dsts node = fromMaybe [] (lookup node graph)
 903      in
 904          if   length set == length set2
 905          then set
 906          else simple_transitive_closure graph set2
 907
 908
 909 -- Calculate SCCs of the module graph, with or without taking into
 910 -- account source imports.
 911 topological_sort :: Bool -> [ModSummary] -> [SCC ModSummary]
 912 topological_sort include_source_imports summaries
 913    = let
 914          toEdge :: ModSummary -> (ModSummary,ModuleName,[ModuleName])
 915          toEdge summ
 916              = (summ, name_of_summary summ,
 917                       (if include_source_imports
 918                        then ms_srcimps summ else []) ++ ms_imps summ)
 919
 920          mash_edge :: (ModSummary,ModuleName,[ModuleName]) -> (ModSummary,Int,[Int])
 921          mash_edge (summ, m, m_imports)
 922             = case lookup m key_map of
 923                  Nothing -> panic "reverse_topological_sort"
 924                  Just mk -> (summ, mk,
 925                                 -- ignore imports not from the home package
 926                                 catMaybes (map (flip lookup key_map) m_imports))
 927
 928          edges     = map toEdge summaries
 929          key_map   = zip [nm | (s,nm,imps) <- edges] [1 ..] :: [(ModuleName,Int)]
 930          scc_input = map mash_edge edges
 931          sccs      = stronglyConnComp scc_input
 932      in
 933          sccs
 934
 935
 936 -- Chase downwards from the specified root set, returning summaries
 937 -- for all home modules encountered.  Only follow source-import
 938 -- links.  Also returns a Bool to indicate whether any of the roots
 939 -- are module Main.
 940 downsweep :: [FilePath] -> [ModSummary] -> IO ([ModSummary], Bool)
 941 downsweep rootNm old_summaries
 942    = do rootSummaries <- mapM getRootSummary rootNm
 943         let a_root_is_Main
 944                = any ((=="Main").moduleNameUserString.name_of_summary)
 945                      rootSummaries
 946         all_summaries
 947            <- loop (concat (map ms_imps rootSummaries))
 948                 (mkModuleEnv [ (mod, s) | s <- rootSummaries,
 949                                           let mod = ms_mod s, isHomeModule mod
 950                              ])
 951         return (all_summaries, a_root_is_Main)
 952      where
 953         getRootSummary :: FilePath -> IO ModSummary
 954         getRootSummary file
 955            | haskellish_file file
 956            = do exists <- doesFileExist file
 957                 if exists then summariseFile file else do
 958                 throwDyn (CmdLineError ("can't find file `" ++ file ++ "'"))
 959            | otherwise
 960            = do exists <- doesFileExist hs_file
 961                 if exists then summariseFile hs_file else do
 962                 exists <- doesFileExist lhs_file
 963                 if exists then summariseFile lhs_file else do
 964                 let mod_name = mkModuleName file
 965                 maybe_summary <- getSummary mod_name
 966                 case maybe_summary of
 967                    Nothing -> packageModErr mod_name
 968                    Just s  -> return s
 969            where
 970                  hs_file = file ++ ".hs"
 971                  lhs_file = file ++ ".lhs"
 972
 973         getSummary :: ModuleName -> IO (Maybe ModSummary)
 974         getSummary nm
 975            = do found <- findModule nm
 976                 case found of
 977                    Just (mod, location) -> do
 978                         let old_summary = findModInSummaries old_summaries mod
 979                         summarise mod location old_summary
 980
 981                    Nothing -> throwDyn (CmdLineError
 982                                    ("can't find module `"
 983                                      ++ showSDoc (ppr nm) ++ "'"))
 984
 985         -- loop invariant: env doesn't contain package modules
 986         loop :: [ModuleName] -> ModuleEnv ModSummary -> IO [ModSummary]
 987         loop [] env = return (moduleEnvElts env)
 988         loop imps env
 989            = do -- imports for modules we don't already have
 990                 let needed_imps = nub (filter (not . (`elemUFM` env)) imps)
 991
 992                 -- summarise them
 993                 needed_summaries <- mapM getSummary needed_imps
 994
 995                 -- get just the "home" modules
 996                 let new_home_summaries = [ s | Just s <- needed_summaries ]
 997
 998                 -- loop, checking the new imports
 999                 let new_imps = concat (map ms_imps new_home_summaries)
1000                 loop new_imps (extendModuleEnvList env
1001                                 [ (ms_mod s, s) | s <- new_home_summaries ])
1002
1003 -----------------------------------------------------------------------------
1004 -- Summarising modules
1005
1006 -- We have two types of summarisation:
1007 --
1008 --    * Summarise a file.  This is used for the root module passed to
1009 --      cmLoadModule.  The file is read, and used to determine the root
1010 --      module name.  The module name may differ from the filename.
1011 --
1012 --    * Summarise a module.  We are given a module name, and must provide
1013 --      a summary.  The finder is used to locate the file in which the module
1014 --      resides.
1015
1016 summariseFile :: FilePath -> IO ModSummary
1017 summariseFile file
1018    = do hspp_fn <- preprocess file
1019         modsrc <- readFile hspp_fn
1020
1021         let (srcimps,imps,mod_name) = getImports modsrc
1022             (path, basename, ext) = splitFilename3 file
1023
1024         Just (mod, location)
1025            <- mkHomeModuleLocn mod_name (path ++ '/':basename) file
1026
1027         src_timestamp
1028            <- case ml_hs_file location of
1029                  Nothing     -> noHsFileErr mod_name
1030                  Just src_fn -> getModificationTime src_fn
1031
1032         return (ModSummary mod
1033                            location{ml_hspp_file=Just hspp_fn}
1034                            srcimps imps src_timestamp)
1035
1036 -- Summarise a module, and pick up source and timestamp.
1037 summarise :: Module -> ModuleLocation -> Maybe ModSummary
1038          -> IO (Maybe ModSummary)
1039 summarise mod location old_summary
1040    | isHomeModule mod
1041    = do let hs_fn = unJust "summarise" (ml_hs_file location)
1042
1043         src_timestamp
1044            <- case ml_hs_file location of
1045                  Nothing     -> noHsFileErr mod
1046                  Just src_fn -> getModificationTime src_fn
1047
1048         -- return the cached summary if the source didn't change
1049         case old_summary of {
1050            Just s | ms_hs_date s == src_timestamp -> return (Just s);
1051            _ -> do
1052
1053         hspp_fn <- preprocess hs_fn
1054         modsrc <- readFile hspp_fn
1055         let (srcimps,imps,mod_name) = getImports modsrc
1056
1057         when (mod_name /= moduleName mod) $
1058                 throwDyn (ProgramError
1059                    (showSDoc (text modsrc
1060                               <>  text ": file name does not match module name"
1061                               <+> quotes (ppr (moduleName mod)))))
1062
1063         return (Just (ModSummary mod location{ml_hspp_file=Just hspp_fn}
1064                                  srcimps imps src_timestamp))
1065         }
1066
1067    | otherwise = return Nothing
1068
1069 noHsFileErr mod
1070   = panic (showSDoc (text "no source file for module" <+> quotes (ppr mod)))
1071
1072 packageModErr mod
1073   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1074                                    quotes (ppr mod) <+>
1075                                    text "is a package module")))
1076 \end{code}