ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaGlobal, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag, vanillaIdInfo )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..),
  31                         )
  32 import Type             ( repType, splitTyConApp_maybe,
  33                           splitFunTys, splitForAllTys,
  34                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkFunTy, splitAppTy, applyTy, funResultTy
  36                         )
  37 import PrimOp           ( CCall(..), CCallTarget(..), dynamicTarget )
  38 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon )
  39 import TysPrim          ( addrPrimTy )
  40 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  41                           bindIOName, returnIOName
  42                         )
  43 import Outputable
  44
  45 import Maybe            ( fromJust )
  46 \end{code}
  47
  48 Desugaring of @foreign@ declarations is naturally split up into
  49 parts, an @import@ and an @export@  part. A @foreign import@
  50 declaration
  51 \begin{verbatim}
  52   foreign import cc nm f :: prim_args -> IO prim_res
  53 \end{verbatim}
  54 is the same as
  55 \begin{verbatim}
  56   f :: prim_args -> IO prim_res
  57   f a1 ... an = _ccall_ nm cc a1 ... an
  58 \end{verbatim}
  59 so we reuse the desugaring code in @DsCCall@ to deal with these.
  60
  61 \begin{code}
  62 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  63                                 -- the occurrence analyser will sort it all out
  64
  65 dsForeigns :: Module
  66            -> [TypecheckedForeignDecl]
  67            -> DsM ( [Id]                -- Foreign-exported binders;
  68                                         -- we have to generate code to register these
  69                   , [Binding]
  70                   , SDoc              -- Header file prototypes for
  71                                       -- "foreign exported" functions.
  72                   , SDoc              -- C stubs to use when calling
  73                                       -- "foreign exported" functions.
  74                   )
  75 dsForeigns mod_name fos = foldlDs combine ([], [], empty, empty) fos
  76  where
  77   combine (acc_feb, acc_f, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  78     | isForeignImport =   -- foreign import (dynamic)?
  79         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  80         returnDs (acc_feb, bs ++ acc_f, acc_h, acc_c)
  81     | isForeignLabel =
  82         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  83         returnDs (acc_feb, b:acc_f, acc_h, acc_c)
  84     | isDynamicExtName ext_nm =
  85         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (feb,bs,h,c) ->
  86         returnDs (feb:acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  87
  88     | otherwise        =  -- foreign export
  89         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (feb,fe,h,c) ->
  90         returnDs (feb:acc_feb, fe:acc_f, h $$ acc_h, c $$ acc_c)
  91    where
  92     isForeignImport =
  93         case imp_exp of
  94           FoImport _ -> True
  95           _          -> False
  96
  97     isForeignLabel =
  98         case imp_exp of
  99           FoLabel -> True
 100           _       -> False
 101
 102     (FoImport uns)   = imp_exp
 103
 104 \end{code}
 105
 106 Desugaring foreign imports is just the matter of creating a binding
 107 that on its RHS unboxes its arguments, performs the external call
 108 (using the @CCallOp@ primop), before boxing the result up and returning it.
 109
 110 However, we create a worker/wrapper pair, thus:
 111
 112         foreign import f :: Int -> IO Int
 113 ==>
 114         f x = IO ( \s -> case x of { I# x# ->
 115                          case fw s x# of { (# s1, y# #) ->
 116                          (# s1, I# y# #)}})
 117
 118         fw s x# = ccall f s x#
 119
 120 The strictness/CPR analyser won't do this automatically because it doesn't look
 121 inside returned tuples; but inlining this wrapper is a Really Good Idea
 122 because it exposes the boxing to the call site.
 123
 124
 125 \begin{code}
 126 dsFImport :: Id
 127           -> Type               -- Type of foreign import.
 128           -> Bool               -- True <=> cannot re-enter the Haskell RTS
 129           -> ExtName
 130           -> CallConv
 131           -> DsM [Binding]
 132 dsFImport fn_id ty unsafe ext_name cconv
 133   = let
 134         (tvs, fun_ty)        = splitForAllTys ty
 135         (arg_tys, io_res_ty) = splitFunTys fun_ty
 136     in
 137     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 138     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 139
 140     let
 141         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 142
 143         -- these are the ids we pass to boxResult, which are used to decide
 144         -- whether to touch# an argument after the call (used to keep
 145         -- ForeignObj#s live across a 'safe' foreign import).
 146         maybe_arg_ids | unsafe    = []
 147                       | otherwise = work_arg_ids
 148     in
 149     boxResult work_arg_ids io_res_ty            `thenDs` \ (ccall_result_ty, res_wrapper) ->
 150
 151     getUniqueDs                                 `thenDs` \ ccall_uniq ->
 152     getUniqueDs                                 `thenDs` \ work_uniq ->
 153     let
 154         lbl = case ext_name of
 155                 Dynamic      -> dynamicTarget
 156                 ExtName fs _ -> StaticTarget fs
 157
 158         -- Build the worker
 159         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 160         the_ccall     = CCall lbl False (not unsafe) cconv
 161         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 162         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 163         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 164
 165         -- Build the wrapper
 166         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 167         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 168         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 169     in
 170     returnDs [(work_id, work_rhs), (fn_id, wrap_rhs)]
 171 \end{code}
 172
 173 Foreign labels
 174
 175 \begin{code}
 176 dsFLabel :: Id -> Type -> ExtName -> DsM Binding
 177 dsFLabel nm ty ext_name =
 178    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 179    returnDs (nm, fo_rhs (mkLit (MachLabel enm)))
 180   where
 181    (res_ty, fo_rhs) = resultWrapper ty
 182    enm    = extNameStatic ext_name
 183 \end{code}
 184
 185 The function that does most of the work for `@foreign export@' declarations.
 186 (see below for the boilerplate code a `@foreign export@' declaration expands
 187  into.)
 188
 189 For each `@foreign export foo@' in a module M we generate:
 190 \begin{itemize}
 191 \item a C function `@foo@', which calls
 192 \item a Haskell stub `@M.$ffoo@', which calls
 193 \end{itemize}
 194 the user-written Haskell function `@M.foo@'.
 195
 196 \begin{code}
 197 dsFExport :: Id
 198           -> Type               -- Type of foreign export.
 199           -> Module
 200           -> ExtName
 201           -> CallConv
 202           -> Bool               -- True => invoke IO action that's hanging off
 203                                 -- the first argument's stable pointer
 204           -> DsM ( Id           -- The foreign-exported Id
 205                  , Binding
 206                  , SDoc
 207                  , SDoc
 208                  )
 209 dsFExport fn_id ty mod_name ext_name cconv isDyn
 210   =     -- BUILD THE returnIO WRAPPER, if necessary
 211         -- Look at the result type of the exported function, orig_res_ty
 212         -- If it's IO t, return         (\x.x,          IO t, t)
 213         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 214      (case splitTyConApp_maybe orig_res_ty of
 215         Just (ioTyCon, [res_ty])
 216               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 217                         -- The function already returns IO t
 218                  returnDs (\body -> body, orig_res_ty, res_ty)
 219
 220         other ->        -- The function returns t, so wrap the call in returnIO
 221                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 222                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 223                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 224                                 -- We don't have ioTyCon conveniently to hand
 225                            orig_res_ty)
 226
 227      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 228                             io_res_ty,          -- IO t
 229                             res_ty) ->          -- t
 230
 231
 232         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 233      (if isDyn then
 234         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 235         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 236         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 237         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 238         let
 239          the_deref_app = mkApps (Var deRefStablePtrId)
 240                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 241
 242          stbl_app cont = mkApps (Var bindIOId)
 243                                 [ Type stbl_ptr_to_ty
 244                                 , Type res_ty
 245                                 , the_deref_app
 246                                 , mkLams [stbl_value] cont]
 247         in
 248         returnDs (stbl_value, stbl_app, stbl_ptr)
 249       else
 250         returnDs (fn_id,
 251                   \ body -> body,
 252                   panic "stbl_ptr"  -- should never be touched.
 253                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 254
 255
 256         -- BUILD THE HELPER
 257      getModuleDs                        `thenDs` \ mod ->
 258      getUniqueDs                        `thenDs` \ uniq ->
 259      getSrcLocDs                        `thenDs` \ src_loc ->
 260      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 261      let
 262         wrapper_args | isDyn      = stbl_ptr:fe_args
 263                      | otherwise  = fe_args
 264
 265         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 266                         | otherwise  = fe_arg_tys
 267
 268         helper_ty =  mkForAllTys tvs $
 269                      mkFunTys wrapper_arg_tys io_res_ty
 270
 271         f_helper_glob = mkVanillaGlobal helper_name helper_ty vanillaIdInfo
 272                       where
 273                         name                = idName fn_id
 274                         mod
 275                          | isLocalName name = mod_name
 276                          | otherwise        = nameModule name
 277
 278                         occ                 = mkForeignExportOcc (nameOccName name)
 279                         helper_name         = mkGlobalName uniq mod occ src_loc
 280
 281         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 282         the_body = mkLams (tvs ++ wrapper_args) the_app
 283         c_nm     = extNameStatic ext_name
 284
 285         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 286                                       c_nm f_helper_glob
 287                                       wrapper_arg_tys res_ty cconv isDyn
 288      in
 289      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 290
 291   where
 292    (tvs,sans_foralls)                   = splitForAllTys ty
 293    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 294
 295    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 296    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 297
 298    fe_arg_tys | isDyn     = tail fe_arg_tys'
 299               | otherwise = fe_arg_tys'
 300
 301    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 302                | otherwise = error "stbl_ptr_ty"
 303 \end{code}
 304
 305 @foreign export dynamic@ lets you dress up Haskell IO actions
 306 of some fixed type behind an externally callable interface (i.e.,
 307 as a C function pointer). Useful for callbacks and stuff.
 308
 309 \begin{verbatim}
 310 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 311
 312 -- Haskell-visible constructor, which is generated from the above:
 313 -- SUP: No check for NULL from createAdjustor anymore???
 314
 315 f :: (Addr -> Int -> IO Int) -> IO Addr
 316 f cback =
 317    bindIO (newStablePtr cback)
 318           (\StablePtr sp# -> IO (\s1# ->
 319               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 320                  (# s2#, a# #) -> (# s2#, A# a# #)))
 321
 322 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 323 -- `special' foreign export that invokes the closure pointed to by the
 324 -- first argument.
 325 \end{verbatim}
 326
 327 \begin{code}
 328 dsFExportDynamic :: Id
 329                  -> Type                -- Type of foreign export.
 330                  -> Module
 331                  -> ExtName
 332                  -> CallConv
 333                  -> DsM (Id, [Binding], SDoc, SDoc)
 334 dsFExportDynamic i ty mod_name ext_name cconv =
 335      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 336      let
 337         -- hack: need to get at the name of the C stub we're about to generate.
 338        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 339        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 340      in
 341      dsFExport  i export_ty mod_name fe_ext_name cconv True
 342         `thenDs` \ (feb, fe, h_code, c_code) ->
 343      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 344      dsLookupGlobalValue newStablePtrName       `thenDs` \ newStablePtrId ->
 345      let
 346         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 347      in
 348      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 349      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 350      let
 351       stbl_app cont ret_ty
 352         = mkApps (Var bindIOId)
 353                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 354                  , Type ret_ty
 355                  , mk_stbl_ptr_app
 356                  , cont
 357                  ]
 358
 359        {-
 360         The arguments to the external function which will
 361         create a little bit of (template) code on the fly
 362         for allowing the (stable pointed) Haskell closure
 363         to be entered using an external calling convention
 364         (stdcall, ccall).
 365        -}
 366       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 367                       , Var stbl_value
 368                       , mkLit (MachLabel (_PK_ fe_nm))
 369                       ]
 370         -- name of external entry point providing these services.
 371         -- (probably in the RTS.)
 372       adjustor      = SLIT("createAdjustor")
 373      in
 374      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 375      let ccall_adj_ty = exprType ccall_adj
 376          ccall_io_adj = mkLams [stbl_value]                  $
 377                         Note (Coerce io_res_ty ccall_adj_ty)
 378                              ccall_adj
 379      in
 380      let io_app = mkLams tvs     $
 381                   mkLams [cback] $
 382                   stbl_app ccall_io_adj res_ty
 383          fed = (i `setInlinePragma` neverInlinePrag, io_app)
 384                 -- Never inline the f.e.d. function, because the litlit
 385                 -- might not be in scope in other modules.
 386      in
 387      returnDs (feb, [fed, fe], h_code, c_code)
 388
 389  where
 390   (tvs,sans_foralls)               = splitForAllTys ty
 391   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 392
 393   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 394
 395   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 396
 397   ioAddrTy :: Type      -- IO Addr
 398   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 399
 400 toCName :: Id -> String
 401 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 402 \end{code}
 403
 404 %*
 405 %
 406 \subsection{Generating @foreign export@ stubs}
 407 %
 408 %*
 409
 410 For each @foreign export@ function, a C stub function is generated.
 411 The C stub constructs the application of the exported Haskell function
 412 using the hugs/ghc rts invocation API.
 413
 414 \begin{code}
 415 fexportEntry :: String
 416              -> FAST_STRING
 417              -> Id
 418              -> [Type]
 419              -> Type
 420              -> CallConv
 421              -> Bool
 422              -> (SDoc, SDoc)
 423 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 424  where
 425    -- name of the (Haskell) helper function generated by the desugarer.
 426   h_nm      = ppr helper <> text "_closure"
 427    -- prototype for the exported function.
 428   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 429
 430   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 431               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 432
 433   c_bits =
 434     externDecl $$
 435     fun_proto  $$
 436     vcat
 437      [ lbrace
 438      ,   text "SchedulerStatus rc;"
 439      ,   declareResult
 440           -- create the application + perform it.
 441      ,   text "rc=rts_evalIO" <>
 442                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 443      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 444                                                 <> comma <> text "rc") <> semi
 445      ,   text "return" <> return_what <> semi
 446      , rbrace
 447      ]
 448
 449   appArg acc (a,c_a) =
 450      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 451
 452   cParamTypes  = map showStgType real_args
 453
 454   res_ty_is_unit = res_ty == unitTy
 455
 456   cResType | res_ty_is_unit = text "void"
 457            | otherwise      = showStgType res_ty
 458
 459   pprCconv
 460    | cc == cCallConv = empty
 461    | otherwise       = pprCallConv cc
 462
 463   declareResult  = text "HaskellObj ret;"
 464
 465   externDecl     = mkExtern (text "HaskellObj") h_nm
 466
 467   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 468
 469   return_what | res_ty_is_unit = empty
 470               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 471
 472   c_args = mkCArgNames 0 args
 473
 474   {-
 475    If we're generating an entry point for a 'foreign export ccall dynamic',
 476    then we receive the return address of the C function that wants to
 477    invoke a Haskell function as any other C function, as second arg.
 478    This arg is unused within the body of the generated C stub, but
 479    needed by the Adjustor.c code to get the stack cleanup right.
 480   -}
 481   (proto_args, real_args)
 482     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 483                                 , head args : addrTy : tail args)
 484     | otherwise = (mkCArgNames 0 args, args)
 485
 486 mkCArgNames :: Int -> [a] -> [SDoc]
 487 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 488
 489 mkHObj :: Type -> SDoc
 490 mkHObj t = text "rts_mk" <> text (showFFIType t)
 491
 492 unpackHObj :: Type -> SDoc
 493 unpackHObj t = text "rts_get" <> text (showFFIType t)
 494
 495 showStgType :: Type -> SDoc
 496 showStgType t = text "Hs" <> text (showFFIType t)
 497
 498 showFFIType :: Type -> String
 499 showFFIType t = getOccString (getName tc)
 500  where
 501   tc = case splitTyConApp_maybe (repType t) of
 502             Just (tc,_) -> tc
 503             Nothing     -> pprPanic "showFFIType" (ppr t)
 504 \end{code}