ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..), Provenance(..), ExportFlag(..)
  31                         )
  32 import Type             ( unUsgTy, repType,
  33                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  34                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  36                         )
  37 import PrimOp           ( PrimOp(..), CCall(..),
  38                           CCallTarget(..), dynamicTarget )
  39 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  40                           addrDataCon
  41                         )
  42 import TysPrim          ( addrPrimTy )
  43 import Unique           ( Uniquable(..), hasKey,
  44                           ioTyConKey, deRefStablePtrIdKey, returnIOIdKey,
  45                           bindIOIdKey, makeStablePtrIdKey
  46                 )
  47 import Outputable
  48
  49 import Maybe            ( fromJust )
  50 \end{code}
  51
  52 Desugaring of @foreign@ declarations is naturally split up into
  53 parts, an @import@ and an @export@  part. A @foreign import@
  54 declaration
  55 \begin{verbatim}
  56   foreign import cc nm f :: prim_args -> IO prim_res
  57 \end{verbatim}
  58 is the same as
  59 \begin{verbatim}
  60   f :: prim_args -> IO prim_res
  61   f a1 ... an = _ccall_ nm cc a1 ... an
  62 \end{verbatim}
  63 so we reuse the desugaring code in @DsCCall@ to deal with these.
  64
  65 \begin{code}
  66 dsForeigns :: Module
  67            -> [TypecheckedForeignDecl]
  68            -> DsM ( [CoreBind]        -- desugared foreign imports
  69                   , [CoreBind]        -- helper functions for foreign exports
  70                   , SDoc              -- Header file prototypes for
  71                                       -- "foreign exported" functions.
  72                   , SDoc              -- C stubs to use when calling
  73                                       -- "foreign exported" functions.
  74                   )
  75 dsForeigns mod_name fos = foldlDs combine ([],[],empty,empty) fos
  76  where
  77   combine (acc_fi, acc_fe, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  78     | isForeignImport =   -- foreign import (dynamic)?
  79         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  80         returnDs (bs ++ acc_fi, acc_fe, acc_h, acc_c)
  81     | isForeignLabel =
  82         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  83         returnDs (b:acc_fi, acc_fe, acc_h, acc_c)
  84     | isDynamicExtName ext_nm =
  85         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (fi,fe,h,c) ->
  86         returnDs (fi:acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  87
  88     | otherwise        =  -- foreign export
  89         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (fe,h,c) ->
  90         returnDs (acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  91    where
  92     isForeignImport =
  93         case imp_exp of
  94           FoImport _ -> True
  95           _          -> False
  96
  97     isForeignLabel =
  98         case imp_exp of
  99           FoLabel -> True
 100           _       -> False
 101
 102     (FoImport uns)   = imp_exp
 103
 104 \end{code}
 105
 106 Desugaring foreign imports is just the matter of creating a binding
 107 that on its RHS unboxes its arguments, performs the external call
 108 (using the @CCallOp@ primop), before boxing the result up and returning it.
 109
 110 However, we create a worker/wrapper pair, thus:
 111
 112         foreign import f :: Int -> IO Int
 113 ==>
 114         f x = IO ( \s -> case x of { I# x# ->
 115                          case fw s x# of { (# s1, y# #) ->
 116                          (# s1, I# y# #)}})
 117
 118         fw s x# = ccall f s x#
 119
 120 The strictness/CPR analyser won't do this automatically because it doesn't look
 121 inside returned tuples; but inlining this wrapper is a Really Good Idea
 122 because it exposes the boxing to the call site.
 123
 124
 125 \begin{code}
 126 dsFImport :: Id
 127           -> Type               -- Type of foreign import.
 128           -> Bool               -- True <=> might cause Haskell GC
 129           -> ExtName
 130           -> CallConv
 131           -> DsM [CoreBind]
 132 dsFImport fn_id ty may_not_gc ext_name cconv
 133   = let
 134         (tvs, fun_ty)        = splitForAllTys ty
 135         (arg_tys, io_res_ty) = splitFunTys fun_ty
 136     in
 137     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 138     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 139     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 140
 141     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 142     getUniqueDs                                         `thenDs` \ work_uniq ->
 143     let
 144         lbl = case ext_name of
 145                 Dynamic      -> dynamicTarget
 146                 ExtName fs _ -> StaticTarget fs
 147
 148         -- Build the worker
 149         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 150         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 151         the_ccall     = CCall lbl False (not may_not_gc) cconv
 152         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 153         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 154         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 155
 156         -- Build the wrapper
 157         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 158         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 159         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 160     in
 161     returnDs [NonRec fn_id wrap_rhs, NonRec work_id work_rhs]
 162 \end{code}
 163
 164 Foreign labels
 165
 166 \begin{code}
 167 dsFLabel :: Id -> Type -> ExtName -> DsM CoreBind
 168 dsFLabel nm ty ext_name =
 169    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 170    returnDs (NonRec nm (fo_rhs (mkLit (MachLabel enm))))
 171   where
 172    (res_ty, fo_rhs) = resultWrapper ty
 173    enm    = extNameStatic ext_name
 174 \end{code}
 175
 176 The function that does most of the work for `@foreign export@' declarations.
 177 (see below for the boilerplate code a `@foreign export@' declaration expands
 178  into.)
 179
 180 For each `@foreign export foo@' in a module M we generate:
 181 \begin{itemize}
 182 \item a C function `@foo@', which calls
 183 \item a Haskell stub `@M.$ffoo@', which calls
 184 \end{itemize}
 185 the user-written Haskell function `@M.foo@'.
 186
 187 \begin{code}
 188 dsFExport :: Id
 189           -> Type               -- Type of foreign export.
 190           -> Module
 191           -> ExtName
 192           -> CallConv
 193           -> Bool               -- True => invoke IO action that's hanging off
 194                                 -- the first argument's stable pointer
 195           -> DsM ( CoreBind
 196                  , SDoc
 197                  , SDoc
 198                  )
 199 dsFExport fn_id ty mod_name ext_name cconv isDyn
 200   =     -- BUILD THE returnIO WRAPPER, if necessary
 201         -- Look at the result type of the exported function, orig_res_ty
 202         -- If it's IO t, return         (\x.x,          IO t, t)
 203         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 204      (case splitTyConApp_maybe orig_res_ty of
 205         Just (ioTyCon, [res_ty])
 206               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 207                         -- The function already returns IO t
 208                  returnDs (\body -> body, orig_res_ty, res_ty)
 209
 210         other ->        -- The function returns t, so wrap the call in returnIO
 211                  dsLookupGlobalValue returnIOIdKey      `thenDs` \ retIOId ->
 212                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 213                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 214                                 -- We don't have ioTyCon conveniently to hand
 215                            orig_res_ty)
 216
 217      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 218                             io_res_ty,          -- IO t
 219                             res_ty) ->          -- t
 220
 221
 222         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 223      (if isDyn then
 224         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 225         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 226         dsLookupGlobalValue deRefStablePtrIdKey         `thenDs` \ deRefStablePtrId ->
 227         dsLookupGlobalValue bindIOIdKey                 `thenDs` \ bindIOId ->
 228         let
 229          the_deref_app = mkApps (Var deRefStablePtrId)
 230                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 231
 232          stbl_app cont = mkApps (Var bindIOId)
 233                                 [ Type stbl_ptr_to_ty
 234                                 , Type res_ty
 235                                 , the_deref_app
 236                                 , mkLams [stbl_value] cont]
 237         in
 238         returnDs (stbl_value, stbl_app, stbl_ptr)
 239       else
 240         returnDs (fn_id,
 241                   \ body -> body,
 242                   panic "stbl_ptr"  -- should never be touched.
 243                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 244
 245
 246         -- BUILD THE HELPER
 247      getModuleDs                        `thenDs` \ mod ->
 248      getUniqueDs                        `thenDs` \ uniq ->
 249      getSrcLocDs                        `thenDs` \ src_loc ->
 250      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 251      let
 252         wrapper_args | isDyn      = stbl_ptr:fe_args
 253                      | otherwise  = fe_args
 254
 255         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 256                         | otherwise  = fe_arg_tys
 257
 258         helper_ty =  mkForAllTys tvs $
 259                      mkFunTys wrapper_arg_tys io_res_ty
 260
 261         f_helper_glob = mkVanillaId helper_name helper_ty
 262                       where
 263                         name                = idName fn_id
 264                         mod
 265                          | isLocalName name = mod_name
 266                          | otherwise        = nameModule name
 267
 268                         occ                 = mkForeignExportOcc (nameOccName name)
 269                         prov                = LocalDef src_loc Exported
 270                         helper_name         = mkGlobalName uniq mod occ prov
 271
 272         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 273         the_body = mkLams (tvs ++ wrapper_args) the_app
 274         c_nm     = extNameStatic ext_name
 275
 276         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 277                                       c_nm f_helper_glob
 278                                       wrapper_arg_tys res_ty cconv isDyn
 279      in
 280      returnDs (NonRec f_helper_glob the_body, h_stub, c_stub)
 281
 282   where
 283    (tvs,sans_foralls)                   = splitForAllTys ty
 284    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 285
 286    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 287    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 288
 289    fe_arg_tys | isDyn     = tail fe_arg_tys'
 290               | otherwise = fe_arg_tys'
 291
 292    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 293                | otherwise = error "stbl_ptr_ty"
 294 \end{code}
 295
 296 @foreign export dynamic@ lets you dress up Haskell IO actions
 297 of some fixed type behind an externally callable interface (i.e.,
 298 as a C function pointer). Useful for callbacks and stuff.
 299
 300 \begin{verbatim}
 301 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 302
 303 -- Haskell-visible constructor, which is generated from the above:
 304 -- SUP: No check for NULL from createAdjustor anymore???
 305
 306 f :: (Addr -> Int -> IO Int) -> IO Addr
 307 f cback =
 308    bindIO (makeStablePtr cback)
 309           (\StablePtr sp# -> IO (\s1# ->
 310               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 311                  (# s2#, a# #) -> (# s2#, A# a# #)))
 312
 313 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 314 -- `special' foreign export that invokes the closure pointed to by the
 315 -- first argument.
 316 \end{verbatim}
 317
 318 \begin{code}
 319 dsFExportDynamic :: Id
 320                  -> Type                -- Type of foreign export.
 321                  -> Module
 322                  -> ExtName
 323                  -> CallConv
 324                  -> DsM (CoreBind, CoreBind, SDoc, SDoc)
 325 dsFExportDynamic i ty mod_name ext_name cconv =
 326      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 327      let
 328         -- hack: need to get at the name of the C stub we're about to generate.
 329        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 330        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 331      in
 332      dsFExport  i export_ty mod_name fe_ext_name cconv True
 333         `thenDs` \ (fe@(NonRec fe_helper fe_expr), h_code, c_code) ->
 334      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 335      dsLookupGlobalValue makeStablePtrIdKey     `thenDs` \ makeStablePtrId ->
 336      let
 337         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 338      in
 339      dsLookupGlobalValue bindIOIdKey                    `thenDs` \ bindIOId ->
 340      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 341      let
 342       stbl_app cont ret_ty
 343         = mkApps (Var bindIOId)
 344                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 345                  , Type ret_ty
 346                  , mk_stbl_ptr_app
 347                  , cont
 348                  ]
 349
 350        {-
 351         The arguments to the external function which will
 352         create a little bit of (template) code on the fly
 353         for allowing the (stable pointed) Haskell closure
 354         to be entered using an external calling convention
 355         (stdcall, ccall).
 356        -}
 357       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 358                       , Var stbl_value
 359                       , mkLit (MachLabel (_PK_ fe_nm))
 360                       ]
 361         -- name of external entry point providing these services.
 362         -- (probably in the RTS.)
 363       adjustor      = SLIT("createAdjustor")
 364      in
 365      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 366      let ccall_adj_ty = exprType ccall_adj
 367          ccall_io_adj = mkLams [stbl_value]                  $
 368                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 369                              ccall_adj
 370      in
 371      let io_app = mkLams tvs     $
 372                   mkLams [cback] $
 373                   stbl_app ccall_io_adj res_ty
 374      in
 375         -- Never inline the f.e.d. function, because the litlit might not be in scope
 376         -- in other modules.
 377      returnDs (NonRec (i `setInlinePragma` neverInlinePrag) io_app, fe, h_code, c_code)
 378
 379  where
 380   (tvs,sans_foralls)               = splitForAllTys ty
 381   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 382
 383   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 384
 385   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 386
 387   ioAddrTy :: Type      -- IO Addr
 388   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 389
 390 toCName :: Id -> String
 391 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 392 \end{code}
 393
 394 %*
 395 %
 396 \subsection{Generating @foreign export@ stubs}
 397 %
 398 %*
 399
 400 For each @foreign export@ function, a C stub function is generated.
 401 The C stub constructs the application of the exported Haskell function
 402 using the hugs/ghc rts invocation API.
 403
 404 \begin{code}
 405 fexportEntry :: String
 406              -> FAST_STRING
 407              -> Id
 408              -> [Type]
 409              -> Type
 410              -> CallConv
 411              -> Bool
 412              -> (SDoc, SDoc)
 413 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 414  where
 415    -- name of the (Haskell) helper function generated by the desugarer.
 416   h_nm      = ppr helper <> text "_closure"
 417    -- prototype for the exported function.
 418   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 419
 420   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 421               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 422
 423   c_bits =
 424     externDecl $$
 425     fun_proto  $$
 426     vcat
 427      [ lbrace
 428      ,   text "SchedulerStatus rc;"
 429      ,   declareResult
 430           -- create the application + perform it.
 431      ,   text "rc=rts_evalIO" <>
 432                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 433      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 434                                                 <> comma <> text "rc") <> semi
 435      ,   text "return" <> return_what <> semi
 436      , rbrace
 437      ]
 438
 439   appArg acc (a,c_a) =
 440      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 441
 442   cParamTypes  = map showStgType real_args
 443
 444   res_ty_is_unit = res_ty == unitTy
 445
 446   cResType | res_ty_is_unit = text "void"
 447            | otherwise      = showStgType res_ty
 448
 449   pprCconv
 450    | cc == cCallConv = empty
 451    | otherwise       = pprCallConv cc
 452
 453   declareResult  = text "HaskellObj ret;"
 454
 455   externDecl     = mkExtern (text "HaskellObj") h_nm
 456
 457   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 458
 459   return_what | res_ty_is_unit = empty
 460               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 461
 462   c_args = mkCArgNames 0 args
 463
 464   {-
 465    If we're generating an entry point for a 'foreign export ccall dynamic',
 466    then we receive the return address of the C function that wants to
 467    invoke a Haskell function as any other C function, as second arg.
 468    This arg is unused within the body of the generated C stub, but
 469    needed by the Adjustor.c code to get the stack cleanup right.
 470   -}
 471   (proto_args, real_args)
 472     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 473                                 , head args : addrTy : tail args)
 474     | otherwise = (mkCArgNames 0 args, args)
 475
 476 mkCArgNames :: Int -> [a] -> [SDoc]
 477 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 478
 479 mkHObj :: Type -> SDoc
 480 mkHObj t = text "rts_mk" <> text (showFFIType t)
 481
 482 unpackHObj :: Type -> SDoc
 483 unpackHObj t = text "rts_get" <> text (showFFIType t)
 484
 485 showStgType :: Type -> SDoc
 486 showStgType t = text "Stg" <> text (showFFIType t)
 487
 488 showFFIType :: Type -> String
 489 showFFIType t = getOccString (getName tc)
 490  where
 491   tc = case splitTyConApp_maybe (repType t) of
 492             Just (tc,_) -> tc
 493             Nothing     -> pprPanic "showFFIType" (ppr t)
 494 \end{code}