ghc/compiler/compMan/CompManager.lhs

   1 %
   2 % (c) The University of Glasgow, 2002
   3 %
   4 % The Compilation Manager
   5 %
   6 \begin{code}
   7 {-# OPTIONS -fvia-C #-}
   8 module CompManager (
   9     ModuleGraph,
  10
  11     CmState, emptyCmState,  -- abstract
  12
  13     cmInit,        -- :: GhciMode -> IO CmState
  14
  15     cmDepAnal,     -- :: CmState -> DynFlags -> [FilePath] -> IO ModuleGraph
  16
  17     cmLoadModules, -- :: CmState -> DynFlags -> ModuleGraph
  18                    --    -> IO (CmState, [String])
  19
  20     cmUnload,      -- :: CmState -> DynFlags -> IO CmState
  21
  22 #ifdef GHCI
  23     cmModuleIsInterpreted, -- :: CmState -> String -> IO Bool
  24
  25     cmSetContext,  -- :: CmState -> DynFlags -> [String] -> [String] -> IO CmState
  26     cmGetContext,  -- :: CmState -> IO ([String],[String])
  27
  28     cmInfoThing,   -- :: CmState -> DynFlags -> String
  29                    --   -> IO (CmState, [(TyThing,Fixity)])
  30
  31     cmBrowseModule, -- :: CmState -> IO [TyThing]
  32
  33     CmRunResult(..),
  34     cmRunStmt,     -- :: CmState -> DynFlags -> String
  35                    --    -> IO (CmState, CmRunResult)
  36
  37     cmTypeOfExpr,  -- :: CmState -> DynFlags -> String
  38                    --   -> IO (CmState, Maybe String)
  39
  40     cmTypeOfName,  -- :: CmState -> Name -> IO (Maybe String)
  41
  42     HValue,
  43     cmCompileExpr, -- :: CmState -> DynFlags -> String
  44                    --   -> IO (CmState, Maybe HValue)
  45
  46     cmGetModuleGraph,           -- :: CmState -> ModuleGraph
  47     cmGetLinkables,             -- :: CmState -> [Linkable]
  48
  49     cmGetBindings,      -- :: CmState -> [TyThing]
  50     cmGetPrintUnqual,   -- :: CmState -> PrintUnqualified
  51 #endif
  52
  53     -- utils
  54     showModMsg,         --
  55   )
  56 where
  57
  58 #include "HsVersions.h"
  59
  60 import MkIface --tmp
  61 import HsSyn    -- tmp
  62
  63 import CmLink
  64 import CmTypes
  65 import DriverPipeline
  66 import DriverState      ( v_Output_file )
  67 import DriverPhases
  68 import DriverUtil
  69 import Finder
  70 #ifdef GHCI
  71 import HscMain          ( initPersistentCompilerState, hscThing,
  72                           hscModuleContents )
  73 #else
  74 import HscMain          ( initPersistentCompilerState )
  75 #endif
  76 import HscTypes
  77 import Name             ( Name, NamedThing(..), nameRdrName, nameModule,
  78                           isHomePackageName, isGlobalName )
  79 import NameEnv
  80 import Rename           ( mkGlobalContext )
  81 import RdrName          ( emptyRdrEnv )
  82 import Module
  83 import GetImports
  84 import UniqFM
  85 import Unique           ( Uniquable )
  86 import Digraph          ( SCC(..), stronglyConnComp, flattenSCC, flattenSCCs )
  87 import ErrUtils         ( showPass )
  88 import SysTools         ( cleanTempFilesExcept )
  89 import Util
  90 import Outputable
  91 import Panic
  92 import CmdLineOpts      ( DynFlags(..), getDynFlags )
  93
  94 import IOExts
  95
  96 #ifdef GHCI
  97 import RdrName          ( lookupRdrEnv )
  98 import Id               ( idType, idName )
  99 import Type             ( tidyType )
 100 import VarEnv           ( emptyTidyEnv )
 101 import BasicTypes       ( Fixity, defaultFixity )
 102 import Interpreter      ( HValue )
 103 import HscMain          ( hscStmt )
 104 import PrelGHC          ( unsafeCoerce# )
 105
 106 import Foreign
 107 import CForeign
 108 import Exception        ( Exception, try )
 109 #endif
 110
 111 -- lang
 112 import Exception        ( throwDyn )
 113
 114 -- std
 115 import Directory        ( getModificationTime, doesFileExist )
 116 import IO
 117 import Monad
 118 import List             ( nub )
 119 import Maybe
 120 \end{code}
 121
 122
 123 \begin{code}
 124 -- Persistent state for the entire system
 125 data CmState
 126    = CmState {
 127         hst   :: HomeSymbolTable,    -- home symbol table
 128         hit   :: HomeIfaceTable,     -- home interface table
 129         ui    :: UnlinkedImage,      -- the unlinked images
 130         mg    :: ModuleGraph,        -- the module graph
 131         gmode :: GhciMode,           -- NEVER CHANGES
 132         ic    :: InteractiveContext, -- command-line binding info
 133
 134         pcs    :: PersistentCompilerState, -- compile's persistent state
 135         pls    :: PersistentLinkerState    -- link's persistent state
 136      }
 137
 138 emptyCmState :: GhciMode -> IO CmState
 139 emptyCmState gmode
 140     = do pcs     <- initPersistentCompilerState
 141          pls     <- emptyPLS
 142          return (CmState { hst    = emptySymbolTable,
 143                            hit    = emptyIfaceTable,
 144                            ui     = emptyUI,
 145                            mg     = emptyMG,
 146                            gmode  = gmode,
 147                            ic     = emptyInteractiveContext,
 148                            pcs    = pcs,
 149                            pls    = pls })
 150
 151 emptyInteractiveContext
 152   = InteractiveContext { ic_toplev_scope = [],
 153                          ic_exports = [],
 154                          ic_rn_gbl_env = emptyRdrEnv,
 155                          ic_print_unqual = alwaysQualify,
 156                          ic_rn_local_env = emptyRdrEnv,
 157                          ic_type_env = emptyTypeEnv }
 158
 159 -- CM internal types
 160 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
 161 emptyUI :: UnlinkedImage
 162 emptyUI = []
 163
 164 type ModuleGraph = [ModSummary]  -- the module graph, topologically sorted
 165 emptyMG :: ModuleGraph
 166 emptyMG = []
 167
 168 -----------------------------------------------------------------------------
 169 -- Produce an initial CmState.
 170
 171 cmInit :: GhciMode -> IO CmState
 172 cmInit mode = emptyCmState mode
 173
 174 -----------------------------------------------------------------------------
 175 -- Grab information from the CmState
 176
 177 cmGetModuleGraph        = mg
 178 cmGetLinkables          = ui
 179
 180 cmGetBindings cmstate = nameEnvElts (ic_type_env (ic cmstate))
 181 cmGetPrintUnqual cmstate = ic_print_unqual (ic cmstate)
 182
 183 -----------------------------------------------------------------------------
 184 -- Setting the context doesn't throw away any bindings; the bindings
 185 -- we've built up in the InteractiveContext simply move to the new
 186 -- module.  They always shadow anything in scope in the current context.
 187
 188 cmSetContext
 189         :: CmState -> DynFlags
 190         -> [String]             -- take the top-level scopes of these modules
 191         -> [String]             -- and the just the exports from these
 192         -> IO CmState
 193 cmSetContext cmstate dflags toplevs exports = do
 194   let CmState{ hit=hit, hst=hst, pcs=pcs, ic=old_ic } = cmstate
 195
 196   toplev_mods <- mapM (getTopLevModule hit)    (map mkModuleName toplevs)
 197   export_mods <- mapM (moduleNameToModule hit) (map mkModuleName exports)
 198
 199   (new_pcs, print_unqual, maybe_env)
 200       <- mkGlobalContext dflags hit hst pcs toplev_mods export_mods
 201
 202   case maybe_env of
 203     Nothing -> return cmstate
 204     Just env -> return cmstate{ pcs = new_pcs,
 205                                 ic = old_ic{ ic_toplev_scope = toplev_mods,
 206                                              ic_exports = export_mods,
 207                                              ic_rn_gbl_env = env,
 208                                              ic_print_unqual = print_unqual } }
 209
 210 getTopLevModule hit mn =
 211   case lookupModuleEnvByName hit mn of
 212     Just iface
 213       | Just _ <- mi_globals iface -> return (mi_module iface)
 214     _other -> throwDyn (CmdLineError (
 215           "cannot enter the top-level scope of a compiled module (module `" ++
 216            moduleNameUserString mn ++ "')"))
 217
 218 moduleNameToModule :: HomeIfaceTable -> ModuleName -> IO Module
 219 moduleNameToModule hit mn = do
 220   case lookupModuleEnvByName hit mn of
 221     Just iface -> return (mi_module iface)
 222     _not_a_home_module -> do
 223           maybe_stuff <- findModule mn
 224           case maybe_stuff of
 225             Nothing -> throwDyn (CmdLineError ("can't find module `"
 226                                     ++ moduleNameUserString mn ++ "'"))
 227             Just (m,_) -> return m
 228
 229 cmGetContext :: CmState -> IO ([String],[String])
 230 cmGetContext CmState{ic=ic} =
 231   return (map moduleUserString (ic_toplev_scope ic),
 232           map moduleUserString (ic_exports ic))
 233
 234 cmModuleIsInterpreted :: CmState -> String -> IO Bool
 235 cmModuleIsInterpreted cmstate str
 236  = case lookupModuleEnvByName (hit cmstate) (mkModuleName str) of
 237       Just iface         -> return (not (isNothing (mi_globals iface)))
 238       _not_a_home_module -> return False
 239
 240 -----------------------------------------------------------------------------
 241 -- cmInfoThing: convert a String to a TyThing
 242
 243 -- A string may refer to more than one TyThing (eg. a constructor,
 244 -- and type constructor), so we return a list of all the possible TyThings.
 245
 246 #ifdef GHCI
 247 cmInfoThing :: CmState -> DynFlags -> String -> IO (CmState, [(TyThing,Fixity)])
 248 cmInfoThing cmstate dflags id
 249    = do (new_pcs, things) <- hscThing dflags hst hit pcs icontext id
 250         let pairs = map (\x -> (x, getFixity new_pcs (getName x))) things
 251         return (cmstate{ pcs=new_pcs }, pairs)
 252    where
 253      CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 254
 255      getFixity :: PersistentCompilerState -> Name -> Fixity
 256      getFixity pcs name
 257         | isGlobalName name,
 258           Just iface  <- lookupModuleEnv iface_table (nameModule name),
 259           Just fixity <- lookupNameEnv (mi_fixities iface) name
 260           = fixity
 261         | otherwise
 262           = defaultFixity
 263         where iface_table | isHomePackageName name = hit
 264                           | otherwise              = pcs_PIT pcs
 265 #endif
 266
 267 -- ---------------------------------------------------------------------------
 268 -- cmBrowseModule: get all the TyThings defined in a module
 269
 270 #ifdef GHCI
 271 cmBrowseModule :: CmState -> DynFlags -> String -> Bool
 272         -> IO (CmState, [TyThing])
 273 cmBrowseModule cmstate dflags str exports_only = do
 274   let mn = mkModuleName str
 275   mod <- moduleNameToModule hit mn
 276   (pcs1, maybe_ty_things)
 277         <- hscModuleContents dflags hst hit pcs mod exports_only
 278   case maybe_ty_things of
 279         Nothing -> return (cmstate{pcs=pcs1}, [])
 280         Just ty_things -> return (cmstate{pcs=pcs1}, ty_things)
 281   where
 282      CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 283 #endif
 284
 285 -----------------------------------------------------------------------------
 286 -- cmRunStmt:  Run a statement/expr.
 287
 288 #ifdef GHCI
 289 data CmRunResult
 290   = CmRunOk [Name]              -- names bound by this evaluation
 291   | CmRunFailed
 292   | CmRunException Exception    -- statement raised an exception
 293
 294 cmRunStmt :: CmState -> DynFlags -> String -> IO (CmState, CmRunResult)
 295 cmRunStmt cmstate@CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext }
 296           dflags expr
 297    = do
 298         let InteractiveContext {
 299                 ic_rn_local_env = rn_env,
 300                 ic_type_env     = type_env } = icontext
 301
 302         (new_pcs, maybe_stuff)
 303             <- hscStmt dflags hst hit pcs icontext expr False{-stmt-}
 304
 305         case maybe_stuff of
 306            Nothing -> return (cmstate{ pcs=new_pcs }, CmRunFailed)
 307            Just (ids, _, bcos) -> do
 308
 309                 -- update the interactive context
 310                 let
 311                     names = map idName ids
 312
 313                     -- these names have just been shadowed
 314                     shadowed = [ n | r <- map nameRdrName names,
 315                                      Just n <- [lookupRdrEnv rn_env r] ]
 316
 317                     new_rn_env   = extendLocalRdrEnv rn_env names
 318
 319                     -- remove any shadowed bindings from the type_env
 320                     filtered_type_env = delListFromNameEnv type_env shadowed
 321
 322                     new_type_env = extendNameEnvList filtered_type_env
 323                                         [ (getName id, AnId id) | id <- ids]
 324
 325                     new_ic = icontext { ic_rn_local_env = new_rn_env,
 326                                         ic_type_env     = new_type_env }
 327
 328                 -- link it
 329                 hval <- linkExpr pls bcos
 330
 331                 -- run it!
 332                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 333                 either_hvals <- sandboxIO thing_to_run
 334                 case either_hvals of
 335                    Left err
 336                         -> do hPutStrLn stderr ("unknown failure, code " ++ show err)
 337                               return ( cmstate{ pcs=new_pcs, ic=new_ic }, CmRunFailed )
 338
 339                    Right maybe_hvals ->
 340                      case maybe_hvals of
 341                         Left e ->
 342                             return ( cmstate{ pcs=new_pcs, ic=new_ic },
 343                                      CmRunException e )
 344                         Right hvals -> do
 345                              -- Get the newly bound things, and bind them.
 346                              -- Don't forget to delete any shadowed bindings from the
 347                              -- closure_env, lest we end up with a space leak.
 348                              pls <- delListFromClosureEnv pls shadowed
 349                              new_pls <- addListToClosureEnv pls (zip names hvals)
 350
 351                              return (cmstate{ pcs=new_pcs, pls=new_pls, ic=new_ic },
 352                                      CmRunOk names)
 353
 354
 355 -- We run the statement in a "sandbox" to protect the rest of the
 356 -- system from anything the expression might do.  For now, this
 357 -- consists of just wrapping it in an exception handler, but see below
 358 -- for another version.
 359
 360 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
 361 sandboxIO thing = do
 362   r <- Exception.try thing
 363   return (Right r)
 364
 365 {-
 366 -- This version of sandboxIO runs the expression in a completely new
 367 -- RTS main thread.  It is disabled for now because ^C exceptions
 368 -- won't be delivered to the new thread, instead they'll be delivered
 369 -- to the (blocked) GHCi main thread.
 370
 371 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
 372 sandboxIO thing = do
 373   st_thing <- newStablePtr (Exception.try thing)
 374   alloca $ \ p_st_result -> do
 375     stat <- rts_evalStableIO st_thing p_st_result
 376     freeStablePtr st_thing
 377     if stat == 1
 378         then do st_result <- peek p_st_result
 379                 result <- deRefStablePtr st_result
 380                 freeStablePtr st_result
 381                 return (Right result)
 382         else do
 383                 return (Left (fromIntegral stat))
 384
 385 foreign import "rts_evalStableIO"  {- safe -}
 386   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
 387   -- more informative than the C type!
 388 -}
 389 #endif
 390
 391 -----------------------------------------------------------------------------
 392 -- cmTypeOfExpr: returns a string representing the type of an expression
 393
 394 #ifdef GHCI
 395 cmTypeOfExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe String)
 396 cmTypeOfExpr cmstate dflags expr
 397    = do (new_pcs, maybe_stuff)
 398           <- hscStmt dflags hst hit pcs ic expr True{-just an expr-}
 399
 400         let new_cmstate = cmstate{pcs = new_pcs}
 401
 402         case maybe_stuff of
 403            Nothing -> return (new_cmstate, Nothing)
 404            Just (_, ty, _) -> return (new_cmstate, Just str)
 405              where
 406                 str = showSDocForUser unqual (ppr tidy_ty)
 407                 unqual  = ic_print_unqual ic
 408                 tidy_ty = tidyType emptyTidyEnv ty
 409    where
 410        CmState{ hst=hst, hit=hit, pcs=pcs, ic=ic } = cmstate
 411 #endif
 412
 413 -----------------------------------------------------------------------------
 414 -- cmTypeOfName: returns a string representing the type of a name.
 415
 416 #ifdef GHCI
 417 cmTypeOfName :: CmState -> Name -> IO (Maybe String)
 418 cmTypeOfName CmState{ hit=hit, pcs=pcs, ic=ic } name
 419  = case lookupNameEnv (ic_type_env ic) name of
 420         Nothing -> return Nothing
 421         Just (AnId id) -> return (Just str)
 422            where
 423              unqual = ic_print_unqual ic
 424              ty = tidyType emptyTidyEnv (idType id)
 425              str = showSDocForUser unqual (ppr ty)
 426
 427         _ -> panic "cmTypeOfName"
 428 #endif
 429
 430 -----------------------------------------------------------------------------
 431 -- cmCompileExpr: compile an expression and deliver an HValue
 432
 433 #ifdef GHCI
 434 cmCompileExpr :: CmState -> DynFlags -> String -> IO (CmState, Maybe HValue)
 435 cmCompileExpr cmstate dflags expr
 436    = do
 437         let InteractiveContext {
 438                 ic_rn_local_env = rn_env,
 439                 ic_type_env     = type_env } = icontext
 440
 441         (new_pcs, maybe_stuff)
 442             <- hscStmt dflags hst hit pcs icontext
 443                   ("let __cmCompileExpr = "++expr) False{-stmt-}
 444
 445         case maybe_stuff of
 446            Nothing -> return (cmstate{ pcs=new_pcs }, Nothing)
 447            Just (ids, _, bcos) -> do
 448
 449                 -- link it
 450                 hval <- linkExpr pls bcos
 451
 452                 -- run it!
 453                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
 454                 hvals <- thing_to_run
 455
 456                 case (ids,hvals) of
 457                   ([id],[hv]) -> return (cmstate{ pcs=new_pcs }, Just hv)
 458                   _ -> panic "cmCompileExpr"
 459
 460    where
 461        CmState{ hst=hst, hit=hit, pcs=pcs, pls=pls, ic=icontext } = cmstate
 462 #endif
 463
 464 -----------------------------------------------------------------------------
 465 -- Unload the compilation manager's state: everything it knows about the
 466 -- current collection of modules in the Home package.
 467
 468 cmUnload :: CmState -> DynFlags -> IO CmState
 469 cmUnload state@CmState{ gmode=mode, pls=pls, pcs=pcs } dflags
 470  = do -- Throw away the old home dir cache
 471       emptyHomeDirCache
 472
 473       -- Unload everything the linker knows about
 474       new_pls <- CmLink.unload mode dflags [] pls
 475
 476       -- Start with a fresh CmState, but keep the PersistentCompilerState
 477       new_state <- cmInit mode
 478       return new_state{ pcs=pcs, pls=new_pls }
 479
 480
 481 -----------------------------------------------------------------------------
 482 -- Trace dependency graph
 483
 484 -- This is a seperate pass so that the caller can back off and keep
 485 -- the current state if the downsweep fails.
 486
 487 cmDepAnal :: CmState -> DynFlags -> [FilePath] -> IO ModuleGraph
 488 cmDepAnal cmstate dflags rootnames
 489   = do showPass dflags "Chasing dependencies"
 490        when (verbosity dflags >= 1 && gmode cmstate == Batch) $
 491            hPutStrLn stderr (showSDoc (hcat [
 492              text progName, text ": chasing modules from: ",
 493              hcat (punctuate comma (map text rootnames))]))
 494        downsweep rootnames (mg cmstate)
 495
 496 -----------------------------------------------------------------------------
 497 -- The real business of the compilation manager: given a system state and
 498 -- a module name, try and bring the module up to date, probably changing
 499 -- the system state at the same time.
 500
 501 cmLoadModules :: CmState
 502              -> DynFlags
 503              -> ModuleGraph
 504              -> IO (CmState,            -- new state
 505                     Bool,               -- was successful
 506                     [String])           -- list of modules loaded
 507
 508 cmLoadModules cmstate1 dflags mg2unsorted
 509    = do -- version 1's are the original, before downsweep
 510         let pls1      = pls    cmstate1
 511         let pcs1      = pcs    cmstate1
 512         let hst1      = hst    cmstate1
 513         let hit1      = hit    cmstate1
 514         -- similarly, ui1 is the (complete) set of linkables from
 515         -- the previous pass, if any.
 516         let ui1       = ui     cmstate1
 517
 518         let ghci_mode = gmode cmstate1 -- this never changes
 519
 520         -- Do the downsweep to reestablish the module graph
 521         let verb = verbosity dflags
 522
 523         -- Find out if we have a Main module
 524         let a_root_is_Main
 525                = any ((=="Main").moduleNameUserString.modSummaryName)
 526                      mg2unsorted
 527
 528         let mg2unsorted_names = map modSummaryName mg2unsorted
 529
 530         -- reachable_from follows source as well as normal imports
 531         let reachable_from :: ModuleName -> [ModuleName]
 532             reachable_from = downwards_closure_of_module mg2unsorted
 533
 534         -- should be cycle free; ignores 'import source's
 535         let mg2 = topological_sort False mg2unsorted
 536         -- ... whereas this takes them into account.  Used for
 537         -- backing out partially complete cycles following a failed
 538         -- upsweep, and for removing from hst/hit all the modules
 539         -- not in strict downwards closure, during calls to compile.
 540         let mg2_with_srcimps = topological_sort True mg2unsorted
 541
 542         -- Sort out which linkables we wish to keep in the unlinked image.
 543         -- See getValidLinkables below for details.
 544         (valid_old_linkables, new_linkables)
 545             <- getValidLinkables ui1 mg2unsorted_names mg2_with_srcimps
 546
 547         -- putStrLn (showSDoc (vcat [ppr valid_old_linkables, ppr new_linkables]))
 548
 549                 -- uniq of ModuleName is the same as Module, fortunately...
 550         let hit2 = delListFromUFM hit1 (map linkableModName new_linkables)
 551
 552         -- When (verb >= 2) $
 553         --    putStrLn (showSDoc (text "Valid linkables:"
 554         --                       <+> ppr valid_linkables))
 555
 556         -- Figure out a stable set of modules which can be retained
 557         -- the top level envs, to avoid upsweeping them.  Goes to a
 558         -- bit of trouble to avoid upsweeping module cycles.
 559         --
 560         -- Construct a set S of stable modules like this:
 561         -- Travel upwards, over the sccified graph.  For each scc
 562         -- of modules ms, add ms to S only if:
 563         -- 1.  All home imports of ms are either in ms or S
 564         -- 2.  A valid old linkable exists for each module in ms
 565
 566         stable_mods <- preUpsweep valid_old_linkables
 567                                   mg2unsorted_names [] mg2_with_srcimps
 568
 569         let stable_summaries
 570                = concatMap (findInSummaries mg2unsorted) stable_mods
 571
 572             stable_linkables
 573                = filter (\m -> linkableModName m `elem` stable_mods)
 574                     valid_old_linkables
 575
 576         when (verb >= 2) $
 577            putStrLn (showSDoc (text "Stable modules:"
 578                                <+> sep (map (text.moduleNameUserString) stable_mods)))
 579
 580         -- unload any modules which are going to be re-linked this
 581         -- time around.
 582         pls2 <- CmLink.unload ghci_mode dflags stable_linkables pls1
 583
 584         -- we can now glom together our linkable sets
 585         let valid_linkables = valid_old_linkables ++ new_linkables
 586
 587         -- We could at this point detect cycles which aren't broken by
 588         -- a source-import, and complain immediately, but it seems better
 589         -- to let upsweep_mods do this, so at least some useful work gets
 590         -- done before the upsweep is abandoned.
 591         let upsweep_these
 592                = filter (\scc -> any (`notElem` stable_mods)
 593                                      (map modSummaryName (flattenSCC scc)))
 594                         mg2
 595
 596         --hPutStrLn stderr "after tsort:\n"
 597         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 598
 599         -- Because we don't take into account source imports when doing
 600         -- the topological sort, there shouldn't be any cycles in mg2.
 601         -- If there is, we complain and give up -- the user needs to
 602         -- break the cycle using a boot file.
 603
 604         -- Now do the upsweep, calling compile for each module in
 605         -- turn.  Final result is version 3 of everything.
 606
 607         let threaded2 = CmThreaded pcs1 hst1 hit2
 608
 609         -- clean up between compilations
 610         let cleanup = cleanTempFilesExcept verb
 611                           (ppFilesFromSummaries (flattenSCCs upsweep_these))
 612
 613         (upsweep_complete_success, threaded3, modsUpswept, newLis)
 614            <- upsweep_mods ghci_mode dflags valid_linkables reachable_from
 615                            threaded2 cleanup upsweep_these
 616
 617         let ui3 = add_to_ui valid_linkables newLis
 618         let (CmThreaded pcs3 hst3 hit3) = threaded3
 619
 620         -- At this point, modsUpswept and newLis should have the same
 621         -- length, so there is one new (or old) linkable for each
 622         -- mod which was processed (passed to compile).
 623
 624         -- Make modsDone be the summaries for each home module now
 625         -- available; this should equal the domains of hst3 and hit3.
 626         -- (NOT STRICTLY TRUE if an interactive session was started
 627         --  with some object on disk ???)
 628         -- Get in in a roughly top .. bottom order (hence reverse).
 629
 630         let modsDone = reverse modsUpswept ++ stable_summaries
 631
 632         -- Try and do linking in some form, depending on whether the
 633         -- upsweep was completely or only partially successful.
 634
 635         if upsweep_complete_success
 636
 637          then
 638            -- Easy; just relink it all.
 639            do when (verb >= 2) $
 640                  hPutStrLn stderr "Upsweep completely successful."
 641
 642               -- clean up after ourselves
 643               cleanTempFilesExcept verb (ppFilesFromSummaries modsDone)
 644
 645               -- issue a warning for the confusing case where the user said '-o foo'
 646               -- but we're not going to do any linking.
 647               ofile <- readIORef v_Output_file
 648               when (ghci_mode == Batch && isJust ofile && not a_root_is_Main
 649                      && verb > 0) $
 650                  hPutStrLn stderr "Warning: output was redirected with -o, but no output will be generated\nbecause there is no Main module."
 651
 652               -- link everything together
 653               linkresult <- link ghci_mode dflags a_root_is_Main ui3 pls2
 654
 655               cmLoadFinish True linkresult
 656                         hst3 hit3 ui3 modsDone ghci_mode pcs3
 657
 658          else
 659            -- Tricky.  We need to back out the effects of compiling any
 660            -- half-done cycles, both so as to clean up the top level envs
 661            -- and to avoid telling the interactive linker to link them.
 662            do when (verb >= 2) $
 663                 hPutStrLn stderr "Upsweep partially successful."
 664
 665               let modsDone_names
 666                      = map modSummaryName modsDone
 667               let mods_to_zap_names
 668                      = findPartiallyCompletedCycles modsDone_names
 669                           mg2_with_srcimps
 670               let mods_to_keep
 671                      = filter ((`notElem` mods_to_zap_names).modSummaryName)
 672                           modsDone
 673
 674               let (hst4, hit4, ui4)
 675                      = retainInTopLevelEnvs (map modSummaryName mods_to_keep)
 676                                             (hst3,hit3,ui3)
 677
 678               -- clean up after ourselves
 679               cleanTempFilesExcept verb (ppFilesFromSummaries mods_to_keep)
 680
 681               -- link everything together
 682               linkresult <- link ghci_mode dflags False ui4 pls2
 683
 684               cmLoadFinish False linkresult
 685                     hst4 hit4 ui4 mods_to_keep ghci_mode pcs3
 686
 687
 688 -- Finish up after a cmLoad.
 689
 690 -- If the link failed, unload everything and return.
 691 cmLoadFinish ok (LinkFailed pls) hst hit ui mods ghci_mode pcs = do
 692   dflags <- getDynFlags
 693   new_pls <- CmLink.unload ghci_mode dflags [] pls
 694   new_state <- cmInit ghci_mode
 695   return (new_state{ pcs=pcs, pls=new_pls }, False, [])
 696
 697 -- Empty the interactive context and set the module context to the topmost
 698 -- newly loaded module, or the Prelude if none were loaded.
 699 cmLoadFinish ok (LinkOK pls) hst hit ui mods ghci_mode pcs
 700   = do let new_cmstate = CmState{ hst=hst, hit=hit, ui=ui, mg=mods,
 701                                   gmode=ghci_mode, pcs=pcs, pls=pls,
 702                                   ic = emptyInteractiveContext }
 703            mods_loaded = map (moduleNameUserString.modSummaryName) mods
 704
 705        return (new_cmstate, ok, mods_loaded)
 706
 707 -- used to fish out the preprocess output files for the purposes
 708 -- of cleaning up.
 709 ppFilesFromSummaries summaries
 710   = [ fn | Just fn <- map toPpFile summaries ]
 711   where
 712    toPpFile sum
 713      | hspp /= ml_hs_file loc = hspp
 714      | otherwise              = Nothing
 715     where
 716       loc  = ms_location sum
 717       hspp = ml_hspp_file loc
 718
 719
 720 -----------------------------------------------------------------------------
 721 -- getValidLin
 722
 723 -- For each module (or SCC of modules), we take:
 724 --
 725 --      - an on-disk linkable, if this is the first time around and one
 726 --        is available.
 727 --
 728 --      - the old linkable, otherwise (and if one is available).
 729 --
 730 -- and we throw away the linkable if it is older than the source
 731 -- file.  We ignore the on-disk linkables unless all of the dependents
 732 -- of this SCC also have on-disk linkables.
 733 --
 734 -- If a module has a valid linkable, then it may be STABLE (see below),
 735 -- and it is classified as SOURCE UNCHANGED for the purposes of calling
 736 -- compile.
 737 --
 738 -- ToDo: this pass could be merged with the preUpsweep.
 739
 740 getValidLinkables
 741         :: [Linkable]           -- old linkables
 742         -> [ModuleName]         -- all home modules
 743         -> [SCC ModSummary]     -- all modules in the program, dependency order
 744         -> IO ( [Linkable],     -- still-valid linkables
 745                 [Linkable]      -- new linkables we just found
 746               )
 747
 748 getValidLinkables old_linkables all_home_mods module_graph = do
 749   ls <- foldM (getValidLinkablesSCC old_linkables all_home_mods)
 750                 [] module_graph
 751   return (partition_it ls [] [])
 752  where
 753   partition_it []         valid new = (valid,new)
 754   partition_it ((l,b):ls) valid new
 755         | b         = partition_it ls valid (l:new)
 756         | otherwise = partition_it ls (l:valid) new
 757
 758
 759 getValidLinkablesSCC old_linkables all_home_mods new_linkables scc0
 760    = let
 761           scc             = flattenSCC scc0
 762           scc_names       = map modSummaryName scc
 763           home_module m   = m `elem` all_home_mods && m `notElem` scc_names
 764           scc_allhomeimps = nub (filter home_module (concatMap ms_imps scc))
 765                 -- NB. ms_imps, not ms_allimps above.  We don't want to
 766                 -- force a module's SOURCE imports to be already compiled for
 767                 -- its object linkable to be valid.
 768
 769           has_object m =
 770                 case findModuleLinkable_maybe (map fst new_linkables) m of
 771                     Nothing -> False
 772                     Just l  -> isObjectLinkable l
 773
 774           objects_allowed = all has_object scc_allhomeimps
 775      in do
 776
 777      new_linkables'
 778         <- foldM (getValidLinkable old_linkables objects_allowed) [] scc
 779
 780         -- since an scc can contain only all objects or no objects at all,
 781         -- we have to check whether we got all objects or not, and re-do
 782         -- the linkable check if not.
 783      new_linkables' <-
 784         if objects_allowed
 785              && not (all isObjectLinkable (map fst new_linkables'))
 786           then foldM (getValidLinkable old_linkables False) [] scc
 787           else return new_linkables'
 788
 789      return (new_linkables ++ new_linkables')
 790
 791
 792 getValidLinkable :: [Linkable] -> Bool -> [(Linkable,Bool)] -> ModSummary
 793         -> IO [(Linkable,Bool)]
 794         -- True <=> linkable is new
 795 getValidLinkable old_linkables objects_allowed new_linkables summary
 796    = do let mod_name = modSummaryName summary
 797
 798         maybe_disk_linkable
 799           <- if (not objects_allowed)
 800                 then return Nothing
 801
 802                 else case ml_obj_file (ms_location summary) of
 803                         Just obj_fn -> maybe_getFileLinkable mod_name obj_fn
 804                         Nothing     -> return Nothing
 805
 806         let old_linkable = findModuleLinkable_maybe old_linkables mod_name
 807
 808             new_linkables' =
 809              case (old_linkable, maybe_disk_linkable) of
 810                 (Nothing, Nothing)                      -> []
 811
 812                 -- new object linkable just appeared
 813                 (Nothing, Just l)                       -> up_to_date l True
 814
 815                 (Just l,  Nothing)
 816                   | isObjectLinkable l                  -> []
 817                     -- object linkable disappeared!  In case we need to
 818                     -- relink the module, disregard the old linkable and
 819                     -- just interpret the module from now on.
 820                   | otherwise                           -> up_to_date l False
 821                     -- old byte code linkable
 822
 823                 (Just l, Just l')
 824                   | not (isObjectLinkable l)            -> up_to_date l  False
 825                     -- if the previous linkable was interpreted, then we
 826                     -- ignore a newly compiled version, because the version
 827                     -- numbers in the interface file will be out-of-sync with
 828                     -- our internal ones.
 829                   | linkableTime l' >  linkableTime l   -> up_to_date l' True
 830                   | linkableTime l' == linkableTime l   -> up_to_date l  False
 831                   | otherwise                           -> []
 832                     -- on-disk linkable has been replaced by an older one!
 833                     -- again, disregard the previous one.
 834
 835             up_to_date l b
 836                 | linkableTime l < ms_hs_date summary = []
 837                 | otherwise = [(l,b)]
 838                 -- why '<' rather than '<=' above?  If the filesystem stores
 839                 -- times to the nearset second, we may occasionally find that
 840                 -- the object & source have the same modification time,
 841                 -- especially if the source was automatically generated
 842                 -- and compiled.  Using >= is slightly unsafe, but it matches
 843                 -- make's behaviour.
 844
 845         return (new_linkables' ++ new_linkables)
 846
 847
 848 maybe_getFileLinkable :: ModuleName -> FilePath -> IO (Maybe Linkable)
 849 maybe_getFileLinkable mod obj_fn
 850    = do obj_exist <- doesFileExist obj_fn
 851         if not obj_exist
 852          then return Nothing
 853          else
 854          do let stub_fn = case splitFilename3 obj_fn of
 855                              (dir, base, ext) -> dir ++ "/" ++ base ++ ".stub_o"
 856             stub_exist <- doesFileExist stub_fn
 857             obj_time <- getModificationTime obj_fn
 858             if stub_exist
 859              then return (Just (LM obj_time mod [DotO obj_fn, DotO stub_fn]))
 860              else return (Just (LM obj_time mod [DotO obj_fn]))
 861
 862
 863 -----------------------------------------------------------------------------
 864 -- Do a pre-upsweep without use of "compile", to establish a
 865 -- (downward-closed) set of stable modules for which we won't call compile.
 866
 867 -- a stable module:
 868 --      * has a valid linkable (see getValidLinkables above)
 869 --      * depends only on stable modules
 870 --      * has an interface in the HIT (interactive mode only)
 871
 872 preUpsweep :: [Linkable]        -- new valid linkables
 873            -> [ModuleName]      -- names of all mods encountered in downsweep
 874            -> [ModuleName]      -- accumulating stable modules
 875            -> [SCC ModSummary]  -- scc-ified mod graph, including src imps
 876            -> IO [ModuleName]   -- stable modules
 877
 878 preUpsweep valid_lis all_home_mods stable []  = return stable
 879 preUpsweep valid_lis all_home_mods stable (scc0:sccs)
 880    = do let scc = flattenSCC scc0
 881             scc_allhomeimps :: [ModuleName]
 882             scc_allhomeimps
 883                = nub (filter (`elem` all_home_mods) (concatMap ms_allimps scc))
 884             all_imports_in_scc_or_stable
 885                = all in_stable_or_scc scc_allhomeimps
 886             scc_names
 887                 = map modSummaryName scc
 888             in_stable_or_scc m
 889                = m `elem` scc_names || m `elem` stable
 890
 891             -- now we check for valid linkables: each module in the SCC must
 892             -- have a valid linkable (see getValidLinkables above).
 893             has_valid_linkable new_summary
 894               = isJust (findModuleLinkable_maybe valid_lis modname)
 895                where modname = modSummaryName new_summary
 896
 897             scc_is_stable = all_imports_in_scc_or_stable
 898                           && all has_valid_linkable scc
 899
 900         if scc_is_stable
 901          then preUpsweep valid_lis all_home_mods (scc_names++stable) sccs
 902          else preUpsweep valid_lis all_home_mods stable sccs
 903
 904
 905 -- Helper for preUpsweep.  Assuming that new_summary's imports are all
 906 -- stable (in the sense of preUpsweep), determine if new_summary is itself
 907 -- stable, and, if so, in batch mode, return its linkable.
 908 findInSummaries :: [ModSummary] -> ModuleName -> [ModSummary]
 909 findInSummaries old_summaries mod_name
 910    = [s | s <- old_summaries, modSummaryName s == mod_name]
 911
 912 findModInSummaries :: [ModSummary] -> Module -> Maybe ModSummary
 913 findModInSummaries old_summaries mod
 914    = case [s | s <- old_summaries, ms_mod s == mod] of
 915          [] -> Nothing
 916          (s:_) -> Just s
 917
 918 -- Return (names of) all those in modsDone who are part of a cycle
 919 -- as defined by theGraph.
 920 findPartiallyCompletedCycles :: [ModuleName] -> [SCC ModSummary] -> [ModuleName]
 921 findPartiallyCompletedCycles modsDone theGraph
 922    = chew theGraph
 923      where
 924         chew [] = []
 925         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 926         chew ((CyclicSCC vs):rest)
 927            = let names_in_this_cycle = nub (map modSummaryName vs)
 928                  mods_in_this_cycle
 929                     = nub ([done | done <- modsDone,
 930                                    done `elem` names_in_this_cycle])
 931                  chewed_rest = chew rest
 932              in
 933              if   not (null mods_in_this_cycle)
 934                   && length mods_in_this_cycle < length names_in_this_cycle
 935              then mods_in_this_cycle ++ chewed_rest
 936              else chewed_rest
 937
 938
 939 -- Add the given (LM-form) Linkables to the UI, overwriting previous
 940 -- versions if they exist.
 941 add_to_ui :: UnlinkedImage -> [Linkable] -> UnlinkedImage
 942 add_to_ui ui lis
 943    = filter (not_in lis) ui ++ lis
 944      where
 945         not_in :: [Linkable] -> Linkable -> Bool
 946         not_in lis li
 947            = all (\l -> linkableModName l /= mod) lis
 948            where mod = linkableModName li
 949
 950
 951 data CmThreaded  -- stuff threaded through individual module compilations
 952    = CmThreaded PersistentCompilerState HomeSymbolTable HomeIfaceTable
 953
 954
 955 -- Compile multiple modules, stopping as soon as an error appears.
 956 -- There better had not be any cyclic groups here -- we check for them.
 957 upsweep_mods :: GhciMode
 958              -> DynFlags
 959              -> UnlinkedImage         -- valid linkables
 960              -> (ModuleName -> [ModuleName])  -- to construct downward closures
 961              -> CmThreaded            -- PCS & HST & HIT
 962              -> IO ()                 -- how to clean up unwanted tmp files
 963              -> [SCC ModSummary]      -- mods to do (the worklist)
 964                                       -- ...... RETURNING ......
 965              -> IO (Bool{-complete success?-},
 966                     CmThreaded,
 967                     [ModSummary],     -- mods which succeeded
 968                     [Linkable])       -- new linkables
 969
 970 upsweep_mods ghci_mode dflags oldUI reachable_from threaded cleanup
 971      []
 972    = return (True, threaded, [], [])
 973
 974 upsweep_mods ghci_mode dflags oldUI reachable_from threaded cleanup
 975      ((CyclicSCC ms):_)
 976    = do hPutStrLn stderr ("Module imports form a cycle for modules:\n\t" ++
 977                           unwords (map (moduleNameUserString.modSummaryName) ms))
 978         return (False, threaded, [], [])
 979
 980 upsweep_mods ghci_mode dflags oldUI reachable_from threaded cleanup
 981      ((AcyclicSCC mod):mods)
 982    = do --case threaded of
 983         --   CmThreaded pcsz hstz hitz
 984         --      -> putStrLn ("UPSWEEP_MOD: hit = " ++ show (map (moduleNameUserString.moduleName.mi_module) (eltsUFM hitz)))
 985
 986         (threaded1, maybe_linkable)
 987            <- upsweep_mod ghci_mode dflags oldUI threaded mod
 988                           (reachable_from (modSummaryName mod))
 989
 990         -- remove unwanted tmp files between compilations
 991         cleanup
 992
 993         case maybe_linkable of
 994            Just linkable
 995               -> -- No errors; do the rest
 996                  do (restOK, threaded2, modOKs, linkables)
 997                        <- upsweep_mods ghci_mode dflags oldUI reachable_from
 998                                        threaded1 cleanup mods
 999                     return (restOK, threaded2, mod:modOKs, linkable:linkables)
1000            Nothing -- we got a compilation error; give up now
1001               -> return (False, threaded1, [], [])
1002
1003
1004 -- Compile a single module.  Always produce a Linkable for it if
1005 -- successful.  If no compilation happened, return the old Linkable.
1006 upsweep_mod :: GhciMode
1007             -> DynFlags
1008             -> UnlinkedImage
1009             -> CmThreaded
1010             -> ModSummary
1011             -> [ModuleName]
1012             -> IO (CmThreaded, Maybe Linkable)
1013
1014 upsweep_mod ghci_mode dflags oldUI threaded1 summary1 reachable_inc_me
1015    = do
1016         let mod_name = modSummaryName summary1
1017
1018         let (CmThreaded pcs1 hst1 hit1) = threaded1
1019         let old_iface = lookupUFM hit1 mod_name
1020
1021         let maybe_old_linkable = findModuleLinkable_maybe oldUI mod_name
1022
1023             source_unchanged = isJust maybe_old_linkable
1024
1025             reachable_only = filter (/= (modSummaryName summary1))
1026                                 reachable_inc_me
1027
1028            -- in interactive mode, all home modules below us *must* have an
1029            -- interface in the HIT.  We never demand-load home interfaces in
1030            -- interactive mode.
1031             (hst1_strictDC, hit1_strictDC, [])
1032                = ASSERT(ghci_mode == Batch ||
1033                         all (`elemUFM` hit1) reachable_only)
1034                  retainInTopLevelEnvs reachable_only (hst1,hit1,[])
1035
1036             old_linkable
1037                = unJust "upsweep_mod:old_linkable" maybe_old_linkable
1038
1039             have_object
1040                | Just l <- maybe_old_linkable, isObjectLinkable l = True
1041                | otherwise = False
1042
1043         compresult <- compile ghci_mode summary1 source_unchanged
1044                          have_object old_iface hst1_strictDC hit1_strictDC pcs1
1045
1046         case compresult of
1047
1048            -- Compilation "succeeded", and may or may not have returned a new
1049            -- linkable (depending on whether compilation was actually performed
1050            -- or not).
1051            CompOK pcs2 new_details new_iface maybe_new_linkable
1052               -> do let hst2      = addToUFM hst1 mod_name new_details
1053                         hit2      = addToUFM hit1 mod_name new_iface
1054                         threaded2 = CmThreaded pcs2 hst2 hit2
1055
1056                     return (threaded2, if isJust maybe_new_linkable
1057                                           then maybe_new_linkable
1058                                           else Just old_linkable)
1059
1060            -- Compilation failed.  compile may still have updated
1061            -- the PCS, tho.
1062            CompErrs pcs2
1063               -> do let threaded2 = CmThreaded pcs2 hst1 hit1
1064                     return (threaded2, Nothing)
1065
1066 -- Filter modules in the top level envs (HST, HIT, UI).
1067 retainInTopLevelEnvs :: [ModuleName]
1068                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
1069                         -> (HomeSymbolTable, HomeIfaceTable, UnlinkedImage)
1070 retainInTopLevelEnvs keep_these (hst, hit, ui)
1071    = (retainInUFM hst keep_these,
1072       retainInUFM hit keep_these,
1073       filterModuleLinkables (`elem` keep_these) ui
1074      )
1075      where
1076         retainInUFM :: Uniquable key => UniqFM elt -> [key] -> UniqFM elt
1077         retainInUFM ufm keys_to_keep
1078            = listToUFM (concatMap (maybeLookupUFM ufm) keys_to_keep)
1079         maybeLookupUFM ufm u
1080            = case lookupUFM ufm u of Nothing -> []; Just val -> [(u, val)]
1081
1082 -- Needed to clean up HIT and HST so that we don't get duplicates in inst env
1083 downwards_closure_of_module :: [ModSummary] -> ModuleName -> [ModuleName]
1084 downwards_closure_of_module summaries root
1085    = let toEdge :: ModSummary -> (ModuleName,[ModuleName])
1086          toEdge summ = (modSummaryName summ,
1087                         filter (`elem` all_mods) (ms_allimps summ))
1088
1089          all_mods = map modSummaryName summaries
1090
1091          res = simple_transitive_closure (map toEdge summaries) [root]
1092      in
1093 --         trace (showSDoc (text "DC of mod" <+> ppr root
1094 --                          <+> text "=" <+> ppr res)) $
1095          res
1096
1097 -- Calculate transitive closures from a set of roots given an adjacency list
1098 simple_transitive_closure :: Eq a => [(a,[a])] -> [a] -> [a]
1099 simple_transitive_closure graph set
1100    = let set2      = nub (concatMap dsts set ++ set)
1101          dsts node = fromMaybe [] (lookup node graph)
1102      in
1103          if   length set == length set2
1104          then set
1105          else simple_transitive_closure graph set2
1106
1107
1108 -- Calculate SCCs of the module graph, with or without taking into
1109 -- account source imports.
1110 topological_sort :: Bool -> [ModSummary] -> [SCC ModSummary]
1111 topological_sort include_source_imports summaries
1112    = let
1113          toEdge :: ModSummary -> (ModSummary,ModuleName,[ModuleName])
1114          toEdge summ
1115              = (summ, modSummaryName summ,
1116                       (if include_source_imports
1117                        then ms_srcimps summ else []) ++ ms_imps summ)
1118
1119          mash_edge :: (ModSummary,ModuleName,[ModuleName]) -> (ModSummary,Int,[Int])
1120          mash_edge (summ, m, m_imports)
1121             = case lookup m key_map of
1122                  Nothing -> panic "reverse_topological_sort"
1123                  Just mk -> (summ, mk,
1124                                 -- ignore imports not from the home package
1125                                 catMaybes (map (flip lookup key_map) m_imports))
1126
1127          edges     = map toEdge summaries
1128          key_map   = zip [nm | (s,nm,imps) <- edges] [1 ..] :: [(ModuleName,Int)]
1129          scc_input = map mash_edge edges
1130          sccs      = stronglyConnComp scc_input
1131      in
1132          sccs
1133
1134
1135 -----------------------------------------------------------------------------
1136 -- Downsweep (dependency analysis)
1137
1138 -- Chase downwards from the specified root set, returning summaries
1139 -- for all home modules encountered.  Only follow source-import
1140 -- links.
1141
1142 -- We pass in the previous collection of summaries, which is used as a
1143 -- cache to avoid recalculating a module summary if the source is
1144 -- unchanged.
1145
1146 downsweep :: [FilePath] -> [ModSummary] -> IO [ModSummary]
1147 downsweep roots old_summaries
1148    = do rootSummaries <- mapM getRootSummary roots
1149         all_summaries
1150            <- loop (concat (map ms_imps rootSummaries))
1151                 (mkModuleEnv [ (mod, s) | s <- rootSummaries,
1152                                           let mod = ms_mod s, isHomeModule mod
1153                              ])
1154         return all_summaries
1155      where
1156         getRootSummary :: FilePath -> IO ModSummary
1157         getRootSummary file
1158            | haskellish_src_file file
1159            = do exists <- doesFileExist file
1160                 if exists then summariseFile file else do
1161                 throwDyn (CmdLineError ("can't find file `" ++ file ++ "'"))
1162            | otherwise
1163            = do exists <- doesFileExist hs_file
1164                 if exists then summariseFile hs_file else do
1165                 exists <- doesFileExist lhs_file
1166                 if exists then summariseFile lhs_file else do
1167                 let mod_name = mkModuleName file
1168                 maybe_summary <- getSummary mod_name
1169                 case maybe_summary of
1170                    Nothing -> packageModErr mod_name
1171                    Just s  -> return s
1172            where
1173                  hs_file = file ++ ".hs"
1174                  lhs_file = file ++ ".lhs"
1175
1176         getSummary :: ModuleName -> IO (Maybe ModSummary)
1177         getSummary nm
1178            = do found <- findModule nm
1179                 case found of
1180                    Just (mod, location) -> do
1181                         let old_summary = findModInSummaries old_summaries mod
1182                         summarise mod location old_summary
1183
1184                    Nothing -> throwDyn (CmdLineError
1185                                    ("can't find module `"
1186                                      ++ showSDoc (ppr nm) ++ "'"))
1187
1188         -- loop invariant: env doesn't contain package modules
1189         loop :: [ModuleName] -> ModuleEnv ModSummary -> IO [ModSummary]
1190         loop [] env = return (moduleEnvElts env)
1191         loop imps env
1192            = do -- imports for modules we don't already have
1193                 let needed_imps = nub (filter (not . (`elemUFM` env)) imps)
1194
1195                 -- summarise them
1196                 needed_summaries <- mapM getSummary needed_imps
1197
1198                 -- get just the "home" modules
1199                 let new_home_summaries = [ s | Just s <- needed_summaries ]
1200
1201                 -- loop, checking the new imports
1202                 let new_imps = concat (map ms_imps new_home_summaries)
1203                 loop new_imps (extendModuleEnvList env
1204                                 [ (ms_mod s, s) | s <- new_home_summaries ])
1205
1206 -----------------------------------------------------------------------------
1207 -- Summarising modules
1208
1209 -- We have two types of summarisation:
1210 --
1211 --    * Summarise a file.  This is used for the root module(s) passed to
1212 --      cmLoadModules.  The file is read, and used to determine the root
1213 --      module name.  The module name may differ from the filename.
1214 --
1215 --    * Summarise a module.  We are given a module name, and must provide
1216 --      a summary.  The finder is used to locate the file in which the module
1217 --      resides.
1218
1219 summariseFile :: FilePath -> IO ModSummary
1220 summariseFile file
1221    = do hspp_fn <- preprocess file
1222         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1223
1224         let (path, basename, _ext) = splitFilename3 file
1225
1226         (mod, location)
1227            <- mkHomeModuleLocn mod_name (path ++ '/':basename) file
1228
1229         src_timestamp
1230            <- case ml_hs_file location of
1231                  Nothing     -> noHsFileErr mod_name
1232                  Just src_fn -> getModificationTime src_fn
1233
1234         return (ModSummary mod
1235                            location{ml_hspp_file=Just hspp_fn}
1236                            srcimps imps src_timestamp)
1237
1238 -- Summarise a module, and pick up source and timestamp.
1239 summarise :: Module -> ModuleLocation -> Maybe ModSummary
1240          -> IO (Maybe ModSummary)
1241 summarise mod location old_summary
1242    | not (isHomeModule mod) = return Nothing
1243    | otherwise
1244    = do let hs_fn = unJust "summarise" (ml_hs_file location)
1245
1246         case ml_hs_file location of {
1247            Nothing -> noHsFileErr mod;
1248            Just src_fn -> do
1249
1250         src_timestamp <- getModificationTime src_fn
1251
1252         -- return the cached summary if the source didn't change
1253         case old_summary of {
1254            Just s | ms_hs_date s == src_timestamp -> return (Just s);
1255            _ -> do
1256
1257         hspp_fn <- preprocess hs_fn
1258         (srcimps,imps,mod_name) <- getImportsFromFile hspp_fn
1259
1260         when (mod_name /= moduleName mod) $
1261                 throwDyn (ProgramError
1262                    (showSDoc (text hs_fn
1263                               <>  text ": file name does not match module name"
1264                               <+> quotes (ppr (moduleName mod)))))
1265
1266         return (Just (ModSummary mod location{ml_hspp_file=Just hspp_fn}
1267                                  srcimps imps src_timestamp))
1268         }
1269       }
1270
1271
1272 noHsFileErr mod
1273   = throwDyn (CmdLineError (showSDoc (text "no source file for module" <+> quotes (ppr mod))))
1274
1275 packageModErr mod
1276   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1277                                    quotes (ppr mod) <+>
1278                                    text "is a package module")))
1279 \end{code}