ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag, vanillaIdInfo, IdFlavour(..),
  26                           setFlavourInfo )
  27 import Literal          ( Literal(..) )
  28 import Module           ( Module, moduleUserString )
  29 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  30                           mkForeignExportOcc, isLocalName,
  31                           NamedThing(..),
  32                         )
  33 import Type             ( repType, splitTyConApp_maybe,
  34                           tyConAppTyCon, splitFunTys, splitForAllTys,
  35                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  36                           mkFunTy, splitAppTy, applyTy, funResultTy
  37                         )
  38 import PrimOp           ( CCall(..), CCallTarget(..), dynamicTarget )
  39 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon )
  40 import TysPrim          ( addrPrimTy )
  41 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  42                           bindIOName, returnIOName
  43                         )
  44 import Outputable
  45
  46 import Maybe            ( fromJust )
  47 \end{code}
  48
  49 Desugaring of @foreign@ declarations is naturally split up into
  50 parts, an @import@ and an @export@  part. A @foreign import@
  51 declaration
  52 \begin{verbatim}
  53   foreign import cc nm f :: prim_args -> IO prim_res
  54 \end{verbatim}
  55 is the same as
  56 \begin{verbatim}
  57   f :: prim_args -> IO prim_res
  58   f a1 ... an = _ccall_ nm cc a1 ... an
  59 \end{verbatim}
  60 so we reuse the desugaring code in @DsCCall@ to deal with these.
  61
  62 \begin{code}
  63 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  64                                 -- the occurrence analyser will sort it all out
  65
  66 dsForeigns :: Module
  67            -> [TypecheckedForeignDecl]
  68            -> DsM ( [Id]                -- Foreign-exported binders;
  69                                         -- we have to generate code to register these
  70                   , [Binding]
  71                   , SDoc              -- Header file prototypes for
  72                                       -- "foreign exported" functions.
  73                   , SDoc              -- C stubs to use when calling
  74                                       -- "foreign exported" functions.
  75                   )
  76 dsForeigns mod_name fos = foldlDs combine ([], [], empty, empty) fos
  77  where
  78   combine (acc_feb, acc_f, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  79     | isForeignImport =   -- foreign import (dynamic)?
  80         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  81         returnDs (acc_feb, bs ++ acc_f, acc_h, acc_c)
  82     | isForeignLabel =
  83         dsFLabel i (idType i) ext_nm `thenDs` \ b ->
  84         returnDs (acc_feb, b:acc_f, acc_h, acc_c)
  85     | isDynamicExtName ext_nm =
  86         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (feb,bs,h,c) ->
  87         returnDs (feb:acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  88
  89     | otherwise        =  -- foreign export
  90         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (feb,fe,h,c) ->
  91         returnDs (feb:acc_feb, fe:acc_f, h $$ acc_h, c $$ acc_c)
  92    where
  93     isForeignImport =
  94         case imp_exp of
  95           FoImport _ -> True
  96           _          -> False
  97
  98     isForeignLabel =
  99         case imp_exp of
 100           FoLabel -> True
 101           _       -> False
 102
 103     (FoImport uns)   = imp_exp
 104
 105 \end{code}
 106
 107 Desugaring foreign imports is just the matter of creating a binding
 108 that on its RHS unboxes its arguments, performs the external call
 109 (using the @CCallOp@ primop), before boxing the result up and returning it.
 110
 111 However, we create a worker/wrapper pair, thus:
 112
 113         foreign import f :: Int -> IO Int
 114 ==>
 115         f x = IO ( \s -> case x of { I# x# ->
 116                          case fw s x# of { (# s1, y# #) ->
 117                          (# s1, I# y# #)}})
 118
 119         fw s x# = ccall f s x#
 120
 121 The strictness/CPR analyser won't do this automatically because it doesn't look
 122 inside returned tuples; but inlining this wrapper is a Really Good Idea
 123 because it exposes the boxing to the call site.
 124
 125
 126 \begin{code}
 127 dsFImport :: Id
 128           -> Type               -- Type of foreign import.
 129           -> Bool               -- True <=> might cause Haskell GC
 130           -> ExtName
 131           -> CallConv
 132           -> DsM [Binding]
 133 dsFImport fn_id ty may_not_gc ext_name cconv
 134   = let
 135         (tvs, fun_ty)        = splitForAllTys ty
 136         (arg_tys, io_res_ty) = splitFunTys fun_ty
 137     in
 138     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 139     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 140     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 141
 142     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 143     getUniqueDs                                         `thenDs` \ work_uniq ->
 144     let
 145         lbl = case ext_name of
 146                 Dynamic      -> dynamicTarget
 147                 ExtName fs _ -> StaticTarget fs
 148
 149         -- Build the worker
 150         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 151         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 152         the_ccall     = CCall lbl False (not may_not_gc) cconv
 153         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 154         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 155         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 156
 157         -- Build the wrapper
 158         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 159         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 160         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 161     in
 162     returnDs [(work_id, work_rhs), (fn_id, wrap_rhs)]
 163 \end{code}
 164
 165 Foreign labels
 166
 167 \begin{code}
 168 dsFLabel :: Id -> Type -> ExtName -> DsM Binding
 169 dsFLabel nm ty ext_name =
 170    ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 171    returnDs (nm, fo_rhs (mkLit (MachLabel enm)))
 172   where
 173    (res_ty, fo_rhs) = resultWrapper ty
 174    enm    = extNameStatic ext_name
 175 \end{code}
 176
 177 The function that does most of the work for `@foreign export@' declarations.
 178 (see below for the boilerplate code a `@foreign export@' declaration expands
 179  into.)
 180
 181 For each `@foreign export foo@' in a module M we generate:
 182 \begin{itemize}
 183 \item a C function `@foo@', which calls
 184 \item a Haskell stub `@M.$ffoo@', which calls
 185 \end{itemize}
 186 the user-written Haskell function `@M.foo@'.
 187
 188 \begin{code}
 189 dsFExport :: Id
 190           -> Type               -- Type of foreign export.
 191           -> Module
 192           -> ExtName
 193           -> CallConv
 194           -> Bool               -- True => invoke IO action that's hanging off
 195                                 -- the first argument's stable pointer
 196           -> DsM ( Id           -- The foreign-exported Id
 197                  , Binding
 198                  , SDoc
 199                  , SDoc
 200                  )
 201 dsFExport fn_id ty mod_name ext_name cconv isDyn
 202   =     -- BUILD THE returnIO WRAPPER, if necessary
 203         -- Look at the result type of the exported function, orig_res_ty
 204         -- If it's IO t, return         (\x.x,          IO t, t)
 205         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 206      (case splitTyConApp_maybe orig_res_ty of
 207         Just (ioTyCon, [res_ty])
 208               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 209                         -- The function already returns IO t
 210                  returnDs (\body -> body, orig_res_ty, res_ty)
 211
 212         other ->        -- The function returns t, so wrap the call in returnIO
 213                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 214                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 215                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 216                                 -- We don't have ioTyCon conveniently to hand
 217                            orig_res_ty)
 218
 219      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 220                             io_res_ty,          -- IO t
 221                             res_ty) ->          -- t
 222
 223
 224         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 225      (if isDyn then
 226         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 227         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 228         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 229         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 230         let
 231          the_deref_app = mkApps (Var deRefStablePtrId)
 232                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 233
 234          stbl_app cont = mkApps (Var bindIOId)
 235                                 [ Type stbl_ptr_to_ty
 236                                 , Type res_ty
 237                                 , the_deref_app
 238                                 , mkLams [stbl_value] cont]
 239         in
 240         returnDs (stbl_value, stbl_app, stbl_ptr)
 241       else
 242         returnDs (fn_id,
 243                   \ body -> body,
 244                   panic "stbl_ptr"  -- should never be touched.
 245                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 246
 247
 248         -- BUILD THE HELPER
 249      getModuleDs                        `thenDs` \ mod ->
 250      getUniqueDs                        `thenDs` \ uniq ->
 251      getSrcLocDs                        `thenDs` \ src_loc ->
 252      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 253      let
 254         wrapper_args | isDyn      = stbl_ptr:fe_args
 255                      | otherwise  = fe_args
 256
 257         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 258                         | otherwise  = fe_arg_tys
 259
 260         helper_ty =  mkForAllTys tvs $
 261                      mkFunTys wrapper_arg_tys io_res_ty
 262
 263         f_helper_glob = mkId helper_name helper_ty
 264                                 (vanillaIdInfo `setFlavourInfo` ExportedId)
 265                       where
 266                         name                = idName fn_id
 267                         mod
 268                          | isLocalName name = mod_name
 269                          | otherwise        = nameModule name
 270
 271                         occ                 = mkForeignExportOcc (nameOccName name)
 272                         helper_name         = mkGlobalName uniq mod occ src_loc
 273
 274         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 275         the_body = mkLams (tvs ++ wrapper_args) the_app
 276         c_nm     = extNameStatic ext_name
 277
 278         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 279                                       c_nm f_helper_glob
 280                                       wrapper_arg_tys res_ty cconv isDyn
 281      in
 282      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 283
 284   where
 285    (tvs,sans_foralls)                   = splitForAllTys ty
 286    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 287
 288    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 289    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 290
 291    fe_arg_tys | isDyn     = tail fe_arg_tys'
 292               | otherwise = fe_arg_tys'
 293
 294    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 295                | otherwise = error "stbl_ptr_ty"
 296 \end{code}
 297
 298 @foreign export dynamic@ lets you dress up Haskell IO actions
 299 of some fixed type behind an externally callable interface (i.e.,
 300 as a C function pointer). Useful for callbacks and stuff.
 301
 302 \begin{verbatim}
 303 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 304
 305 -- Haskell-visible constructor, which is generated from the above:
 306 -- SUP: No check for NULL from createAdjustor anymore???
 307
 308 f :: (Addr -> Int -> IO Int) -> IO Addr
 309 f cback =
 310    bindIO (newStablePtr cback)
 311           (\StablePtr sp# -> IO (\s1# ->
 312               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 313                  (# s2#, a# #) -> (# s2#, A# a# #)))
 314
 315 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 316 -- `special' foreign export that invokes the closure pointed to by the
 317 -- first argument.
 318 \end{verbatim}
 319
 320 \begin{code}
 321 dsFExportDynamic :: Id
 322                  -> Type                -- Type of foreign export.
 323                  -> Module
 324                  -> ExtName
 325                  -> CallConv
 326                  -> DsM (Id, [Binding], SDoc, SDoc)
 327 dsFExportDynamic i ty mod_name ext_name cconv =
 328      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 329      let
 330         -- hack: need to get at the name of the C stub we're about to generate.
 331        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 332        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 333      in
 334      dsFExport  i export_ty mod_name fe_ext_name cconv True
 335         `thenDs` \ (feb, fe, h_code, c_code) ->
 336      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 337      dsLookupGlobalValue newStablePtrName       `thenDs` \ newStablePtrId ->
 338      let
 339         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 340      in
 341      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 342      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 343      let
 344       stbl_app cont ret_ty
 345         = mkApps (Var bindIOId)
 346                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 347                  , Type ret_ty
 348                  , mk_stbl_ptr_app
 349                  , cont
 350                  ]
 351
 352        {-
 353         The arguments to the external function which will
 354         create a little bit of (template) code on the fly
 355         for allowing the (stable pointed) Haskell closure
 356         to be entered using an external calling convention
 357         (stdcall, ccall).
 358        -}
 359       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 360                       , Var stbl_value
 361                       , mkLit (MachLabel (_PK_ fe_nm))
 362                       ]
 363         -- name of external entry point providing these services.
 364         -- (probably in the RTS.)
 365       adjustor      = SLIT("createAdjustor")
 366      in
 367      dsCCall adjustor adj_args False False io_res_ty `thenDs` \ ccall_adj ->
 368      let ccall_adj_ty = exprType ccall_adj
 369          ccall_io_adj = mkLams [stbl_value]                  $
 370                         Note (Coerce io_res_ty ccall_adj_ty)
 371                              ccall_adj
 372      in
 373      let io_app = mkLams tvs     $
 374                   mkLams [cback] $
 375                   stbl_app ccall_io_adj res_ty
 376          fed = (i `setInlinePragma` neverInlinePrag, io_app)
 377                 -- Never inline the f.e.d. function, because the litlit
 378                 -- might not be in scope in other modules.
 379      in
 380      returnDs (feb, [fed, fe], h_code, c_code)
 381
 382  where
 383   (tvs,sans_foralls)               = splitForAllTys ty
 384   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 385
 386   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 387
 388   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 389
 390   ioAddrTy :: Type      -- IO Addr
 391   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 392
 393 toCName :: Id -> String
 394 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 395 \end{code}
 396
 397 %*
 398 %
 399 \subsection{Generating @foreign export@ stubs}
 400 %
 401 %*
 402
 403 For each @foreign export@ function, a C stub function is generated.
 404 The C stub constructs the application of the exported Haskell function
 405 using the hugs/ghc rts invocation API.
 406
 407 \begin{code}
 408 fexportEntry :: String
 409              -> FAST_STRING
 410              -> Id
 411              -> [Type]
 412              -> Type
 413              -> CallConv
 414              -> Bool
 415              -> (SDoc, SDoc)
 416 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 417  where
 418    -- name of the (Haskell) helper function generated by the desugarer.
 419   h_nm      = ppr helper <> text "_closure"
 420    -- prototype for the exported function.
 421   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 422
 423   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 424               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 425
 426   c_bits =
 427     externDecl $$
 428     fun_proto  $$
 429     vcat
 430      [ lbrace
 431      ,   text "SchedulerStatus rc;"
 432      ,   declareResult
 433           -- create the application + perform it.
 434      ,   text "rc=rts_evalIO" <>
 435                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 436      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 437                                                 <> comma <> text "rc") <> semi
 438      ,   text "return" <> return_what <> semi
 439      , rbrace
 440      ]
 441
 442   appArg acc (a,c_a) =
 443      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 444
 445   cParamTypes  = map showStgType real_args
 446
 447   res_ty_is_unit = res_ty == unitTy
 448
 449   cResType | res_ty_is_unit = text "void"
 450            | otherwise      = showStgType res_ty
 451
 452   pprCconv
 453    | cc == cCallConv = empty
 454    | otherwise       = pprCallConv cc
 455
 456   declareResult  = text "HaskellObj ret;"
 457
 458   externDecl     = mkExtern (text "HaskellObj") h_nm
 459
 460   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 461
 462   return_what | res_ty_is_unit = empty
 463               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 464
 465   c_args = mkCArgNames 0 args
 466
 467   {-
 468    If we're generating an entry point for a 'foreign export ccall dynamic',
 469    then we receive the return address of the C function that wants to
 470    invoke a Haskell function as any other C function, as second arg.
 471    This arg is unused within the body of the generated C stub, but
 472    needed by the Adjustor.c code to get the stack cleanup right.
 473   -}
 474   (proto_args, real_args)
 475     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 476                                 , head args : addrTy : tail args)
 477     | otherwise = (mkCArgNames 0 args, args)
 478
 479 mkCArgNames :: Int -> [a] -> [SDoc]
 480 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 481
 482 mkHObj :: Type -> SDoc
 483 mkHObj t = text "rts_mk" <> text (showFFIType t)
 484
 485 unpackHObj :: Type -> SDoc
 486 unpackHObj t = text "rts_get" <> text (showFFIType t)
 487
 488 showStgType :: Type -> SDoc
 489 showStgType t = text "Hs" <> text (showFFIType t)
 490
 491 showFFIType :: Type -> String
 492 showFFIType t = getOccString (getName tc)
 493  where
 494   tc = case splitTyConApp_maybe (repType t) of
 495             Just (tc,_) -> tc
 496             Nothing     -> pprPanic "showFFIType" (ppr t)
 497 \end{code}