ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkFCall, boxResult, unboxArg, resultWrapper )
  16 import DsMonad
  17
  18 import HsSyn            ( ForeignDecl(..), FoExport(..), FoImport(..)  )
  19 import TcHsSyn          ( TypecheckedForeignDecl )
  20 import CoreUtils        ( exprType, mkInlineMe )
  21 import Id               ( Id, idType, idName, mkVanillaGlobal, mkSysLocal,
  22                           setInlinePragma )
  23 import IdInfo           ( neverInlinePrag, vanillaIdInfo )
  24 import Literal          ( Literal(..) )
  25 import Module           ( Module, moduleUserString )
  26 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  27                           mkForeignExportOcc, isLocalName,
  28                           NamedThing(..),
  29                         )
  30 import Type             ( repType, splitTyConApp_maybe,
  31                           splitFunTys, splitForAllTys,
  32                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  33                           mkFunTy, splitAppTy, applyTy, funResultTy
  34                         )
  35 import ForeignCall      ( ForeignCall(..), CCallSpec(..),
  36                           Safety(..), playSafe,
  37                           CExportSpec(..),
  38                           CCallConv(..), ccallConvToInt
  39                         )
  40 import CStrings         ( CLabelString )
  41 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon )
  42 import TysPrim          ( addrPrimTy )
  43 import PrelNames        ( hasKey, ioTyConKey, deRefStablePtrName, newStablePtrName,
  44                           bindIOName, returnIOName
  45                         )
  46 import Outputable
  47
  48 import Maybe            ( fromJust )
  49 \end{code}
  50
  51 Desugaring of @foreign@ declarations is naturally split up into
  52 parts, an @import@ and an @export@  part. A @foreign import@
  53 declaration
  54 \begin{verbatim}
  55   foreign import cc nm f :: prim_args -> IO prim_res
  56 \end{verbatim}
  57 is the same as
  58 \begin{verbatim}
  59   f :: prim_args -> IO prim_res
  60   f a1 ... an = _ccall_ nm cc a1 ... an
  61 \end{verbatim}
  62 so we reuse the desugaring code in @DsCCall@ to deal with these.
  63
  64 \begin{code}
  65 type Binding = (Id, CoreExpr)   -- No rec/nonrec structure;
  66                                 -- the occurrence analyser will sort it all out
  67
  68 dsForeigns :: Module
  69            -> [TypecheckedForeignDecl]
  70            -> DsM ( [Id]                -- Foreign-exported binders;
  71                                         -- we have to generate code to register these
  72                   , [Binding]
  73                   , SDoc              -- Header file prototypes for
  74                                       -- "foreign exported" functions.
  75                   , SDoc              -- C stubs to use when calling
  76                                       -- "foreign exported" functions.
  77                   )
  78 dsForeigns mod_name fos
  79   = foldlDs combine ([], [], empty, empty) fos
  80  where
  81   combine (acc_feb, acc_f, acc_h, acc_c) (ForeignImport id _ spec _)
  82     = dsFImport mod_name id spec        `thenDs` \ (bs, h, c) ->
  83       returnDs (acc_feb, bs ++ acc_f, h $$ acc_h, c $$ acc_c)
  84
  85   combine (acc_feb, acc_f, acc_h, acc_c) (ForeignExport id _ (CExport (CExportStatic ext_nm cconv)) _)
  86     = dsFExport mod_name id (idType id) ext_nm cconv False      `thenDs` \ (feb, b, h, c) ->
  87       returnDs (feb:acc_feb, b : acc_f, h $$ acc_h, c $$ acc_c)
  88 \end{code}
  89
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection{Foreign import}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 Desugaring foreign imports is just the matter of creating a binding
  98 that on its RHS unboxes its arguments, performs the external call
  99 (using the @CCallOp@ primop), before boxing the result up and returning it.
 100
 101 However, we create a worker/wrapper pair, thus:
 102
 103         foreign import f :: Int -> IO Int
 104 ==>
 105         f x = IO ( \s -> case x of { I# x# ->
 106                          case fw s x# of { (# s1, y# #) ->
 107                          (# s1, I# y# #)}})
 108
 109         fw s x# = ccall f s x#
 110
 111 The strictness/CPR analyser won't do this automatically because it doesn't look
 112 inside returned tuples; but inlining this wrapper is a Really Good Idea
 113 because it exposes the boxing to the call site.
 114
 115
 116 \begin{code}
 117 dsFImport :: Module
 118           -> Id
 119           -> FoImport
 120           -> DsM ([Binding], SDoc, SDoc)
 121 dsFImport mod_name lbl_id (LblImport ext_nm)
 122  = ASSERT(fromJust res_ty == addrPrimTy) -- typechecker ensures this
 123    returnDs ([(lbl_id, rhs)], empty, empty)
 124  where
 125    (res_ty, fo_rhs) = resultWrapper (idType lbl_id)
 126    rhs              = fo_rhs (mkLit (MachLabel ext_nm))
 127
 128 dsFImport mod_name fn_id (CImport spec)     = dsFCall mod_name fn_id (CCall spec)
 129 dsFImport mod_name fn_id (DNImport spec)    = dsFCall mod_name fn_id (DNCall spec)
 130 dsFImport mod_name fn_id (CDynImport cconv) = dsFExportDynamic mod_name fn_id cconv
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{Foreign calls}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 \begin{code}
 141 dsFCall mod_Name fn_id fcall
 142   = let
 143         ty                   = idType fn_id
 144         (tvs, fun_ty)        = splitForAllTys ty
 145         (arg_tys, io_res_ty) = splitFunTys fun_ty
 146     in
 147     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 148     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 149
 150     let
 151         work_arg_ids  = [v | Var v <- val_args] -- All guaranteed to be vars
 152
 153         -- These are the ids we pass to boxResult, which are used to decide
 154         -- whether to touch# an argument after the call (used to keep
 155         -- ForeignObj#s live across a 'safe' foreign import).
 156         maybe_arg_ids | unsafe_call fcall = work_arg_ids
 157                       | otherwise         = []
 158     in
 159     boxResult maybe_arg_ids io_res_ty           `thenDs` \ (ccall_result_ty, res_wrapper) ->
 160
 161     getUniqueDs                                 `thenDs` \ ccall_uniq ->
 162     getUniqueDs                                 `thenDs` \ work_uniq ->
 163     let
 164         -- Build the worker
 165         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 166         the_ccall_app = mkFCall ccall_uniq fcall val_args ccall_result_ty
 167         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 168         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 169
 170         -- Build the wrapper
 171         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 172         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 173         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 174     in
 175     returnDs ([(work_id, work_rhs), (fn_id, wrap_rhs)], empty, empty)
 176
 177 unsafe_call (CCall (CCallSpec _ _ safety)) = playSafe safety
 178 unsafe_call (DNCall _)                     = False
 179 \end{code}
 180
 181
 182 %************************************************************************
 183 %*                                                                      *
 184 \subsection{Foreign export}
 185 %*                                                                      *
 186 %************************************************************************
 187
 188 The function that does most of the work for `@foreign export@' declarations.
 189 (see below for the boilerplate code a `@foreign export@' declaration expands
 190  into.)
 191
 192 For each `@foreign export foo@' in a module M we generate:
 193 \begin{itemize}
 194 \item a C function `@foo@', which calls
 195 \item a Haskell stub `@M.$ffoo@', which calls
 196 \end{itemize}
 197 the user-written Haskell function `@M.foo@'.
 198
 199 \begin{code}
 200 dsFExport :: Module
 201           -> Id                 -- Either the exported Id,
 202                                 -- or the foreign-export-dynamic constructor
 203           -> Type               -- The type of the thing callable from C
 204           -> CLabelString       -- The name to export to C land
 205           -> CCallConv
 206           -> Bool               -- True => foreign export dynamic
 207                                 --         so invoke IO action that's hanging off
 208                                 --         the first argument's stable pointer
 209           -> DsM ( Id           -- The foreign-exported Id
 210                  , Binding
 211                  , SDoc
 212                  , SDoc
 213                  )
 214 dsFExport mod_name fn_id ty ext_name cconv isDyn
 215   =     -- BUILD THE returnIO WRAPPER, if necessary
 216         -- Look at the result type of the exported function, orig_res_ty
 217         -- If it's IO t, return         (\x.x,          IO t, t)
 218         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 219      (case splitTyConApp_maybe orig_res_ty of
 220         Just (ioTyCon, [res_ty])
 221               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 222                         -- The function already returns IO t
 223                  returnDs (\body -> body, orig_res_ty, res_ty)
 224
 225         other ->        -- The function returns t, so wrap the call in returnIO
 226                  dsLookupGlobalValue returnIOName       `thenDs` \ retIOId ->
 227                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 228                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 229                                 -- We don't have ioTyCon conveniently to hand
 230                            orig_res_ty)
 231
 232      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 233                             io_res_ty,          -- IO t
 234                             res_ty) ->          -- t
 235
 236
 237         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 238      (if isDyn then
 239         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 240         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 241         dsLookupGlobalValue deRefStablePtrName          `thenDs` \ deRefStablePtrId ->
 242         dsLookupGlobalValue bindIOName                  `thenDs` \ bindIOId ->
 243         let
 244          the_deref_app = mkApps (Var deRefStablePtrId)
 245                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 246
 247          stbl_app cont = mkApps (Var bindIOId)
 248                                 [ Type stbl_ptr_to_ty
 249                                 , Type res_ty
 250                                 , the_deref_app
 251                                 , mkLams [stbl_value] cont]
 252         in
 253         returnDs (stbl_value, stbl_app, stbl_ptr)
 254       else
 255         returnDs (fn_id,
 256                   \ body -> body,
 257                   panic "stbl_ptr"  -- should never be touched.
 258                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 259
 260
 261         -- BUILD THE HELPER
 262      getModuleDs                        `thenDs` \ mod ->
 263      getUniqueDs                        `thenDs` \ uniq ->
 264      getSrcLocDs                        `thenDs` \ src_loc ->
 265      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 266      let
 267         wrapper_args | isDyn      = stbl_ptr:fe_args
 268                      | otherwise  = fe_args
 269
 270         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 271                         | otherwise  = fe_arg_tys
 272
 273         helper_ty =  mkForAllTys tvs $
 274                      mkFunTys wrapper_arg_tys io_res_ty
 275
 276         f_helper_glob = mkVanillaGlobal helper_name helper_ty vanillaIdInfo
 277                       where
 278                         name                = idName fn_id
 279                         mod
 280                          | isLocalName name = mod_name
 281                          | otherwise        = nameModule name
 282
 283                         occ                 = mkForeignExportOcc (nameOccName name)
 284                         helper_name         = mkGlobalName uniq mod occ src_loc
 285
 286         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 287         the_body = mkLams (tvs ++ wrapper_args) the_app
 288
 289         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 290                                         ext_name f_helper_glob
 291                                         wrapper_arg_tys res_ty cconv isDyn
 292      in
 293      returnDs (f_helper_glob, (f_helper_glob, the_body), h_stub, c_stub)
 294
 295   where
 296    (tvs,sans_foralls)           = splitForAllTys ty
 297    (fe_arg_tys', orig_res_ty)   = splitFunTys sans_foralls
 298
 299    (_, stbl_ptr_ty')            = splitForAllTys stbl_ptr_ty
 300    (_, stbl_ptr_to_ty)          = splitAppTy stbl_ptr_ty'
 301
 302    fe_arg_tys | isDyn     = tail fe_arg_tys'
 303               | otherwise = fe_arg_tys'
 304
 305    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 306                | otherwise = error "stbl_ptr_ty"
 307 \end{code}
 308
 309 @foreign export dynamic@ lets you dress up Haskell IO actions
 310 of some fixed type behind an externally callable interface (i.e.,
 311 as a C function pointer). Useful for callbacks and stuff.
 312
 313 \begin{verbatim}
 314 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 315
 316 -- Haskell-visible constructor, which is generated from the above:
 317 -- SUP: No check for NULL from createAdjustor anymore???
 318
 319 f :: (Addr -> Int -> IO Int) -> IO Addr
 320 f cback =
 321    bindIO (newStablePtr cback)
 322           (\StablePtr sp# -> IO (\s1# ->
 323               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 324                  (# s2#, a# #) -> (# s2#, A# a# #)))
 325
 326 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 327 -- `special' foreign export that invokes the closure pointed to by the
 328 -- first argument.
 329 \end{verbatim}
 330
 331 \begin{code}
 332 dsFExportDynamic :: Module
 333                  -> Id
 334                  -> CCallConv
 335                  -> DsM ([Binding], SDoc, SDoc)
 336 dsFExportDynamic mod_name id cconv
 337   =  newSysLocalDs ty                                    `thenDs` \ fe_id ->
 338      let
 339         -- hack: need to get at the name of the C stub we're about to generate.
 340        fe_nm       = _PK_ (moduleUserString mod_name ++ "_" ++ toCName fe_id)
 341      in
 342      dsFExport mod_name id export_ty fe_nm cconv True   `thenDs` \ (feb, fe, h_code, c_code) ->
 343      newSysLocalDs arg_ty                               `thenDs` \ cback ->
 344      dsLookupGlobalValue newStablePtrName               `thenDs` \ newStablePtrId ->
 345      let
 346         mk_stbl_ptr_app    = mkApps (Var newStablePtrId) [ Type arg_ty, Var cback ]
 347      in
 348      dsLookupGlobalValue bindIOName                     `thenDs` \ bindIOId ->
 349      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 350      let
 351       stbl_app cont ret_ty
 352         = mkApps (Var bindIOId)
 353                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 354                  , Type ret_ty
 355                  , mk_stbl_ptr_app
 356                  , cont
 357                  ]
 358
 359        {-
 360         The arguments to the external function which will
 361         create a little bit of (template) code on the fly
 362         for allowing the (stable pointed) Haskell closure
 363         to be entered using an external calling convention
 364         (stdcall, ccall).
 365        -}
 366       adj_args      = [ mkIntLitInt (ccallConvToInt cconv)
 367                       , Var stbl_value
 368                       , mkLit (MachLabel fe_nm)
 369                       ]
 370         -- name of external entry point providing these services.
 371         -- (probably in the RTS.)
 372       adjustor      = SLIT("createAdjustor")
 373      in
 374      dsCCall adjustor adj_args PlayRisky False io_res_ty        `thenDs` \ ccall_adj ->
 375         -- PlayRisky: the adjustor doesn't allocate in the Haskell heap or do a callback
 376      let ccall_adj_ty = exprType ccall_adj
 377          ccall_io_adj = mkLams [stbl_value]                  $
 378                         Note (Coerce io_res_ty ccall_adj_ty)
 379                              ccall_adj
 380          io_app = mkLams tvs     $
 381                   mkLams [cback] $
 382                   stbl_app ccall_io_adj res_ty
 383          fed = (id `setInlinePragma` neverInlinePrag, io_app)
 384                 -- Never inline the f.e.d. function, because the litlit
 385                 -- might not be in scope in other modules.
 386      in
 387      returnDs ([fed, fe], h_code, c_code)
 388
 389  where
 390   ty                               = idType id
 391   (tvs,sans_foralls)               = splitForAllTys ty
 392   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 393   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 394   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 395
 396 toCName :: Id -> String
 397 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 398 \end{code}
 399
 400 %*
 401 %
 402 \subsection{Generating @foreign export@ stubs}
 403 %
 404 %*
 405
 406 For each @foreign export@ function, a C stub function is generated.
 407 The C stub constructs the application of the exported Haskell function
 408 using the hugs/ghc rts invocation API.
 409
 410 \begin{code}
 411 fexportEntry :: String
 412              -> FAST_STRING
 413              -> Id
 414              -> [Type]
 415              -> Type
 416              -> CCallConv
 417              -> Bool
 418              -> (SDoc, SDoc)
 419 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 420  where
 421    -- name of the (Haskell) helper function generated by the desugarer.
 422   h_nm      = ppr helper <> text "_closure"
 423    -- prototype for the exported function.
 424   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 425
 426   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 427               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 428
 429   c_bits =
 430     externDecl $$
 431     fun_proto  $$
 432     vcat
 433      [ lbrace
 434      ,   text "SchedulerStatus rc;"
 435      ,   declareResult
 436           -- create the application + perform it.
 437      ,   text "rc=rts_evalIO" <>
 438                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 439      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 440                                                 <> comma <> text "rc") <> semi
 441      ,   text "return" <> return_what <> semi
 442      , rbrace
 443      ]
 444
 445   appArg acc (a,c_a) =
 446      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 447
 448   cParamTypes  = map showStgType real_args
 449
 450   res_ty_is_unit = res_ty == unitTy
 451
 452   cResType | res_ty_is_unit = text "void"
 453            | otherwise      = showStgType res_ty
 454
 455   pprCconv = case cc of
 456                 CCallConv   -> empty
 457                 StdCallConv -> ppr cc
 458
 459   declareResult  = text "HaskellObj ret;"
 460
 461   externDecl     = mkExtern (text "HaskellObj") h_nm
 462
 463   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 464
 465   return_what | res_ty_is_unit = empty
 466               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 467
 468   c_args = mkCArgNames 0 args
 469
 470   {-
 471    If we're generating an entry point for a 'foreign export ccall dynamic',
 472    then we receive the return address of the C function that wants to
 473    invoke a Haskell function as any other C function, as second arg.
 474    This arg is unused within the body of the generated C stub, but
 475    needed by the Adjustor.c code to get the stack cleanup right.
 476   -}
 477   (proto_args, real_args)
 478     = case cc of
 479         CCallConv | isDyn -> ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 480                              , head args : addrTy : tail args)
 481         other             -> (mkCArgNames 0 args, args)
 482
 483 mkCArgNames :: Int -> [a] -> [SDoc]
 484 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 485
 486 mkHObj :: Type -> SDoc
 487 mkHObj t = text "rts_mk" <> text (showFFIType t)
 488
 489 unpackHObj :: Type -> SDoc
 490 unpackHObj t = text "rts_get" <> text (showFFIType t)
 491
 492 showStgType :: Type -> SDoc
 493 showStgType t = text "Hs" <> text (showFFIType t)
 494
 495 showFFIType :: Type -> String
 496 showFFIType t = getOccString (getName tc)
 497  where
 498   tc = case splitTyConApp_maybe (repType t) of
 499             Just (tc,_) -> tc
 500             Nothing     -> pprPanic "showFFIType" (ppr t)
 501 \end{code}