ghc/compiler/compMan/CompManager.lhs

   1 %
   2 % (c) The University of Glasgow, 2002
   3 %
   4 % The Compilation Manager
   5 %
   6 \begin{code}
   7 module CompManager (
   8     ModSummary,         -- Abstract
   9     ModuleGraph,        -- All the modules from the home package
  10
  11     CmState,            -- Abstract
  12
  13     cmInit,        -- :: GhciMode -> IO CmState
  14
  15     cmDepAnal,     -- :: CmState -> [FilePath] -> IO ModuleGraph
  16     cmDownsweep,
  17     cmTopSort,     -- :: Bool -> ModuleGraph -> [SCC ModSummary]
  18     cyclicModuleErr,    -- :: [ModSummary] -> String    -- Used by DriverMkDepend
  19
  20     cmLoadModules, -- :: CmState -> ModuleGraph
  21                    --    -> IO (CmState, Bool, [String])
  22
  23     cmUnload,      -- :: CmState -> IO CmState
  24
  25
  26 #ifdef GHCI
  27     cmModuleIsInterpreted, -- :: CmState -> String -> IO Bool
  28
  29     cmSetContext,  -- :: CmState -> [String] -> [String] -> IO CmState
  30     cmGetContext,  -- :: CmState -> IO ([String],[String])
  31
  32     cmGetInfo,    -- :: CmState -> String -> IO (CmState, [(TyThing,Fixity)])
  33     GetInfoResult,
  34     cmBrowseModule, -- :: CmState -> IO [TyThing]
  35     cmShowModule,
  36
  37     CmRunResult(..),
  38     cmRunStmt,          -- :: CmState -> String -> IO (CmState, CmRunResult)
  39
  40     cmTypeOfExpr,       -- :: CmState -> String -> IO (CmState, Maybe String)
  41     cmKindOfType,       -- :: CmState -> String -> IO (CmState, Maybe String)
  42     cmTypeOfName,       -- :: CmState -> Name -> IO (Maybe String)
  43
  44     HValue,
  45     cmCompileExpr,      -- :: CmState -> String -> IO (CmState, Maybe HValue)
  46     cmGetModuleGraph,   -- :: CmState -> ModuleGraph
  47     cmSetDFlags,
  48     cmGetDFlags,
  49
  50     cmGetBindings,      -- :: CmState -> [TyThing]
  51     cmGetPrintUnqual,   -- :: CmState -> PrintUnqualified
  52 #endif
  53   )
  54 where
  55
  56 #include "HsVersions.h"
  57
  58 import Packages         ( isHomePackage )
  59 import DriverPipeline   ( CompResult(..), preprocess, compile, link )
  60 import HscMain          ( newHscEnv )
  61 import DriverState      ( v_Output_file, v_NoHsMain, v_MainModIs )
  62 import DriverPhases     ( HscSource(..), hscSourceString, isHaskellSrcFilename )
  63 import Finder           ( findModule, findLinkable, addHomeModuleToFinder,
  64                           flushFinderCache, mkHomeModLocation, FindResult(..), cantFindError )
  65 import HscTypes         ( ModSummary(..), HomeModInfo(..), ModIface(..), msHsFilePath,
  66                           HscEnv(..), GhciMode(..), isBootSummary,
  67                           InteractiveContext(..), emptyInteractiveContext,
  68                           HomePackageTable, emptyHomePackageTable, IsBootInterface,
  69                           Linkable(..), isObjectLinkable )
  70 import Module           ( Module, mkModule, delModuleEnv, delModuleEnvList, mkModuleEnv,
  71                           lookupModuleEnv, moduleEnvElts, extendModuleEnv, filterModuleEnv,
  72                           moduleUserString, addBootSuffixLocn,
  73                           ModLocation(..) )
  74 import GetImports       ( getImports )
  75 import Digraph          ( SCC(..), stronglyConnComp, flattenSCC, flattenSCCs )
  76 import ErrUtils         ( showPass )
  77 import SysTools         ( cleanTempFilesExcept )
  78 import BasicTypes       ( SuccessFlag(..), succeeded )
  79 import StringBuffer     ( hGetStringBuffer )
  80 import Util
  81 import Outputable
  82 import Panic
  83 import CmdLineOpts      ( DynFlags(..) )
  84 import Maybes           ( expectJust, orElse, mapCatMaybes )
  85 import FiniteMap
  86
  87 import DATA_IOREF       ( readIORef )
  88
  89 #ifdef GHCI
  90 import Finder           ( findPackageModule )
  91 import HscMain          ( hscGetInfo, GetInfoResult, hscStmt, hscTcExpr, hscKcType )
  92 import HscTypes         ( TyThing(..), icPrintUnqual, showModMsg )
  93 import TcRnDriver       ( mkExportEnv, getModuleContents )
  94 import IfaceSyn         ( IfaceDecl )
  95 import RdrName          ( GlobalRdrEnv, plusGlobalRdrEnv )
  96 import Name             ( Name )
  97 import NameEnv
  98 import Id               ( idType )
  99 import Type             ( tidyType, dropForAlls )
 100 import VarEnv           ( emptyTidyEnv )
 101 import Linker           ( HValue, unload, extendLinkEnv )
 102 import GHC.Exts         ( unsafeCoerce# )
 103 import Foreign
 104 import Control.Exception as Exception ( Exception, try )
 105 import CmdLineOpts      ( DynFlag(..), dopt_unset, dopt )
 106 #endif
 107
 108 import EXCEPTION        ( throwDyn )
 109
 110 -- std
 111 import Directory        ( getModificationTime, doesFileExist )
 112 import IO
 113 import Monad
 114 import List             ( nub )
 115 import Maybe
 116 \end{code}
 117
 118
 119 %************************************************************************
 120 %*                                                                      *
 121                 The module dependency graph
 122                 ModSummary, ModGraph, NodeKey, NodeMap
 123 %*                                                                      *
 124 %************************************************************************
 125
 126 The nodes of the module graph are
 127         EITHER a regular Haskell source module
 128         OR     a hi-boot source module
 129
 130 A ModuleGraph contains all the nodes from the home package (only).
 131 There will be a node for each source module, plus a node for each hi-boot
 132 module.
 133
 134 \begin{code}
 135 type ModuleGraph = [ModSummary]  -- The module graph,
 136                                  -- NOT NECESSARILY IN TOPOLOGICAL ORDER
 137
 138 emptyMG :: ModuleGraph
 139 emptyMG = []
 140
 141 --------------------
 142 ms_allimps :: ModSummary -> [Module]
 143 ms_allimps ms = ms_srcimps ms ++ ms_imps ms
 144
 145 --------------------
 146 type NodeKey   = (Module, HscSource)      -- The nodes of the graph are
 147 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
 148
 149 msKey :: ModSummary -> NodeKey
 150 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (mod,boot)
 151
 152 emptyNodeMap :: NodeMap a
 153 emptyNodeMap = emptyFM
 154
 155 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
 156 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
 157
 158 nodeMapElts :: NodeMap a -> [a]
 159 nodeMapElts = eltsFM
 160 \end{code}
 161
 162
 163 %************************************************************************
 164 %*                                                                      *
 165                 The compilation manager state
 166 %*                                                                      *
 167 %************************************************************************
 168
 169
 170 \begin{code}
 171 -- Persistent state for the entire system
 172 data CmState
 173    = CmState {
 174         cm_hsc :: HscEnv,               -- Includes the home-package table
 175         cm_mg  :: ModuleGraph,          -- The module graph
 176         cm_ic  :: InteractiveContext    -- Command-line binding info
 177      }
 178
 179 #ifdef GHCI
 180 cmGetModuleGraph cmstate = cm_mg cmstate
 181 cmGetBindings    cmstate = nameEnvElts (ic_type_env (cm_ic cmstate))
 182 cmGetPrintUnqual cmstate = icPrintUnqual (cm_ic cmstate)
 183 cmHPT            cmstate = hsc_HPT (cm_hsc cmstate)
 184 #endif
 185
 186 cmInit :: GhciMode -> DynFlags -> IO CmState
 187 cmInit ghci_mode dflags
 188    = do { hsc_env <- newHscEnv ghci_mode dflags
 189         ; return (CmState { cm_hsc = hsc_env,
 190                             cm_mg  = emptyMG,
 191                             cm_ic  = emptyInteractiveContext })}
 192
 193 discardCMInfo :: CmState -> CmState
 194 -- Forget the compilation manager's state, including the home package table
 195 -- but retain the persistent info in HscEnv
 196 discardCMInfo cm_state
 197   = cm_state { cm_mg = emptyMG, cm_ic = emptyInteractiveContext,
 198                cm_hsc = (cm_hsc cm_state) { hsc_HPT = emptyHomePackageTable } }
 199
 200 -------------------------------------------------------------------
 201 --                      The unlinked image
 202 --
 203 -- The compilation manager keeps a list of compiled, but as-yet unlinked
 204 -- binaries (byte code or object code).  Even when it links bytecode
 205 -- it keeps the unlinked version so it can re-link it later without
 206 -- recompiling.
 207
 208 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
 209
 210 findModuleLinkable_maybe :: [Linkable] -> Module -> Maybe Linkable
 211 findModuleLinkable_maybe lis mod
 212    = case [LM time nm us | LM time nm us <- lis, nm == mod] of
 213         []   -> Nothing
 214         [li] -> Just li
 215         many -> pprPanic "findModuleLinkable" (ppr mod)
 216
 217 delModuleLinkable :: [Linkable] -> Module -> [Linkable]
 218 delModuleLinkable ls mod = [ l | l@(LM _ nm _) <- ls, nm /= mod ]
 219 \end{code}
 220
 221
 222 %************************************************************************
 223 %*                                                                      *
 224         GHCI stuff
 225 %*                                                                      *
 226 %************************************************************************
 227
 228 \begin{code}
 229 #ifdef GHCI
 230 -----------------------------------------------------------------------------
 231 -- Setting the context doesn't throw away any bindings; the bindings
 232 -- we've built up in the InteractiveContext simply move to the new
 233 -- module.  They always shadow anything in scope in the current context.
 234
 235 cmSetContext
 236         :: CmState
 237         -> [String]             -- take the top-level scopes of these modules
 238         -> [String]             -- and the just the exports from these
 239         -> IO CmState
 240 cmSetContext cmstate toplevs exports = do
 241   let old_ic  = cm_ic cmstate
 242       hsc_env = cm_hsc cmstate
 243       hpt     = hsc_HPT hsc_env
 244
 245   let export_mods = map mkModule exports
 246   mapM_ (checkModuleExists (hsc_dflags hsc_env) hpt) export_mods
 247   export_env  <- mkExportEnv hsc_env export_mods
 248   toplev_envs <- mapM (mkTopLevEnv hpt) toplevs
 249
 250   let all_env = foldr plusGlobalRdrEnv export_env toplev_envs
 251   return cmstate{ cm_ic = old_ic { ic_toplev_scope = toplevs,
 252                                    ic_exports      = exports,
 253                                    ic_rn_gbl_env   = all_env } }
 254
 255 checkModuleExists :: DynFlags -> HomePackageTable -> Module -> IO ()
 256 checkModuleExists dflags hpt mod =
 257   case lookupModuleEnv hpt mod of
 258     Just mod_info -> return ()
 259     _not_a_home_module -> do
 260           res <- findPackageModule dflags mod True
 261           case res of
 262             Found _ _ -> return  ()
 263             err -> let msg = cantFindError dflags mod err in
 264                    throwDyn (CmdLineError (showSDoc msg))
 265
 266 mkTopLevEnv :: HomePackageTable -> String -> IO GlobalRdrEnv
 267 mkTopLevEnv hpt mod
 268  = case lookupModuleEnv hpt (mkModule mod) of
 269       Nothing      -> throwDyn (ProgramError ("mkTopLevEnv: not a home module " ++ mod))
 270       Just details -> case mi_globals (hm_iface details) of
 271                         Nothing  -> throwDyn (ProgramError ("mkTopLevEnv: not interpreted " ++ mod))
 272                         Just env -> return env
 273
 274 cmGetContext :: CmState -> IO ([String],[String])
 275 cmGetContext CmState{cm_ic=ic} =
 276   return (ic_toplev_scope ic, ic_exports ic)
 277
 278 cmModuleIsInterpreted :: CmState -> String -> IO Bool
 279 cmModuleIsInterpreted cmstate str
 280  = case lookupModuleEnv (cmHPT cmstate) (mkModule str) of
 281       Just details       -> return (isJust (mi_globals (hm_iface details)))
 282       _not_a_home_module -> return False
 283
 284 -----------------------------------------------------------------------------
 285
 286 cmSetDFlags :: CmState -> DynFlags -> CmState
 287 cmSetDFlags cm_state dflags
 288   = cm_state { cm_hsc = (cm_hsc cm_state) { hsc_dflags = dflags } }
 289
 290 cmGetDFlags :: CmState -> DynFlags
 291 cmGetDFlags cm_state = hsc_dflags (cm_hsc cm_state)
 292
 293 -----------------------------------------------------------------------------
 294 -- cmInfoThing: convert a String to a TyThing
 295
 296 -- A string may refer to more than one TyThing (eg. a constructor,
 297 -- and type constructor), so we return a list of all the possible TyThings.
 298
 299 cmGetInfo :: CmState -> String -> IO [GetInfoResult]
 300 cmGetInfo cmstate id = hscGetInfo (cm_hsc cmstate) (cm_ic cmstate) id
 301
 302 -- ---------------------------------------------------------------------------
 303 -- cmBrowseModule: get all the TyThings defined in a module
 304
 305 cmBrowseModule :: CmState -> String -> Bool -> IO [IfaceDecl]
 306 cmBrowseModule cmstate str exports_only
 307   = do { mb_decls <- getModuleContents (cm_hsc cmstate) (cm_ic cmstate)
 308                                        (mkModule str) exports_only
 309        ; case mb_decls of
 310            Nothing -> return []         -- An error of some kind
 311            Just ds -> return ds
 312    }
 313
 314
 315 -----------------------------------------------------------------------------
 316 cmShowModule :: CmState -> ModSummary -> String
 317 cmShowModule cmstate mod_summary
 318   = case lookupModuleEnv hpt (ms_mod mod_summary) of
 319         Nothing       -> panic "missing linkable"
 320         Just mod_info -> showModMsg obj_linkable mod_summary
 321                       where
 322                          obj_linkable = isObjectLinkable (hm_linkable mod_info)
 323   where
 324     hpt  = hsc_HPT (cm_hsc cmstate)
 325
 326 -----------------------------------------------------------------------------
 327 -- cmRunStmt:  Run a statement/expr.
 328
 329 data CmRunResult
 330   = CmRunOk [Name]              -- names bound by this evaluation
 331   | CmRunFailed
 332   | CmRunException Exception    -- statement raised an exception
 333
 334 cmRunStmt :: CmState -> String -> IO (CmState, CmRunResult)
 335 cmRunStmt cmstate@CmState{ cm_hsc=hsc_env, cm_ic=icontext } expr
 336    = do
 337         -- Turn off -fwarn-unused-bindings when running a statement, to hide
 338         -- warnings about the implicit bindings we introduce.
 339         let dflags'  = dopt_unset (hsc_dflags hsc_env) Opt_WarnUnusedBinds
 340             hsc_env' = hsc_env{ hsc_dflags = dflags' }
 341
 342         maybe_stuff <- hscStmt hsc_env' icontext expr
 343
 344         case maybe_stuff of
 345            Nothing -> return (cmstate, CmRunFailed)
 346            Just (new_ic, names, hval) -> do
 347
 348                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 349                 either_hvals <- sandboxIO thing_to_run
 350
 351                 case either_hvals of
 352                     Left e -> do
 353                         -- on error, keep the *old* interactive context,
 354                         -- so that 'it' is not bound to something
 355                         -- that doesn't exist.
 356                         return ( cmstate, CmRunException e )
 357
 358                     Right hvals -> do
 359                         -- Get the newly bound things, and bind them.
 360                         -- Don't need to delete any shadowed bindings;
 361                         -- the new ones override the old ones.
 362                         extendLinkEnv (zip names hvals)
 363
 364                         return (cmstate{ cm_ic=new_ic },
 365                                 CmRunOk names)
 366
 367
 368 -- We run the statement in a "sandbox" to protect the rest of the
 369 -- system from anything the expression might do.  For now, this
 370 -- consists of just wrapping it in an exception handler, but see below
 371 -- for another version.
 372
 373 sandboxIO :: IO a -> IO (Either Exception a)
 374 sandboxIO thing = Exception.try thing
 375
 376 {-
 377 -- This version of sandboxIO runs the expression in a completely new
 378 -- RTS main thread.  It is disabled for now because ^C exceptions
 379 -- won't be delivered to the new thread, instead they'll be delivered
 380 -- to the (blocked) GHCi main thread.
 381
 382 -- SLPJ: when re-enabling this, reflect a wrong-stat error as an exception
 383
 384 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
 385 sandboxIO thing = do
 386   st_thing <- newStablePtr (Exception.try thing)
 387   alloca $ \ p_st_result -> do
 388     stat <- rts_evalStableIO st_thing p_st_result
 389     freeStablePtr st_thing
 390     if stat == 1
 391         then do st_result <- peek p_st_result
 392                 result <- deRefStablePtr st_result
 393                 freeStablePtr st_result
 394                 return (Right result)
 395         else do
 396                 return (Left (fromIntegral stat))
 397
 398 foreign import "rts_evalStableIO"  {- safe -}
 399   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
 400   -- more informative than the C type!
 401 -}
 402
 403 -----------------------------------------------------------------------------
 404 -- cmTypeOfExpr: returns a string representing the type of an expression
 405
 406 cmTypeOfExpr :: CmState -> String -> IO (Maybe String)
 407 cmTypeOfExpr cmstate expr
 408    = do maybe_stuff <- hscTcExpr (cm_hsc cmstate) (cm_ic cmstate) expr
 409
 410         case maybe_stuff of
 411            Nothing -> return Nothing
 412            Just ty -> return (Just (showSDocForUser unqual doc))
 413              where
 414                 doc     = text expr <+> dcolon <+> ppr final_ty
 415                 unqual  = icPrintUnqual (cm_ic cmstate)
 416                 tidy_ty = tidyType emptyTidyEnv ty
 417                 dflags  = hsc_dflags (cm_hsc cmstate)
 418                 -- if -fglasgow-exts is on we show the foralls, otherwise
 419                 -- we don't.
 420                 final_ty
 421                   | dopt Opt_GlasgowExts dflags = tidy_ty
 422                   | otherwise                   = dropForAlls tidy_ty
 423
 424 -----------------------------------------------------------------------------
 425 -- cmKindOfType: returns a string representing the kind of a type
 426
 427 cmKindOfType :: CmState -> String -> IO (Maybe String)
 428 cmKindOfType cmstate str
 429    = do maybe_stuff <- hscKcType (cm_hsc cmstate) (cm_ic cmstate) str
 430         case maybe_stuff of
 431            Nothing -> return Nothing
 432            Just kind -> return (Just res_str)
 433              where
 434                 res_str = showSDocForUser unqual (text str <+> dcolon <+> ppr kind)
 435                 unqual  = icPrintUnqual (cm_ic cmstate)
 436
 437 -----------------------------------------------------------------------------
 438 -- cmTypeOfName: returns a string representing the type of a name.
 439
 440 cmTypeOfName :: CmState -> Name -> IO (Maybe String)
 441 cmTypeOfName CmState{ cm_ic=ic } name
 442  = do
 443     hPutStrLn stderr ("cmTypeOfName: " ++ showSDoc (ppr name))
 444     case lookupNameEnv (ic_type_env ic) name of
 445         Nothing        -> return Nothing
 446         Just (AnId id) -> return (Just str)
 447            where
 448              unqual = icPrintUnqual ic
 449              ty = tidyType emptyTidyEnv (idType id)
 450              str = showSDocForUser unqual (ppr ty)
 451
 452         _ -> panic "cmTypeOfName"
 453
 454 -----------------------------------------------------------------------------
 455 -- cmCompileExpr: compile an expression and deliver an HValue
 456
 457 cmCompileExpr :: CmState -> String -> IO (Maybe HValue)
 458 cmCompileExpr cmstate expr
 459    = do
 460         maybe_stuff
 461             <- hscStmt (cm_hsc cmstate) (cm_ic cmstate)
 462                        ("let __cmCompileExpr = "++expr)
 463
 464         case maybe_stuff of
 465            Nothing -> return Nothing
 466            Just (new_ic, names, hval) -> do
 467
 468                         -- Run it!
 469                 hvals <- (unsafeCoerce# hval) :: IO [HValue]
 470
 471                 case (names,hvals) of
 472                   ([n],[hv]) -> return (Just hv)
 473                   _          -> panic "cmCompileExpr"
 474
 475 #endif /* GHCI */
 476 \end{code}
 477
 478
 479 %************************************************************************
 480 %*                                                                      *
 481         Loading and unloading
 482 %*                                                                      *
 483 %************************************************************************
 484
 485 \begin{code}
 486 -----------------------------------------------------------------------------
 487 -- Unload the compilation manager's state: everything it knows about the
 488 -- current collection of modules in the Home package.
 489
 490 cmUnload :: CmState -> IO CmState
 491 cmUnload state@CmState{ cm_hsc = hsc_env }
 492  = do -- Throw away the old home dir cache
 493       flushFinderCache
 494
 495       -- Unload everything the linker knows about
 496       cm_unload hsc_env []
 497
 498       -- Start with a fresh CmState, but keep the PersistentCompilerState
 499       return (discardCMInfo state)
 500
 501 cm_unload hsc_env stable_linkables      -- Unload everthing *except* 'stable_linkables'
 502   = case hsc_mode hsc_env of
 503         Batch -> return ()
 504 #ifdef GHCI
 505         Interactive -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 506 #else
 507         Interactive -> panic "cm_unload: no interpreter"
 508 #endif
 509         other -> panic "cm_unload: strange mode"
 510
 511
 512 -----------------------------------------------------------------------------
 513 -- Trace dependency graph
 514
 515 -- This is a seperate pass so that the caller can back off and keep
 516 -- the current state if the downsweep fails.  Typically the caller
 517 -- might go     cmDepAnal
 518 --              cmUnload
 519 --              cmLoadModules
 520 -- He wants to do the dependency analysis before the unload, so that
 521 -- if the former fails he can use the later
 522
 523 cmDepAnal :: CmState -> [FilePath] -> IO ModuleGraph
 524 cmDepAnal cmstate rootnames
 525   = do showPass dflags "Chasing dependencies"
 526        when (verbosity dflags >= 1 && gmode == Batch) $
 527            hPutStrLn stderr (showSDoc (hcat [
 528              text "Chasing modules from: ",
 529              hcat (punctuate comma (map text rootnames))]))
 530        cmDownsweep dflags rootnames (cm_mg cmstate) []
 531   where
 532     hsc_env = cm_hsc cmstate
 533     dflags  = hsc_dflags hsc_env
 534     gmode   = hsc_mode hsc_env
 535
 536 -----------------------------------------------------------------------------
 537 -- The real business of the compilation manager: given a system state and
 538 -- a module name, try and bring the module up to date, probably changing
 539 -- the system state at the same time.
 540
 541 cmLoadModules :: CmState                -- The HPT may not be as up to date
 542               -> ModuleGraph            -- Bang up to date; but may contain hi-boot no
 543               -> IO (CmState,           -- new state
 544                      SuccessFlag,       -- was successful
 545                      [String])          -- list of modules loaded
 546
 547 cmLoadModules cmstate1 mg2unsorted
 548    = do -- version 1's are the original, before downsweep
 549         let hsc_env   = cm_hsc cmstate1
 550         let hpt1      = hsc_HPT hsc_env
 551         let ghci_mode = hsc_mode   hsc_env -- this never changes
 552         let dflags    = hsc_dflags hsc_env -- this never changes
 553         let verb      = verbosity dflags
 554
 555         -- The "bad" boot modules are the ones for which we have
 556         -- B.hs-boot in the module graph, but no B.hs
 557         -- The downsweep should have ensured this does not happen
 558         -- (see msDeps)
 559         let all_home_mods = [ms_mod s | s <- mg2unsorted, not (isBootSummary s)]
 560             bad_boot_mods = [s        | s <- mg2unsorted, isBootSummary s,
 561                                         not (ms_mod s `elem` all_home_mods)]
 562         ASSERT( null bad_boot_mods ) return ()
 563
 564         -- Do the downsweep to reestablish the module graph
 565         -- mg2 should be cycle free; but it includes hi-boot ModSummary nodes
 566         let mg2 :: [SCC ModSummary]
 567             mg2 = cmTopSort False mg2unsorted
 568
 569         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 570         -- graph with cycles.  Among other things, it is used for
 571         -- backing out partially complete cycles following a failed
 572         -- upsweep, and for removing from hpt all the modules
 573         -- not in strict downwards closure, during calls to compile.
 574         let mg2_with_srcimps :: [SCC ModSummary]
 575             mg2_with_srcimps = cmTopSort True mg2unsorted
 576
 577         -- Sort out which linkables we wish to keep in the unlinked image.
 578         -- See getValidLinkables below for details.
 579         (valid_old_linkables, new_linkables)
 580             <- getValidLinkables ghci_mode (hptLinkables hpt1)
 581                   all_home_mods mg2_with_srcimps
 582
 583         -- putStrLn (showSDoc (vcat [ppr valid_old_linkables, ppr new_linkables]))
 584
 585         -- The new_linkables are .o files we found on the disk, presumably
 586         -- as a result of a GHC run "on the side".  So we'd better forget
 587         -- everything we know abouut those modules!
 588         let old_hpt = delModuleEnvList hpt1 (map linkableModule new_linkables)
 589
 590         -- When (verb >= 2) $
 591         --    putStrLn (showSDoc (text "Valid linkables:"
 592         --                       <+> ppr valid_linkables))
 593
 594         -- Figure out a stable set of modules which can be retained
 595         -- the top level envs, to avoid upsweeping them.  Goes to a
 596         -- bit of trouble to avoid upsweeping module cycles.
 597         --
 598         -- Construct a set S of stable modules like this:
 599         -- Travel upwards, over the sccified graph.  For each scc
 600         -- of modules ms, add ms to S only if:
 601         -- 1.  All home imports of ms are either in ms or S
 602         -- 2.  A valid old linkable exists for each module in ms
 603
 604         -- mg2_with_srcimps has no hi-boot nodes,
 605         -- and hence neither does stable_mods
 606         stable_summaries <- preUpsweep valid_old_linkables
 607                                        all_home_mods [] mg2_with_srcimps
 608         let stable_mods      = map ms_mod stable_summaries
 609             stable_linkables = filter (\m -> linkableModule m `elem` stable_mods)
 610                                       valid_old_linkables
 611
 612             stable_hpt = filterModuleEnv is_stable_hm hpt1
 613             is_stable_hm hm_info = mi_module (hm_iface hm_info) `elem` stable_mods
 614
 615             upsweep_these
 616                = filter (\scc -> any (`notElem` stable_mods)
 617                                      (map ms_mod (flattenSCC scc)))
 618                         mg2
 619
 620         when (verb >= 2) $
 621            hPutStrLn stderr (showSDoc (text "Stable modules:"
 622                                <+> sep (map (text.moduleUserString) stable_mods)))
 623
 624         -- Unload any modules which are going to be re-linked this time around.
 625         cm_unload hsc_env stable_linkables
 626
 627         -- We can now glom together our linkable sets
 628         let valid_linkables = valid_old_linkables ++ new_linkables
 629
 630         -- We could at this point detect cycles which aren't broken by
 631         -- a source-import, and complain immediately, but it seems better
 632         -- to let upsweep_mods do this, so at least some useful work gets
 633         -- done before the upsweep is abandoned.
 634         --hPutStrLn stderr "after tsort:\n"
 635         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 636
 637         -- Because we don't take into account source imports when doing
 638         -- the topological sort, there shouldn't be any cycles in mg2.
 639         -- If there is, we complain and give up -- the user needs to
 640         -- break the cycle using a boot file.
 641
 642         -- Now do the upsweep, calling compile for each module in
 643         -- turn.  Final result is version 3 of everything.
 644
 645         -- clean up between compilations
 646         let cleanup = cleanTempFilesExcept dflags
 647                           (ppFilesFromSummaries (flattenSCCs mg2))
 648
 649         (upsweep_ok, hsc_env3, modsUpswept)
 650            <- upsweep_mods (hsc_env { hsc_HPT = stable_hpt })
 651                            (old_hpt, valid_linkables)
 652                            cleanup upsweep_these
 653
 654         -- At this point, modsUpswept and newLis should have the same
 655         -- length, so there is one new (or old) linkable for each
 656         -- mod which was processed (passed to compile).
 657
 658         -- Make modsDone be the summaries for each home module now
 659         -- available; this should equal the domain of hpt3.
 660         -- (NOT STRICTLY TRUE if an interactive session was started
 661         --  with some object on disk ???)
 662         -- Get in in a roughly top .. bottom order (hence reverse).
 663
 664         let modsDone = reverse modsUpswept ++ stable_summaries
 665
 666         -- Try and do linking in some form, depending on whether the
 667         -- upsweep was completely or only partially successful.
 668
 669         if succeeded upsweep_ok
 670
 671          then
 672            -- Easy; just relink it all.
 673            do when (verb >= 2) $
 674                  hPutStrLn stderr "Upsweep completely successful."
 675
 676               -- Clean up after ourselves
 677               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 678
 679
 680               -- Issue a warning for the confusing case where the user
 681               -- said '-o foo' but we're not going to do any linking.
 682               -- We attempt linking if either (a) one of the modules is
 683               -- called Main, or (b) the user said -no-hs-main, indicating
 684               -- that main() is going to come from somewhere else.
 685               --
 686               ofile       <- readIORef v_Output_file
 687               no_hs_main  <- readIORef v_NoHsMain
 688               mb_main_mod <- readIORef v_MainModIs
 689               let
 690                 main_mod = mb_main_mod `orElse` "Main"
 691                 a_root_is_Main
 692                     = any ((==main_mod).moduleUserString.ms_mod)
 693                           mg2unsorted
 694                 do_linking = a_root_is_Main || no_hs_main
 695
 696               when (ghci_mode == Batch && isJust ofile && not do_linking
 697                      && verb > 0) $
 698                  hPutStrLn stderr ("Warning: output was redirected with -o, " ++
 699                                    "but no output will be generated\n" ++
 700                                    "because there is no " ++ main_mod ++ " module.")
 701
 702               -- link everything together
 703               linkresult <- link ghci_mode dflags do_linking (hsc_HPT hsc_env3)
 704
 705               let cmstate3 = cmstate1 { cm_mg = modsDone, cm_hsc = hsc_env3 }
 706               cmLoadFinish Succeeded linkresult cmstate3
 707
 708          else
 709            -- Tricky.  We need to back out the effects of compiling any
 710            -- half-done cycles, both so as to clean up the top level envs
 711            -- and to avoid telling the interactive linker to link them.
 712            do when (verb >= 2) $
 713                 hPutStrLn stderr "Upsweep partially successful."
 714
 715               let modsDone_names
 716                      = map ms_mod modsDone
 717               let mods_to_zap_names
 718                      = findPartiallyCompletedCycles modsDone_names
 719                           mg2_with_srcimps
 720               let mods_to_keep
 721                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 722                           modsDone
 723
 724               let hpt4 = retainInTopLevelEnvs (map ms_mod mods_to_keep)
 725                                               (hsc_HPT hsc_env3)
 726
 727               -- Clean up after ourselves
 728               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 729
 730               -- Link everything together
 731               linkresult <- link ghci_mode dflags False hpt4
 732
 733               let cmstate3 = cmstate1 { cm_mg = mods_to_keep,
 734                                         cm_hsc = hsc_env3 { hsc_HPT = hpt4 } }
 735               cmLoadFinish Failed linkresult cmstate3
 736
 737 -- Finish up after a cmLoad.
 738
 739 -- If the link failed, unload everything and return.
 740 cmLoadFinish ok Failed cmstate
 741   = do cm_unload (cm_hsc cmstate) []
 742        return (discardCMInfo cmstate, Failed, [])
 743
 744 -- Empty the interactive context and set the module context to the topmost
 745 -- newly loaded module, or the Prelude if none were loaded.
 746 cmLoadFinish ok Succeeded cmstate
 747   = do let new_cmstate = cmstate { cm_ic = emptyInteractiveContext }
 748            mods_loaded = map (moduleUserString.ms_mod)
 749                              (cm_mg cmstate)
 750
 751        return (new_cmstate, ok, mods_loaded)
 752
 753 -- used to fish out the preprocess output files for the purposes of
 754 -- cleaning up.  The preprocessed file *might* be the same as the
 755 -- source file, but that doesn't do any harm.
 756 ppFilesFromSummaries summaries = [ fn | Just fn <- map ms_hspp_file summaries ]
 757
 758 -----------------------------------------------------------------------------
 759 -- getValidLinkables
 760
 761 -- For each module (or SCC of modules), we take:
 762 --
 763 --      - an on-disk linkable, if this is the first time around and one
 764 --        is available.
 765 --
 766 --      - the old linkable, otherwise (and if one is available).
 767 --
 768 -- and we throw away the linkable if it is older than the source file.
 769 -- In interactive mode, we also ignore the on-disk linkables unless
 770 -- all of the dependents of this SCC also have on-disk linkables (we
 771 -- can't have dynamically loaded objects that depend on interpreted
 772 -- modules in GHCi).
 773 --
 774 -- If a module has a valid linkable, then it may be STABLE (see below),
 775 -- and it is classified as SOURCE UNCHANGED for the purposes of calling
 776 -- compile.
 777 --
 778 -- ToDo: this pass could be merged with the preUpsweep.
 779
 780 getValidLinkables
 781         :: GhciMode
 782         -> [Linkable]           -- old linkables
 783         -> [Module]             -- all home modules
 784         -> [SCC ModSummary]     -- all modules in the program, dependency order
 785         -> IO ( [Linkable],     -- still-valid linkables
 786                 [Linkable]      -- new linkables we just found on the disk
 787                                 -- presumably generated by separate run of ghc
 788               )
 789
 790 getValidLinkables mode old_linkables all_home_mods module_graph
 791   = do  {       -- Process the SCCs in bottom-to-top order
 792                 -- (foldM works left-to-right)
 793           ls <- foldM (getValidLinkablesSCC mode old_linkables all_home_mods)
 794                       [] module_graph
 795         ; return (partition_it ls [] []) }
 796  where
 797   partition_it []         valid new = (valid,new)
 798   partition_it ((l,b):ls) valid new
 799         | b         = partition_it ls valid (l:new)
 800         | otherwise = partition_it ls (l:valid) new
 801
 802
 803 getValidLinkablesSCC
 804         :: GhciMode
 805         -> [Linkable]           -- old linkables
 806         -> [Module]             -- all home modules
 807         -> [(Linkable,Bool)]
 808         -> SCC ModSummary
 809         -> IO [(Linkable,Bool)]
 810
 811 getValidLinkablesSCC mode old_linkables all_home_mods new_linkables scc0
 812    = let
 813           scc             = flattenSCC scc0
 814           scc_names       = map ms_mod scc
 815           home_module m   = m `elem` all_home_mods && m `notElem` scc_names
 816           scc_allhomeimps = nub (filter home_module (concatMap ms_imps scc))
 817                 -- NB. ms_imps, not ms_allimps above.  We don't want to
 818                 -- force a module's SOURCE imports to be already compiled for
 819                 -- its object linkable to be valid.
 820
 821                 -- The new_linkables is only the *valid* linkables below here
 822           has_object m = case findModuleLinkable_maybe (map fst new_linkables) m of
 823                             Nothing -> False
 824                             Just l  -> isObjectLinkable l
 825
 826           objects_allowed = mode == Batch || all has_object scc_allhomeimps
 827      in do
 828
 829      new_linkables'
 830         <- foldM (getValidLinkable old_linkables objects_allowed) [] scc
 831
 832         -- since an scc can contain only all objects or no objects at all,
 833         -- we have to check whether we got all objects or not, and re-do
 834         -- the linkable check if not.
 835      new_linkables' <-
 836         if objects_allowed
 837              && not (all isObjectLinkable (map fst new_linkables'))
 838           then foldM (getValidLinkable old_linkables False) [] scc
 839           else return new_linkables'
 840
 841      return (new_linkables ++ new_linkables')
 842
 843
 844 getValidLinkable :: [Linkable] -> Bool -> [(Linkable,Bool)] -> ModSummary
 845         -> IO [(Linkable,Bool)]
 846         -- True <=> linkable is new; i.e. freshly discovered on the disk
 847         --                                presumably generated 'on the side'
 848         --                                by a separate GHC run
 849 getValidLinkable old_linkables objects_allowed new_linkables summary
 850         -- 'objects_allowed' says whether we permit this module to
 851         -- have a .o-file linkable.  We only permit it if all the
 852         -- modules it depends on also have .o files; a .o file can't
 853         -- link to a bytecode module
 854    = do let mod_name = ms_mod summary
 855
 856         maybe_disk_linkable
 857           <- if (not objects_allowed)
 858                 then return Nothing
 859
 860                 else findLinkable mod_name (ms_location summary)
 861
 862         let old_linkable = findModuleLinkable_maybe old_linkables mod_name
 863
 864             new_linkables' =
 865              case (old_linkable, maybe_disk_linkable) of
 866                 (Nothing, Nothing)                      -> []
 867
 868                 -- new object linkable just appeared
 869                 (Nothing, Just l)                       -> up_to_date l True
 870
 871                 (Just l,  Nothing)
 872                   | isObjectLinkable l                  -> []
 873                     -- object linkable disappeared!  In case we need to
 874                     -- relink the module, disregard the old linkable and
 875                     -- just interpret the module from now on.
 876                   | otherwise                           -> up_to_date l False
 877                     -- old byte code linkable
 878
 879                 (Just l, Just l')
 880                   | not (isObjectLinkable l)            -> up_to_date l  False
 881                     -- if the previous linkable was interpreted, then we
 882                     -- ignore a newly compiled version, because the version
 883                     -- numbers in the interface file will be out-of-sync with
 884                     -- our internal ones.
 885                   | linkableTime l' >  linkableTime l   -> up_to_date l' True
 886                   | linkableTime l' == linkableTime l   -> up_to_date l  False
 887                   | otherwise                           -> []
 888                     -- on-disk linkable has been replaced by an older one!
 889                     -- again, disregard the previous one.
 890
 891             up_to_date l b
 892                 | linkableTime l < ms_hs_date summary = []
 893                 | otherwise = [(l,b)]
 894                 -- why '<' rather than '<=' above?  If the filesystem stores
 895                 -- times to the nearset second, we may occasionally find that
 896                 -- the object & source have the same modification time,
 897                 -- especially if the source was automatically generated
 898                 -- and compiled.  Using >= is slightly unsafe, but it matches
 899                 -- make's behaviour.
 900
 901         return (new_linkables' ++ new_linkables)
 902
 903
 904 hptLinkables :: HomePackageTable -> [Linkable]
 905 -- Get all the linkables from the home package table, one for each module
 906 -- Once the HPT is up to date, these are the ones we should link
 907 hptLinkables hpt = map hm_linkable (moduleEnvElts hpt)
 908
 909
 910 -----------------------------------------------------------------------------
 911 -- Do a pre-upsweep without use of "compile", to establish a
 912 -- (downward-closed) set of stable modules for which we won't call compile.
 913
 914 -- a stable module:
 915 --      * has a valid linkable (see getValidLinkables above)
 916 --      * depends only on stable modules
 917 --      * has an interface in the HPT (interactive mode only)
 918
 919 preUpsweep :: [Linkable]        -- new valid linkables
 920            -> [Module]          -- names of all mods encountered in downsweep
 921            -> [ModSummary]      -- accumulating stable modules
 922            -> [SCC ModSummary]  -- scc-ified mod graph, including src imps
 923            -> IO [ModSummary]   -- stable modules
 924
 925 preUpsweep valid_lis all_home_mods stable []  = return stable
 926 preUpsweep valid_lis all_home_mods stable (scc0:sccs)
 927    = do let scc = flattenSCC scc0
 928             scc_allhomeimps :: [Module]
 929             scc_allhomeimps
 930                = nub (filter (`elem` all_home_mods) (concatMap ms_allimps scc))
 931             all_imports_in_scc_or_stable
 932                = all in_stable_or_scc scc_allhomeimps
 933             scc_mods     = map ms_mod scc
 934             stable_names = scc_mods ++ map ms_mod stable
 935             in_stable_or_scc m = m `elem` stable_names
 936
 937             -- now we check for valid linkables: each module in the SCC must
 938             -- have a valid linkable (see getValidLinkables above).
 939             has_valid_linkable scc_mod
 940               = isJust (findModuleLinkable_maybe valid_lis scc_mod)
 941
 942             scc_is_stable = all_imports_in_scc_or_stable
 943                           && all has_valid_linkable scc_mods
 944
 945         if scc_is_stable
 946          then preUpsweep valid_lis all_home_mods (scc ++ stable) sccs
 947          else preUpsweep valid_lis all_home_mods stable          sccs
 948
 949
 950 -- Return (names of) all those in modsDone who are part of a cycle
 951 -- as defined by theGraph.
 952 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 953 findPartiallyCompletedCycles modsDone theGraph
 954    = chew theGraph
 955      where
 956         chew [] = []
 957         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 958         chew ((CyclicSCC vs):rest)
 959            = let names_in_this_cycle = nub (map ms_mod vs)
 960                  mods_in_this_cycle
 961                     = nub ([done | done <- modsDone,
 962                                    done `elem` names_in_this_cycle])
 963                  chewed_rest = chew rest
 964              in
 965              if   notNull mods_in_this_cycle
 966                   && length mods_in_this_cycle < length names_in_this_cycle
 967              then mods_in_this_cycle ++ chewed_rest
 968              else chewed_rest
 969
 970
 971 -- Compile multiple modules, stopping as soon as an error appears.
 972 -- There better had not be any cyclic groups here -- we check for them.
 973 upsweep_mods :: HscEnv                          -- Includes initially-empty HPT
 974              -> (HomePackageTable, [Linkable])  -- HPT and valid linkables from last time round
 975              -> IO ()                           -- How to clean up unwanted tmp files
 976              -> [SCC ModSummary]                -- Mods to do (the worklist)
 977              -> IO (SuccessFlag,
 978                     HscEnv,             -- With an updated HPT
 979                     [ModSummary])       -- Mods which succeeded
 980
 981 upsweep_mods hsc_env oldUI cleanup
 982      []
 983    = return (Succeeded, hsc_env, [])
 984
 985 upsweep_mods hsc_env oldUI cleanup
 986      (CyclicSCC ms:_)
 987    = do hPutStrLn stderr (showSDoc (cyclicModuleErr ms))
 988         return (Failed, hsc_env, [])
 989
 990 upsweep_mods hsc_env oldUI@(old_hpt, old_linkables) cleanup
 991      (AcyclicSCC mod:mods)
 992    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
 993         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
 994         --                     (moduleEnvElts (hsc_HPT hsc_env)))
 995
 996         mb_mod_info <- upsweep_mod hsc_env oldUI mod
 997
 998         cleanup         -- Remove unwanted tmp files between compilations
 999
1000         case mb_mod_info of
1001             Nothing -> return (Failed, hsc_env, [])
1002             Just mod_info -> do
1003                 { let this_mod = ms_mod mod
1004
1005                         -- Add new info to hsc_env
1006                       hpt1     = extendModuleEnv (hsc_HPT hsc_env) this_mod mod_info
1007                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
1008
1009                         -- Space-saving: delete the old HPT entry and linkable for mod
1010                         -- BUT if mod is a hs-boot node, don't delete it
1011                         -- For the linkable this is dead right: the linkable relates only
1012                         -- to the main Haskell source file.
1013                         -- For the interface, the HPT entry is probaby for the main Haskell
1014                         -- source file.  Deleting it would force
1015                       oldUI1 | isBootSummary mod = oldUI
1016                              | otherwise
1017                              = (delModuleEnv old_hpt this_mod,
1018                                   delModuleLinkable old_linkables this_mod)
1019
1020                 ; (restOK, hsc_env2, modOKs) <- upsweep_mods hsc_env1 oldUI1 cleanup mods
1021                 ; return (restOK, hsc_env2, mod:modOKs) }
1022
1023
1024 -- Compile a single module.  Always produce a Linkable for it if
1025 -- successful.  If no compilation happened, return the old Linkable.
1026 upsweep_mod :: HscEnv
1027             -> (HomePackageTable, UnlinkedImage)
1028             -> ModSummary
1029             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
1030
1031 upsweep_mod hsc_env (old_hpt, old_linkables) summary
1032    = do
1033         let this_mod = ms_mod summary
1034
1035         -- The old interface is ok if it's in the old HPT
1036         --      a) we're compiling a source file, and the old HPT entry is for a source file
1037         --      b) we're compiling a hs-boot file
1038         -- Case (b) allows an hs-boot file to get the interface of its real source file
1039         -- on the second iteration of the compilation manager, but that does no harm.
1040         -- Otherwise the hs-boot file will always be recompiled
1041             mb_old_iface
1042                 = case lookupModuleEnv old_hpt this_mod of
1043                      Nothing                              -> Nothing
1044                      Just hm_info | isBootSummary summary -> Just iface
1045                                   | not (mi_boot iface)   -> Just iface
1046                                   | otherwise             -> Nothing
1047                                    where
1048                                      iface = hm_iface hm_info
1049
1050             maybe_old_linkable = findModuleLinkable_maybe old_linkables this_mod
1051             source_unchanged   = isJust maybe_old_linkable
1052
1053             old_linkable = expectJust "upsweep_mod:old_linkable" maybe_old_linkable
1054
1055             have_object
1056                | Just l <- maybe_old_linkable, isObjectLinkable l = True
1057                | otherwise = False
1058
1059         compresult <- compile hsc_env summary source_unchanged have_object mb_old_iface
1060
1061         case compresult of
1062
1063            -- Compilation "succeeded", and may or may not have returned a new
1064            -- linkable (depending on whether compilation was actually performed
1065            -- or not).
1066            CompOK new_details new_iface maybe_new_linkable
1067               -> do let
1068                         new_linkable = maybe_new_linkable `orElse` old_linkable
1069                         new_info = HomeModInfo { hm_iface = new_iface,
1070                                                  hm_details = new_details,
1071                                                  hm_linkable = new_linkable }
1072                     return (Just new_info)
1073
1074            -- Compilation failed.  Compile may still have updated the PCS, tho.
1075            CompErrs -> return Nothing
1076
1077 -- Filter modules in the HPT
1078 retainInTopLevelEnvs :: [Module] -> HomePackageTable -> HomePackageTable
1079 retainInTopLevelEnvs keep_these hpt
1080    = mkModuleEnv [ (mod, fromJust mb_mod_info)
1081                  | mod <- keep_these
1082                  , let mb_mod_info = lookupModuleEnv hpt mod
1083                  , isJust mb_mod_info ]
1084
1085 -----------------------------------------------------------------------------
1086 cmTopSort :: Bool               -- Drop hi-boot nodes? (see below)
1087           -> [ModSummary]
1088           -> [SCC ModSummary]
1089 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1090 --
1091 -- Drop hi-boot nodes (first boolean arg)?
1092 --
1093 --   False:     treat the hi-boot summaries as nodes of the graph,
1094 --              so the graph must be acyclic
1095 --
1096 --   True:      eliminate the hi-boot nodes, and instead pretend
1097 --              the a source-import of Foo is an import of Foo
1098 --              The resulting graph has no hi-boot nodes, but can by cyclic
1099
1100 cmTopSort drop_hs_boot_nodes summaries
1101    = stronglyConnComp nodes
1102    where
1103         -- Drop hs-boot nodes by using HsSrcFile as the key
1104         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1105                     | otherwise          = HsBootFile
1106
1107         -- We use integers as the keys for the SCC algorithm
1108         nodes :: [(ModSummary, Int, [Int])]
1109         nodes = [(s, fromJust (lookup_key (ms_hsc_src s) (ms_mod s)),
1110                      out_edge_keys hs_boot_key (ms_srcimps s) ++
1111                      out_edge_keys HsSrcFile   (ms_imps s)    )
1112                 | s <- summaries
1113                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1114                 -- Drop the hi-boot ones if told to do so
1115
1116         key_map :: NodeMap Int
1117         key_map = listToFM ([(ms_mod s, ms_hsc_src s) | s <- summaries]
1118                            `zip` [1..])
1119
1120         lookup_key :: HscSource -> Module -> Maybe Int
1121         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1122
1123         out_edge_keys :: HscSource -> [Module] -> [Int]
1124         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1125                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1126                 -- the IsBootInterface parameter True; else False
1127
1128
1129 -----------------------------------------------------------------------------
1130 -- Downsweep (dependency analysis)
1131
1132 -- Chase downwards from the specified root set, returning summaries
1133 -- for all home modules encountered.  Only follow source-import
1134 -- links.
1135
1136 -- We pass in the previous collection of summaries, which is used as a
1137 -- cache to avoid recalculating a module summary if the source is
1138 -- unchanged.
1139 --
1140 -- The returned list of [ModSummary] nodes has one node for each home-package
1141 -- module, plus one for any hs-boot files.  The imports of these nodes
1142 -- are all there, including the imports of non-home-package modules.
1143
1144 cmDownsweep :: DynFlags
1145             -> [FilePath]       -- Roots
1146             -> [ModSummary]     -- Old summaries
1147             -> [Module]         -- Ignore dependencies on these; treat them as
1148                                 -- if they were package modules
1149             -> IO [ModSummary]
1150 cmDownsweep dflags roots old_summaries excl_mods
1151    = do rootSummaries <- mapM getRootSummary roots
1152         checkDuplicates rootSummaries
1153         loop (concatMap msDeps rootSummaries)
1154              (mkNodeMap rootSummaries)
1155      where
1156         old_summary_map :: NodeMap ModSummary
1157         old_summary_map = mkNodeMap old_summaries
1158
1159         getRootSummary :: FilePath -> IO ModSummary
1160         getRootSummary file
1161            | isHaskellSrcFilename file
1162            = do exists <- doesFileExist file
1163                 if exists then summariseFile dflags file else do
1164                 throwDyn (CmdLineError ("can't find file `" ++ file ++ "'"))
1165            | otherwise
1166            = do exists <- doesFileExist hs_file
1167                 if exists then summariseFile dflags hs_file else do
1168                 exists <- doesFileExist lhs_file
1169                 if exists then summariseFile dflags lhs_file else do
1170                 let mod_name = mkModule file
1171                 maybe_summary <- summarise dflags emptyNodeMap Nothing False
1172                                            mod_name excl_mods
1173                 case maybe_summary of
1174                    Nothing -> packageModErr mod_name
1175                    Just s  -> return s
1176            where
1177                  hs_file = file ++ ".hs"
1178                  lhs_file = file ++ ".lhs"
1179
1180         -- In a root module, the filename is allowed to diverge from the module
1181         -- name, so we have to check that there aren't multiple root files
1182         -- defining the same module (otherwise the duplicates will be silently
1183         -- ignored, leading to confusing behaviour).
1184         checkDuplicates :: [ModSummary] -> IO ()
1185         checkDuplicates summaries = mapM_ check summaries
1186           where check summ =
1187                   case dups of
1188                         []     -> return ()
1189                         [_one] -> return ()
1190                         many   -> multiRootsErr modl many
1191                    where modl = ms_mod summ
1192                          dups =
1193                            [ fromJust (ml_hs_file (ms_location summ'))
1194                            | summ' <- summaries, ms_mod summ' == modl ]
1195
1196         loop :: [(FilePath,Module,IsBootInterface)]     -- Work list: process these modules
1197              -> NodeMap ModSummary      -- Visited set
1198              -> IO [ModSummary]         -- The result includes the worklist, except
1199                                         -- for those mentioned in the visited set
1200         loop [] done      = return (nodeMapElts done)
1201         loop ((cur_path, wanted_mod, is_boot) : ss) done
1202           | key `elemFM` done = loop ss done
1203           | otherwise         = do { mb_s <- summarise dflags old_summary_map
1204                                                  (Just cur_path) is_boot
1205                                                  wanted_mod excl_mods
1206                                    ; case mb_s of
1207                                         Nothing -> loop ss done
1208                                         Just s  -> loop (msDeps s ++ ss)
1209                                                         (addToFM done key s) }
1210           where
1211             key = (wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1212
1213 msDeps :: ModSummary -> [(FilePath,             -- Importing module
1214                           Module,               -- Imported module
1215                           IsBootInterface)]      -- {-# SOURCE #-} import or not
1216 -- (msDeps s) returns the dependencies of the ModSummary s.
1217 -- A wrinkle is that for a {-# SOURCE #-} import we return
1218 --      *both* the hs-boot file
1219 --      *and* the source file
1220 -- as "dependencies".  That ensures that the list of all relevant
1221 -- modules always contains B.hs if it contains B.hs-boot.
1222 -- Remember, this pass isn't doing the topological sort.  It's
1223 -- just gathering the list of all relevant ModSummaries
1224 msDeps s =  concat [ [(f, m, True), (f,m,False)] | m <- ms_srcimps s]
1225          ++ [(f,m,False) | m <- ms_imps    s]
1226         where
1227           f = msHsFilePath s    -- Keep the importing module for error reporting
1228
1229
1230 -----------------------------------------------------------------------------
1231 -- Summarising modules
1232
1233 -- We have two types of summarisation:
1234 --
1235 --    * Summarise a file.  This is used for the root module(s) passed to
1236 --      cmLoadModules.  The file is read, and used to determine the root
1237 --      module name.  The module name may differ from the filename.
1238 --
1239 --    * Summarise a module.  We are given a module name, and must provide
1240 --      a summary.  The finder is used to locate the file in which the module
1241 --      resides.
1242
1243 summariseFile :: DynFlags -> FilePath -> IO ModSummary
1244 -- Used for Haskell source only, I think
1245 -- We know the file name, and we know it exists,
1246 -- but we don't necessarily know the module name (might differ)
1247 summariseFile dflags file
1248    = do (dflags', hspp_fn) <- preprocess dflags file
1249                 -- The dflags' contains the OPTIONS pragmas
1250
1251         -- Read the file into a buffer.  We're going to cache
1252         -- this buffer in the ModLocation (ml_hspp_buf) so that it
1253         -- doesn't have to be slurped again when hscMain parses the
1254         -- file later.
1255         buf <- hGetStringBuffer hspp_fn
1256         (srcimps,the_imps,mod) <- getImports dflags' buf hspp_fn
1257
1258         -- Make a ModLocation for this file
1259         location <- mkHomeModLocation mod file
1260
1261         -- Tell the Finder cache where it is, so that subsequent calls
1262         -- to findModule will find it, even if it's not on any search path
1263         addHomeModuleToFinder mod location
1264
1265         src_timestamp <- getModificationTime file
1266         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1267                              ms_location = location,
1268                              ms_hspp_file = Just hspp_fn,
1269                              ms_hspp_buf  = Just buf,
1270                              ms_srcimps = srcimps, ms_imps = the_imps,
1271                              ms_hs_date = src_timestamp })
1272
1273 -- Summarise a module, and pick up source and timestamp.
1274 summarise :: DynFlags
1275           -> NodeMap ModSummary -- Map of old summaries
1276           -> Maybe FilePath     -- Importing module (for error messages)
1277           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1278           -> Module             -- Imported module to be summarised
1279           -> [Module]           -- Modules to exclude
1280           -> IO (Maybe ModSummary)      -- Its new summary
1281
1282 summarise dflags old_summary_map cur_mod is_boot wanted_mod excl_mods
1283   | wanted_mod `elem` excl_mods
1284   = return Nothing
1285
1286   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1287   = do  {       -- Find its new timestamp; all the
1288                 -- ModSummaries in the old map have valid ml_hs_files
1289            let location = ms_location old_summary
1290                src_fn = fromJust (ml_hs_file location)
1291
1292         ;  src_timestamp <- getModificationTime src_fn
1293
1294                 -- return the cached summary if the source didn't change
1295         ; if ms_hs_date old_summary == src_timestamp
1296           then return (Just old_summary)
1297           else new_summary location
1298         }
1299
1300   | otherwise
1301   = do  { found <- findModule dflags wanted_mod True {-explicit-}
1302         ; case found of
1303              Found location pkg
1304                 | not (isHomePackage pkg)      -> return Nothing        -- Drop external-pkg
1305                 | isJust (ml_hs_file location) -> new_summary location  -- Home package
1306              err        -> noModError dflags cur_mod wanted_mod err     -- Not found
1307         }
1308   where
1309     hsc_src = if is_boot then HsBootFile else HsSrcFile
1310
1311     new_summary location
1312       = do {    -- Adjust location to point to the hs-boot source file,
1313                 -- hi file, object file, when is_boot says so
1314           let location' | is_boot   = addBootSuffixLocn location
1315                         | otherwise = location
1316               src_fn = fromJust (ml_hs_file location')
1317
1318                 -- Check that it exists
1319                 -- It might have been deleted since the Finder last found it
1320         ; exists <- doesFileExist src_fn
1321         ; if exists then return () else noHsFileErr cur_mod src_fn
1322
1323         -- Preprocess the source file and get its imports
1324         -- The dflags' contains the OPTIONS pragmas
1325         ; (dflags', hspp_fn) <- preprocess dflags src_fn
1326         ; buf <- hGetStringBuffer hspp_fn
1327         ; (srcimps, the_imps, mod_name) <- getImports dflags' buf hspp_fn
1328
1329         ; when (mod_name /= wanted_mod) $
1330                 throwDyn (ProgramError
1331                    (showSDoc (text src_fn
1332                               <>  text ": file name does not match module name"
1333                               <+> quotes (ppr mod_name))))
1334
1335                 -- Find its timestamp, and return the summary
1336         ; src_timestamp <- getModificationTime src_fn
1337         ; return (Just ( ModSummary { ms_mod       = wanted_mod,
1338                                       ms_hsc_src   = hsc_src,
1339                                       ms_location  = location',
1340                                       ms_hspp_file = Just hspp_fn,
1341                                       ms_hspp_buf  = Just buf,
1342                                       ms_srcimps   = srcimps,
1343                                       ms_imps      = the_imps,
1344                                       ms_hs_date   = src_timestamp }))
1345         }
1346
1347
1348 -----------------------------------------------------------------------------
1349 --                      Error messages
1350 -----------------------------------------------------------------------------
1351
1352 noModError :: DynFlags -> Maybe FilePath -> Module -> FindResult -> IO ab
1353 -- ToDo: we don't have a proper line number for this error
1354 noModError dflags cur_mod wanted_mod err
1355   = throwDyn $ ProgramError $ showSDoc $
1356     vcat [cantFindError dflags wanted_mod err,
1357           nest 2 (parens (pp_where cur_mod))]
1358
1359 noHsFileErr cur_mod path
1360   = throwDyn $ CmdLineError $ showSDoc $
1361     vcat [text "Can't find" <+> text path,
1362           nest 2 (parens (pp_where cur_mod))]
1363
1364 pp_where Nothing  = text "one of the roots of the dependency analysis"
1365 pp_where (Just p) = text "imported from" <+> text p
1366
1367 packageModErr mod
1368   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1369                                    quotes (ppr mod) <+>
1370                                    text "is a package module")))
1371
1372 multiRootsErr mod files
1373   = throwDyn (ProgramError (showSDoc (
1374         text "module" <+> quotes (ppr mod) <+>
1375         text "is defined in multiple files:" <+>
1376         sep (map text files))))
1377
1378 cyclicModuleErr :: [ModSummary] -> SDoc
1379 cyclicModuleErr ms
1380   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1381        2 (vcat (map show_one ms))
1382   where
1383     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1384                         nest 2 $ ptext SLIT("imports:") <+>
1385                                    (pp_imps HsBootFile (ms_srcimps ms)
1386                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1387     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1388     pp_imps src mods = fsep (map (show_mod src) mods)
1389 \end{code}
1390