ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..),
  31                         )
  32 import Type             ( unUsgTy, repType,
  33                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  34                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  36                         )
  37 import PrimOp           ( PrimOp(..), CCall(..),
  38                           CCallTarget(..), dynamicTarget )
  39 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  40                           addrDataCon
  41                         )
  42 import TysPrim          ( addrPrimTy )
  43 import PrelNames        ( Uniquable(..), hasKey,
  44                           ioTyConKey, deRefStablePtrIdKey, returnIOIdKey,
  45                           bindIOIdKey, makeStablePtrIdKey
  46                         )
  47 import Outputable
  48
  49 import Maybe            ( fromJust )
  50 \end{code}
  51
  52 Desugaring of @foreign@ declarations is naturally split up into
  53 parts, an @import@ and an @export@  part. A @foreign import@
  54 declaration
  55 \begin{verbatim}
  56   foreign import cc nm f :: prim_args -> IO prim_res
  57 \end{verbatim}
  58 is the same as
  59 \begin{verbatim}
  60   f :: prim_args -> IO prim_res
  61   f a1 ... an = _ccall_ nm cc a1 ... an
  62 \end{verbatim}
  63 so we reuse the desugaring code in @DsCCall@ to deal with these.
  64
  65 \begin{code}
  66 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  67                                 -- the occurrence analyser will sort it all out
  68
  69 dsForeigns :: Module
  70            -> [TypecheckedForeignDecl]
  71            -> DsM ( [Id]                -- Foreign-exported binders;
  72                                         -- we have to generate code to register these
  73                   , [Binding]
  74                   , SDoc              -- Header file prototypes for
  75                                       -- "foreign exported" functions.
  76                   , SDoc              -- C stubs to use when calling
  77                                       -- "foreign exported" functions.
  78                   )
  79 dsForeigns mod_name fos = foldlDs combine ([], [], empty, empty) fos
  80  where
  81   combine (acc_feb, acc_f, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  82     | isForeignImport =   -- foreign import (dynamic)?
  83         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  84         returnDs (acc_feb, bs ++ acc_f, acc_h, acc_c)
  85     | isForeignLabel =
  86         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  87         returnDs (acc_feb, b:acc_f, acc_h, acc_c)
  88     | isDynamicExtName ext_nm =
  89         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (feb,bs,h,c) ->
  90         returnDs (feb:acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  91
  92     | otherwise        =  -- foreign export
  93         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (feb,fe,h,c) ->
  94         returnDs (feb:acc_feb, fe:acc_f, h $$ acc_h, c $$ acc_c)
  95    where
  96     isForeignImport =
  97         case imp_exp of
  98           FoImport _ -> True
  99           _          -> False
 100
 101     isForeignLabel =
 102         case imp_exp of
 103           FoLabel -> True
 104           _       -> False
 105
 106     (FoImport uns)   = imp_exp
 107
 108 \end{code}
 109
 110 Desugaring foreign imports is just the matter of creating a binding
 111 that on its RHS unboxes its arguments, performs the external call
 112 (using the @CCallOp@ primop), before boxing the result up and returning it.
 113
 114 However, we create a worker/wrapper pair, thus:
 115
 116         foreign import f :: Int -> IO Int
 117 ==>
 118         f x = IO ( \s -> case x of { I# x# ->
 119                          case fw s x# of { (# s1, y# #) ->
 120                          (# s1, I# y# #)}})
 121
 122         fw s x# = ccall f s x#
 123
 124 The strictness/CPR analyser won't do this automatically because it doesn't look
 125 inside returned tuples; but inlining this wrapper is a Really Good Idea
 126 because it exposes the boxing to the call site.
 127
 128
 129 \begin{code}
 130 dsFImport :: Id
 131           -> Type               -- Type of foreign import.
 132           -> Bool               -- True <=> might cause Haskell GC
 133           -> ExtName
 134           -> CallConv
 135           -> DsM [Binding]
 136 dsFImport fn_id ty may_not_gc ext_name cconv
 137   = let
 138         (tvs, fun_ty)        = splitForAllTys ty
 139         (arg_tys, io_res_ty) = splitFunTys fun_ty
 140     in
 141     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 142     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 143     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 144
 145     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 146     getUniqueDs                                         `thenDs` \ work_uniq ->
 147     let
 148         lbl = case ext_name of
 149                 Dynamic      -> dynamicTarget
 150                 ExtName fs _ -> StaticTarget fs
 151
 152         -- Build the worker
 153         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 154         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 155         the_ccall     = CCall lbl False (not may_not_gc) cconv
 156         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 157         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 158         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 159
 160         -- Build the wrapper
 161         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 162         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 163         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 164     in
 165     returnDs [(work_id, work_rhs), (fn_id, wrap_rhs)]
 166 \end{code}
 167
 168 Foreign labels
 169
 170 \begin{code}
 171 dsFLabel :: Id -> Type -> ExtName -> DsM Binding
 172 dsFLabel nm ty ext_name =
 173    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 174    returnDs (nm, fo_rhs (mkLit (MachLabel enm)))
 175   where
 176    (res_ty, fo_rhs) = resultWrapper ty
 177    enm    = extNameStatic ext_name
 178 \end{code}
 179
 180 The function that does most of the work for `@foreign export@' declarations.
 181 (see below for the boilerplate code a `@foreign export@' declaration expands
 182  into.)
 183
 184 For each `@foreign export foo@' in a module M we generate:
 185 \begin{itemize}
 186 \item a C function `@foo@', which calls
 187 \item a Haskell stub `@M.$ffoo@', which calls
 188 \end{itemize}
 189 the user-written Haskell function `@M.foo@'.
 190
 191 \begin{code}
 192 dsFExport :: Id
 193           -> Type               -- Type of foreign export.
 194           -> Module
 195           -> ExtName
 196           -> CallConv
 197           -> Bool               -- True => invoke IO action that's hanging off
 198                                 -- the first argument's stable pointer
 199           -> DsM ( Id           -- The foreign-exported Id
 200                  , Binding
 201                  , SDoc
 202                  , SDoc
 203                  )
 204 dsFExport fn_id ty mod_name ext_name cconv isDyn
 205   =     -- BUILD THE returnIO WRAPPER, if necessary
 206         -- Look at the result type of the exported function, orig_res_ty
 207         -- If it's IO t, return         (\x.x,          IO t, t)
 208         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 209      (case splitTyConApp_maybe orig_res_ty of
 210         Just (ioTyCon, [res_ty])
 211               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 212                         -- The function already returns IO t
 213                  returnDs (\body -> body, orig_res_ty, res_ty)
 214
 215         other ->        -- The function returns t, so wrap the call in returnIO
 216                  dsLookupGlobalValue returnIOIdKey      `thenDs` \ retIOId ->
 217                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 218                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 219                                 -- We don't have ioTyCon conveniently to hand
 220                            orig_res_ty)
 221
 222      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 223                             io_res_ty,          -- IO t
 224                             res_ty) ->          -- t
 225
 226
 227         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 228      (if isDyn then
 229         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 230         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 231         dsLookupGlobalValue deRefStablePtrIdKey         `thenDs` \ deRefStablePtrId ->
 232         dsLookupGlobalValue bindIOIdKey                 `thenDs` \ bindIOId ->
 233         let
 234          the_deref_app = mkApps (Var deRefStablePtrId)
 235                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 236
 237          stbl_app cont = mkApps (Var bindIOId)
 238                                 [ Type stbl_ptr_to_ty
 239                                 , Type res_ty
 240                                 , the_deref_app
 241                                 , mkLams [stbl_value] cont]
 242         in
 243         returnDs (stbl_value, stbl_app, stbl_ptr)
 244       else
 245         returnDs (fn_id,
 246                   \ body -> body,
 247                   panic "stbl_ptr"  -- should never be touched.
 248                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 249
 250
 251         -- BUILD THE HELPER
 252      getModuleDs                        `thenDs` \ mod ->
 253      getUniqueDs                        `thenDs` \ uniq ->
 254      getSrcLocDs                        `thenDs` \ src_loc ->
 255      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 256      let
 257         wrapper_args | isDyn      = stbl_ptr:fe_args
 258                      | otherwise  = fe_args
 259
 260         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 261                         | otherwise  = fe_arg_tys
 262
 263         helper_ty =  mkForAllTys tvs $
 264                      mkFunTys wrapper_arg_tys io_res_ty
 265
 266         f_helper_glob = mkVanillaId helper_name helper_ty
 267                       where
 268                         name                = idName fn_id
 269                         mod
 270                          | isLocalName name = mod_name
 271                          | otherwise        = nameModule name
 272
 273                         occ                 = mkForeignExportOcc (nameOccName name)
 274                         helper_name         = mkGlobalName uniq mod occ src_loc
 275
 276         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 277         the_body = mkLams (tvs ++ wrapper_args) the_app
 278         c_nm     = extNameStatic ext_name
 279
 280         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 281                                       c_nm f_helper_glob
 282                                       wrapper_arg_tys res_ty cconv isDyn
 283      in
 284      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 285
 286   where
 287    (tvs,sans_foralls)                   = splitForAllTys ty
 288    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 289
 290    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 291    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 292
 293    fe_arg_tys | isDyn     = tail fe_arg_tys'
 294               | otherwise = fe_arg_tys'
 295
 296    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 297                | otherwise = error "stbl_ptr_ty"
 298 \end{code}
 299
 300 @foreign export dynamic@ lets you dress up Haskell IO actions
 301 of some fixed type behind an externally callable interface (i.e.,
 302 as a C function pointer). Useful for callbacks and stuff.
 303
 304 \begin{verbatim}
 305 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 306
 307 -- Haskell-visible constructor, which is generated from the above:
 308 -- SUP: No check for NULL from createAdjustor anymore???
 309
 310 f :: (Addr -> Int -> IO Int) -> IO Addr
 311 f cback =
 312    bindIO (makeStablePtr cback)
 313           (\StablePtr sp# -> IO (\s1# ->
 314               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 315                  (# s2#, a# #) -> (# s2#, A# a# #)))
 316
 317 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 318 -- `special' foreign export that invokes the closure pointed to by the
 319 -- first argument.
 320 \end{verbatim}
 321
 322 \begin{code}
 323 dsFExportDynamic :: Id
 324                  -> Type                -- Type of foreign export.
 325                  -> Module
 326                  -> ExtName
 327                  -> CallConv
 328                  -> DsM (Id, [Binding], SDoc, SDoc)
 329 dsFExportDynamic i ty mod_name ext_name cconv =
 330      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 331      let
 332         -- hack: need to get at the name of the C stub we're about to generate.
 333        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 334        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 335      in
 336      dsFExport  i export_ty mod_name fe_ext_name cconv True
 337         `thenDs` \ (feb, fe, h_code, c_code) ->
 338      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 339      dsLookupGlobalValue makeStablePtrIdKey     `thenDs` \ makeStablePtrId ->
 340      let
 341         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 342      in
 343      dsLookupGlobalValue bindIOIdKey                    `thenDs` \ bindIOId ->
 344      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 345      let
 346       stbl_app cont ret_ty
 347         = mkApps (Var bindIOId)
 348                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 349                  , Type ret_ty
 350                  , mk_stbl_ptr_app
 351                  , cont
 352                  ]
 353
 354        {-
 355         The arguments to the external function which will
 356         create a little bit of (template) code on the fly
 357         for allowing the (stable pointed) Haskell closure
 358         to be entered using an external calling convention
 359         (stdcall, ccall).
 360        -}
 361       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 362                       , Var stbl_value
 363                       , mkLit (MachLabel (_PK_ fe_nm))
 364                       ]
 365         -- name of external entry point providing these services.
 366         -- (probably in the RTS.)
 367       adjustor      = SLIT("createAdjustor")
 368      in
 369      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 370      let ccall_adj_ty = exprType ccall_adj
 371          ccall_io_adj = mkLams [stbl_value]                  $
 372                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 373                              ccall_adj
 374      in
 375      let io_app = mkLams tvs     $
 376                   mkLams [cback] $
 377                   stbl_app ccall_io_adj res_ty
 378          fed = (i `setInlinePragma` neverInlinePrag, io_app)
 379                 -- Never inline the f.e.d. function, because the litlit
 380                 -- might not be in scope in other modules.
 381      in
 382      returnDs (feb, [fed, fe], h_code, c_code)
 383
 384  where
 385   (tvs,sans_foralls)               = splitForAllTys ty
 386   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 387
 388   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 389
 390   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 391
 392   ioAddrTy :: Type      -- IO Addr
 393   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 394
 395 toCName :: Id -> String
 396 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 397 \end{code}
 398
 399 %*
 400 %
 401 \subsection{Generating @foreign export@ stubs}
 402 %
 403 %*
 404
 405 For each @foreign export@ function, a C stub function is generated.
 406 The C stub constructs the application of the exported Haskell function
 407 using the hugs/ghc rts invocation API.
 408
 409 \begin{code}
 410 fexportEntry :: String
 411              -> FAST_STRING
 412              -> Id
 413              -> [Type]
 414              -> Type
 415              -> CallConv
 416              -> Bool
 417              -> (SDoc, SDoc)
 418 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 419  where
 420    -- name of the (Haskell) helper function generated by the desugarer.
 421   h_nm      = ppr helper <> text "_closure"
 422    -- prototype for the exported function.
 423   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 424
 425   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 426               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 427
 428   c_bits =
 429     externDecl $$
 430     fun_proto  $$
 431     vcat
 432      [ lbrace
 433      ,   text "SchedulerStatus rc;"
 434      ,   declareResult
 435           -- create the application + perform it.
 436      ,   text "rc=rts_evalIO" <>
 437                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 438      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 439                                                 <> comma <> text "rc") <> semi
 440      ,   text "return" <> return_what <> semi
 441      , rbrace
 442      ]
 443
 444   appArg acc (a,c_a) =
 445      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 446
 447   cParamTypes  = map showStgType real_args
 448
 449   res_ty_is_unit = res_ty == unitTy
 450
 451   cResType | res_ty_is_unit = text "void"
 452            | otherwise      = showStgType res_ty
 453
 454   pprCconv
 455    | cc == cCallConv = empty
 456    | otherwise       = pprCallConv cc
 457
 458   declareResult  = text "HaskellObj ret;"
 459
 460   externDecl     = mkExtern (text "HaskellObj") h_nm
 461
 462   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 463
 464   return_what | res_ty_is_unit = empty
 465               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 466
 467   c_args = mkCArgNames 0 args
 468
 469   {-
 470    If we're generating an entry point for a 'foreign export ccall dynamic',
 471    then we receive the return address of the C function that wants to
 472    invoke a Haskell function as any other C function, as second arg.
 473    This arg is unused within the body of the generated C stub, but
 474    needed by the Adjustor.c code to get the stack cleanup right.
 475   -}
 476   (proto_args, real_args)
 477     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 478                                 , head args : addrTy : tail args)
 479     | otherwise = (mkCArgNames 0 args, args)
 480
 481 mkCArgNames :: Int -> [a] -> [SDoc]
 482 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 483
 484 mkHObj :: Type -> SDoc
 485 mkHObj t = text "rts_mk" <> text (showFFIType t)
 486
 487 unpackHObj :: Type -> SDoc
 488 unpackHObj t = text "rts_get" <> text (showFFIType t)
 489
 490 showStgType :: Type -> SDoc
 491 showStgType t = text "Stg" <> text (showFFIType t)
 492
 493 showFFIType :: Type -> String
 494 showFFIType t = getOccString (getName tc)
 495  where
 496   tc = case splitTyConApp_maybe (repType t) of
 497             Just (tc,_) -> tc
 498             Nothing     -> pprPanic "showFFIType" (ppr t)
 499 \end{code}