ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ForeignDecl(..), FoExport(..), FoImport(..)  )
  19 import TcHsSyn          ( TypecheckedForeignDecl )
  20 import CoreUtils        ( exprType, mkInlineMe )
  21 import Id               ( Id, idType, idName, mkVanillaGlobal, mkSysLocal,
  22                           setInlinePragma )
  23 import IdInfo           ( neverInlinePrag, vanillaIdInfo )
  24 import Literal          ( Literal(..) )
  25 import Module           ( Module, moduleUserString )
  26 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  27                           mkForeignExportOcc, isLocalName,
  28                           NamedThing(..),
  29                         )
  30
  31 import Type             ( repType, eqType )
  32 import TcType           ( Type, mkFunTys, mkForAllTys, mkTyConApp,
  33                           mkFunTy, applyTy,
  34                           tcSplitForAllTys, tcSplitFunTys, tcTyConAppArgs,
  35                           tcSplitTyConApp_maybe, tcSplitAppTy,
  36                           tcFunResultTy
  37                         )
  38
  39 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  40                           Safety(..), playSafe,
  41                           CExportSpec(..),
  42                           CCallConv(..), ccallConvToInt
  43                         )
  44 import CStrings         ( CLabelString )
  45 import TysWiredIn       ( addrTy, unitTy, stablePtrTyCon )
  46 import TysPrim          ( addrPrimTy )
  47 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  48                           bindIOName, returnIOName
  49                         )
  50 import Outputable
  51
  52 import Maybe            ( fromJust )
  53 \end{code}
  54
  55 Desugaring of @foreign@ declarations is naturally split up into
  56 parts, an @import@ and an @export@  part. A @foreign import@
  57 declaration
  58 \begin{verbatim}
  59   foreign import cc nm f :: prim_args -> IO prim_res
  60 \end{verbatim}
  61 is the same as
  62 \begin{verbatim}
  63   f :: prim_args -> IO prim_res
  64   f a1 ... an = _ccall_ nm cc a1 ... an
  65 \end{verbatim}
  66 so we reuse the desugaring code in @DsCCall@ to deal with these.
  67
  68 \begin{code}
  69 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  70                                 -- the occurrence analyser will sort it all out
  71
  72 dsForeigns :: Module
  73            -> [TypecheckedForeignDecl]
  74            -> DsM ( [Id]                -- Foreign-exported binders;
  75                                         -- we have to generate code to register these
  76                   , [Binding]
  77                   , SDoc              -- Header file prototypes for
  78                                       -- "foreign exported" functions.
  79                   , SDoc              -- C stubs to use when calling
  80                                       -- "foreign exported" functions.
  81                   )
  82 dsForeigns mod_name fos
  83   = foldlDs combine ([], [], empty, empty) fos
  84  where
  85   combine (acc_feb, acc_f, acc_h, acc_c) (ForeignImport id _ spec _)
  86     = dsFImport mod_name id spec        `thenDs` \ (bs, h, c) ->
  87       returnDs (acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  88
  89   combine (acc_feb, acc_f, acc_h, acc_c) (ForeignExport id _ (CExport (CExportStatic ext_nm cconv)) _)
  90     = dsFExport mod_name id (idType id) ext_nm cconv False      `thenDs` \ (feb, b, h, c) ->
  91       returnDs (feb:acc_feb, b : acc_f, h $$ acc_h, c $$ acc_c)
  92 \end{code}
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Foreign import}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 Desugaring foreign imports is just the matter of creating a binding
 102 that on its RHS unboxes its arguments, performs the external call
 103 (using the @CCallOp@ primop), before boxing the result up and returning it.
 104
 105 However, we create a worker/wrapper pair, thus:
 106
 107         foreign import f :: Int -> IO Int
 108 ==>
 109         f x = IO ( \s -> case x of { I# x# ->
 110                          case fw s x# of { (# s1, y# #) ->
 111                          (# s1, I# y# #)}})
 112
 113         fw s x# = ccall f s x#
 114
 115 The strictness/CPR analyser won't do this automatically because it doesn't look
 116 inside returned tuples; but inlining this wrapper is a Really Good Idea
 117 because it exposes the boxing to the call site.
 118
 119
 120 \begin{code}
 121 dsFImport :: Module
 122           -> Id
 123           -> FoImport
 124           -> DsM ([Binding], SDoc, SDoc)
 125 dsFImport mod_name lbl_id (LblImport ext_nm)
 126  = ASSERT(fromJust res_ty `eqType` addrPrimTy) -- typechecker ensures this
 127    returnDs ([(lbl_id, rhs)], empty, empty)
 128  where
 129    (res_ty, fo_rhs) = resultWrapper (idType lbl_id)
 130    rhs              = fo_rhs (mkLit (MachLabel ext_nm))
 131
 132 dsFImport mod_name fn_id (CImport spec)     = dsFCall mod_name fn_id (CCall spec)
 133 dsFImport mod_name fn_id (DNImport spec)    = dsFCall mod_name fn_id (DNCall spec)
 134 dsFImport mod_name fn_id (CDynImport cconv) = dsFExportDynamic mod_name fn_id cconv
 135 \end{code}
 136
 137
 138 %************************************************************************
 139 %*                                                                      *
 140 \subsection{Foreign calls}
 141 %*                                                                      *
 142 %************************************************************************
 143
 144 \begin{code}
 145 dsFCall mod_Name fn_id fcall
 146   = let
 147         ty                   = idType fn_id
 148         (tvs, fun_ty)        = tcSplitForAllTys ty
 149         (arg_tys, io_res_ty) = tcSplitFunTys fun_ty
 150                 -- Must use tcSplit* functions because we want to
 151                 -- see that (IO t) in the corner
 152     in
 153     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 154     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 155
 156     let
 157         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 158
 159         -- These are the ids we pass to boxResult, which are used to decide
 160         -- whether to touch# an argument after the call (used to keep
 161         -- ForeignObj#s live across a 'safe' foreign import).
 162         maybe_arg_ids | unsafe_call fcall = work_arg_ids
 163                       | otherwise         = []
 164     in
 165     boxResult maybe_arg_ids io_res_ty           `thenDs` \ (ccall_result_ty, res_wrapper) ->
 166
 167     getUniqueDs                                 `thenDs` \ ccall_uniq ->
 168     getUniqueDs                                 `thenDs` \ work_uniq ->
 169     let
 170         -- Build the worker
 171         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 172         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 173         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 174         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 175
 176         -- Build the wrapper
 177         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 178         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 179         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 180     in
 181     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 182
 183 unsafe_call (CCall (CCallSpec _ _ safety)) = playSafe safety
 184 unsafe_call (DNCall _)                     = False
 185 \end{code}
 186
 187
 188 %************************************************************************
 189 %*                                                                      *
 190 \subsection{Foreign export}
 191 %*                                                                      *
 192 %************************************************************************
 193
 194 The function that does most of the work for `@foreign export@' declarations.
 195 (see below for the boilerplate code a `@foreign export@' declaration expands
 196  into.)
 197
 198 For each `@foreign export foo@' in a module M we generate:
 199 \begin{itemize}
 200 \item a C function `@foo@', which calls
 201 \item a Haskell stub `@M.$ffoo@', which calls
 202 \end{itemize}
 203 the user-written Haskell function `@M.foo@'.
 204
 205 \begin{code}
 206 dsFExport :: Module
 207           -> Id                 -- Either the exported Id,
 208                                 -- or the foreign-export-dynamic constructor
 209           -> Type               -- The type of the thing callable from C
 210           -> CLabelString       -- The name to export to C land
 211           -> CCallConv
 212           -> Bool               -- True => foreign export dynamic
 213                                 --         so invoke IO action that's hanging off
 214                                 --         the first argument's stable pointer
 215           -> DsM ( Id           -- The foreign-exported Id
 216                  , Binding
 217                  , SDoc
 218                  , SDoc
 219                  )
 220 dsFExport mod_name fn_id ty ext_name cconv isDyn
 221   =     -- BUILD THE returnIO WRAPPER, if necessary
 222         -- Look at the result type of the exported function, orig_res_ty
 223         -- If it's IO t, return         (\x.x,          IO t, t)
 224         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 225      (case tcSplitTyConApp_maybe orig_res_ty of
 226         -- We must use tcSplit here so that we see the (IO t) in
 227         -- the type.  [IO t is transparent to plain splitTyConApp.]
 228
 229         Just (ioTyCon, [res_ty])
 230               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 231                         -- The function already returns IO t
 232                  returnDs (\body -> body, orig_res_ty, res_ty)
 233
 234         other ->        -- The function returns t, so wrap the call in returnIO
 235                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 236                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 237                            tcFunResultTy (applyTy (idType retIOId) orig_res_ty),
 238                                 -- We don't have ioTyCon conveniently to hand
 239                            orig_res_ty)
 240
 241      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 242                             io_res_ty,          -- IO t
 243                             res_ty) ->          -- t
 244
 245
 246         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 247      (if isDyn then
 248         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 249         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 250         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 251         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 252         let
 253          the_deref_app = mkApps (Var deRefStablePtrId)
 254                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 255
 256          stbl_app cont = mkApps (Var bindIOId)
 257                                 [ Type stbl_ptr_to_ty
 258                                 , Type res_ty
 259                                 , the_deref_app
 260                                 , mkLams [stbl_value] cont]
 261         in
 262         returnDs (stbl_value, stbl_app, stbl_ptr)
 263       else
 264         returnDs (fn_id,
 265                   \ body -> body,
 266                   panic "stbl_ptr"  -- should never be touched.
 267                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 268
 269
 270         -- BUILD THE HELPER
 271      getModuleDs                        `thenDs` \ mod ->
 272      getUniqueDs                        `thenDs` \ uniq ->
 273      getSrcLocDs                        `thenDs` \ src_loc ->
 274      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 275      let
 276         wrapper_args | isDyn      = stbl_ptr:fe_args
 277                      | otherwise  = fe_args
 278
 279         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 280                         | otherwise  = fe_arg_tys
 281
 282         helper_ty =  mkForAllTys tvs $
 283                      mkFunTys wrapper_arg_tys io_res_ty
 284
 285         f_helper_glob = mkVanillaGlobal helper_name helper_ty vanillaIdInfo
 286                       where
 287                         name                = idName fn_id
 288                         mod
 289                          | isLocalName name = mod_name
 290                          | otherwise        = nameModule name
 291
 292                         occ                 = mkForeignExportOcc (nameOccName name)
 293                         helper_name         = mkGlobalName uniq mod occ src_loc
 294
 295         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 296         the_body = mkLams (tvs ++ wrapper_args) the_app
 297
 298         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 299                                         ext_name f_helper_glob
 300                                         wrapper_arg_tys res_ty cconv isDyn
 301      in
 302      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 303
 304   where
 305    (tvs,sans_foralls)           = tcSplitForAllTys ty
 306    (fe_arg_tys', orig_res_ty)   = tcSplitFunTys sans_foralls
 307         -- We must use tcSplits here, because we want to see
 308         -- the (IO t) in the corner of the type!
 309
 310    fe_arg_tys | isDyn     = tail fe_arg_tys'
 311               | otherwise = fe_arg_tys'
 312
 313    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 314                | otherwise = error "stbl_ptr_ty"
 315
 316    (_, stbl_ptr_ty')            = tcSplitForAllTys stbl_ptr_ty
 317    (_, stbl_ptr_to_ty)          = tcSplitAppTy stbl_ptr_ty'
 318         -- Again, stable pointers are just newtypes,
 319         -- so we must see them!  Hence tcSplit*
 320 \end{code}
 321
 322 @foreign export dynamic@ lets you dress up Haskell IO actions
 323 of some fixed type behind an externally callable interface (i.e.,
 324 as a C function pointer). Useful for callbacks and stuff.
 325
 326 \begin{verbatim}
 327 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 328
 329 -- Haskell-visible constructor, which is generated from the above:
 330 -- SUP: No check for NULL from createAdjustor anymore???
 331
 332 f :: (Addr -> Int -> IO Int) -> IO Addr
 333 f cback =
 334    bindIO (newStablePtr cback)
 335           (\StablePtr sp# -> IO (\s1# ->
 336               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 337                  (# s2#, a# #) -> (# s2#, A# a# #)))
 338
 339 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 340 -- `special' foreign export that invokes the closure pointed to by the
 341 -- first argument.
 342 \end{verbatim}
 343
 344 \begin{code}
 345 dsFExportDynamic :: Module
 346                  -> Id
 347                  -> CCallConv
 348                  -> DsM ([Binding], SDoc, SDoc)
 349 dsFExportDynamic mod_name id cconv
 350   =  newSysLocalDs ty                                    `thenDs` \ fe_id ->
 351      let
 352         -- hack: need to get at the name of the C stub we're about to generate.
 353        fe_nm       = _PK_ (moduleUserString mod_name ++ "_" ++ toCName fe_id)
 354      in
 355      dsFExport mod_name id export_ty fe_nm cconv True   `thenDs` \ (feb, fe, h_code, c_code) ->
 356      newSysLocalDs arg_ty                               `thenDs` \ cback ->
 357      dsLookupGlobalValue newStablePtrName               `thenDs` \ newStablePtrId ->
 358      let
 359         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 360      in
 361      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 362      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 363      let
 364       stbl_app cont ret_ty
 365         = mkApps (Var bindIOId)
 366                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 367                  , Type ret_ty
 368                  , mk_stbl_ptr_app
 369                  , cont
 370                  ]
 371
 372        {-
 373         The arguments to the external function which will
 374         create a little bit of (template) code on the fly
 375         for allowing the (stable pointed) Haskell closure
 376         to be entered using an external calling convention
 377         (stdcall, ccall).
 378        -}
 379       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 380                       , Var stbl_value
 381                       , mkLit (MachLabel fe_nm)
 382                       ]
 383         -- name of external entry point providing these services.
 384         -- (probably in the RTS.)
 385       adjustor      = SLIT("createAdjustor")
 386      in
 387      dsCCall adjustor adj_args PlayRisky False io_res_ty        `thenDs` \ ccall_adj ->
 388         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 389      let ccall_adj_ty = exprType ccall_adj
 390          ccall_io_adj = mkLams [stbl_value]                  $
 391                         Note (Coerce io_res_ty ccall_adj_ty)
 392                              ccall_adj
 393          io_app = mkLams tvs     $
 394                   mkLams [cback] $
 395                   stbl_app ccall_io_adj res_ty
 396          fed = (id `setInlinePragma` neverInlinePrag, io_app)
 397                 -- Never inline the f.e.d. function, because the litlit
 398                 -- might not be in scope in other modules.
 399      in
 400      returnDs ([fed, fe], h_code, c_code)
 401
 402  where
 403   ty                    = idType id
 404   (tvs,sans_foralls)    = tcSplitForAllTys ty
 405   ([arg_ty], io_res_ty) = tcSplitFunTys sans_foralls
 406   [res_ty]              = tcTyConAppArgs io_res_ty
 407         -- Must use tcSplit* to see the (IO t), which is a newtype
 408   export_ty             = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 409
 410 toCName :: Id -> String
 411 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 412 \end{code}
 413
 414 %*
 415 %
 416 \subsection{Generating @foreign export@ stubs}
 417 %
 418 %*
 419
 420 For each @foreign export@ function, a C stub function is generated.
 421 The C stub constructs the application of the exported Haskell function
 422 using the hugs/ghc rts invocation API.
 423
 424 \begin{code}
 425 fexportEntry :: String
 426              -> FAST_STRING
 427              -> Id
 428              -> [Type]
 429              -> Type
 430              -> CCallConv
 431              -> Bool
 432              -> (SDoc, SDoc)
 433 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 434  where
 435    -- name of the (Haskell) helper function generated by the desugarer.
 436   h_nm      = ppr helper <> text "_closure"
 437    -- prototype for the exported function.
 438   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 439
 440   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 441               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 442
 443   c_bits =
 444     externDecl $$
 445     fun_proto  $$
 446     vcat
 447      [ lbrace
 448      ,   text "SchedulerStatus rc;"
 449      ,   declareResult
 450           -- create the application + perform it.
 451      ,   text "rc=rts_evalIO" <>
 452                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 453      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 454                                                 <> comma <> text "rc") <> semi
 455      ,   text "return" <> return_what <> semi
 456      , rbrace
 457      ]
 458
 459   appArg acc (a,c_a) =
 460      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 461
 462   cParamTypes  = map showStgType real_args
 463
 464   res_ty_is_unit = res_ty `eqType` unitTy       -- Look through any newtypes
 465
 466   cResType | res_ty_is_unit = text "void"
 467            | otherwise      = showStgType res_ty
 468
 469   pprCconv = case cc of
 470                 CCallConv   -> empty
 471                 StdCallConv -> ppr cc
 472
 473   declareResult  = text "HaskellObj ret;"
 474
 475   externDecl     = mkExtern (text "HaskellObj") h_nm
 476
 477   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 478
 479   return_what | res_ty_is_unit = empty
 480               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 481
 482   c_args = mkCArgNames 0 args
 483
 484   {-
 485    If we're generating an entry point for a 'foreign export ccall dynamic',
 486    then we receive the return address of the C function that wants to
 487    invoke a Haskell function as any other C function, as second arg.
 488    This arg is unused within the body of the generated C stub, but
 489    needed by the Adjustor.c code to get the stack cleanup right.
 490   -}
 491   (proto_args, real_args)
 492     = case cc of
 493         CCallConv | isDyn -> ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 494                              , head args : addrTy : tail args)
 495         other             -> (mkCArgNames 0 args, args)
 496
 497 mkCArgNames :: Int -> [a] -> [SDoc]
 498 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 499
 500 mkHObj :: Type -> SDoc
 501 mkHObj t = text "rts_mk" <> text (showFFIType t)
 502
 503 unpackHObj :: Type -> SDoc
 504 unpackHObj t = text "rts_get" <> text (showFFIType t)
 505
 506 showStgType :: Type -> SDoc
 507 showStgType t = text "Hs" <> text (showFFIType t)
 508
 509 showFFIType :: Type -> String
 510 showFFIType t = getOccString (getName tc)
 511  where
 512   tc = case tcSplitTyConApp_maybe (repType t) of
 513             Just (tc,_) -> tc
 514             Nothing     -> pprPanic "showFFIType" (ppr t)
 515 \end{code}