ghc/compiler/coreSyn/CoreUnfold.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1998
   3 %
   4 \section[CoreUnfold]{Core-syntax unfoldings}
   5
   6 Unfoldings (which can travel across module boundaries) are in Core
   7 syntax (namely @CoreExpr@s).
   8
   9 The type @Unfolding@ sits ``above'' simply-Core-expressions
  10 unfoldings, capturing ``higher-level'' things we know about a binding,
  11 usually things that the simplifier found out (e.g., ``it's a
  12 literal'').  In the corner of a @CoreUnfolding@ unfolding, you will
  13 find, unsurprisingly, a Core expression.
  14
  15 \begin{code}
  16 module CoreUnfold (
  17         Unfolding, UnfoldingGuidance,   -- Abstract types
  18
  19         noUnfolding, mkTopUnfolding, mkUnfolding, mkCompulsoryUnfolding, seqUnfolding,
  20         mkOtherCon, otherCons,
  21         unfoldingTemplate, maybeUnfoldingTemplate,
  22         isEvaldUnfolding, isValueUnfolding, isCheapUnfolding, isCompulsoryUnfolding,
  23         hasUnfolding, hasSomeUnfolding,
  24
  25         couldBeSmallEnoughToInline,
  26         certainlyWillInline,
  27         okToUnfoldInHiFile,
  28
  29         callSiteInline, blackListed
  30     ) where
  31
  32 #include "HsVersions.h"
  33
  34 import CmdLineOpts      ( opt_UF_CreationThreshold,
  35                           opt_UF_UseThreshold,
  36                           opt_UF_FunAppDiscount,
  37                           opt_UF_KeenessFactor,
  38                           opt_UF_CheapOp, opt_UF_DearOp,
  39                           opt_UnfoldCasms, opt_PprStyle_Debug,
  40                           opt_D_dump_inlinings
  41                         )
  42 import CoreSyn
  43 import PprCore          ( pprCoreExpr )
  44 import OccurAnal        ( occurAnalyseGlobalExpr )
  45 import CoreUtils        ( exprIsValue, exprIsCheap, exprIsBottom, exprIsTrivial )
  46 import Id               ( Id, idType, idFlavour, isId, idWorkerInfo,
  47                           idSpecialisation, idInlinePragma, idUnfolding,
  48                           isPrimOpId_maybe
  49                         )
  50 import VarSet
  51 import Literal          ( isLitLitLit, litIsDupable )
  52 import PrimOp           ( PrimOp(..), primOpIsDupable, primOpOutOfLine, ccallIsCasm )
  53 import IdInfo           ( ArityInfo(..), InlinePragInfo(..), OccInfo(..), IdFlavour(..), CprInfo(..),
  54                           insideLam, workerExists, isNeverInlinePrag
  55                         )
  56 import Type             ( splitFunTy_maybe, isUnLiftedType )
  57 import Unique           ( Unique, buildIdKey, augmentIdKey, hasKey )
  58 import Bag
  59 import Outputable
  60
  61 #if __GLASGOW_HASKELL__ >= 404
  62 import GlaExts          ( fromInt )
  63 #endif
  64 \end{code}
  65
  66
  67 %************************************************************************
  68 %*                                                                      *
  69 \subsection{Making unfoldings}
  70 %*                                                                      *
  71 %************************************************************************
  72
  73 \begin{code}
  74 mkTopUnfolding expr = mkUnfolding True {- Top level -} expr
  75
  76 mkUnfolding top_lvl expr
  77   = CoreUnfolding (occurAnalyseGlobalExpr expr)
  78                   top_lvl
  79                   (exprIsValue expr)
  80                         -- Already evaluated
  81
  82                   (exprIsCheap expr)
  83                         -- OK to inline inside a lambda
  84
  85                   (calcUnfoldingGuidance opt_UF_CreationThreshold expr)
  86         -- Sometimes during simplification, there's a large let-bound thing
  87         -- which has been substituted, and so is now dead; so 'expr' contains
  88         -- two copies of the thing while the occurrence-analysed expression doesn't
  89         -- Nevertheless, we don't occ-analyse before computing the size because the
  90         -- size computation bales out after a while, whereas occurrence analysis does not.
  91         --
  92         -- This can occasionally mean that the guidance is very pessimistic;
  93         -- it gets fixed up next round
  94
  95 mkCompulsoryUnfolding expr      -- Used for things that absolutely must be unfolded
  96   = CompulsoryUnfolding (occurAnalyseGlobalExpr expr)
  97 \end{code}
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102 \subsection{The UnfoldingGuidance type}
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107 instance Outputable UnfoldingGuidance where
 108     ppr UnfoldNever     = ptext SLIT("NEVER")
 109     ppr (UnfoldIfGoodArgs v cs size discount)
 110       = hsep [ ptext SLIT("IF_ARGS"), int v,
 111                brackets (hsep (map int cs)),
 112                int size,
 113                int discount ]
 114 \end{code}
 115
 116
 117 \begin{code}
 118 calcUnfoldingGuidance
 119         :: Int                  -- bomb out if size gets bigger than this
 120         -> CoreExpr             -- expression to look at
 121         -> UnfoldingGuidance
 122 calcUnfoldingGuidance bOMB_OUT_SIZE expr
 123   = case collect_val_bndrs expr of { (inline, val_binders, body) ->
 124     let
 125         n_val_binders = length val_binders
 126
 127         max_inline_size = n_val_binders+2
 128         -- The idea is that if there is an INLINE pragma (inline is True)
 129         -- and there's a big body, we give a size of n_val_binders+2.  This
 130         -- This is just enough to fail the no-size-increase test in callSiteInline,
 131         --   so that INLINE things don't get inlined into entirely boring contexts,
 132         --   but no more.
 133
 134     in
 135     case (sizeExpr bOMB_OUT_SIZE val_binders body) of
 136
 137       TooBig
 138         | not inline -> UnfoldNever
 139                 -- A big function with an INLINE pragma must
 140                 -- have an UnfoldIfGoodArgs guidance
 141         | inline     -> UnfoldIfGoodArgs n_val_binders
 142                                          (map (const 0) val_binders)
 143                                          max_inline_size 0
 144
 145       SizeIs size cased_args scrut_discount
 146         -> UnfoldIfGoodArgs
 147                         n_val_binders
 148                         (map discount_for val_binders)
 149                         final_size
 150                         (I# scrut_discount)
 151         where
 152             boxed_size    = I# size
 153
 154             final_size | inline     = boxed_size `min` max_inline_size
 155                        | otherwise  = boxed_size
 156
 157                 -- Sometimes an INLINE thing is smaller than n_val_binders+2.
 158                 -- A particular case in point is a constructor, which has size 1.
 159                 -- We want to inline this regardless, hence the `min`
 160
 161             discount_for b = foldlBag (\acc (b',n) -> if b==b' then acc+n else acc)
 162                                       0 cased_args
 163         }
 164   where
 165     collect_val_bndrs e = go False [] e
 166         -- We need to be a bit careful about how we collect the
 167         -- value binders.  In ptic, if we see
 168         --      __inline_me (\x y -> e)
 169         -- We want to say "2 value binders".  Why?  So that
 170         -- we take account of information given for the arguments
 171
 172     go inline rev_vbs (Note InlineMe e)     = go True   rev_vbs     e
 173     go inline rev_vbs (Lam b e) | isId b    = go inline (b:rev_vbs) e
 174                                 | otherwise = go inline rev_vbs     e
 175     go inline rev_vbs e                     = (inline, reverse rev_vbs, e)
 176 \end{code}
 177
 178 \begin{code}
 179 sizeExpr :: Int             -- Bomb out if it gets bigger than this
 180          -> [Id]            -- Arguments; we're interested in which of these
 181                             -- get case'd
 182          -> CoreExpr
 183          -> ExprSize
 184
 185 sizeExpr (I# bOMB_OUT_SIZE) top_args expr
 186   = size_up expr
 187   where
 188     size_up (Type t)          = sizeZero        -- Types cost nothing
 189     size_up (Var v)           = sizeOne
 190
 191     size_up (Note _ body)     = size_up body    -- Notes cost nothing
 192
 193     size_up (App fun (Type t))  = size_up fun
 194     size_up (App fun arg)     = size_up_app fun [arg]
 195
 196     size_up (Lit lit) | litIsDupable lit = sizeOne
 197                       | otherwise        = sizeN opt_UF_DearOp  -- For lack of anything better
 198
 199     size_up (Lam b e) | isId b    = lamScrutDiscount (size_up e `addSizeN` 1)
 200                       | otherwise = size_up e
 201
 202     size_up (Let (NonRec binder rhs) body)
 203       = nukeScrutDiscount (size_up rhs)         `addSize`
 204         size_up body                            `addSizeN`
 205         (if isUnLiftedType (idType binder) then 0 else 1)
 206                 -- For the allocation
 207                 -- If the binder has an unlifted type there is no allocation
 208
 209     size_up (Let (Rec pairs) body)
 210       = nukeScrutDiscount rhs_size              `addSize`
 211         size_up body                            `addSizeN`
 212         length pairs            -- For the allocation
 213       where
 214         rhs_size = foldr (addSize . size_up . snd) sizeZero pairs
 215
 216     size_up (Case (Var v) _ alts)
 217         | v `elem` top_args             -- We are scrutinising an argument variable
 218         =
 219 {-      I'm nuking this special case; BUT see the comment with case alternatives.
 220
 221         (a) It's too eager.  We don't want to inline a wrapper into a
 222             context with no benefit.
 223             E.g.  \ x. f (x+x)          o point in inlining (+) here!
 224
 225         (b) It's ineffective. Once g's wrapper is inlined, its case-expressions
 226             aren't scrutinising arguments any more
 227
 228             case alts of
 229
 230                 [alt] -> size_up_alt alt `addSize` SizeIs 0# (unitBag (v, 1)) 0#
 231                 -- We want to make wrapper-style evaluation look cheap, so that
 232                 -- when we inline a wrapper it doesn't make call site (much) bigger
 233                 -- Otherwise we get nasty phase ordering stuff:
 234                 --      f x = g x x
 235                 --      h y = ...(f e)...
 236                 -- If we inline g's wrapper, f looks big, and doesn't get inlined
 237                 -- into h; if we inline f first, while it looks small, then g's
 238                 -- wrapper will get inlined later anyway.  To avoid this nasty
 239                 -- ordering difference, we make (case a of (x,y) -> ...),
 240                 -- *where a is one of the arguments* look free.
 241
 242                 other ->
 243 -}
 244                          alts_size (foldr addSize sizeOne alt_sizes)    -- The 1 is for the scrutinee
 245                                    (foldr1 maxSize alt_sizes)
 246
 247                 -- Good to inline if an arg is scrutinised, because
 248                 -- that may eliminate allocation in the caller
 249                 -- And it eliminates the case itself
 250
 251         where
 252           alt_sizes = map size_up_alt alts
 253
 254                 -- alts_size tries to compute a good discount for
 255                 -- the case when we are scrutinising an argument variable
 256           alts_size (SizeIs tot tot_disc tot_scrut)             -- Size of all alternatives
 257                     (SizeIs max max_disc max_scrut)             -- Size of biggest alternative
 258                 = SizeIs tot (unitBag (v, I# (1# +# tot -# max)) `unionBags` max_disc) max_scrut
 259                         -- If the variable is known, we produce a discount that
 260                         -- will take us back to 'max', the size of rh largest alternative
 261                         -- The 1+ is a little discount for reduced allocation in the caller
 262           alts_size tot_size _ = tot_size
 263
 264
 265     size_up (Case e _ alts) = nukeScrutDiscount (size_up e) `addSize`
 266                               foldr (addSize . size_up_alt) sizeZero alts
 267                 -- We don't charge for the case itself
 268                 -- It's a strict thing, and the price of the call
 269                 -- is paid by scrut.  Also consider
 270                 --      case f x of DEFAULT -> e
 271                 -- This is just ';'!  Don't charge for it.
 272
 273     ------------
 274     size_up_app (App fun arg) args
 275         | isTypeArg arg              = size_up_app fun args
 276         | otherwise                  = size_up_app fun (arg:args)
 277     size_up_app fun           args   = foldr (addSize . nukeScrutDiscount . size_up)
 278                                              (size_up_fun fun args)
 279                                              args
 280
 281         -- A function application with at least one value argument
 282         -- so if the function is an argument give it an arg-discount
 283         --
 284         -- Also behave specially if the function is a build
 285         --
 286         -- Also if the function is a constant Id (constr or primop)
 287         -- compute discounts specially
 288     size_up_fun (Var fun) args
 289       | fun `hasKey` buildIdKey   = buildSize
 290       | fun `hasKey` augmentIdKey = augmentSize
 291       | otherwise
 292       = case idFlavour fun of
 293           DataConId dc -> conSizeN (valArgCount args)
 294
 295           PrimOpId op  -> primOpSize op (valArgCount args)
 296                           -- foldr addSize (primOpSize op) (map arg_discount args)
 297                           -- At one time I tried giving an arg-discount if a primop
 298                           -- is applied to one of the function's arguments, but it's
 299                           -- not good.  At the moment, any unlifted-type arg gets a
 300                           -- 'True' for 'yes I'm evald', so we collect the discount even
 301                           -- if we know nothing about it.  And just having it in a primop
 302                           -- doesn't help at all if we don't know something more.
 303
 304           other        -> fun_discount fun `addSizeN`
 305                           (1 + length (filter (not . exprIsTrivial) args))
 306                                 -- The 1+ is for the function itself
 307                                 -- Add 1 for each non-trivial arg;
 308                                 -- the allocation cost, as in let(rec)
 309                                 -- Slight hack here: for constructors the args are almost always
 310                                 --      trivial; and for primops they are almost always prim typed
 311                                 --      We should really only count for non-prim-typed args in the
 312                                 --      general case, but that seems too much like hard work
 313
 314     size_up_fun other args = size_up other
 315
 316     ------------
 317     size_up_alt (con, bndrs, rhs) = size_up rhs
 318         -- Don't charge for args, so that wrappers look cheap
 319         -- (See comments about wrappers with Case)
 320
 321     ------------
 322         -- We want to record if we're case'ing, or applying, an argument
 323     fun_discount v | v `elem` top_args = SizeIs 0# (unitBag (v, opt_UF_FunAppDiscount)) 0#
 324     fun_discount other                 = sizeZero
 325
 326     ------------
 327         -- These addSize things have to be here because
 328         -- I don't want to give them bOMB_OUT_SIZE as an argument
 329
 330     addSizeN TooBig          _      = TooBig
 331     addSizeN (SizeIs n xs d) (I# m)
 332       | n_tot ># bOMB_OUT_SIZE      = TooBig
 333       | otherwise                   = SizeIs n_tot xs d
 334       where
 335         n_tot = n +# m
 336
 337     addSize TooBig _ = TooBig
 338     addSize _ TooBig = TooBig
 339     addSize (SizeIs n1 xs d1) (SizeIs n2 ys d2)
 340       | n_tot ># bOMB_OUT_SIZE = TooBig
 341       | otherwise              = SizeIs n_tot xys d_tot
 342       where
 343         n_tot = n1 +# n2
 344         d_tot = d1 +# d2
 345         xys   = xs `unionBags` ys
 346 \end{code}
 347
 348 Code for manipulating sizes
 349
 350 \begin{code}
 351
 352 data ExprSize = TooBig
 353               | SizeIs Int#             -- Size found
 354                        (Bag (Id,Int))   -- Arguments cased herein, and discount for each such
 355                        Int#             -- Size to subtract if result is scrutinised
 356                                         -- by a case expression
 357
 358 isTooBig TooBig = True
 359 isTooBig _      = False
 360
 361 maxSize TooBig         _                                  = TooBig
 362 maxSize _              TooBig                             = TooBig
 363 maxSize s1@(SizeIs n1 _ _) s2@(SizeIs n2 _ _) | n1 ># n2  = s1
 364                                               | otherwise = s2
 365
 366 sizeZero        = SizeIs 0# emptyBag 0#
 367 sizeOne         = SizeIs 1# emptyBag 0#
 368 sizeTwo         = SizeIs 2# emptyBag 0#
 369 sizeN (I# n)    = SizeIs n  emptyBag 0#
 370 conSizeN (I# n) = SizeIs 1# emptyBag (n +# 1#)
 371         -- Treat constructors as size 1; we are keen to expose them
 372         -- (and we charge separately for their args).  We can't treat
 373         -- them as size zero, else we find that (I# x) has size 1,
 374         -- which is the same as a lone variable; and hence 'v' will
 375         -- always be replaced by (I# x), where v is bound to I# x.
 376
 377 primOpSize op n_args
 378  | not (primOpIsDupable op) = sizeN opt_UF_DearOp
 379  | not (primOpOutOfLine op) = sizeZero                  -- These are good to inline
 380  | otherwise                = sizeOne
 381
 382 buildSize = SizeIs (-2#) emptyBag 4#
 383         -- We really want to inline applications of build
 384         -- build t (\cn -> e) should cost only the cost of e (because build will be inlined later)
 385         -- Indeed, we should add a result_discount becuause build is
 386         -- very like a constructor.  We don't bother to check that the
 387         -- build is saturated (it usually is).  The "-2" discounts for the \c n,
 388         -- The "4" is rather arbitrary.
 389
 390 augmentSize = SizeIs (-2#) emptyBag 4#
 391         -- Ditto (augment t (\cn -> e) ys) should cost only the cost of
 392         -- e plus ys. The -2 accounts for the \cn
 393
 394 nukeScrutDiscount (SizeIs n vs d) = SizeIs n vs 0#
 395 nukeScrutDiscount TooBig          = TooBig
 396
 397 -- When we return a lambda, give a discount if it's used (applied)
 398 lamScrutDiscount  (SizeIs n vs d) = case opt_UF_FunAppDiscount of { I# d -> SizeIs n vs d }
 399 lamScrutDiscount TooBig           = TooBig
 400 \end{code}
 401
 402
 403 %************************************************************************
 404 %*                                                                      *
 405 \subsection[considerUnfolding]{Given all the info, do (not) do the unfolding}
 406 %*                                                                      *
 407 %************************************************************************
 408
 409 We have very limited information about an unfolding expression: (1)~so
 410 many type arguments and so many value arguments expected---for our
 411 purposes here, we assume we've got those.  (2)~A ``size'' or ``cost,''
 412 a single integer.  (3)~An ``argument info'' vector.  For this, what we
 413 have at the moment is a Boolean per argument position that says, ``I
 414 will look with great favour on an explicit constructor in this
 415 position.'' (4)~The ``discount'' to subtract if the expression
 416 is being scrutinised.
 417
 418 Assuming we have enough type- and value arguments (if not, we give up
 419 immediately), then we see if the ``discounted size'' is below some
 420 (semi-arbitrary) threshold.  It works like this: for every argument
 421 position where we're looking for a constructor AND WE HAVE ONE in our
 422 hands, we get a (again, semi-arbitrary) discount [proportion to the
 423 number of constructors in the type being scrutinized].
 424
 425 If we're in the context of a scrutinee ( \tr{(case <expr > of A .. -> ...;.. )})
 426 and the expression in question will evaluate to a constructor, we use
 427 the computed discount size *for the result only* rather than
 428 computing the argument discounts. Since we know the result of
 429 the expression is going to be taken apart, discounting its size
 430 is more accurate (see @sizeExpr@ above for how this discount size
 431 is computed).
 432
 433 We use this one to avoid exporting inlinings that we ``couldn't possibly
 434 use'' on the other side.  Can be overridden w/ flaggery.
 435 Just the same as smallEnoughToInline, except that it has no actual arguments.
 436
 437 \begin{code}
 438 couldBeSmallEnoughToInline :: Int -> CoreExpr -> Bool
 439 couldBeSmallEnoughToInline threshold rhs = case calcUnfoldingGuidance threshold rhs of
 440                                                 UnfoldNever -> False
 441                                                 other       -> True
 442
 443 certainlyWillInline :: Id -> Bool
 444         -- Sees if the Id is pretty certain to inline
 445 certainlyWillInline v
 446   = case idUnfolding v of
 447
 448         CoreUnfolding _ _ is_value _ g@(UnfoldIfGoodArgs n_vals _ size _)
 449            ->    is_value
 450               && size - (n_vals +1) <= opt_UF_UseThreshold
 451
 452         other -> False
 453 \end{code}
 454
 455 @okToUnfoldInHifile@ is used when emitting unfolding info into an interface
 456 file to determine whether an unfolding candidate really should be unfolded.
 457 The predicate is needed to prevent @_casm_@s (+ lit-lits) from being emitted
 458 into interface files.
 459
 460 The reason for inlining expressions containing _casm_s into interface files
 461 is that these fragments of C are likely to mention functions/#defines that
 462 will be out-of-scope when inlined into another module. This is not an
 463 unfixable problem for the user (just need to -#include the approp. header
 464 file), but turning it off seems to the simplest thing to do.
 465
 466 \begin{code}
 467 okToUnfoldInHiFile :: CoreExpr -> Bool
 468 okToUnfoldInHiFile e = opt_UnfoldCasms || go e
 469  where
 470     -- Race over an expression looking for CCalls..
 471     go (Var v)                = case isPrimOpId_maybe v of
 472                                   Just op -> okToUnfoldPrimOp op
 473                                   Nothing -> True
 474     go (Lit lit)              = not (isLitLitLit lit)
 475     go (App fun arg)          = go fun && go arg
 476     go (Lam _ body)           = go body
 477     go (Let binds body)       = and (map go (body :rhssOfBind binds))
 478     go (Case scrut bndr alts) = and (map go (scrut:rhssOfAlts alts)) &&
 479                                 not (any isLitLitLit [ lit | (LitAlt lit, _, _) <- alts ])
 480     go (Note _ body)          = go body
 481     go (Type _)               = True
 482
 483     -- ok to unfold a PrimOp as long as it's not a _casm_
 484     okToUnfoldPrimOp (CCallOp ccall) = not (ccallIsCasm ccall)
 485     okToUnfoldPrimOp _               = True
 486 \end{code}
 487
 488
 489 %************************************************************************
 490 %*                                                                      *
 491 \subsection{callSiteInline}
 492 %*                                                                      *
 493 %************************************************************************
 494
 495 This is the key function.  It decides whether to inline a variable at a call site
 496
 497 callSiteInline is used at call sites, so it is a bit more generous.
 498 It's a very important function that embodies lots of heuristics.
 499 A non-WHNF can be inlined if it doesn't occur inside a lambda,
 500 and occurs exactly once or
 501     occurs once in each branch of a case and is small
 502
 503 If the thing is in WHNF, there's no danger of duplicating work,
 504 so we can inline if it occurs once, or is small
 505
 506 NOTE: we don't want to inline top-level functions that always diverge.
 507 It just makes the code bigger.  Tt turns out that the convenient way to prevent
 508 them inlining is to give them a NOINLINE pragma, which we do in
 509 StrictAnal.addStrictnessInfoToTopId
 510
 511 \begin{code}
 512 callSiteInline :: Bool                  -- True <=> the Id is black listed
 513                -> Bool                  -- 'inline' note at call site
 514                -> OccInfo
 515                -> Id                    -- The Id
 516                -> [Bool]                -- One for each value arg; True if it is interesting
 517                -> Bool                  -- True <=> continuation is interesting
 518                -> Maybe CoreExpr        -- Unfolding, if any
 519
 520
 521 callSiteInline black_listed inline_call occ id arg_infos interesting_cont
 522   = case idUnfolding id of {
 523         NoUnfolding -> Nothing ;
 524         OtherCon cs -> Nothing ;
 525         CompulsoryUnfolding unf_template | black_listed -> Nothing
 526                                          | otherwise    -> Just unf_template ;
 527                 -- Constructors have compulsory unfoldings, but
 528                 -- may have rules, in which case they are
 529                 -- black listed till later
 530         CoreUnfolding unf_template is_top is_value is_cheap guidance ->
 531
 532     let
 533         result | yes_or_no = Just unf_template
 534                | otherwise = Nothing
 535
 536         n_val_args  = length arg_infos
 537
 538         yes_or_no
 539           | black_listed = False
 540           | otherwise    = case occ of
 541                                 IAmDead              -> pprTrace "callSiteInline: dead" (ppr id) False
 542                                 IAmALoopBreaker      -> False
 543                                 OneOcc in_lam one_br -> (not in_lam || is_cheap) && consider_safe in_lam True  one_br
 544                                 NoOccInfo            -> is_cheap                 && consider_safe True   False False
 545
 546         consider_safe in_lam once once_in_one_branch
 547                 -- consider_safe decides whether it's a good idea to inline something,
 548                 -- given that there's no work-duplication issue (the caller checks that).
 549                 -- once_in_one_branch = True means there's a unique textual occurrence
 550           | inline_call  = True
 551
 552           | once_in_one_branch
 553                 -- Be very keen to inline something if this is its unique occurrence:
 554                 --
 555                 --   a) Inlining gives a good chance of eliminating the original
 556                 --      binding (and hence the allocation) for the thing.
 557                 --      (Provided it's not a top level binding, in which case the
 558                 --       allocation costs nothing.)
 559                 --
 560                 --   b) Inlining a function that is called only once exposes the
 561                 --      body function to the call site.
 562                 --
 563                 -- The only time we hold back is when substituting inside a lambda;
 564                 -- then if the context is totally uninteresting (not applied, not scrutinised)
 565                 -- there is no point in substituting because it might just increase allocation,
 566                 -- by allocating the function itself many times
 567                 --
 568                 -- Note: there used to be a '&& not top_level' in the guard above,
 569                 --       but that stopped us inlining top-level functions used only once,
 570                 --       which is stupid
 571           = not in_lam || not (null arg_infos) || interesting_cont
 572
 573           | otherwise
 574           = case guidance of
 575               UnfoldNever  -> False ;
 576               UnfoldIfGoodArgs n_vals_wanted arg_discounts size res_discount
 577
 578                   | enough_args && size <= (n_vals_wanted + 1)
 579                         -- No size increase
 580                         -- Size of call is n_vals_wanted (+1 for the function)
 581                   -> True
 582
 583                   | otherwise
 584                   -> some_benefit && small_enough
 585
 586                   where
 587                     some_benefit = or arg_infos || really_interesting_cont ||
 588                                    (not is_top && (once || (n_vals_wanted > 0 && enough_args)))
 589                         -- If it occurs more than once, there must be something interesting
 590                         -- about some argument, or the result context, to make it worth inlining
 591                         --
 592                         -- If a function has a nested defn we also record some-benefit,
 593                         -- on the grounds that we are often able to eliminate the binding,
 594                         -- and hence the allocation, for the function altogether; this is good
 595                         -- for join points.  But this only makes sense for *functions*;
 596                         -- inlining a constructor doesn't help allocation unless the result is
 597                         -- scrutinised.  UNLESS the constructor occurs just once, albeit possibly
 598                         -- in multiple case branches.  Then inlining it doesn't increase allocation,
 599                         -- but it does increase the chance that the constructor won't be allocated at all
 600                         -- in the branches that don't use it.
 601
 602                     enough_args           = n_val_args >= n_vals_wanted
 603                     really_interesting_cont | n_val_args <  n_vals_wanted = False       -- Too few args
 604                                             | n_val_args == n_vals_wanted = interesting_cont
 605                                             | otherwise                   = True        -- Extra args
 606                         -- really_interesting_cont tells if the result of the
 607                         -- call is in an interesting context.
 608
 609                     small_enough = (size - discount) <= opt_UF_UseThreshold
 610                     discount     = computeDiscount n_vals_wanted arg_discounts res_discount
 611                                                  arg_infos really_interesting_cont
 612
 613     in
 614 #ifdef DEBUG
 615     if opt_D_dump_inlinings then
 616         pprTrace "Considering inlining"
 617                  (ppr id <+> vcat [text "black listed:" <+> ppr black_listed,
 618                                    text "occ info:" <+> ppr occ,
 619                                    text "arg infos" <+> ppr arg_infos,
 620                                    text "interesting continuation" <+> ppr interesting_cont,
 621                                    text "is value:" <+> ppr is_value,
 622                                    text "is cheap:" <+> ppr is_cheap,
 623                                    text "guidance" <+> ppr guidance,
 624                                    text "ANSWER =" <+> if yes_or_no then text "YES" else text "NO",
 625                                    if yes_or_no then
 626                                         text "Unfolding =" <+> pprCoreExpr unf_template
 627                                    else empty])
 628                   result
 629     else
 630 #endif
 631     result
 632     }
 633
 634 computeDiscount :: Int -> [Int] -> Int -> [Bool] -> Bool -> Int
 635 computeDiscount n_vals_wanted arg_discounts res_discount arg_infos result_used
 636         -- We multiple the raw discounts (args_discount and result_discount)
 637         -- ty opt_UnfoldingKeenessFactor because the former have to do with
 638         -- *size* whereas the discounts imply that there's some extra
 639         -- *efficiency* to be gained (e.g. beta reductions, case reductions)
 640         -- by inlining.
 641
 642         -- we also discount 1 for each argument passed, because these will
 643         -- reduce with the lambdas in the function (we count 1 for a lambda
 644         -- in size_up).
 645   = 1 +                 -- Discount of 1 because the result replaces the call
 646                         -- so we count 1 for the function itself
 647     length (take n_vals_wanted arg_infos) +
 648                         -- Discount of 1 for each arg supplied, because the
 649                         -- result replaces the call
 650     round (opt_UF_KeenessFactor *
 651            fromInt (arg_discount + result_discount))
 652   where
 653     arg_discount = sum (zipWith mk_arg_discount arg_discounts arg_infos)
 654
 655     mk_arg_discount discount is_evald | is_evald  = discount
 656                                       | otherwise = 0
 657
 658         -- Don't give a result discount unless there are enough args
 659     result_discount | result_used = res_discount        -- Over-applied, or case scrut
 660                     | otherwise   = 0
 661 \end{code}
 662
 663
 664 %************************************************************************
 665 %*                                                                      *
 666 \subsection{Black-listing}
 667 %*                                                                      *
 668 %************************************************************************
 669
 670 Inlining is controlled by the "Inline phase" number, which is set
 671 by the per-simplification-pass '-finline-phase' flag.
 672
 673 For optimisation we use phase 1,2 and nothing (i.e. no -finline-phase flag)
 674 in that order.  The meanings of these are determined by the @blackListed@ function
 675 here.
 676
 677 The final simplification doesn't have a phase number.
 678
 679 Pragmas
 680 ~~~~~~~
 681         Pragma          Black list if
 682
 683 (least black listing, most inlining)
 684         INLINE n foo    phase is Just p *and* p<n *and* foo appears on LHS of rule
 685         INLINE foo      phase is Just p *and*           foo appears on LHS of rule
 686         NOINLINE n foo  phase is Just p *and* (p<n *or* foo appears on LHS of rule)
 687         NOINLINE foo    always
 688 (most black listing, least inlining)
 689
 690 \begin{code}
 691 blackListed :: IdSet            -- Used in transformation rules
 692             -> Maybe Int        -- Inline phase
 693             -> Id -> Bool       -- True <=> blacklisted
 694
 695 -- The blackListed function sees whether a variable should *not* be
 696 -- inlined because of the inline phase we are in.  This is the sole
 697 -- place that the inline phase number is looked at.
 698
 699 blackListed rule_vars Nothing           -- Last phase
 700   = \v -> isNeverInlinePrag (idInlinePragma v)
 701
 702 blackListed rule_vars (Just phase)
 703   = \v -> normal_case rule_vars phase v
 704
 705 normal_case rule_vars phase v
 706   = case idInlinePragma v of
 707         NoInlinePragInfo -> has_rules
 708
 709         IMustNotBeINLINEd from_INLINE Nothing
 710           | from_INLINE -> has_rules    -- Black list until final phase
 711           | otherwise   -> True         -- Always blacklisted
 712
 713         IMustNotBeINLINEd from_INLINE (Just threshold)
 714           | from_INLINE -> (phase < threshold && has_rules)
 715           | otherwise   -> (phase < threshold || has_rules)
 716   where
 717     has_rules =  v `elemVarSet` rule_vars
 718               || not (isEmptyCoreRules (idSpecialisation v))
 719 \end{code}
 720
 721
 722 SLPJ 95/04: Why @runST@ must be inlined very late:
 723 \begin{verbatim}
 724 f x =
 725   runST ( \ s -> let
 726                     (a, s')  = newArray# 100 [] s
 727                     (_, s'') = fill_in_array_or_something a x s'
 728                   in
 729                   freezeArray# a s'' )
 730 \end{verbatim}
 731 If we inline @runST@, we'll get:
 732 \begin{verbatim}
 733 f x = let
 734         (a, s')  = newArray# 100 [] realWorld#{-NB-}
 735         (_, s'') = fill_in_array_or_something a x s'
 736       in
 737       freezeArray# a s''
 738 \end{verbatim}
 739 And now the @newArray#@ binding can be floated to become a CAF, which
 740 is totally and utterly wrong:
 741 \begin{verbatim}
 742 f = let
 743     (a, s')  = newArray# 100 [] realWorld#{-NB-} -- YIKES!!!
 744     in
 745     \ x ->
 746         let (_, s'') = fill_in_array_or_something a x s' in
 747         freezeArray# a s''
 748 \end{verbatim}
 749 All calls to @f@ will share a {\em single} array!
 750
 751 Yet we do want to inline runST sometime, so we can avoid
 752 needless code.  Solution: black list it until the last moment.
 753