ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ForeignDecl(..), ForeignExport(..),
  19                           ForeignImport(..), CImportSpec(..) )
  20 import TcHsSyn          ( TypecheckedForeignDecl )
  21 import CoreUtils        ( exprType, mkInlineMe )
  22 import Id               ( Id, idType, idName, mkVanillaGlobal, mkSysLocal,
  23                           setInlinePragma )
  24 import IdInfo           ( vanillaIdInfo )
  25 import Literal          ( Literal(..) )
  26 import Module           ( Module, moduleUserString )
  27 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  28                           mkForeignExportOcc, isLocalName,
  29                           NamedThing(..),
  30                         )
  31 import Type             ( repType, eqType )
  32 import TcType           ( Type, mkFunTys, mkForAllTys, mkTyConApp,
  33                           mkFunTy, applyTy,
  34                           tcSplitForAllTys, tcSplitFunTys, tcTyConAppArgs,
  35                           tcSplitTyConApp_maybe, tcSplitAppTy,
  36                           tcFunResultTy
  37                         )
  38
  39 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  40                           Safety(..), playSafe,
  41                           CExportSpec(..),
  42                           CCallConv(..), ccallConvToInt,
  43                           ccallConvAttribute
  44                         )
  45 import CStrings         ( CLabelString )
  46 import TysWiredIn       ( addrTy, unitTy, stablePtrTyCon )
  47 import TysPrim          ( addrPrimTy )
  48 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  49                           bindIOName, returnIOName
  50                         )
  51 import BasicTypes       ( Activation( NeverActive ) )
  52 import ErrUtils         ( addShortWarnLocLine )
  53 import Outputable
  54 import Maybe            ( fromJust )
  55 \end{code}
  56
  57 Desugaring of @foreign@ declarations is naturally split up into
  58 parts, an @import@ and an @export@  part. A @foreign import@
  59 declaration
  60 \begin{verbatim}
  61   foreign import cc nm f :: prim_args -> IO prim_res
  62 \end{verbatim}
  63 is the same as
  64 \begin{verbatim}
  65   f :: prim_args -> IO prim_res
  66   f a1 ... an = _ccall_ nm cc a1 ... an
  67 \end{verbatim}
  68 so we reuse the desugaring code in @DsCCall@ to deal with these.
  69
  70 \begin{code}
  71 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  72                                 -- the occurrence analyser will sort it all out
  73
  74 dsForeigns :: Module
  75            -> [TypecheckedForeignDecl]
  76            -> DsM ( [Id]                -- Foreign-exported binders;
  77                                         -- we have to generate code to register these
  78                   , [Binding]
  79                   , SDoc              -- Header file prototypes for
  80                                       -- "foreign exported" functions.
  81                   , SDoc              -- C stubs to use when calling
  82                                       -- "foreign exported" functions.
  83                   , [FAST_STRING]     -- headers that need to be included
  84                                       -- into C code generated for this module
  85                   )
  86 dsForeigns mod_name fos
  87   = foldlDs combine ([], [], empty, empty, []) fos
  88  where
  89   combine (acc_feb, acc_f, acc_h, acc_c, acc_header)
  90           (ForeignImport id _ spec depr loc)
  91     = dsFImport mod_name id spec                   `thenDs` \(bs, h, c, hd) ->
  92       warnDepr depr loc                            `thenDs` \_              ->
  93       returnDs (acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c, hd ++ acc_header)
  94
  95   combine (acc_feb, acc_f, acc_h, acc_c, acc_header)
  96           (ForeignExport id _ (CExport (CExportStatic ext_nm cconv)) depr loc)
  97     = dsFExport mod_name id (idType id)
  98                 ext_nm cconv False                 `thenDs` \(h, c) ->
  99       warnDepr depr loc                            `thenDs` \_              ->
 100       returnDs (acc_feb, acc_f, h $$ acc_h, c $$ acc_c, acc_header)
 101
 102   warnDepr False _   = returnDs ()
 103   warnDepr True  loc = dsWarn (addShortWarnLocLine loc msg)
 104    where
 105     msg = ptext SLIT("foreign declaration uses deprecated non-standard syntax")
 106 \end{code}
 107
 108
 109 %************************************************************************
 110 %*                                                                      *
 111 \subsection{Foreign import}
 112 %*                                                                      *
 113 %************************************************************************
 114
 115 Desugaring foreign imports is just the matter of creating a binding
 116 that on its RHS unboxes its arguments, performs the external call
 117 (using the @CCallOp@ primop), before boxing the result up and returning it.
 118
 119 However, we create a worker/wrapper pair, thus:
 120
 121         foreign import f :: Int -> IO Int
 122 ==>
 123         f x = IO ( \s -> case x of { I# x# ->
 124                          case fw s x# of { (# s1, y# #) ->
 125                          (# s1, I# y# #)}})
 126
 127         fw s x# = ccall f s x#
 128
 129 The strictness/CPR analyser won't do this automatically because it doesn't look
 130 inside returned tuples; but inlining this wrapper is a Really Good Idea
 131 because it exposes the boxing to the call site.
 132
 133 \begin{code}
 134 dsFImport :: Module
 135           -> Id
 136           -> ForeignImport
 137           -> DsM ([Binding], SDoc, SDoc, [FAST_STRING])
 138 dsFImport modName id (CImport cconv safety header lib spec)
 139   = dsCImport modName id spec cconv safety        `thenDs` \(ids, h, c) ->
 140     returnDs (ids, h, c, if _NULL_ header then [] else [header])
 141   -- FIXME: the `lib' field is needed for .NET ILX generation when invoking
 142   --        routines that are external to the .NET runtime, but GHC doesn't
 143   --        support such calls yet; if `_NULL_ lib', the value was not given
 144 dsFImport modName id (DNImport spec)
 145   = dsFCall modName id (DNCall spec)              `thenDs` \(ids, h, c) ->
 146     returnDs (ids, h, c, [])
 147
 148 dsCImport :: Module
 149           -> Id
 150           -> CImportSpec
 151           -> CCallConv
 152           -> Safety
 153           -> DsM ([Binding], SDoc, SDoc)
 154 dsCImport modName id (CLabel cid)       _     _
 155  = ASSERT(fromJust resTy `eqType` addrPrimTy)    -- typechecker ensures this
 156    returnDs ([(id, rhs)], empty, empty)
 157  where
 158    (resTy, foRhs) = resultWrapper (idType id)
 159    rhs            = foRhs (mkLit (MachLabel cid))
 160 dsCImport modName id (CFunction target) cconv safety
 161   = dsFCall modName id (CCall (CCallSpec target cconv safety))
 162 dsCImport modName id CWrapper           cconv _
 163   = dsFExportDynamic modName id cconv
 164 \end{code}
 165
 166
 167 %************************************************************************
 168 %*                                                                      *
 169 \subsection{Foreign calls}
 170 %*                                                                      *
 171 %************************************************************************
 172
 173 \begin{code}
 174 dsFCall mod_Name fn_id fcall
 175   = let
 176         ty                   = idType fn_id
 177         (tvs, fun_ty)        = tcSplitForAllTys ty
 178         (arg_tys, io_res_ty) = tcSplitFunTys fun_ty
 179                 -- Must use tcSplit* functions because we want to
 180                 -- see that (IO t) in the corner
 181     in
 182     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 183     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 184
 185     let
 186         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 187
 188         -- These are the ids we pass to boxResult, which are used to decide
 189         -- whether to touch# an argument after the call (used to keep
 190         -- ForeignObj#s live across a 'safe' foreign import).
 191         maybe_arg_ids | unsafe_call fcall = work_arg_ids
 192                       | otherwise         = []
 193     in
 194     boxResult maybe_arg_ids io_res_ty           `thenDs` \ (ccall_result_ty, res_wrapper) ->
 195
 196     getUniqueDs                                 `thenDs` \ ccall_uniq ->
 197     getUniqueDs                                 `thenDs` \ work_uniq ->
 198     let
 199         -- Build the worker
 200         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 201         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 202         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 203         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 204
 205         -- Build the wrapper
 206         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 207         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 208         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 209     in
 210     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 211
 212 unsafe_call (CCall (CCallSpec _ _ safety)) = playSafe safety
 213 unsafe_call (DNCall _)                     = False
 214 \end{code}
 215
 216
 217 %************************************************************************
 218 %*                                                                      *
 219 \subsection{Foreign export}
 220 %*                                                                      *
 221 %************************************************************************
 222
 223 The function that does most of the work for `@foreign export@' declarations.
 224 (see below for the boilerplate code a `@foreign export@' declaration expands
 225  into.)
 226
 227 For each `@foreign export foo@' in a module M we generate:
 228 \begin{itemize}
 229 \item a C function `@foo@', which calls
 230 \item a Haskell stub `@M.$ffoo@', which calls
 231 \end{itemize}
 232 the user-written Haskell function `@M.foo@'.
 233
 234 \begin{code}
 235 dsFExport :: Module
 236           -> Id                 -- Either the exported Id,
 237                                 -- or the foreign-export-dynamic constructor
 238           -> Type               -- The type of the thing callable from C
 239           -> CLabelString       -- The name to export to C land
 240           -> CCallConv
 241           -> Bool               -- True => foreign export dynamic
 242                                 --         so invoke IO action that's hanging off
 243                                 --         the first argument's stable pointer
 244           -> DsM ( SDoc         -- contents of Module_stub.h
 245                  , SDoc         -- contents of Module_stub.c
 246                  )
 247
 248 dsFExport mod_name fn_id ty ext_name cconv isDyn
 249    =
 250      let
 251         (tvs,sans_foralls)              = tcSplitForAllTys ty
 252         (fe_arg_tys', orig_res_ty)      = tcSplitFunTys sans_foralls
 253         -- We must use tcSplits here, because we want to see
 254         -- the (IO t) in the corner of the type!
 255         fe_arg_tys | isDyn     = tail fe_arg_tys'
 256                    | otherwise = fe_arg_tys'
 257      in
 258         -- Look at the result type of the exported function, orig_res_ty
 259         -- If it's IO t, return         (t, True)
 260         -- If it's plain t, return      (t, False)
 261      (case tcSplitTyConApp_maybe orig_res_ty of
 262         -- We must use tcSplit here so that we see the (IO t) in
 263         -- the type.  [IO t is transparent to plain splitTyConApp.]
 264
 265         Just (ioTyCon, [res_ty])
 266               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 267                  -- The function already returns IO t
 268                  returnDs (res_ty, True)
 269
 270         other -> -- The function returns t
 271                  returnDs (orig_res_ty, False)
 272      )
 273                                         `thenDs` \ (res_ty,             -- t
 274                                                     is_IO_res_ty) ->    -- Bool
 275      getModuleDs
 276                                         `thenDs` \ mod ->
 277      let
 278         (h_stub, c_stub)
 279            = mkFExportCBits (moduleUserString mod) ext_name
 280                             (if isDyn then Nothing else Just fn_id)
 281                             fe_arg_tys res_ty is_IO_res_ty cconv
 282      in
 283      returnDs (h_stub, c_stub)
 284 \end{code}
 285
 286 @foreign export dynamic@ lets you dress up Haskell IO actions
 287 of some fixed type behind an externally callable interface (i.e.,
 288 as a C function pointer). Useful for callbacks and stuff.
 289
 290 \begin{verbatim}
 291 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 292
 293 -- Haskell-visible constructor, which is generated from the above:
 294 -- SUP: No check for NULL from createAdjustor anymore???
 295
 296 f :: (Addr -> Int -> IO Int) -> IO Addr
 297 f cback =
 298    bindIO (newStablePtr cback)
 299           (\StablePtr sp# -> IO (\s1# ->
 300               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 301                  (# s2#, a# #) -> (# s2#, A# a# #)))
 302
 303 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 304 -- `special' foreign export that invokes the closure pointed to by the
 305 -- first argument.
 306 \end{verbatim}
 307
 308 \begin{code}
 309 dsFExportDynamic :: Module
 310                  -> Id
 311                  -> CCallConv
 312                  -> DsM ([Binding], SDoc, SDoc)
 313 dsFExportDynamic mod_name id cconv
 314   =  newSysLocalDs ty                                    `thenDs` \ fe_id ->
 315      let
 316         -- hack: need to get at the name of the C stub we're about to generate.
 317        fe_nm       = _PK_ (moduleUserString mod_name ++ "_" ++ toCName fe_id)
 318      in
 319      dsFExport mod_name id export_ty fe_nm cconv True   `thenDs` \ (h_code, c_code) ->
 320      newSysLocalDs arg_ty                               `thenDs` \ cback ->
 321      dsLookupGlobalValue newStablePtrName               `thenDs` \ newStablePtrId ->
 322      let
 323         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 324      in
 325      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 326      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 327      let
 328       stbl_app cont ret_ty
 329         = mkApps (Var bindIOId)
 330                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 331                  , Type ret_ty
 332                  , mk_stbl_ptr_app
 333                  , cont
 334                  ]
 335
 336        {-
 337         The arguments to the external function which will
 338         create a little bit of (template) code on the fly
 339         for allowing the (stable pointed) Haskell closure
 340         to be entered using an external calling convention
 341         (stdcall, ccall).
 342        -}
 343       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 344                       , Var stbl_value
 345                       , mkLit (MachLabel fe_nm)
 346                       ]
 347         -- name of external entry point providing these services.
 348         -- (probably in the RTS.)
 349       adjustor      = SLIT("createAdjustor")
 350      in
 351      dsCCall adjustor adj_args PlayRisky False io_res_ty        `thenDs` \ ccall_adj ->
 352         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 353      let ccall_adj_ty = exprType ccall_adj
 354          ccall_io_adj = mkLams [stbl_value]                  $
 355                         Note (Coerce io_res_ty ccall_adj_ty)
 356                              ccall_adj
 357          io_app = mkLams tvs     $
 358                   mkLams [cback] $
 359                   stbl_app ccall_io_adj res_ty
 360          fed = (id `setInlinePragma` NeverActive, io_app)
 361                 -- Never inline the f.e.d. function, because the litlit
 362                 -- might not be in scope in other modules.
 363      in
 364      returnDs ([fed], h_code, c_code)
 365
 366  where
 367   ty                    = idType id
 368   (tvs,sans_foralls)    = tcSplitForAllTys ty
 369   ([arg_ty], io_res_ty) = tcSplitFunTys sans_foralls
 370   [res_ty]              = tcTyConAppArgs io_res_ty
 371         -- Must use tcSplit* to see the (IO t), which is a newtype
 372   export_ty             = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 373
 374 toCName :: Id -> String
 375 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 376 \end{code}
 377
 378 %*
 379 %
 380 \subsection{Generating @foreign export@ stubs}
 381 %
 382 %*
 383
 384 For each @foreign export@ function, a C stub function is generated.
 385 The C stub constructs the application of the exported Haskell function
 386 using the hugs/ghc rts invocation API.
 387
 388 \begin{code}
 389 mkFExportCBits :: String
 390                -> FAST_STRING
 391                -> Maybe Id      -- Just==static, Nothing==dynamic
 392                -> [Type]
 393                -> Type
 394                -> Bool          -- True <=> returns an IO type
 395                -> CCallConv
 396                -> (SDoc, SDoc)
 397 mkFExportCBits mod_nm c_nm maybe_target arg_htys res_hty is_IO_res_ty cc
 398  = (header_bits, c_bits)
 399  where
 400   -- Create up types and names for the real args
 401   arg_cnames, arg_ctys :: [SDoc]
 402   arg_cnames = mkCArgNames 1 arg_htys
 403   arg_ctys   = map showStgType arg_htys
 404
 405   -- and also for auxiliary ones; the stable ptr in the dynamic case, and
 406   -- a slot for the dummy return address in the dynamic + ccall case
 407   extra_cnames_and_ctys
 408      = case maybe_target of
 409           Nothing -> [(text "the_stableptr", text "StgStablePtr")]
 410           other   -> []
 411        ++
 412        case (maybe_target, cc) of
 413           (Nothing, CCallConv) -> [(text "original_return_addr", text "void*")]
 414           other                -> []
 415
 416   all_cnames_and_ctys :: [(SDoc, SDoc)]
 417   all_cnames_and_ctys
 418      = extra_cnames_and_ctys ++ zip arg_cnames arg_ctys
 419
 420   -- stuff to do with the return type of the C function
 421   res_hty_is_unit = res_hty `eqType` unitTy     -- Look through any newtypes
 422
 423   cResType | res_hty_is_unit = text "void"
 424            | otherwise       = showStgType res_hty
 425
 426   -- Now we can cook up the prototype for the exported function.
 427   pprCconv = case cc of
 428                 CCallConv   -> empty
 429                 StdCallConv -> text (ccallConvAttribute cc)
 430
 431   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 432
 433   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 434               parens (hsep (punctuate comma (map (\(nm,ty) -> ty <+> nm)
 435                                                  all_cnames_and_ctys)))
 436
 437   -- the target which will form the root of what we ask rts_evalIO to run
 438   the_cfun
 439      = case maybe_target of
 440           Nothing    -> text "(StgClosure*)deRefStablePtr(the_stableptr)"
 441           Just hs_fn -> ppr hs_fn <> text "_closure"
 442
 443   -- the expression we give to rts_evalIO
 444   expr_to_run
 445      = foldl appArg the_cfun (zip arg_cnames arg_htys)
 446        where
 447           appArg acc (arg_cname, arg_hty)
 448              = text "rts_apply"
 449                <> parens (acc <> comma <> mkHObj arg_hty <> parens arg_cname)
 450
 451   -- various other bits for inside the fn
 452   declareResult = text "HaskellObj ret;"
 453
 454   return_what | res_hty_is_unit = empty
 455               | otherwise       = parens (unpackHObj res_hty <> parens (text "ret"))
 456
 457   -- an extern decl for the fn being called
 458   extern_decl
 459      = case maybe_target of
 460           Nothing -> empty
 461           Just hs_fn -> text "extern StgClosure* " <> ppr hs_fn <> text "_closure" <> semi
 462
 463   -- finally, the whole darn thing
 464   c_bits =
 465     space $$
 466     extern_decl $$
 467     fun_proto  $$
 468     vcat
 469      [ lbrace
 470      ,   text "SchedulerStatus rc;"
 471      ,   declareResult
 472           -- create the application + perform it.
 473      ,   text (if is_IO_res_ty then "rc=rts_evalIO" else "rc=rts_eval")
 474          <> parens (expr_to_run <+> comma <> text "&ret")
 475          <> semi
 476      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 477                                                 <> comma <> text "rc") <> semi
 478      ,   text "return" <> return_what <> semi
 479      , rbrace
 480      ]
 481
 482
 483 mkCArgNames :: Int -> [a] -> [SDoc]
 484 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 485
 486 mkHObj :: Type -> SDoc
 487 mkHObj t = text "rts_mk" <> text (showFFIType t)
 488
 489 unpackHObj :: Type -> SDoc
 490 unpackHObj t = text "rts_get" <> text (showFFIType t)
 491
 492 showStgType :: Type -> SDoc
 493 showStgType t = text "Hs" <> text (showFFIType t)
 494
 495 showFFIType :: Type -> String
 496 showFFIType t = getOccString (getName tc)
 497  where
 498   tc = case tcSplitTyConApp_maybe (repType t) of
 499             Just (tc,_) -> tc
 500             Nothing     -> pprPanic "showFFIType" (ppr t)
 501 \end{code}