ghc/compiler/coreSyn/CoreTidy.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Tidying up Core}
   5
   6 \begin{code}
   7 module CoreTidy (
   8         tidyCorePgm, tidyExpr,
   9         tidyBndr, tidyBndrs
  10     ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CmdLineOpts      ( opt_D_dump_simpl, opt_D_verbose_core2core, opt_UsageSPOn )
  15 import CoreSyn
  16 import CoreUnfold       ( noUnfolding )
  17 import CoreLint         ( beginPass, endPass )
  18 import Rules            ( ProtoCoreRule(..), RuleBase )
  19 import UsageSPInf       ( doUsageSPInf )
  20 import VarEnv
  21 import VarSet
  22 import Var              ( Id, Var )
  23 import Id               ( idType, idInfo, idName, idSpecialisation,
  24                           mkVanillaId, mkId, exportWithOrigOccName,
  25                           idStrictness, setIdStrictness,
  26                           idDemandInfo, setIdDemandInfo,
  27                         )
  28 import IdInfo           ( specInfo, setSpecInfo,
  29                           setUnfoldingInfo, setDemandInfo,
  30                           workerInfo, setWorkerInfo, WorkerInfo(..)
  31                         )
  32 import Demand           ( wwLazy )
  33 import Name             ( getOccName, tidyTopName, mkLocalName, isLocallyDefined )
  34 import OccName          ( initTidyOccEnv, tidyOccName )
  35 import Type             ( tidyTopType, tidyType, tidyTypes, tidyTyVar, tidyTyVars )
  36 import Module           ( Module )
  37 import UniqSupply       ( UniqSupply )
  38 import Unique           ( Uniquable(..) )
  39 import SrcLoc           ( noSrcLoc )
  40 import Util             ( mapAccumL )
  41 \end{code}
  42
  43
  44
  45 %************************************************************************
  46 %*                                                                      *
  47 \subsection{Tidying core}
  48 %*                                                                      *
  49 %************************************************************************
  50
  51 Several tasks are done by @tidyCorePgm@
  52
  53 1. If @opt_UsageSPOn@ then compute usage information (which is
  54    needed by Core2Stg).  ** NOTE _scc_ HERE **
  55    Do this first, because it may introduce new binders.
  56
  57 2.  Make certain top-level bindings into Globals. The point is that
  58     Global things get externally-visible labels at code generation
  59     time
  60
  61
  62 3. Give all binders a nice print-name.  Their uniques aren't changed;
  63    rather we give them lexically unique occ-names, so that we can
  64    safely print the OccNae only in the interface file.  [Bad idea to
  65    change the uniques, because the code generator makes global labels
  66    from the uniques for local thunks etc.]
  67
  68 \begin{code}
  69 tidyCorePgm :: UniqSupply -> Module -> [CoreBind] -> RuleBase
  70             -> IO ([CoreBind], [ProtoCoreRule])
  71 tidyCorePgm us module_name binds_in rulebase_in
  72   = do
  73         beginPass "Tidy Core"
  74
  75         binds_in1 <- if opt_UsageSPOn
  76                      then _scc_ "CoreUsageSPInf"
  77                                 doUsageSPInf us binds_in rulebase_in
  78                      else return binds_in
  79
  80         let (tidy_env1, binds_out)  = mapAccumL (tidyBind (Just module_name))
  81                                                 init_tidy_env binds_in1
  82             rules_out               = tidyProtoRules tidy_env1 (mk_local_protos rulebase_in)
  83
  84         endPass "Tidy Core" (opt_D_dump_simpl || opt_D_verbose_core2core) binds_out
  85         return (binds_out, rules_out)
  86   where
  87         -- We also make sure to avoid any exported binders.  Consider
  88         --      f{-u1-} = 1     -- Local decl
  89         --      ...
  90         --      f{-u2-} = 2     -- Exported decl
  91         --
  92         -- The second exported decl must 'get' the name 'f', so we
  93         -- have to put 'f' in the avoids list before we get to the first
  94         -- decl.  tidyTopId then does a no-op on exported binders.
  95     init_tidy_env = (initTidyOccEnv avoids, emptyVarEnv)
  96     avoids        = [getOccName bndr | bndr <- bindersOfBinds binds_in,
  97                                        exportWithOrigOccName bndr]
  98
  99     mk_local_protos :: RuleBase -> [ProtoCoreRule]
 100     mk_local_protos (rule_ids, _)
 101       = [ProtoCoreRule True id rule | id <- varSetElems rule_ids,
 102                                       rule <- rulesRules (idSpecialisation id)]
 103
 104 tidyBind :: Maybe Module                -- (Just m) for top level, Nothing for nested
 105          -> TidyEnv
 106          -> CoreBind
 107          -> (TidyEnv, CoreBind)
 108 tidyBind maybe_mod env (NonRec bndr rhs)
 109   = let
 110         (env', bndr') = tidy_bndr maybe_mod env' env bndr
 111         rhs'          = tidyExpr env' rhs
 112         -- We use env' when tidying the RHS even though it's not
 113         -- strictly necessary; it makes the code pretty hard to read
 114         -- if we don't!
 115     in
 116     (env', NonRec bndr' rhs')
 117
 118 tidyBind maybe_mod env (Rec pairs)
 119   = let
 120         -- We use env' when tidying the rhss
 121         -- When tidying the binder itself we may tidy it's
 122         -- specialisations; if any of these mention other binders
 123         -- in the group we should really feed env' to them too;
 124         -- but that seems (a) unlikely and (b) a bit tiresome.
 125         -- So I left it out for now
 126
 127         (bndrs, rhss)  = unzip pairs
 128         (env', bndrs') = mapAccumL (tidy_bndr maybe_mod env') env bndrs
 129         rhss'          = map (tidyExpr env') rhss
 130   in
 131   (env', Rec (zip bndrs' rhss'))
 132
 133 tidyExpr env (Type ty)       = Type (tidyType env ty)
 134 tidyExpr env (Lit lit)       = Lit lit
 135 tidyExpr env (App f a)       = App (tidyExpr env f) (tidyExpr env a)
 136 tidyExpr env (Note n e)      = Note (tidyNote env n) (tidyExpr env e)
 137
 138 tidyExpr env (Let b e)       = Let b' (tidyExpr env' e)
 139                              where
 140                                (env', b') = tidyBind Nothing env b
 141
 142 tidyExpr env (Case e b alts) = Case (tidyExpr env e) b' (map (tidyAlt env') alts)
 143                              where
 144                                (env', b') = tidyBndr env b
 145
 146 tidyExpr env (Var v)         = Var (tidyVarOcc env v)
 147
 148 tidyExpr env (Lam b e)       = Lam b' (tidyExpr env' e)
 149                              where
 150                                (env', b') = tidyBndr env b
 151
 152 tidyAlt env (con, vs, rhs)   = (con, vs', tidyExpr env' rhs)
 153                              where
 154                                (env', vs') = tidyBndrs env vs
 155
 156 tidyNote env (Coerce t1 t2)  = Coerce (tidyType env t1) (tidyType env t2)
 157
 158 tidyNote env note            = note
 159
 160 tidyVarOcc (_, var_env) v = case lookupVarEnv var_env v of
 161                                   Just v' -> v'
 162                                   Nothing -> v
 163 \end{code}
 164
 165 \begin{code}
 166 tidy_bndr (Just mod) env_idinfo env var = tidyTopId mod env env_idinfo var
 167 tidy_bndr Nothing    env_idinfo env var = tidyBndr      env            var
 168 \end{code}
 169
 170
 171
 172 %************************************************************************
 173 %*                                                                      *
 174 \subsection{Tidying up a binder}
 175 %*                                                                      *
 176 %************************************************************************
 177
 178 \begin{code}
 179 tidyBndr :: TidyEnv -> Var -> (TidyEnv, Var)
 180 tidyBndr env var | isTyVar var = tidyTyVar env var
 181                  | otherwise   = tidyId    env var
 182
 183 tidyBndrs :: TidyEnv -> [Var] -> (TidyEnv, [Var])
 184 tidyBndrs env vars = mapAccumL tidyBndr env vars
 185
 186 tidyId :: TidyEnv -> Id -> (TidyEnv, Id)
 187 tidyId env@(tidy_env, var_env) id
 188   =     -- Non-top-level variables
 189     let
 190         -- Give the Id a fresh print-name, *and* rename its type
 191         -- The SrcLoc isn't important now, though we could extract it from the Id
 192         name'             = mkLocalName (getUnique id) occ' noSrcLoc
 193         (tidy_env', occ') = tidyOccName tidy_env (getOccName id)
 194         ty'               = tidyType env (idType id)
 195         id'               = mkVanillaId name' ty'
 196                             `setIdStrictness` idStrictness id
 197                             `setIdDemandInfo` idDemandInfo id
 198                         -- NB: This throws away the IdInfo of the Id, which we
 199                         -- no longer need.  That means we don't need to
 200                         -- run over it with env, nor renumber it.
 201                         --
 202                         -- The exception is strictness and demand info, which
 203                         -- is used to decide whether to use let or case for
 204                         -- function arguments and let bindings
 205
 206         var_env'          = extendVarEnv var_env id id'
 207     in
 208     ((tidy_env', var_env'), id')
 209
 210 tidyTopId :: Module -> TidyEnv -> TidyEnv -> Id -> (TidyEnv, Id)
 211         -- The second env is the one to use for the IdInfo
 212         -- It's necessary because when we are dealing with a recursive
 213         -- group, a variable late in the group might be mentioned
 214         -- in the IdInfo of one early in the group
 215 tidyTopId mod env@(tidy_env, var_env) env_idinfo id
 216   =     -- Top level variables
 217     let
 218         (tidy_env', name') | exportWithOrigOccName id = (tidy_env, idName id)
 219                            | otherwise                = tidyTopName mod tidy_env (idName id)
 220         ty'                = tidyTopType (idType id)
 221         idinfo'            = tidyIdInfo env_idinfo (idInfo id)
 222         id'                = mkId name' ty' idinfo'
 223         var_env'           = extendVarEnv var_env id id'
 224     in
 225     ((tidy_env', var_env'), id')
 226 \end{code}
 227
 228 \begin{code}
 229 -- tidyIdInfo does these things:
 230 --      a) tidy the specialisation info and worker info (if any)
 231 --      b) zap the unfolding and demand info
 232 -- The latter two are to avoid space leaks
 233
 234 tidyIdInfo env info
 235   = info5
 236   where
 237     rules = specInfo info
 238
 239     info2 | isEmptyCoreRules rules = info
 240           | otherwise              = info `setSpecInfo` tidyRules env rules
 241
 242     info3 = info2 `setUnfoldingInfo` noUnfolding
 243     info4 = info3 `setDemandInfo`    wwLazy             -- I don't understand why...
 244
 245     info5 = case workerInfo info of
 246                 NoWorker -> info4
 247                 HasWorker w a  -> info4 `setWorkerInfo` HasWorker (tidyVarOcc env w) a
 248
 249 tidyProtoRules :: TidyEnv -> [ProtoCoreRule] -> [ProtoCoreRule]
 250 tidyProtoRules env rules
 251   = [ ProtoCoreRule is_local (tidyVarOcc env fn) (tidyRule env rule)
 252     | ProtoCoreRule is_local fn rule <- rules
 253     ]
 254
 255 tidyRules :: TidyEnv -> CoreRules -> CoreRules
 256 tidyRules env (Rules rules fvs)
 257   = Rules (map (tidyRule env) rules)
 258           (foldVarSet tidy_set_elem emptyVarSet fvs)
 259   where
 260     tidy_set_elem var new_set = extendVarSet new_set (tidyVarOcc env var)
 261
 262 tidyRule :: TidyEnv -> CoreRule -> CoreRule
 263 tidyRule env rule@(BuiltinRule _) = rule
 264 tidyRule env (Rule name vars tpl_args rhs)
 265   = (Rule name vars' (map (tidyExpr env') tpl_args) (tidyExpr env' rhs))
 266   where
 267     (env', vars') = tidyBndrs env vars
 268 \end{code}