ghc/compiler/deSugar/DsCCall.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1994-1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{_ccall_}s and \tr{_casm_}s}
   5
   6 \begin{code}
   7 module DsCCall
   8         ( dsCCall
   9         , mkFCall
  10         , unboxArg
  11         , boxResult
  12         , resultWrapper
  13         ) where
  14
  15 #include "HsVersions.h"
  16
  17 import CoreSyn
  18
  19 import DsMonad
  20
  21 import CoreUtils        ( exprType, mkCoerce2 )
  22 import Id               ( Id, mkWildId )
  23 import MkId             ( mkFCallId, realWorldPrimId, mkPrimOpId )
  24 import Maybes           ( maybeToBool )
  25 import ForeignCall      ( ForeignCall(..), CCallSpec(..), CCallTarget(..), Safety, CCallConv(..) )
  26 import DataCon          ( splitProductType_maybe, dataConSourceArity, dataConWrapId )
  27 import ForeignCall      ( ForeignCall, CCallTarget(..) )
  28
  29 import TcType           ( tcSplitTyConApp_maybe )
  30 import Type             ( Type, isUnLiftedType, mkFunTys, mkFunTy,
  31                           tyVarsOfType, mkForAllTys, mkTyConApp,
  32                           isPrimitiveType, splitTyConApp_maybe,
  33                           splitNewType_maybe, splitForAllTy_maybe,
  34                           isUnboxedTupleType
  35                         )
  36
  37 import PrimOp           ( PrimOp(..) )
  38 import TysPrim          ( realWorldStatePrimTy, intPrimTy,
  39                           byteArrayPrimTyCon, mutableByteArrayPrimTyCon,
  40                           addrPrimTy
  41                         )
  42 import TyCon            ( TyCon, tyConDataCons, tyConName )
  43 import TysWiredIn       ( unitDataConId,
  44                           unboxedSingletonDataCon, unboxedPairDataCon,
  45                           unboxedSingletonTyCon, unboxedPairTyCon,
  46                           trueDataCon, falseDataCon,
  47                           trueDataConId, falseDataConId,
  48                           listTyCon, charTyCon,
  49                           tupleTyCon, tupleCon
  50                         )
  51 import BasicTypes       ( Boxity(..) )
  52 import Literal          ( mkMachInt )
  53 import CStrings         ( CLabelString )
  54 import PrelNames        ( Unique, hasKey, ioTyConKey, boolTyConKey, unitTyConKey,
  55                           int8TyConKey, int16TyConKey, int32TyConKey,
  56                           word8TyConKey, word16TyConKey, word32TyConKey
  57                           -- dotnet interop
  58                           , marshalStringName, unmarshalStringName
  59                           , marshalObjectName, unmarshalObjectName
  60                           , objectTyConName
  61                         )
  62 import VarSet           ( varSetElems )
  63 import Constants        ( wORD_SIZE)
  64 import Outputable
  65 \end{code}
  66
  67 Desugaring of @ccall@s consists of adding some state manipulation,
  68 unboxing any boxed primitive arguments and boxing the result if
  69 desired.
  70
  71 The state stuff just consists of adding in
  72 @PrimIO (\ s -> case s of { S# s# -> ... })@ in an appropriate place.
  73
  74 The unboxing is straightforward, as all information needed to unbox is
  75 available from the type.  For each boxed-primitive argument, we
  76 transform:
  77 \begin{verbatim}
  78    _ccall_ foo [ r, t1, ... tm ] e1 ... em
  79    |
  80    |
  81    V
  82    case e1 of { T1# x1# ->
  83    ...
  84    case em of { Tm# xm# -> xm#
  85    ccall# foo [ r, t1#, ... tm# ] x1# ... xm#
  86    } ... }
  87 \end{verbatim}
  88
  89 The reboxing of a @_ccall_@ result is a bit tricker: the types don't
  90 contain information about the state-pairing functions so we have to
  91 keep a list of \tr{(type, s-p-function)} pairs.  We transform as
  92 follows:
  93 \begin{verbatim}
  94    ccall# foo [ r, t1#, ... tm# ] e1# ... em#
  95    |
  96    |
  97    V
  98    \ s# -> case (ccall# foo [ r, t1#, ... tm# ] s# e1# ... em#) of
  99           (StateAnd<r># result# state#) -> (R# result#, realWorld#)
 100 \end{verbatim}
 101
 102 \begin{code}
 103 dsCCall :: CLabelString -- C routine to invoke
 104         -> [CoreExpr]   -- Arguments (desugared)
 105         -> Safety       -- Safety of the call
 106         -> Bool         -- True <=> really a "_casm_"
 107         -> Type         -- Type of the result: IO t
 108         -> DsM CoreExpr
 109
 110 dsCCall lbl args may_gc is_asm result_ty
 111   = mapAndUnzipDs unboxArg args        `thenDs` \ (unboxed_args, arg_wrappers) ->
 112     boxResult [] id Nothing result_ty  `thenDs` \ (ccall_result_ty, res_wrapper) ->
 113     getUniqueDs                        `thenDs` \ uniq ->
 114     let
 115         target | is_asm    = CasmTarget lbl
 116                | otherwise = StaticTarget lbl
 117         the_fcall    = CCall (CCallSpec target CCallConv may_gc)
 118         the_prim_app = mkFCall uniq the_fcall unboxed_args ccall_result_ty
 119     in
 120     returnDs (foldr ($) (res_wrapper the_prim_app) arg_wrappers)
 121
 122 mkFCall :: Unique -> ForeignCall
 123         -> [CoreExpr]   -- Args
 124         -> Type         -- Result type
 125         -> CoreExpr
 126 -- Construct the ccall.  The only tricky bit is that the ccall Id should have
 127 -- no free vars, so if any of the arg tys do we must give it a polymorphic type.
 128 --      [I forget *why* it should have no free vars!]
 129 -- For example:
 130 --      mkCCall ... [s::StablePtr (a->b), x::Addr, c::Char]
 131 --
 132 -- Here we build a ccall thus
 133 --      (ccallid::(forall a b.  StablePtr (a -> b) -> Addr -> Char -> IO Addr))
 134 --                      a b s x c
 135 mkFCall uniq the_fcall val_args res_ty
 136   = mkApps (mkVarApps (Var the_fcall_id) tyvars) val_args
 137   where
 138     arg_tys = map exprType val_args
 139     body_ty = (mkFunTys arg_tys res_ty)
 140     tyvars  = varSetElems (tyVarsOfType body_ty)
 141     ty      = mkForAllTys tyvars body_ty
 142     the_fcall_id = mkFCallId uniq the_fcall ty
 143 \end{code}
 144
 145 \begin{code}
 146 unboxArg :: CoreExpr                    -- The supplied argument
 147          -> DsM (CoreExpr,              -- To pass as the actual argument
 148                  CoreExpr -> CoreExpr   -- Wrapper to unbox the arg
 149                 )
 150 -- Example: if the arg is e::Int, unboxArg will return
 151 --      (x#::Int#, \W. case x of I# x# -> W)
 152 -- where W is a CoreExpr that probably mentions x#
 153
 154 unboxArg arg
 155   -- Primtive types: nothing to unbox
 156   | isPrimitiveType arg_ty
 157   = returnDs (arg, \body -> body)
 158
 159   -- Recursive newtypes
 160   | Just rep_ty <- splitNewType_maybe arg_ty
 161   = unboxArg (mkCoerce2 rep_ty arg_ty arg)
 162
 163   -- Booleans
 164   | Just (tc,_) <- splitTyConApp_maybe arg_ty,
 165     tc `hasKey` boolTyConKey
 166   = newSysLocalDs intPrimTy             `thenDs` \ prim_arg ->
 167     returnDs (Var prim_arg,
 168               \ body -> Case (Case arg (mkWildId arg_ty)
 169                                        [(DataAlt falseDataCon,[],mkIntLit 0),
 170                                         (DataAlt trueDataCon, [],mkIntLit 1)])
 171                              prim_arg
 172                              [(DEFAULT,[],body)])
 173
 174   -- Data types with a single constructor, which has a single, primitive-typed arg
 175   -- This deals with Int, Float etc; also Ptr, ForeignPtr
 176   | is_product_type && data_con_arity == 1
 177   = ASSERT(isUnLiftedType data_con_arg_ty1 )    -- Typechecker ensures this
 178     newSysLocalDs arg_ty                `thenDs` \ case_bndr ->
 179     newSysLocalDs data_con_arg_ty1      `thenDs` \ prim_arg ->
 180     returnDs (Var prim_arg,
 181               \ body -> Case arg case_bndr [(DataAlt data_con,[prim_arg],body)]
 182     )
 183
 184   -- Byte-arrays, both mutable and otherwise; hack warning
 185   -- We're looking for values of type ByteArray, MutableByteArray
 186   --    data ByteArray          ix = ByteArray        ix ix ByteArray#
 187   --    data MutableByteArray s ix = MutableByteArray ix ix (MutableByteArray# s)
 188   | is_product_type &&
 189     data_con_arity == 3 &&
 190     maybeToBool maybe_arg3_tycon &&
 191     (arg3_tycon ==  byteArrayPrimTyCon ||
 192      arg3_tycon ==  mutableByteArrayPrimTyCon)
 193     -- and, of course, it is an instance of CCallable
 194   = newSysLocalDs arg_ty                `thenDs` \ case_bndr ->
 195     newSysLocalsDs data_con_arg_tys     `thenDs` \ vars@[l_var, r_var, arr_cts_var] ->
 196     returnDs (Var arr_cts_var,
 197               \ body -> Case arg case_bndr [(DataAlt data_con,vars,body)]
 198     )
 199
 200   | Just (tc, [arg_ty]) <- splitTyConApp_maybe arg_ty,
 201     tc == listTyCon,
 202     Just (cc,[]) <- splitTyConApp_maybe arg_ty,
 203     cc == charTyCon
 204     -- String; dotnet only
 205   = dsLookupGlobalId marshalStringName `thenDs` \ unpack_id ->
 206     newSysLocalDs addrPrimTy           `thenDs` \ prim_string ->
 207     returnDs (Var prim_string,
 208               \ body ->
 209                 let
 210                  io_ty = exprType body
 211                  (Just (_,[io_arg])) = tcSplitTyConApp_maybe io_ty
 212                 in
 213                 mkApps (Var unpack_id)
 214                        [ Type io_arg
 215                        , arg
 216                        , Lam prim_string body
 217                        ])
 218   | Just (tc, [arg_ty]) <- splitTyConApp_maybe arg_ty,
 219     tyConName tc == objectTyConName
 220     -- Object; dotnet only
 221   = dsLookupGlobalId marshalObjectName `thenDs` \ unpack_id ->
 222     newSysLocalDs addrPrimTy           `thenDs` \ prim_obj  ->
 223     returnDs (Var prim_obj,
 224               \ body ->
 225                 let
 226                  io_ty = exprType body
 227                  (Just (_,[io_arg])) = tcSplitTyConApp_maybe io_ty
 228                 in
 229                 mkApps (Var unpack_id)
 230                        [ Type io_arg
 231                        , arg
 232                        , Lam prim_obj body
 233                        ])
 234
 235   | otherwise
 236   = getSrcLocDs `thenDs` \ l ->
 237     pprPanic "unboxArg: " (ppr l <+> ppr arg_ty)
 238   where
 239     arg_ty                                      = exprType arg
 240     maybe_product_type                          = splitProductType_maybe arg_ty
 241     is_product_type                             = maybeToBool maybe_product_type
 242     Just (_, _, data_con, data_con_arg_tys)     = maybe_product_type
 243     data_con_arity                              = dataConSourceArity data_con
 244     (data_con_arg_ty1 : _)                      = data_con_arg_tys
 245
 246     (_ : _ : data_con_arg_ty3 : _) = data_con_arg_tys
 247     maybe_arg3_tycon               = splitTyConApp_maybe data_con_arg_ty3
 248     Just (arg3_tycon,_)            = maybe_arg3_tycon
 249 \end{code}
 250
 251
 252 \begin{code}
 253 boxResult :: [Id]
 254           -> ((Maybe Type, CoreExpr -> CoreExpr) -> (Maybe Type, CoreExpr -> CoreExpr))
 255           -> Maybe Id
 256           -> Type
 257           -> DsM (Type, CoreExpr -> CoreExpr)
 258
 259 -- Takes the result of the user-level ccall:
 260 --      either (IO t),
 261 --      or maybe just t for an side-effect-free call
 262 -- Returns a wrapper for the primitive ccall itself, along with the
 263 -- type of the result of the primitive ccall.  This result type
 264 -- will be of the form
 265 --      State# RealWorld -> (# State# RealWorld, t' #)
 266 -- where t' is the unwrapped form of t.  If t is simply (), then
 267 -- the result type will be
 268 --      State# RealWorld -> (# State# RealWorld #)
 269
 270 boxResult arg_ids augment mbTopCon result_ty
 271   = case tcSplitTyConApp_maybe result_ty of
 272         -- This split absolutely has to be a tcSplit, because we must
 273         -- see the IO type; and it's a newtype which is transparent to splitTyConApp.
 274
 275         -- The result is IO t, so wrap the result in an IO constructor
 276         Just (io_tycon, [io_res_ty]) | io_tycon `hasKey` ioTyConKey
 277                 -> resultWrapper io_res_ty             `thenDs` \ res ->
 278                    let aug_res          = augment res
 279                        extra_result_tys =
 280                          case aug_res of
 281                            (Just ty,_)
 282                              | isUnboxedTupleType ty ->
 283                                 let (Just (_, ls)) = splitTyConApp_maybe ty in tail ls
 284                            _ -> []
 285                    in
 286                    mk_alt (return_result extra_result_tys) aug_res
 287                                                         `thenDs` \ (ccall_res_ty, the_alt) ->
 288                    newSysLocalDs  realWorldStatePrimTy  `thenDs` \ state_id ->
 289                    let
 290                         io_data_con = head (tyConDataCons io_tycon)
 291                         toIOCon =
 292                           case mbTopCon of
 293                             Nothing -> dataConWrapId io_data_con
 294                             Just x  -> x
 295                         wrap = \ the_call ->
 296                                  mkApps (Var toIOCon)
 297                                            [ Type io_res_ty,
 298                                              Lam state_id $
 299                                               Case (App the_call (Var state_id))
 300                                                    (mkWildId ccall_res_ty)
 301                                                    [the_alt]
 302                                            ]
 303                    in
 304                    returnDs (realWorldStatePrimTy `mkFunTy` ccall_res_ty, wrap)
 305                 where
 306                    return_result ts state anss
 307                      = mkConApp (tupleCon Unboxed (2 + length ts))
 308                                 (Type realWorldStatePrimTy : Type io_res_ty : map Type ts ++
 309                                  state : anss)
 310         -- It isn't, so do unsafePerformIO
 311         -- It's not conveniently available, so we inline it
 312         other -> resultWrapper result_ty            `thenDs` \ res ->
 313                  mk_alt return_result (augment res) `thenDs` \ (ccall_res_ty, the_alt) ->
 314                  let
 315                     wrap = \ the_call -> Case (App the_call (Var realWorldPrimId))
 316                                               (mkWildId ccall_res_ty)
 317                                               [the_alt]
 318                  in
 319                  returnDs (realWorldStatePrimTy `mkFunTy` ccall_res_ty, wrap)
 320               where
 321                  return_result state [ans] = ans
 322                  return_result _ _ = panic "return_result: expected single result"
 323   where
 324     mk_alt return_result (Nothing, wrap_result)
 325         =       -- The ccall returns ()
 326           newSysLocalDs realWorldStatePrimTy    `thenDs` \ state_id ->
 327           let
 328                 the_rhs = return_result (Var state_id)
 329                                         [wrap_result (panic "boxResult")]
 330
 331                 ccall_res_ty = mkTyConApp unboxedSingletonTyCon [realWorldStatePrimTy]
 332                 the_alt      = (DataAlt unboxedSingletonDataCon, [state_id], the_rhs)
 333           in
 334           returnDs (ccall_res_ty, the_alt)
 335
 336     mk_alt return_result (Just prim_res_ty, wrap_result)
 337                 -- The ccall returns a non-() value
 338         | isUnboxedTupleType prim_res_ty
 339         = let
 340                 (Just (_, ls@(prim_res_ty1:extras))) = splitTyConApp_maybe prim_res_ty
 341                 arity = 1 + length ls
 342           in
 343           mapDs newSysLocalDs ls                `thenDs` \ args_ids@(result_id:as) ->
 344           newSysLocalDs realWorldStatePrimTy    `thenDs` \ state_id ->
 345           let
 346                 the_rhs = return_result (Var state_id)
 347                                         (wrap_result (Var result_id) : map Var as)
 348                 ccall_res_ty = mkTyConApp (tupleTyCon Unboxed arity)
 349                                           (realWorldStatePrimTy : ls)
 350                 the_alt      = ( DataAlt (tupleCon Unboxed arity)
 351                                , (state_id : args_ids)
 352                                , the_rhs
 353                                )
 354           in
 355           returnDs (ccall_res_ty, the_alt)
 356         | otherwise
 357         =
 358           newSysLocalDs prim_res_ty             `thenDs` \ result_id ->
 359           newSysLocalDs realWorldStatePrimTy    `thenDs` \ state_id ->
 360           let
 361                 the_rhs = return_result (Var state_id)
 362                                         [wrap_result (Var result_id)]
 363
 364                 ccall_res_ty = mkTyConApp unboxedPairTyCon [realWorldStatePrimTy, prim_res_ty]
 365                 the_alt      = (DataAlt unboxedPairDataCon, [state_id, result_id], the_rhs)
 366           in
 367           returnDs (ccall_res_ty, the_alt)
 368
 369
 370 resultWrapper :: Type
 371               -> DsM (Maybe Type,               -- Type of the expected result, if any
 372                       CoreExpr -> CoreExpr)     -- Wrapper for the result
 373 resultWrapper result_ty
 374   -- Base case 1: primitive types
 375   | isPrimitiveType result_ty
 376   = returnDs (Just result_ty, \e -> e)
 377
 378   -- Base case 2: the unit type ()
 379   | Just (tc,_) <- maybe_tc_app, tc `hasKey` unitTyConKey
 380   = returnDs (Nothing, \e -> Var unitDataConId)
 381
 382   -- Base case 3: the boolean type
 383   | Just (tc,_) <- maybe_tc_app, tc `hasKey` boolTyConKey
 384   = returnDs
 385      (Just intPrimTy, \e -> Case e (mkWildId intPrimTy)
 386                                    [(DEFAULT             ,[],Var trueDataConId ),
 387                                     (LitAlt (mkMachInt 0),[],Var falseDataConId)])
 388
 389   -- Recursive newtypes
 390   | Just rep_ty <- splitNewType_maybe result_ty
 391   = resultWrapper rep_ty `thenDs` \ (maybe_ty, wrapper) ->
 392     returnDs (maybe_ty, \e -> mkCoerce2 result_ty rep_ty (wrapper e))
 393
 394   -- The type might contain foralls (eg. for dummy type arguments,
 395   -- referring to 'Ptr a' is legal).
 396   | Just (tyvar, rest) <- splitForAllTy_maybe result_ty
 397   = resultWrapper rest `thenDs` \ (maybe_ty, wrapper) ->
 398     returnDs (maybe_ty, \e -> Lam tyvar (wrapper e))
 399
 400   -- Data types with a single constructor, which has a single arg
 401   -- This includes types like Ptr and ForeignPtr
 402   | Just (tycon, tycon_arg_tys, data_con, data_con_arg_tys) <- splitProductType_maybe result_ty,
 403     dataConSourceArity data_con == 1
 404   = let
 405         (unwrapped_res_ty : _) = data_con_arg_tys
 406         narrow_wrapper         = maybeNarrow tycon
 407     in
 408     resultWrapper unwrapped_res_ty `thenDs` \ (maybe_ty, wrapper) ->
 409     returnDs
 410       (maybe_ty, \e -> mkApps (Var (dataConWrapId data_con))
 411                               (map Type tycon_arg_tys ++ [wrapper (narrow_wrapper e)]))
 412
 413     -- Strings; 'dotnet' only.
 414   | Just (tc, [arg_ty]) <- maybe_tc_app,               tc == listTyCon,
 415     Just (cc,[])        <- splitTyConApp_maybe arg_ty, cc == charTyCon
 416   = dsLookupGlobalId unmarshalStringName        `thenDs` \ pack_id ->
 417     returnDs (Just addrPrimTy,
 418               \ e -> App (Var pack_id) e)
 419
 420     -- Objects; 'dotnet' only.
 421   | Just (tc, [arg_ty]) <- maybe_tc_app,
 422     tyConName tc == objectTyConName
 423   = dsLookupGlobalId unmarshalObjectName        `thenDs` \ pack_id ->
 424     returnDs (Just addrPrimTy,
 425               \ e -> App (Var pack_id) e)
 426
 427   | otherwise
 428   = pprPanic "resultWrapper" (ppr result_ty)
 429   where
 430     maybe_tc_app = splitTyConApp_maybe result_ty
 431
 432 -- When the result of a foreign call is smaller than the word size, we
 433 -- need to sign- or zero-extend the result up to the word size.  The C
 434 -- standard appears to say that this is the responsibility of the
 435 -- caller, not the callee.
 436
 437 maybeNarrow :: TyCon -> (CoreExpr -> CoreExpr)
 438 maybeNarrow tycon
 439   | tycon `hasKey` int8TyConKey   = \e -> App (Var (mkPrimOpId Narrow8IntOp)) e
 440   | tycon `hasKey` int16TyConKey  = \e -> App (Var (mkPrimOpId Narrow16IntOp)) e
 441   | tycon `hasKey` int32TyConKey
 442          && wORD_SIZE > 4         = \e -> App (Var (mkPrimOpId Narrow32IntOp)) e
 443
 444   | tycon `hasKey` word8TyConKey  = \e -> App (Var (mkPrimOpId Narrow8WordOp)) e
 445   | tycon `hasKey` word16TyConKey = \e -> App (Var (mkPrimOpId Narrow16WordOp)) e
 446   | tycon `hasKey` word32TyConKey
 447          && wORD_SIZE > 4         = \e -> App (Var (mkPrimOpId Narrow32WordOp)) e
 448   | otherwise                     = id
 449 \end{code}