ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, wrapUnboxedValue )
  16 import DsMonad
  17 import DsUtils
  18
  19 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  20 import HsDecls          ( extNameStatic )
  21 import CallConv
  22 import TcHsSyn          ( TypecheckedForeignDecl )
  23 import CoreUtils        ( exprType, mkInlineMe )
  24 import DataCon          ( DataCon, dataConWrapId )
  25 import Id               ( Id, idType, idName, mkWildId, mkVanillaId )
  26 import MkId             ( mkCCallOpId, mkWorkerId )
  27 import Literal          ( Literal(..) )
  28 import Module           ( Module, moduleUserString )
  29 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  30                           mkForeignExportOcc, isLocalName,
  31                           NamedThing(..), Provenance(..), ExportFlag(..)
  32                         )
  33 import PrelInfo         ( deRefStablePtr_NAME, bindIO_NAME, makeStablePtr_NAME, realWorldPrimId )
  34 import Type             ( splitAlgTyConApp_maybe,  unUsgTy,
  35                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  36                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  37                           mkTyVarTy, mkFunTy, splitAppTy
  38                         )
  39 import PrimOp           ( PrimOp(..), CCall(..), CCallTarget(..) )
  40 import Var              ( TyVar )
  41 import TysPrim          ( realWorldStatePrimTy, addrPrimTy )
  42 import TysWiredIn       ( unitTyCon, addrTy, stablePtrTyCon,
  43                           unboxedTupleCon, addrDataCon
  44                         )
  45 import Unique
  46 import Maybes           ( maybeToBool )
  47 import Outputable
  48
  49 #if __GLASGOW_HASKELL__ >= 404
  50 import GlaExts          ( fromInt )
  51 #endif
  52 \end{code}
  53
  54 Desugaring of @foreign@ declarations is naturally split up into
  55 parts, an @import@ and an @export@  part. A @foreign import@
  56 declaration
  57 \begin{verbatim}
  58   foreign import cc nm f :: prim_args -> IO prim_res
  59 \end{verbatim}
  60 is the same as
  61 \begin{verbatim}
  62   f :: prim_args -> IO prim_res
  63   f a1 ... an = _ccall_ nm cc a1 ... an
  64 \end{verbatim}
  65 so we reuse the desugaring code in @DsCCall@ to deal with these.
  66
  67 \begin{code}
  68 dsForeigns :: Module
  69            -> [TypecheckedForeignDecl]
  70            -> DsM ( [CoreBind]        -- desugared foreign imports
  71                   , [CoreBind]        -- helper functions for foreign exports
  72                   , SDoc              -- Header file prototypes for
  73                                       -- "foreign exported" functions.
  74                   , SDoc              -- C stubs to use when calling
  75                                       -- "foreign exported" functions.
  76                   )
  77 dsForeigns mod_name fos = foldlDs combine ([],[],empty,empty) fos
  78  where
  79   combine (acc_fi, acc_fe, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  80     | isForeignImport =   -- foreign import (dynamic)?
  81         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  82         returnDs (bs ++ acc_fi, acc_fe, acc_h, acc_c)
  83     | isForeignLabel =
  84         dsFLabel i ext_nm `thenDs` \ b ->
  85         returnDs (b:acc_fi, acc_fe, acc_h, acc_c)
  86     | isDynamicExtName ext_nm =
  87         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (fi,fe,h,c) ->
  88         returnDs (fi:acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  89
  90     | otherwise        =  -- foreign export
  91         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (fe,h,c) ->
  92         returnDs (acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  93    where
  94     isForeignImport =
  95         case imp_exp of
  96           FoImport _ -> True
  97           _          -> False
  98
  99     isForeignLabel =
 100         case imp_exp of
 101           FoLabel -> True
 102           _       -> False
 103
 104     (FoImport uns)   = imp_exp
 105
 106 \end{code}
 107
 108 Desugaring foreign imports is just the matter of creating a binding
 109 that on its RHS unboxes its arguments, performs the external call
 110 (using the @CCallOp@ primop), before boxing the result up and returning it.
 111
 112 However, we create a worker/wrapper pair, thus:
 113
 114         foreign import f :: Int -> IO Int
 115 ==>
 116         f x = IO ( \s -> case x of { I# x# ->
 117                          case fw s x# of { (# s1, y# #) ->
 118                          (# s1, I# y# #)}})
 119
 120         fw s x# = ccall f s x#
 121
 122 The strictness/CPR analyser won't do this automatically because it doesn't look
 123 inside returned tuples; but inlining this wrapper is a Really Good Idea
 124 because it exposes the boxing to the call site.
 125
 126
 127 \begin{code}
 128 dsFImport :: Id
 129           -> Type               -- Type of foreign import.
 130           -> Bool               -- True <=> might cause Haskell GC
 131           -> ExtName
 132           -> CallConv
 133           -> DsM [CoreBind]
 134 dsFImport fn_id ty may_not_gc ext_name cconv
 135   = let
 136         (tvs, arg_tys, mbIoDataCon, io_res_ty) = splitForeignTyDs ty
 137         is_io_action                           = maybeToBool mbIoDataCon
 138     in
 139     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 140     newSysLocalDs realWorldStatePrimTy          `thenDs` \ old_s ->
 141     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (unboxed_args, arg_wrappers) ->
 142
 143     (if not is_io_action then
 144        newSysLocalDs realWorldStatePrimTy       `thenDs` \ state_tok ->
 145        wrapUnboxedValue io_res_ty               `thenDs` \ (ccall_result_ty, v, res_v) ->
 146        returnDs ( ccall_result_ty
 147                 , \ prim_app -> Case prim_app  (mkWildId ccall_result_ty)
 148                                     [(DataAlt (unboxedTupleCon 2), [state_tok, v], res_v)])
 149      else
 150        boxResult io_res_ty)                     `thenDs` \ (ccall_result_ty, res_wrapper) ->
 151
 152     (case ext_name of
 153        Dynamic       -> getUniqueDs `thenDs` \ u ->
 154                         returnDs (DynamicTarget u)
 155        ExtName fs _  -> returnDs (StaticTarget fs))     `thenDs` \ lbl ->
 156
 157     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 158     getUniqueDs                                         `thenDs` \ work_uniq ->
 159     let
 160         the_state_arg | is_io_action = old_s
 161                       | otherwise    = realWorldPrimId
 162
 163         -- Build the worker
 164         val_args      = Var the_state_arg : unboxed_args
 165         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 166         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 167         the_ccall     = CCall lbl False (not may_not_gc) cconv
 168         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 169         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 170         work_id       = mkWorkerId work_uniq fn_id worker_ty
 171
 172         -- Build the wrapper
 173         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 174         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 175         io_app       = case mbIoDataCon of
 176                            Nothing        -> wrapper_body
 177                            Just ioDataCon -> mkApps (Var (dataConWrapId ioDataCon))
 178                                                     [Type io_res_ty, Lam old_s wrapper_body]
 179         wrap_rhs = mkInlineMe (mkLams (tvs ++ args) io_app)
 180     in
 181     returnDs [NonRec fn_id wrap_rhs, NonRec work_id work_rhs]
 182 \end{code}
 183
 184 Given the type of a foreign import declaration, split it up into
 185 its constituent parts.
 186
 187 \begin{code}
 188 splitForeignTyDs :: Type -> ([TyVar], [Type], Maybe DataCon, Type)
 189 splitForeignTyDs ty
 190   = case splitAlgTyConApp_maybe res_ty of
 191        Just (_,(io_res_ty:_),(ioCon:_)) ->   -- .... -> IO t
 192              (tvs, arg_tys, Just ioCon, io_res_ty)
 193        _   ->                                -- .... -> t
 194              (tvs, arg_tys, Nothing, res_ty)
 195   where
 196    (arg_tys, res_ty)   = splitFunTys sans_foralls
 197    (tvs, sans_foralls) = splitForAllTys ty
 198 \end{code}
 199
 200 foreign labels
 201
 202 \begin{code}
 203 dsFLabel :: Id -> ExtName -> DsM CoreBind
 204 dsFLabel nm ext_name = returnDs (NonRec nm fo_rhs)
 205   where
 206    fo_rhs = mkConApp addrDataCon [mkLit (MachLitLit enm addrPrimTy)]
 207    enm    = extNameStatic ext_name
 208 \end{code}
 209
 210 The function that does most of the work for `@foreign export@' declarations.
 211 (see below for the boilerplate code a `@foreign export@' declaration expands
 212  into.)
 213
 214 For each `@foreign export foo@' in a module M we generate:
 215 \begin{itemize}
 216 \item a C function `@foo@', which calls
 217 \item a Haskell stub `@M.$ffoo@', which calls
 218 \end{itemize}
 219 the user-written Haskell function `@M.foo@'.
 220
 221 \begin{code}
 222 dsFExport :: Id
 223           -> Type               -- Type of foreign export.
 224           -> Module
 225           -> ExtName
 226           -> CallConv
 227           -> Bool               -- True => invoke IO action that's hanging off
 228                                 -- the first argument's stable pointer
 229           -> DsM ( CoreBind
 230                  , SDoc
 231                  , SDoc
 232                  )
 233 dsFExport i ty mod_name ext_name cconv isDyn =
 234      getUniqueDs                                        `thenDs` \ uniq ->
 235      getSrcLocDs                                        `thenDs` \ src_loc ->
 236      let
 237         f_helper_glob = mkVanillaId helper_name helper_ty
 238                       where
 239                         name                = idName i
 240                         mod
 241                          | isLocalName name = mod_name
 242                          | otherwise        = nameModule name
 243
 244                         occ                 = mkForeignExportOcc (nameOccName name)
 245                         prov                = LocalDef src_loc Exported
 246                         helper_name         = mkGlobalName uniq mod occ prov
 247      in
 248      newSysLocalsDs fe_arg_tys                          `thenDs` \ fe_args ->
 249      (if isDyn then
 250         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 251         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 252         dsLookupGlobalValue deRefStablePtr_NAME         `thenDs` \ deRefStablePtrId ->
 253         let
 254          the_deref_app = mkApps (Var deRefStablePtrId)
 255                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 256         in
 257         newSysLocalDs (exprType the_deref_app)   `thenDs` \ x_deref_app ->
 258         dsLookupGlobalValue bindIO_NAME                  `thenDs` \ bindIOId ->
 259         newSysLocalDs (mkFunTy stbl_ptr_to_ty
 260                                (mkTyConApp ioTyCon [res_ty])) `thenDs` \ x_cont ->
 261         let
 262          stbl_app      = \ cont ->
 263                 bindNonRec x_cont   (mkLams [stbl_value] cont) $
 264                 bindNonRec x_deref_app the_deref_app
 265                            (mkApps (Var bindIOId)
 266                                      [ Type stbl_ptr_to_ty
 267                                      , Type res_ty
 268                                      , Var x_deref_app
 269                                      , Var x_cont])
 270         in
 271         returnDs (stbl_value, stbl_app, stbl_ptr)
 272       else
 273         returnDs (i,
 274                   \ body -> body,
 275                   panic "stbl_ptr"  -- should never be touched.
 276                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 277      let
 278       wrapper_args
 279        | isDyn      = stbl_ptr:fe_args
 280        | otherwise  = fe_args
 281
 282       wrapper_arg_tys
 283        | isDyn      = stbl_ptr_ty:helper_arg_tys
 284        | otherwise  = helper_arg_tys
 285
 286       the_app  =
 287          getFun_wrapper $
 288          mkApps (Var i) (map (Type . mkTyVarTy) tvs ++ map Var fe_args)
 289      in
 290      getModuleDs                        `thenDs` \ mod ->
 291      getUniqueDs                        `thenDs` \ uniq ->
 292      let
 293       the_body = mkLams (tvs ++ wrapper_args) the_app
 294       c_nm     = extNameStatic ext_name
 295
 296       (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 297                                       c_nm f_helper_glob
 298                                       wrapper_arg_tys the_result_ty cconv isDyn
 299      in
 300      returnDs (NonRec f_helper_glob the_body, h_stub, c_stub)
 301
 302   where
 303
 304    (tvs,sans_foralls)                   = splitForAllTys ty
 305    (fe_arg_tys', io_res)                = splitFunTys sans_foralls
 306
 307
 308    Just (ioTyCon, [res_ty])             = splitTyConApp_maybe io_res
 309
 310    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 311    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 312
 313    fe_arg_tys
 314      | isDyn        = tail fe_arg_tys'
 315      | otherwise    = fe_arg_tys'
 316
 317    (stbl_ptr_ty, helper_arg_tys) =
 318      case fe_arg_tys' of
 319        (x:xs) | isDyn -> (x,xs)
 320        ls             -> (error "stbl_ptr_ty", ls)
 321
 322    helper_ty      =
 323         mkForAllTys tvs $
 324         mkFunTys arg_tys io_res
 325         where
 326           arg_tys
 327            | isDyn      = stbl_ptr_ty : helper_arg_tys
 328            | otherwise  = helper_arg_tys
 329
 330    the_result_ty =
 331      case splitTyConApp_maybe io_res of
 332        Just (_,[res_ty]) ->
 333          case splitTyConApp_maybe res_ty of
 334            Just (tc,_) | getUnique tc /= getUnique unitTyCon -> Just res_ty
 335            _                                                 -> Nothing
 336        _                 -> Nothing
 337
 338 \end{code}
 339
 340 @foreign export dynamic@ lets you dress up Haskell IO actions
 341 of some fixed type behind an externally callable interface (i.e.,
 342 as a C function pointer). Useful for callbacks and stuff.
 343
 344 \begin{verbatim}
 345 foreign export stdcall f :: (Addr -> Int -> IO Int) -> IO Addr
 346
 347 -- Haskell-visible constructor, which is generated from the
 348 -- above:
 349
 350 f :: (Addr -> Int -> IO Int) -> IO Addr
 351 f cback = IO ( \ s1# ->
 352   case makeStablePtr# cback s1# of { StateAndStablePtr# s2# sp# ->
 353   case _ccall_ "mkAdjustor" sp# ``f_helper'' s2# of
 354     StateAndAddr# s3# a# ->
 355     case addr2Int# a# of
 356       0# -> IOfail s# err
 357       _  ->
 358          let
 359           a :: Addr
 360           a = A# a#
 361          in
 362          IOok s3# a)
 363
 364 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 365 -- `special' foreign export that invokes the closure pointed to by the
 366 -- first argument.
 367 \end{verbatim}
 368
 369 \begin{code}
 370 dsFExportDynamic :: Id
 371                  -> Type                -- Type of foreign export.
 372                  -> Module
 373                  -> ExtName
 374                  -> CallConv
 375                  -> DsM (CoreBind, CoreBind, SDoc, SDoc)
 376 dsFExportDynamic i ty mod_name ext_name cconv =
 377      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 378      let
 379         -- hack: need to get at the name of the C stub we're about to generate.
 380        fe_nm       = toCName fe_id
 381        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 382      in
 383      dsFExport  i export_ty mod_name fe_ext_name cconv True
 384      `thenDs` \ (fe@(NonRec fe_helper fe_expr), h_code, c_code) ->
 385      newSysLocalDs arg_ty                                   `thenDs` \ cback ->
 386      dsLookupGlobalValue makeStablePtr_NAME        `thenDs` \ makeStablePtrId ->
 387      let
 388         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 389         mk_stbl_ptr_app_ty = exprType mk_stbl_ptr_app
 390      in
 391      newSysLocalDs mk_stbl_ptr_app_ty                   `thenDs` \ x_mk_stbl_ptr_app ->
 392      dsLookupGlobalValue bindIO_NAME                    `thenDs` \ bindIOId ->
 393      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 394      let
 395       stbl_app      = \ x_cont cont ret_ty ->
 396         bindNonRec x_cont            cont            $
 397         bindNonRec x_mk_stbl_ptr_app mk_stbl_ptr_app $
 398                    (mkApps (Var bindIOId)
 399                            [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 400                            , Type ret_ty
 401                            , Var x_mk_stbl_ptr_app
 402                            , Var x_cont
 403                            ])
 404
 405        {-
 406         The arguments to the external function which will
 407         create a little bit of (template) code on the fly
 408         for allowing the (stable pointed) Haskell closure
 409         to be entered using an external calling convention
 410         (stdcall, ccall).
 411        -}
 412       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 413                       , Var stbl_value
 414                       , mkLit (MachLitLit (_PK_ fe_nm) addrPrimTy)
 415                       ]
 416         -- name of external entry point providing these services.
 417         -- (probably in the RTS.)
 418       adjustor      = SLIT("createAdjustor")
 419      in
 420      dsCCall adjustor adj_args False False addrTy `thenDs` \ ccall_adj ->
 421      let ccall_adj_ty = exprType ccall_adj
 422      in
 423      newSysLocalDs ccall_adj_ty                   `thenDs` \ x_ccall_adj ->
 424      let ccall_io_adj =
 425             mkLams [stbl_value]              $
 426             bindNonRec x_ccall_adj ccall_adj $
 427             Note (Coerce (mkTyConApp ioTyCon [res_ty]) (unUsgTy ccall_adj_ty))
 428                  (Var x_ccall_adj)
 429      in
 430      newSysLocalDs (exprType ccall_io_adj)        `thenDs` \ x_ccall_io_adj ->
 431      let io_app = mkLams tvs     $
 432                   mkLams [cback] $
 433                   stbl_app x_ccall_io_adj ccall_io_adj addrTy
 434      in
 435      returnDs (NonRec i io_app, fe, h_code, c_code)
 436
 437  where
 438   (tvs,sans_foralls)               = splitForAllTys ty
 439   ([arg_ty], io_res)               = splitFunTys sans_foralls
 440
 441   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res
 442
 443   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 444
 445 toCName :: Id -> String
 446 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 447
 448 \end{code}
 449
 450 %*
 451 %
 452 \subsection{Generating @foreign export@ stubs}
 453 %
 454 %*
 455
 456 For each @foreign export@ function, a C stub function is generated.
 457 The C stub constructs the application of the exported Haskell function
 458 using the hugs/ghc rts invocation API.
 459
 460 \begin{code}
 461 fexportEntry :: String
 462              -> FAST_STRING
 463              -> Id
 464              -> [Type]
 465              -> Maybe Type
 466              -> CallConv
 467              -> Bool
 468              -> (SDoc, SDoc)
 469 fexportEntry mod_nm c_nm helper args res cc isDyn = (header_bits, c_bits)
 470  where
 471    -- name of the (Haskell) helper function generated by the desugarer.
 472   h_nm      = ppr helper <> text "_closure"
 473    -- prototype for the exported function.
 474   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 475
 476   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 477               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 478
 479   c_bits =
 480     externDecl $$
 481     fun_proto  $$
 482     vcat
 483      [ lbrace
 484      ,   text "SchedulerStatus rc;"
 485      ,   declareResult
 486           -- create the application + perform it.
 487      ,   text "rc=rts_evalIO" <>
 488                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 489      ,   returnResult
 490      , rbrace
 491      ]
 492
 493   appArg acc (a,c_a) =
 494      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 495
 496   cParamTypes  = map showStgType real_args
 497
 498   cResType =
 499    case res of
 500      Nothing -> text "void"
 501      Just t  -> showStgType t
 502
 503   pprCconv
 504    | cc == cCallConv = empty
 505    | otherwise       = pprCallConv cc
 506
 507   declareResult  = text "HaskellObj ret;"
 508
 509   externDecl     = mkExtern (text "HaskellObj") h_nm
 510
 511   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 512
 513   returnResult =
 514     text "rts_checkSchedStatus" <>
 515     parens (doubleQuotes (text mod_nm <> char '.' <> ptext c_nm) <> comma <> text "rc") <> semi $$
 516     (case res of
 517       Nothing -> text "return"
 518       Just _  -> text "return" <> parens (res_name)) <> semi
 519
 520   res_name =
 521     case res of
 522       Nothing -> empty
 523       Just t  -> unpackHObj t <> parens (text "ret")
 524
 525   c_args = mkCArgNames 0 args
 526
 527   {-
 528    If we're generating an entry point for a 'foreign export ccall dynamic',
 529    then we receive the return address of the C function that wants to
 530    invoke a Haskell function as any other C function, as second arg.
 531    This arg is unused within the body of the generated C stub, but
 532    needed by the Adjustor.c code to get the stack cleanup right.
 533   -}
 534   (proto_args, real_args)
 535     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 536                                 , head args : addrTy : tail args)
 537     | otherwise = (mkCArgNames 0 args, args)
 538
 539 mkCArgNames :: Int -> [a] -> [SDoc]
 540 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 541
 542 mkHObj :: Type -> SDoc
 543 mkHObj t = text "rts_mk" <> text (showFFIType t)
 544
 545 unpackHObj :: Type -> SDoc
 546 unpackHObj t = text "rts_get" <> text (showFFIType t)
 547
 548 showStgType :: Type -> SDoc
 549 showStgType t = text "Stg" <> text (showFFIType t)
 550
 551 showFFIType :: Type -> String
 552 showFFIType t = getOccString (getName tc)
 553  where
 554   tc = case splitTyConApp_maybe t of
 555             Just (tc,_) -> tc
 556             Nothing     -> pprPanic "showFFIType" (ppr t)
 557 \end{code}