ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..),
  31                         )
  32 import Type             ( splitTyConApp_maybe, tyConAppTyCon, splitFunTys, splitForAllTys,
  33                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  34                           mkFunTy, splitAppTy, applyTy, funResultTy
  35                         )
  36 import PrimOp           ( CCall(..), CCallTarget(..), dynamicTarget )
  37 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon )
  38 import TysPrim          ( addrPrimTy )
  39 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  40                           bindIOName, returnIOName
  41                         )
  42 import Outputable
  43
  44 import Maybe            ( fromJust )
  45 \end{code}
  46
  47 Desugaring of @foreign@ declarations is naturally split up into
  48 parts, an @import@ and an @export@  part. A @foreign import@
  49 declaration
  50 \begin{verbatim}
  51   foreign import cc nm f :: prim_args -> IO prim_res
  52 \end{verbatim}
  53 is the same as
  54 \begin{verbatim}
  55   f :: prim_args -> IO prim_res
  56   f a1 ... an = _ccall_ nm cc a1 ... an
  57 \end{verbatim}
  58 so we reuse the desugaring code in @DsCCall@ to deal with these.
  59
  60 \begin{code}
  61 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  62                                 -- the occurrence analyser will sort it all out
  63
  64 dsForeigns :: Module
  65            -> [TypecheckedForeignDecl]
  66            -> DsM ( [Id]                -- Foreign-exported binders;
  67                                         -- we have to generate code to register these
  68                   , [Binding]
  69                   , SDoc              -- Header file prototypes for
  70                                       -- "foreign exported" functions.
  71                   , SDoc              -- C stubs to use when calling
  72                                       -- "foreign exported" functions.
  73                   )
  74 dsForeigns mod_name fos = foldlDs combine ([], [], empty, empty) fos
  75  where
  76   combine (acc_feb, acc_f, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  77     | isForeignImport =   -- foreign import (dynamic)?
  78         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  79         returnDs (acc_feb, bs ++ acc_f, acc_h, acc_c)
  80     | isForeignLabel =
  81         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  82         returnDs (acc_feb, b:acc_f, acc_h, acc_c)
  83     | isDynamicExtName ext_nm =
  84         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (feb,bs,h,c) ->
  85         returnDs (feb:acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  86
  87     | otherwise        =  -- foreign export
  88         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (feb,fe,h,c) ->
  89         returnDs (feb:acc_feb, fe:acc_f, h $$ acc_h, c $$ acc_c)
  90    where
  91     isForeignImport =
  92         case imp_exp of
  93           FoImport _ -> True
  94           _          -> False
  95
  96     isForeignLabel =
  97         case imp_exp of
  98           FoLabel -> True
  99           _       -> False
 100
 101     (FoImport uns)   = imp_exp
 102
 103 \end{code}
 104
 105 Desugaring foreign imports is just the matter of creating a binding
 106 that on its RHS unboxes its arguments, performs the external call
 107 (using the @CCallOp@ primop), before boxing the result up and returning it.
 108
 109 However, we create a worker/wrapper pair, thus:
 110
 111         foreign import f :: Int -> IO Int
 112 ==>
 113         f x = IO ( \s -> case x of { I# x# ->
 114                          case fw s x# of { (# s1, y# #) ->
 115                          (# s1, I# y# #)}})
 116
 117         fw s x# = ccall f s x#
 118
 119 The strictness/CPR analyser won't do this automatically because it doesn't look
 120 inside returned tuples; but inlining this wrapper is a Really Good Idea
 121 because it exposes the boxing to the call site.
 122
 123
 124 \begin{code}
 125 dsFImport :: Id
 126           -> Type               -- Type of foreign import.
 127           -> Bool               -- True <=> might cause Haskell GC
 128           -> ExtName
 129           -> CallConv
 130           -> DsM [Binding]
 131 dsFImport fn_id ty may_not_gc ext_name cconv
 132   = let
 133         (tvs, fun_ty)        = splitForAllTys ty
 134         (arg_tys, io_res_ty) = splitFunTys fun_ty
 135     in
 136     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 137     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 138     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 139
 140     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 141     getUniqueDs                                         `thenDs` \ work_uniq ->
 142     let
 143         lbl = case ext_name of
 144                 Dynamic      -> dynamicTarget
 145                 ExtName fs _ -> StaticTarget fs
 146
 147         -- Build the worker
 148         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 149         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 150         the_ccall     = CCall lbl False (not may_not_gc) cconv
 151         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 152         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 153         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 154
 155         -- Build the wrapper
 156         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 157         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 158         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 159     in
 160     returnDs [(work_id, work_rhs), (fn_id, wrap_rhs)]
 161 \end{code}
 162
 163 Foreign labels
 164
 165 \begin{code}
 166 dsFLabel :: Id -> Type -> ExtName -> DsM Binding
 167 dsFLabel nm ty ext_name =
 168    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 169    returnDs (nm, fo_rhs (mkLit (MachLabel enm)))
 170   where
 171    (res_ty, fo_rhs) = resultWrapper ty
 172    enm    = extNameStatic ext_name
 173 \end{code}
 174
 175 The function that does most of the work for `@foreign export@' declarations.
 176 (see below for the boilerplate code a `@foreign export@' declaration expands
 177  into.)
 178
 179 For each `@foreign export foo@' in a module M we generate:
 180 \begin{itemize}
 181 \item a C function `@foo@', which calls
 182 \item a Haskell stub `@M.$ffoo@', which calls
 183 \end{itemize}
 184 the user-written Haskell function `@M.foo@'.
 185
 186 \begin{code}
 187 dsFExport :: Id
 188           -> Type               -- Type of foreign export.
 189           -> Module
 190           -> ExtName
 191           -> CallConv
 192           -> Bool               -- True => invoke IO action that's hanging off
 193                                 -- the first argument's stable pointer
 194           -> DsM ( Id           -- The foreign-exported Id
 195                  , Binding
 196                  , SDoc
 197                  , SDoc
 198                  )
 199 dsFExport fn_id ty mod_name ext_name cconv isDyn
 200   =     -- BUILD THE returnIO WRAPPER, if necessary
 201         -- Look at the result type of the exported function, orig_res_ty
 202         -- If it's IO t, return         (\x.x,          IO t, t)
 203         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 204      (case splitTyConApp_maybe orig_res_ty of
 205         Just (ioTyCon, [res_ty])
 206               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 207                         -- The function already returns IO t
 208                  returnDs (\body -> body, orig_res_ty, res_ty)
 209
 210         other ->        -- The function returns t, so wrap the call in returnIO
 211                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 212                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 213                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 214                                 -- We don't have ioTyCon conveniently to hand
 215                            orig_res_ty)
 216
 217      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 218                             io_res_ty,          -- IO t
 219                             res_ty) ->          -- t
 220
 221
 222         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 223      (if isDyn then
 224         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 225         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 226         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 227         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 228         let
 229          the_deref_app = mkApps (Var deRefStablePtrId)
 230                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 231
 232          stbl_app cont = mkApps (Var bindIOId)
 233                                 [ Type stbl_ptr_to_ty
 234                                 , Type res_ty
 235                                 , the_deref_app
 236                                 , mkLams [stbl_value] cont]
 237         in
 238         returnDs (stbl_value, stbl_app, stbl_ptr)
 239       else
 240         returnDs (fn_id,
 241                   \ body -> body,
 242                   panic "stbl_ptr"  -- should never be touched.
 243                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 244
 245
 246         -- BUILD THE HELPER
 247      getModuleDs                        `thenDs` \ mod ->
 248      getUniqueDs                        `thenDs` \ uniq ->
 249      getSrcLocDs                        `thenDs` \ src_loc ->
 250      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 251      let
 252         wrapper_args | isDyn      = stbl_ptr:fe_args
 253                      | otherwise  = fe_args
 254
 255         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 256                         | otherwise  = fe_arg_tys
 257
 258         helper_ty =  mkForAllTys tvs $
 259                      mkFunTys wrapper_arg_tys io_res_ty
 260
 261         f_helper_glob = mkVanillaId helper_name helper_ty
 262                       where
 263                         name                = idName fn_id
 264                         mod
 265                          | isLocalName name = mod_name
 266                          | otherwise        = nameModule name
 267
 268                         occ                 = mkForeignExportOcc (nameOccName name)
 269                         helper_name         = mkGlobalName uniq mod occ src_loc
 270
 271         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 272         the_body = mkLams (tvs ++ wrapper_args) the_app
 273         c_nm     = extNameStatic ext_name
 274
 275         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 276                                       c_nm f_helper_glob
 277                                       wrapper_arg_tys res_ty cconv isDyn
 278      in
 279      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 280
 281   where
 282    (tvs,sans_foralls)                   = splitForAllTys ty
 283    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 284
 285    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 286    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 287
 288    fe_arg_tys | isDyn     = tail fe_arg_tys'
 289               | otherwise = fe_arg_tys'
 290
 291    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 292                | otherwise = error "stbl_ptr_ty"
 293 \end{code}
 294
 295 @foreign export dynamic@ lets you dress up Haskell IO actions
 296 of some fixed type behind an externally callable interface (i.e.,
 297 as a C function pointer). Useful for callbacks and stuff.
 298
 299 \begin{verbatim}
 300 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 301
 302 -- Haskell-visible constructor, which is generated from the above:
 303 -- SUP: No check for NULL from createAdjustor anymore???
 304
 305 f :: (Addr -> Int -> IO Int) -> IO Addr
 306 f cback =
 307    bindIO (newStablePtr cback)
 308           (\StablePtr sp# -> IO (\s1# ->
 309               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 310                  (# s2#, a# #) -> (# s2#, A# a# #)))
 311
 312 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 313 -- `special' foreign export that invokes the closure pointed to by the
 314 -- first argument.
 315 \end{verbatim}
 316
 317 \begin{code}
 318 dsFExportDynamic :: Id
 319                  -> Type                -- Type of foreign export.
 320                  -> Module
 321                  -> ExtName
 322                  -> CallConv
 323                  -> DsM (Id, [Binding], SDoc, SDoc)
 324 dsFExportDynamic i ty mod_name ext_name cconv =
 325      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 326      let
 327         -- hack: need to get at the name of the C stub we're about to generate.
 328        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 329        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 330      in
 331      dsFExport  i export_ty mod_name fe_ext_name cconv True
 332         `thenDs` \ (feb, fe, h_code, c_code) ->
 333      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 334      dsLookupGlobalValue newStablePtrName       `thenDs` \ newStablePtrId ->
 335      let
 336         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 337      in
 338      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 339      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 340      let
 341       stbl_app cont ret_ty
 342         = mkApps (Var bindIOId)
 343                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 344                  , Type ret_ty
 345                  , mk_stbl_ptr_app
 346                  , cont
 347                  ]
 348
 349        {-
 350         The arguments to the external function which will
 351         create a little bit of (template) code on the fly
 352         for allowing the (stable pointed) Haskell closure
 353         to be entered using an external calling convention
 354         (stdcall, ccall).
 355        -}
 356       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 357                       , Var stbl_value
 358                       , mkLit (MachLabel (_PK_ fe_nm))
 359                       ]
 360         -- name of external entry point providing these services.
 361         -- (probably in the RTS.)
 362       adjustor      = SLIT("createAdjustor")
 363      in
 364      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 365      let ccall_adj_ty = exprType ccall_adj
 366          ccall_io_adj = mkLams [stbl_value]                  $
 367                         Note (Coerce io_res_ty ccall_adj_ty)
 368                              ccall_adj
 369      in
 370      let io_app = mkLams tvs     $
 371                   mkLams [cback] $
 372                   stbl_app ccall_io_adj res_ty
 373          fed = (i `setInlinePragma` neverInlinePrag, io_app)
 374                 -- Never inline the f.e.d. function, because the litlit
 375                 -- might not be in scope in other modules.
 376      in
 377      returnDs (feb, [fed, fe], h_code, c_code)
 378
 379  where
 380   (tvs,sans_foralls)               = splitForAllTys ty
 381   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 382
 383   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 384
 385   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 386
 387   ioAddrTy :: Type      -- IO Addr
 388   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 389
 390 toCName :: Id -> String
 391 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 392 \end{code}
 393
 394 %*
 395 %
 396 \subsection{Generating @foreign export@ stubs}
 397 %
 398 %*
 399
 400 For each @foreign export@ function, a C stub function is generated.
 401 The C stub constructs the application of the exported Haskell function
 402 using the hugs/ghc rts invocation API.
 403
 404 \begin{code}
 405 fexportEntry :: String
 406              -> FAST_STRING
 407              -> Id
 408              -> [Type]
 409              -> Type
 410              -> CallConv
 411              -> Bool
 412              -> (SDoc, SDoc)
 413 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 414  where
 415    -- name of the (Haskell) helper function generated by the desugarer.
 416   h_nm      = ppr helper <> text "_closure"
 417    -- prototype for the exported function.
 418   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 419
 420   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 421               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 422
 423   c_bits =
 424     externDecl $$
 425     fun_proto  $$
 426     vcat
 427      [ lbrace
 428      ,   text "SchedulerStatus rc;"
 429      ,   declareResult
 430           -- create the application + perform it.
 431      ,   text "rc=rts_evalIO" <>
 432                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 433      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 434                                                 <> comma <> text "rc") <> semi
 435      ,   text "return" <> return_what <> semi
 436      , rbrace
 437      ]
 438
 439   appArg acc (a,c_a) =
 440      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 441
 442   cParamTypes  = map showStgType real_args
 443
 444   res_ty_is_unit = res_ty == unitTy
 445
 446   cResType | res_ty_is_unit = text "void"
 447            | otherwise      = showStgType res_ty
 448
 449   pprCconv
 450    | cc == cCallConv = empty
 451    | otherwise       = pprCallConv cc
 452
 453   declareResult  = text "HaskellObj ret;"
 454
 455   externDecl     = mkExtern (text "HaskellObj") h_nm
 456
 457   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 458
 459   return_what | res_ty_is_unit = empty
 460               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 461
 462   c_args = mkCArgNames 0 args
 463
 464   {-
 465    If we're generating an entry point for a 'foreign export ccall dynamic',
 466    then we receive the return address of the C function that wants to
 467    invoke a Haskell function as any other C function, as second arg.
 468    This arg is unused within the body of the generated C stub, but
 469    needed by the Adjustor.c code to get the stack cleanup right.
 470   -}
 471   (proto_args, real_args)
 472     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 473                                 , head args : addrTy : tail args)
 474     | otherwise = (mkCArgNames 0 args, args)
 475
 476 mkCArgNames :: Int -> [a] -> [SDoc]
 477 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 478
 479 mkHObj :: Type -> SDoc
 480 mkHObj t = text "rts_mk" <> text (showFFIType t)
 481
 482 unpackHObj :: Type -> SDoc
 483 unpackHObj t = text "rts_get" <> text (showFFIType t)
 484
 485 showStgType :: Type -> SDoc
 486 showStgType t = text "Hs" <> text (showFFIType t)
 487
 488 showFFIType :: Type -> String
 489 showFFIType t = getOccString (getName (tyConAppTyCon t))
 490 \end{code}